1: # The LearningOnline Network
2: # Cookie Based Access Handler
3: #
4: # $Id: lonacc.pm,v 1.164 2016/08/16 20:17:49 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: =head1 NAME
31:
32: Apache::lonacc - Cookie Based Access Handler
33:
34: =head1 SYNOPSIS
35:
36: Invoked (for various locations) by /etc/httpd/conf/srm.conf:
37:
38: PerlAccessHandler Apache::lonacc
39:
40: =head1 INTRODUCTION
41:
42: This module enables cookie based authentication and is used
43: to control access for many different LON-CAPA URIs.
44:
45: Whenever the client sends the cookie back to the server,
46: this cookie is handled by either lonacc.pm or loncacc.pm
47: (see srm.conf for what is invoked when). If
48: the cookie is missing or invalid, the user is re-challenged
49: for login information.
50:
51: This is part of the LearningOnline Network with CAPA project
52: described at http://www.lon-capa.org.
53:
54: =head1 HANDLER SUBROUTINE
55:
56: This routine is called by Apache and mod_perl.
57:
58: =over 4
59:
60: =item *
61:
62: transfer profile into environment
63:
64: =item *
65:
66: load POST parameters
67:
68: =item *
69:
70: check access
71:
72: =item *
73:
74: if allowed, get symb, log, generate course statistics if applicable
75:
76: =item *
77:
78: otherwise return error
79:
80: =item *
81:
82: see if public resource
83:
84: =item *
85:
86: store attempted access
87:
88: =back
89:
90: =head1 NOTABLE SUBROUTINES
91:
92: =cut
93:
94:
95: package Apache::lonacc;
96:
97: use strict;
98: use Apache::Constants qw(:common :http :methods);
99: use Apache::File;
100: use Apache::lonnet;
101: use Apache::loncommon();
102: use Apache::lonlocal;
103: use Apache::restrictedaccess();
104: use Apache::blockedaccess();
105: use Fcntl qw(:flock);
106: use LONCAPA qw(:DEFAULT :match);
107:
108: sub cleanup {
109: my ($r)=@_;
110: if (! $r->is_initial_req()) { return DECLINED; }
111: &Apache::lonnet::save_cache();
112: return OK;
113: }
114:
115: sub goodbye {
116: my ($r)=@_;
117: &Apache::lonnet::goodbye();
118: return DONE;
119: }
120:
121: ###############################################
122:
123: sub get_posted_cgi {
124: my ($r,$fields) = @_;
125:
126: my $buffer;
127: if ($r->header_in('Content-length')) {
128: $r->read($buffer,$r->header_in('Content-length'),0);
129: }
130: my $content_type = $r->header_in('Content-type');
131: if ($content_type !~ m{^multipart/form-data}) {
132: my @pairs=split(/&/,$buffer);
133: my $pair;
134: foreach $pair (@pairs) {
135: my ($name,$value) = split(/=/,$pair);
136: $value =~ tr/+/ /;
137: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
138: $name =~ tr/+/ /;
139: $name =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
140: if (ref($fields) eq 'ARRAY') {
141: next if (!grep(/^\Q$name\E$/,@{$fields}));
142: }
143: &Apache::loncommon::add_to_env("form.$name",$value);
144: }
145: } else {
146: my ($contentsep) = ($content_type =~ /boundary=\"?([^\";,]+)\"?/);
147: my @lines = split (/\n/,$buffer);
148: my $name='';
149: my $value='';
150: my $fname='';
151: my $fmime='';
152: my $i;
153: for ($i=0;$i<=$#lines;$i++) {
154: if ($lines[$i]=~/^--\Q$contentsep\E/) {
155: if ($name) {
156: chomp($value);
157: if (($r->uri eq '/adm/portfolio') &&
158: ($name eq 'uploaddoc')) {
159: if (length($value) == 1) {
160: $value=~s/[\r\n]$//;
161: }
162: } elsif ($fname =~ /\.(xls|doc|ppt)x$/i) {
163: $value=~s/[\r\n]$//;
164: }
165: if (ref($fields) eq 'ARRAY') {
166: next if (!grep(/^\Q$name\E$/,@{$fields}));
167: }
168: if ($fname) {
169: if ($env{'form.symb'} ne '') {
170: my $size = (length($value))/(1024.0 * 1024.0);
171: if (&upload_size_allowed($name,$size,$fname) eq 'ok') {
172: $env{"form.$name.filename"}=$fname;
173: $env{"form.$name.mimetype"}=$fmime;
174: &Apache::loncommon::add_to_env("form.$name",$value);
175: }
176: } else {
177: $env{"form.$name.filename"}=$fname;
178: $env{"form.$name.mimetype"}=$fmime;
179: &Apache::loncommon::add_to_env("form.$name",$value);
180: }
181: } else {
182: $value=~s/\s+$//s;
183: &Apache::loncommon::add_to_env("form.$name",$value);
184: }
185: }
186: if ($i<$#lines) {
187: $i++;
188: $lines[$i]=~
189: /Content\-Disposition\:\s*form\-data\;\s*name\=\"([^\"]+)\"/i;
190: $name=$1;
191: $value='';
192: if ($lines[$i]=~/filename\=\"([^\"]+)\"/i) {
193: $fname=$1;
194: if
195: ($lines[$i+1]=~/Content\-Type\:\s*([\w\-\/]+)/i) {
196: $fmime=$1;
197: $i++;
198: } else {
199: $fmime='';
200: }
201: } else {
202: $fname='';
203: $fmime='';
204: }
205: if ($i<$#lines && $lines[$i+1]=~/^Content\-Type\:\s*([\w\-\/]+)/i) {
206: # TODO: something with $1 !
207: $i++;
208: }
209: if ($i<$#lines && $lines[$i+1]=~/^Content\-transfer\-encoding\:\s*([\w\-\/]+)/i) {
210: # TODO: something with $1 !
211: $i++;
212: }
213: $i++;
214: }
215: } else {
216: $value.=$lines[$i]."\n";
217: }
218: }
219: }
220: #
221: # Digested POSTed values
222: #
223: # Remember the way this was originally done (GET or POST)
224: #
225: $env{'request.method'}=$ENV{'REQUEST_METHOD'};
226: #
227: # There may also be stuff in the query string
228: # Tell subsequent handlers that this was GET, not POST, so they can access query string.
229: # Also, unset POSTed content length to cover all tracks.
230: #
231:
232: $r->method_number(M_GET);
233:
234: $r->method('GET');
235: $r->headers_in->unset('Content-length');
236: }
237:
238: =pod
239:
240: =over
241:
242: =item upload_size_allowed()
243:
244: Perform size checks for file uploads to essayresponse items in course context.
245:
246: Add form.HWFILESIZE.$part_$id to %env with file size (MB)
247: If file exceeds maximum allowed size, add form.HWFILETOOBIG.$part_$id to %env.
248:
249: =cut
250:
251: sub upload_size_allowed {
252: my ($name,$size,$fname) = @_;
253: if ($name =~ /^HWFILE(\w+)$/) {
254: my $ident = $1;
255: my $item = 'HWFILESIZE'.$ident;
256: my $savesize = sprintf("%.6f",$size);
257: &Apache::loncommon::add_to_env("form.$item",$savesize);
258: my $maxsize= &Apache::lonnet::EXT("resource.$ident.maxfilesize");
259: if (!$maxsize) {
260: $maxsize = 10.0; # FIXME This should become a domain configuration.
261: }
262: if ($size > $maxsize) {
263: my $warn = 'HWFILETOOBIG'.$ident;
264: &Apache::loncommon::add_to_env("form.$warn",$fname);
265: return;
266: }
267: }
268: return 'ok';
269: }
270:
271: =pod
272:
273: =item sso_login()
274:
275: handle the case of the single sign on user, at this point $r->user
276: will be set and valid; now need to find the loncapa user info, and possibly
277: balance them. If $r->user() is set this means either it was either set by
278: SSO or by checkauthen.pm, if a valid cookie was found. The latter case can
279: be identified by the third arg ($usename), except when lonacc is called in
280: an internal redirect to /adm/switchserver (e.g., load-balancing following
281: successful authentication) -- no cookie set yet. For that particular case
282: simply skip the call to sso_login().
283:
284: returns OK if it was SSO and user was handled.
285: returns undef if not SSO or no means to handle the user.
286:
287: =cut
288:
289: sub sso_login {
290: my ($r,$handle,$username) = @_;
291:
292: my $lonidsdir=$r->dir_config('lonIDsDir');
293: if (($r->user eq '') || ($username ne '') || ($r->user eq 'public:public') ||
294: (defined($env{'user.name'}) && (defined($env{'user.domain'}))
295: && ($handle ne ''))) {
296: # not an SSO case or already logged in
297: return undef;
298: }
299:
300: my ($user) = ($r->user =~ m/^($match_username)$/);
301: if ($user eq '') {
302: return undef;
303: }
304:
305: my $query = $r->args;
306: my %form;
307: if ($query) {
308: my @items = ('role','symb','iptoken');
309: &Apache::loncommon::get_unprocessed_cgi($query,\@items);
310: foreach my $item (@items) {
311: if (defined($env{'form.'.$item})) {
312: $form{$item} = $env{'form.'.$item};
313: }
314: }
315: }
316:
317: my %sessiondata;
318: if ($form{'iptoken'}) {
319: %sessiondata = &Apache::lonnet::tmpget($form{'iptoken'});
320: my $delete = &Apache::lonnet::tmpdel($form{'iptoken'});
321: unless ($sessiondata{'sessionserver'}) {
322: delete($form{'iptoken'});
323: }
324: }
325:
326: my $domain = $r->dir_config('lonSSOUserDomain');
327: if ($domain eq '') {
328: $domain = $r->dir_config('lonDefDomain');
329: }
330: my $home=&Apache::lonnet::homeserver($user,$domain);
331: if ($home !~ /(con_lost|no_host|no_such_host)/) {
332: &Apache::lonnet::logthis(" SSO authorized user $user ");
333: my ($is_balancer,$otherserver,$hosthere);
334: if ($form{'iptoken'}) {
335: if (($sessiondata{'domain'} eq $domain) &&
336: ($sessiondata{'username'} eq $user)) {
337: $hosthere = 1;
338: }
339: }
340: unless ($hosthere) {
341: ($is_balancer,$otherserver) =
342: &Apache::lonnet::check_loadbalancing($user,$domain);
343: }
344:
345: if ($is_balancer) {
346: # login but immediately go to switch server to find us a new
347: # machine
348: &Apache::lonauth::success($r,$user,$domain,$home,'noredirect');
349: $env{'request.sso.login'} = 1;
350: if (defined($r->dir_config("lonSSOReloginServer"))) {
351: $env{'request.sso.reloginserver'} =
352: $r->dir_config('lonSSOReloginServer');
353: }
354: my $redirecturl = '/adm/switchserver';
355: if ($otherserver ne '') {
356: $redirecturl .= '?otherserver='.$otherserver;
357: }
358: $r->internal_redirect($redirecturl);
359: $r->set_handlers('PerlHandler'=> undef);
360: } else {
361: # need to login them in, so generate the need data that
362: # migrate expects to do login
363: my $ip = $r->get_remote_host();
364: my %info=('ip' => $ip,
365: 'domain' => $domain,
366: 'username' => $user,
367: 'server' => $r->dir_config('lonHostID'),
368: 'sso.login' => 1
369: );
370: foreach my $item ('role','symb','iptoken') {
371: if (exists($form{$item})) {
372: $info{$item} = $form{$item};
373: }
374: }
375: unless ($info{'symb'}) {
376: unless (($r->uri eq '/adm/roles') || ($r->uri eq '/adm/sso')) {
377: $info{'origurl'} = $r->uri;
378: }
379: }
380: if ($r->dir_config("ssodirecturl") == 1) {
381: $info{'origurl'} = $r->uri;
382: }
383: if (defined($r->dir_config("lonSSOReloginServer"))) {
384: $info{'sso.reloginserver'} =
385: $r->dir_config('lonSSOReloginServer');
386: }
387: my $token =
388: &Apache::lonnet::tmpput(\%info,
389: $r->dir_config('lonHostID'));
390: $env{'form.token'} = $token;
391: $r->internal_redirect('/adm/migrateuser');
392: $r->set_handlers('PerlHandler'=> undef);
393: }
394: return OK;
395: } else {
396: &Apache::lonnet::logthis(" SSO authorized unknown user $user ");
397: my @cancreate;
398: my %domconfig =
399: &Apache::lonnet::get_dom('configuration',['usercreation'],$domain);
400: if (ref($domconfig{'usercreation'}) eq 'HASH') {
401: if (ref($domconfig{'usercreation'}{'cancreate'}) eq 'HASH') {
402: if (ref($domconfig{'usercreation'}{'cancreate'}{'selfcreate'}) eq 'ARRAY') {
403: @cancreate = @{$domconfig{'usercreation'}{'cancreate'}{'selfcreate'}};
404: } elsif (($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne 'none') &&
405: ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne '')) {
406: @cancreate = ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'});
407: }
408: }
409: }
410: if ((grep(/^sso$/,@cancreate)) || (defined($r->dir_config('lonSSOUserUnknownRedirect')))) {
411: $r->subprocess_env->set('SSOUserUnknown' => $user);
412: $r->subprocess_env->set('SSOUserDomain' => $domain);
413: if (grep(/^sso$/,@cancreate)) {
414: $r->set_handlers('PerlHandler'=> [\&Apache::createaccount::handler]);
415: $r->handler('perl-script');
416: } else {
417: $r->internal_redirect($r->dir_config('lonSSOUserUnknownRedirect'));
418: $r->set_handlers('PerlHandler'=> undef);
419: }
420: return OK;
421: }
422: }
423: return undef;
424: }
425:
426: sub handler {
427: my $r = shift;
428: my $requrl=$r->uri;
429:
430: if ($requrl =~ m{^/res/adm/pages/[^/]+\.(gif|png)$}) {
431: return OK;
432: }
433:
434: if (&Apache::lonnet::is_domainimage($requrl)) {
435: return OK;
436: }
437:
438: my %user;
439: my $handle = &Apache::lonnet::check_for_valid_session($r,undef,\%user);
440:
441: unless (($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) {
442: my $result = &sso_login($r,$handle,$user{'name'});
443: if (defined($result)) {
444: return $result;
445: }
446: }
447:
448: my ($is_balancer,$otherserver);
449:
450: if ($handle eq '') {
451: unless ((($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) ||
452: ($requrl =~ m{^/public/$match_domain/$match_courseid/syllabus}) ||
453: ($requrl =~ m{^/adm/help/}) ||
454: ($requrl =~ m{^/res/$match_domain/$match_username/})) {
455: $r->log_reason("Cookie not valid", $r->filename);
456: }
457: } elsif ($handle ne '') {
458:
459: # ------------------------------------------------------ Initialize Environment
460: my $lonidsdir=$r->dir_config('lonIDsDir');
461: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
462:
463: # --------------------------------------------------------- Initialize Language
464:
465: &Apache::lonlocal::get_language_handle($r);
466:
467: }
468:
469: # -------------------------------------------------- Should be a valid user now
470: if ($env{'user.name'} ne '' && $env{'user.domain'} ne '') {
471: # -------------------------------------------------------------- Resource State
472:
473: my ($cdom,$cnum);
474: if ($env{'request.course.id'}) {
475: $cdom = $env{'course.'.$env{'request.course.id'}.'.domain'};
476: $cnum = $env{'course.'.$env{'request.course.id'}.'.num'};
477: }
478: if ($requrl=~/^\/+(res|uploaded)\//) {
479: $env{'request.state'} = "published";
480: } else {
481: $env{'request.state'} = 'unknown';
482: }
483: $env{'request.filename'} = $r->filename;
484: $env{'request.noversionuri'} = &Apache::lonnet::deversion($requrl);
485: my ($suppext,$checkabsolute);
486: if ($requrl =~ m{^/adm/wrapper/ext/}) {
487: my $query = $r->args;
488: if ($query) {
489: my $preserved;
490: foreach my $pair (split(/&/,$query)) {
491: my ($name, $value) = split(/=/,$pair);
492: unless ($name eq 'symb') {
493: $preserved .= $pair.'&';
494: }
495: if (($env{'request.course.id'}) && ($name eq 'folderpath')) {
496: if ($value =~ /^supplemental/) {
497: $suppext = 1;
498: }
499: }
500: }
501: $preserved =~ s/\&$//;
502: if ($preserved) {
503: $env{'request.external.querystring'} = $preserved;
504: }
505: }
506: if ($env{'request.course.id'}) {
507: $checkabsolute = 1;
508: }
509: } elsif ($env{'request.course.id'} &&
510: (($requrl =~ m{^/adm/$match_domain/$match_username/aboutme$}) ||
511: ($requrl =~ m{^/public/$cdom/$cnum/syllabus$}))) {
512: my $query = $r->args;
513: if ($query) {
514: foreach my $pair (split(/&/,$query)) {
515: my ($name, $value) = split(/=/,$pair);
516: if ($name eq 'folderpath') {
517: if ($value =~ /^supplemental/) {
518: $suppext = 1;
519: }
520: }
521: }
522: }
523: if ($requrl =~ m{^/public/$cdom/$cnum/syllabus$}) {
524: $checkabsolute = 1;
525: }
526: }
527: if ($checkabsolute) {
528: my $hostname = $r->hostname();
529: my $lonhost = &Apache::lonnet::host_from_dns($hostname);
530: if ($lonhost) {
531: my $actual = &Apache::lonnet::absolute_url($hostname);
532: my $expected = $Apache::lonnet::protocol{$lonhost}.'://'.$hostname;
533: unless ($actual eq $expected) {
534: $env{'request.use_absolute'} = $expected;
535: }
536: }
537: }
538: # -------------------------------------------------------- Load POST parameters
539:
540: &Apache::lonacc::get_posted_cgi($r);
541:
542: # ------------------------------------------------------ Check if load balancer
543:
544: my $checkexempt;
545: if ($env{'user.loadbalexempt'} eq $r->dir_config('lonHostID')) {
546: if ($env{'user.loadbalcheck.time'} + 600 > time) {
547: $checkexempt = 1;
548: }
549: }
550: if ($env{'user.noloadbalance'} eq $r->dir_config('lonHostID')) {
551: $checkexempt = 1;
552: }
553: unless ($checkexempt) {
554: ($is_balancer,$otherserver) =
555: &Apache::lonnet::check_loadbalancing($env{'user.name'},
556: $env{'user.domain'});
557: }
558: if ($is_balancer) {
559: $r->set_handlers('PerlResponseHandler'=>
560: [\&Apache::switchserver::handler]);
561: if ($otherserver ne '') {
562: $env{'form.otherserver'} = $otherserver;
563: }
564: unless (($env{'form.origurl'}) || ($r->uri eq '/adm/roles') ||
565: ($r->uri eq '/adm/switchserver') || ($r->uri eq '/adm/sso')) {
566: $env{'form.origurl'} = $r->uri;
567: }
568: }
569:
570: # ---------------------------------------------------------------- Check access
571: my $now = time;
572: if ($requrl !~ m{^/(?:adm|public|prtspool)/}
573: || $requrl =~ /^\/adm\/.*\/(smppg|bulletinboard)(\?|$ )/x) {
574: my $access=&Apache::lonnet::allowed('bre',$requrl);
575: if ($handle eq '') {
576: unless ($access eq 'F') {
577: if ($requrl =~ m{^/res/$match_domain/$match_username/}) {
578: $r->log_reason("Cookie not valid", $r->filename);
579: }
580: }
581: }
582: if ($access eq '1') {
583: $env{'user.error.msg'}="$requrl:bre:0:0:Choose Course";
584: return HTTP_NOT_ACCEPTABLE;
585: }
586: if ($access eq 'A') {
587: &Apache::restrictedaccess::setup_handler($r);
588: return OK;
589: }
590: if ($access eq 'B') {
591: &Apache::blockedaccess::setup_handler($r);
592: return OK;
593: }
594: if (($access ne '2') && ($access ne 'F')) {
595: if ($requrl =~ m{^/res/}) {
596: $access = &Apache::lonnet::allowed('bro',$requrl);
597: if ($access ne 'F') {
598: if ($requrl eq '/res/lib/templates/simpleproblem.problem/smpedit') {
599: $access = &Apache::lonnet::allowed('bre','/res/lib/templates/simpleproblem.problem');
600: if ($access ne 'F') {
601: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
602: return HTTP_NOT_ACCEPTABLE;
603: }
604: } else {
605: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
606: return HTTP_NOT_ACCEPTABLE;
607: }
608: }
609: } elsif (($handle =~ /^publicuser_\d+$/) && (&Apache::lonnet::is_portfolio_url($requrl))) {
610: my $clientip = $r->get_remote_host();
611: if (&Apache::lonnet::allowed('bre',$requrl,undef,undef,$clientip) ne 'F') {
612: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
613: return HTTP_NOT_ACCEPTABLE;
614: }
615: } else {
616: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
617: return HTTP_NOT_ACCEPTABLE;
618: }
619: }
620: }
621: if ($requrl =~ m|^/prtspool/|) {
622: my $start='/prtspool/'.$env{'user.name'}.'_'.
623: $env{'user.domain'};
624: if ($requrl !~ /^\Q$start\E/) {
625: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
626: return HTTP_NOT_ACCEPTABLE;
627: }
628: }
629: if ($requrl =~ m|^/zipspool/|) {
630: my $start='/zipspool/zipout/'.$env{'user.name'}.":".
631: $env{'user.domain'};
632: if ($requrl !~ /^\Q$start\E/) {
633: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
634: return HTTP_NOT_ACCEPTABLE;
635: }
636: }
637: if ($env{'user.name'} eq 'public' &&
638: $env{'user.domain'} eq 'public' &&
639: $requrl !~ m{^/+(res|public|uploaded)/} &&
640: $requrl !~ m{^/adm/[^/]+/[^/]+/aboutme/portfolio$ }x &&
641: $requrl !~ m{^/adm/blockingstatus/.*$} &&
642: $requrl !~ m{^/+adm/(help|logout|restrictedaccess|randomlabel\.png)}) {
643: $env{'request.querystring'}=$r->args;
644: $env{'request.firsturl'}=$requrl;
645: return FORBIDDEN;
646: }
647: # ------------------------------------------------------------- This is allowed
648: if ($env{'request.course.id'}) {
649: &Apache::lonnet::countacc($requrl);
650: $requrl=~/\.(\w+)$/;
651: my $query=$r->args;
652: if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
653: ($requrl=~/^\/adm\/.*\/(aboutme|smppg|bulletinboard)(\?|$ )/x) ||
654: ($requrl=~/^\/adm\/wrapper\//) ||
655: ($requrl=~m|^/adm/coursedocs/showdoc/|) ||
656: ($requrl=~m|\.problem/smpedit$|) ||
657: ($requrl=~/^\/public\/.*\/syllabus$/) ||
658: ($requrl=~/^\/adm\/(viewclasslist|navmaps)$/) ||
659: ($requrl=~/^\/adm\/.*\/aboutme\/portfolio(\?|$)/)) {
660: # ------------------------------------- This is serious stuff, get symb and log
661: my $symb;
662: if ($query) {
663: &Apache::loncommon::get_unprocessed_cgi($query,['symb','folderpath']);
664: }
665: if ($env{'form.symb'}) {
666: $symb=&Apache::lonnet::symbclean($env{'form.symb'});
667: if ($requrl =~ m|^/adm/wrapper/|
668: || $requrl =~ m|^/adm/coursedocs/showdoc/|) {
669: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
670: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
671: 'last_known' =>[$murl,$mid]);
672: } elsif ((&Apache::lonnet::symbverify($symb,$requrl)) ||
673: (($requrl=~m|(.*)/smpedit$|) &&
674: &Apache::lonnet::symbverify($symb,$1)) ||
675: (($requrl=~m|(.*/aboutme)/portfolio$|) &&
676: &Apache::lonnet::symbverify($symb,$1))) {
677: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
678: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
679: 'last_known' =>[$murl,$mid]);
680: } else {
681: $r->log_reason('Invalid symb for '.$requrl.': '.
682: $symb);
683: $env{'user.error.msg'}=
684: "$requrl:bre:1:1:Invalid Access";
685: return HTTP_NOT_ACCEPTABLE;
686: }
687: } else {
688: if ($requrl=~m{^(/adm/.*/aboutme)/portfolio$}) {
689: $requrl = $1;
690: }
691: unless ($suppext) {
692: $symb=&Apache::lonnet::symbread($requrl);
693: if (&Apache::lonnet::is_on_map($requrl) && $symb &&
694: !&Apache::lonnet::symbverify($symb,$requrl)) {
695: $r->log_reason('Invalid symb for '.$requrl.': '.$symb);
696: $env{'user.error.msg'}=
697: "$requrl:bre:1:1:Invalid Access";
698: return HTTP_NOT_ACCEPTABLE;
699: }
700: if ($symb) {
701: my ($map,$mid,$murl)=
702: &Apache::lonnet::decode_symb($symb);
703: &Apache::lonnet::symblist($map,$murl =>[$murl,$mid],
704: 'last_known' =>[$murl,$mid]);
705: }
706: }
707: }
708: $env{'request.symb'}=$symb;
709: &Apache::lonnet::courseacclog($symb);
710: } else {
711: # ------------------------------------------------------- This is other content
712: &Apache::lonnet::courseacclog($requrl);
713: }
714: if ($requrl =~ m{^/+uploaded/\Q$cdom\E/\Q$cnum\E/(docs|supplemental)/.+\.html?$}) {
715: if (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) {
716: if ($query) {
717: &Apache::loncommon::get_unprocessed_cgi($query,['forceedit']);
718: if ($env{'form.forceedit'}) {
719: $env{'request.state'} = 'edit';
720: }
721: }
722: }
723: } elsif ($requrl =~ m{^/+uploaded/\Q$cdom\E/\Q$cnum\E/portfolio/syllabus/.+\.html?$}) {
724: if (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) {
725: if ($query) {
726: &Apache::loncommon::get_unprocessed_cgi($query,['forceedit','editmode']);
727: if (($env{'form.forceedit'}) || ($env{'form.editmode'})) {
728: $env{'request.state'} = 'edit';
729: }
730: }
731: }
732: }
733: }
734: return OK;
735: } else {
736: my $defdom=$r->dir_config('lonDefDomain');
737: ($is_balancer,$otherserver) =
738: &Apache::lonnet::check_loadbalancing(undef,$defdom);
739: if ($is_balancer) {
740: $r->set_handlers('PerlResponseHandler'=>
741: [\&Apache::switchserver::handler]);
742: if ($otherserver ne '') {
743: $env{'form.otherserver'} = $otherserver;
744: }
745: }
746: }
747: # -------------------------------------------- See if this is a public resource
748: if ($requrl=~m|^/+adm/+help/+|) {
749: return OK;
750: }
751: # ------------------------------------ See if this is a viewable portfolio file
752: if (&Apache::lonnet::is_portfolio_url($requrl)) {
753: my $clientip = $r->get_remote_host();
754: my $access=&Apache::lonnet::allowed('bre',$requrl,undef,undef,$clientip);
755: if ($access eq 'A') {
756: &Apache::restrictedaccess::setup_handler($r);
757: return OK;
758: }
759: if (($access ne '2') && ($access ne 'F')) {
760: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
761: return HTTP_NOT_ACCEPTABLE;
762: }
763: }
764:
765: # -------------------------------------------------------------- Not authorized
766: $requrl=~/\.(\w+)$/;
767: # if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
768: # ($requrl=~/^\/adm\/(roles|logout|email|menu|remote)/) ||
769: # ($requrl=~m|^/prtspool/|)) {
770: # -------------------------- Store where they wanted to go and get login screen
771: $env{'request.querystring'}=$r->args;
772: $env{'request.firsturl'}=$requrl;
773: return FORBIDDEN;
774: # } else {
775: # --------------------------------------------------------------------- Goodbye
776: # return HTTP_BAD_REQUEST;
777: # }
778: }
779:
780: 1;
781: __END__
782:
783: =pod
784:
785: =back
786:
787: =cut
788:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>