1: # The LearningOnline Network
2: # User Authentication Module
3: #
4: # $Id: lonauth.pm,v 1.101.8.9.2.1 2012/02/06 03:27:59 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonauth;
30:
31: use strict;
32: use LONCAPA;
33: use Apache::Constants qw(:common);
34: use CGI qw(:standard);
35: use DynaLoader; # for Crypt::DES version
36: use Crypt::DES;
37: use Apache::loncommon();
38: use Apache::lonnet;
39: use Apache::lonmenu();
40: use Apache::createaccount;
41: use Fcntl qw(:flock);
42: use Apache::lonlocal;
43: use Apache::File();
44: use HTML::Entities;
45:
46: # ------------------------------------------------------------ Successful login
47: sub success {
48: my ($r, $username, $domain, $authhost, $lowerurl, $extra_env,
49: $form) = @_;
50:
51: # ------------------------------------------------------------ Get cookie ready
52: my $cookie =
53: &Apache::loncommon::init_user_environment($r, $username, $domain,
54: $authhost, $form,
55: {'extra_env' => $extra_env,});
56:
57: my $public=($username eq 'public' && $domain eq 'public');
58:
59: if ($public or $lowerurl eq 'noredirect') { return $cookie; }
60:
61: # -------------------------------------------------------------------- Log this
62:
63: &Apache::lonnet::log($domain,$username,$authhost,
64: "Login $ENV{'REMOTE_ADDR'}");
65:
66: # ------------------------------------------------- Check for critical messages
67:
68: my @what=&Apache::lonnet::dump('critical',$domain,$username);
69: if ($what[0]) {
70: if (($what[0] ne 'con_lost') && ($what[0]!~/^error\:/)) {
71: $lowerurl='/adm/email?critical=display';
72: }
73: }
74:
75: # ------------------------------------------------------------ Get cookie ready
76: $cookie="lonID=$cookie; path=/";
77: # -------------------------------------------------------- Menu script and info
78: my $destination = $lowerurl;
79:
80: if (defined($form->{role})) {
81: my $envkey = 'user.role.'.$form->{role};
82: my $now=time;
83: my $then=$env{'user.login.time'};
84: my $refresh=$env{'user.refresh.time'};
85: if (exists($env{$envkey})) {
86: my ($role,$where,$trolecode,$tstart,$tend,$tremark,$tstatus);
87: &Apache::lonnet::role_status($envkey,$then,$refresh,$now,\$role,\$where,
88: \$trolecode,\$tstatus,\$tstart,\$tend);
89: if ($tstatus eq 'is') {
90: $destination .= ($destination =~ /\?/) ? '&' : '?';
91: my $newrole = &HTML::Entities::encode($form->{role},'"<>&');
92: $destination .= 'selectrole=1&'.$newrole.'=1';
93: }
94: }
95: }
96: if (defined($form->{symb})) {
97: my $destsymb = $form->{symb};
98: $destination .= ($destination =~ /\?/) ? '&' : '?';
99: if ($destsymb =~ /___/) {
100: # FIXME Need to deal with encrypted symbs and urls as needed.
101: my ($map,$resid,$desturl)=split(/___/,$destsymb);
102: unless ($desturl=~/^(adm|uploaded|editupload|public)/) {
103: $desturl = &Apache::lonnet::clutter($desturl);
104: }
105: $desturl = &HTML::Entities::encode($desturl,'"<>&');
106: $destsymb = &HTML::Entities::encode($destsymb,'"<>&');
107: $destination .= '&destinationurl='.$desturl.
108: '&destsymb='.$destsymb;
109: } else {
110: $destsymb = &HTML::Entities::encode($destsymb,'"<>&');
111: $destination .= '&destinationurl='.$destsymb;
112: }
113: }
114:
115: my $windowinfo=&Apache::lonmenu::open($env{'browser.os'});
116: my $startupremote=&Apache::lonmenu::startupremote($destination);
117: my $remoteinfo=&Apache::lonmenu::load_remote_msg($lowerurl);
118: my $setflags=&Apache::lonmenu::setflags();
119: my $maincall=&Apache::lonmenu::maincall();
120: my $brcrum = [{'href' => '',
121: 'text' => 'Successful Login'},];
122: my $start_page=&Apache::loncommon::start_page('Successful Login',
123: $startupremote,
124: {'no_inline_link' => 1,
125: 'bread_crumbs' => $brcrum,});
126: my $end_page =&Apache::loncommon::end_page();
127:
128: my $continuelink;
129: if ($env{'environment.remote'} eq 'off') {
130: $continuelink='<a href="'.$destination.'">'.&mt('Continue').'</a>';
131: }
132: # ------------------------------------------------- Output for successful login
133:
134: &Apache::loncommon::content_type($r,'text/html');
135: $r->header_out('Set-cookie' => $cookie);
136: $r->send_http_header;
137:
138: my %lt=&Apache::lonlocal::texthash(
139: 'wel' => 'Welcome',
140: 'pro' => 'Login problems?',
141: 'log' => 'loginproblems.html',
142: );
143: my $welcome = &mt('Welcome to the Learning[_1]Online[_2] Network with CAPA. Please wait while your session is being set up.','<i>','</i>');
144: $r->print(<<ENDSUCCESS);
145: $start_page
146: $setflags
147: $windowinfo
148: <h1>$lt{'wel'}</h1>
149: $welcome<p>
150: <a href="/adm/$lt{'log'}">$lt{'pro'}</a></p>
151: $remoteinfo
152: $maincall
153: $continuelink
154: $end_page
155: ENDSUCCESS
156: }
157:
158: # --------------------------------------------------------------- Failed login!
159:
160: sub failed {
161: my ($r,$message,$form) = @_;
162: my $start_page = &Apache::loncommon::start_page('Unsuccessful Login',undef,
163: {'no_inline_link' => 1,});
164: my $retry = '/adm/login?username='.$form->{'uname'}.
165: '&domain='.$form->{'udom'};
166: if (exists($form->{role})) {
167: $retry .= '&role='.$form->{role};
168: }
169: if (exists($form->{symb})) {
170: $retry .= '&symb='.$form->{symb};
171: }
172: my $end_page = &Apache::loncommon::end_page();
173: &Apache::loncommon::content_type($r,'text/html');
174: $r->send_http_header;
175: $r->print(
176: $start_page
177: .'<h1>'.&mt('Sorry ...').'</h1>'
178: .'<p class="LC_warning">'.&mt($message).'</p>'
179: .'<p>'.&mt('Please [_1]log in again[_2].','<a href="'.$retry.'">','</a>')
180: .'</p>'
181: .'<p><a href="/adm/loginproblems.html">'.&mt('Login problems?').'</a></p>'
182: .$end_page
183: );
184: }
185:
186: # ------------------------------------------------------------------ Rerouting!
187:
188: sub reroute {
189: my ($r) = @_;
190: &Apache::loncommon::content_type($r,'text/html');
191: $r->send_http_header;
192: my $msg='<h1>'.&mt('Sorry ...').'</h1>'
193: .&mt('Please [_1]log in again[_2].');
194: &Apache::loncommon::simple_error_page($r,'Rerouting',$msg);
195: }
196:
197: # ---------------------------------------------------------------- Main handler
198:
199: sub handler {
200: my $r = shift;
201: my $form;
202: # Are we re-routing?
203: if (-e '/home/httpd/html/lon-status/reroute.txt') {
204: &reroute($r);
205: return OK;
206: }
207:
208: &Apache::lonlocal::get_language_handle($r);
209:
210: # -------------------------------- Prevent users from attempting to login twice
211: my $handle = &Apache::lonnet::check_for_valid_session($r);
212: if ($handle ne '') {
213: my $lonidsdir=$r->dir_config('lonIDsDir');
214: if ($handle=~/^publicuser\_/) {
215: # For "public user" - remove it, we apparently really want to login
216: unlink($r->dir_config('lonIDsDir')."/$handle.id");
217: } else {
218: # Indeed, a valid token is found
219: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
220: &Apache::loncommon::content_type($r,'text/html');
221: $r->send_http_header;
222: my $start_page =
223: &Apache::loncommon::start_page('Already logged in');
224: my $end_page =
225: &Apache::loncommon::end_page();
226: my $dest = '/adm/roles';
227: if ($env{'form.firsturl'} ne '') {
228: $dest = $env{'form.firsturl'};
229: }
230: $r->print(
231: $start_page
232: .'<h1>'.&mt('You are already logged in!').'</h1>'
233: .'<p>'.&mt('Please either [_1]continue the current session[_2] or [_3]log out[_4].'
234: ,'<a href="'.$dest.'">','</a>','<a href="/adm/logout">','</a>')
235: .'</p>'
236: .$end_page
237: );
238: return OK;
239: }
240: }
241:
242: # ---------------------------------------------------- No valid token, continue
243:
244:
245: my $buffer;
246: if ($r->header_in('Content-length') > 0) {
247: $r->read($buffer,$r->header_in('Content-length'),0);
248: }
249: my %form;
250: foreach my $pair (split(/&/,$buffer)) {
251: my ($name,$value) = split(/=/,$pair);
252: $value =~ tr/+/ /;
253: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
254: $form{$name}=$value;
255: }
256:
257: if ((!$form{'uname'}) || (!$form{'upass0'}) || (!$form{'udom'})) {
258: &failed($r,'Username, password and domain need to be specified.',
259: \%form);
260: return OK;
261: }
262:
263: # split user logging in and "su"-user
264:
265: ($form{'uname'},$form{'suname'})=split(/\:/,$form{'uname'});
266: $form{'uname'} = &LONCAPA::clean_username($form{'uname'});
267: $form{'suname'}= &LONCAPA::clean_username($form{'suname'});
268: $form{'udom'} = &LONCAPA::clean_domain( $form{'udom'});
269:
270: my $role = $r->dir_config('lonRole');
271: my $domain = $r->dir_config('lonDefDomain');
272: my $prodir = $r->dir_config('lonUsersDir');
273: my $contact_name = &mt('LON-CAPA helpdesk');
274:
275: # ---------------------------------------- Get the information from login token
276:
277: my $tmpinfo=Apache::lonnet::reply('tmpget:'.$form{'logtoken'},
278: $form{'serverid'});
279:
280: if (($tmpinfo=~/^error/) || ($tmpinfo eq 'con_lost') ||
281: ($tmpinfo eq 'no_such_host')) {
282: &failed($r,'Information needed to verify your login information is missing, inaccessible or expired.',\%form);
283: return OK;
284: } else {
285: my $reply = &Apache::lonnet::reply('tmpdel:'.$form{'logtoken'},
286: $form{'serverid'});
287: if ( $reply ne 'ok' ) {
288: &failed($r,'Session could not be opened.',\%form);
289: &Apache::lonnet::logthis("ERROR got a reply of $reply when trying to contact ". $form{'serverid'}." to get login token");
290: return OK;
291: }
292: }
293:
294: if (!&Apache::lonnet::domain($form{'udom'})) {
295: &failed($r,'The domain you provided is not a valid LON-CAPA domain.',\%form);
296: return OK;
297: }
298:
299: my ($key,$firsturl,$rolestr,$symbstr)=split(/&/,$tmpinfo);
300: if ($rolestr) {
301: $rolestr = &unescape($rolestr);
302: }
303: if ($symbstr) {
304: $symbstr= &unescape($symbstr);
305: }
306: if ($rolestr =~ /^role=/) {
307: (undef,$form{'role'}) = split('=',$rolestr);
308: }
309: if ($symbstr =~ /^symb=/) {
310: (undef,$form{'symb'}) = split('=',$symbstr);
311: }
312:
313: my $keybin=pack("H16",$key);
314:
315: my $cipher;
316: if ($Crypt::DES::VERSION>=2.03) {
317: $cipher=new Crypt::DES $keybin;
318: }
319: else {
320: $cipher=new DES $keybin;
321: }
322: my $upass='';
323: for (my $i=0;$i<=2;$i++) {
324: my $chunk=
325: $cipher->decrypt(unpack("a8",pack("H16",substr($form{'upass'.$i},0,16))));
326:
327: $chunk.=
328: $cipher->decrypt(unpack("a8",pack("H16",substr($form{'upass'.$i},16,16))));
329:
330: $chunk=substr($chunk,1,ord(substr($chunk,0,1)));
331: $upass.=$chunk;
332: }
333:
334: # ---------------------------------------------------------------- Authenticate
335:
336: my %domconfig = &Apache::lonnet::get_dom('configuration',['usercreation'],$form{'udom'});
337: my ($cancreate,$statustocreate) =
338: &Apache::createaccount::get_creation_controls($form{'udom'},$domconfig{'usercreation'});
339: my $defaultauth;
340: if (ref($cancreate) eq 'ARRAY') {
341: if (grep(/^login$/,@{$cancreate})) {
342: $defaultauth = 1;
343: }
344: }
345: my $clientcancheckhost = 1;
346: my $uname = $form{'uname'};
347: my $authhost=Apache::lonnet::authenticate($uname,$upass,
348: $form{'udom'},$defaultauth,
349: $clientcancheckhost);
350:
351: # --------------------------------------------------------------------- Failed?
352:
353: if ($authhost eq 'no_host') {
354: my $lc_uname = lc($uname);
355: if ($uname eq $lc_uname) {
356: &failed($r,'Username and/or password could not be authenticated.',
357: \%form);
358: return OK;
359: } else {
360: $authhost=Apache::lonnet::authenticate($lc_uname,$upass,
361: $form{'udom'},$defaultauth);
362: if ($authhost eq 'no_host') {
363: &failed($r,'Username (in lower case) and/or password could not be authenticated.',
364: \%form);
365: return OK;
366: } elsif ($authhost eq 'no_account_on_host') {
367: &create_account($r,\%form,\@cancreate,$lc_uname,$contact_name);
368: return OK;
369: } else {
370: $form{'uname'} = $lc_uname;
371: }
372: }
373: } elsif ($authhost eq 'no_account_on_host') {
374: &create_account($r,\%form,\@cancreate,$uname,$contact_name);
375: return OK;
376: }
377:
378: if (($firsturl eq '') ||
379: ($firsturl=~/^\/adm\/(logout|remote)/)) {
380: $firsturl='/adm/roles';
381: }
382: # --------------------------------- Are we attempting to login as somebody else?
383: if ($form{'suname'}) {
384: # ------------ see if the original user has enough privileges to pull this stunt
385: if (&Apache::lonnet::privileged($form{'uname'},$form{'udom'})) {
386: # ---------------------------------------------------- see if the su-user exists
387: unless (&Apache::lonnet::homeserver($form{'suname'},$form{'udom'})
388: eq 'no_host') {
389: &Apache::lonnet::logthis(&Apache::lonnet::homeserver($form{'suname'},$form{'udom'}));
390: # ------------------------------ see if the su-user is not too highly privileged
391: unless (&Apache::lonnet::privileged($form{'suname'},$form{'udom'})) {
392: # -------------------------------------------------------- actually switch users
393: &Apache::lonnet::logperm('User '.$form{'uname'}.' at '.$form{'udom'}.
394: ' logging in as '.$form{'suname'});
395: $form{'uname'}=$form{'suname'};
396: } else {
397: &Apache::lonnet::logthis('Attempted switch user to privileged user');
398: }
399: }
400: } else {
401: &Apache::lonnet::logthis('Non-privileged user attempting switch user');
402: }
403: }
404:
405: if ($r->dir_config("lonBalancer") eq 'yes') {
406: my $otherserver = &Apache::lonnet::spareserver(30000,undef,1,$form{'udom'});
407: if (!$otherserver) {
408: ($otherserver) = &Apache::lonnet::choose_server($form{'udom'});
409: }
410: if ($otherserver) {
411: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',undef,
412: \%form);
413: $r->internal_redirect('/adm/switchserver?otherserver='.$otherserver.'&origurl='.$firsturl);
414: } else {
415: $r->print(&noswitch());
416: }
417: return OK;
418: } else {
419: if (!&check_can_host($r,\%form,$authhost)) {
420: my ($otherserver) = &Apache::lonnet::choose_server($form{'udom'});
421: if ($otherserver) {
422: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',undef,
423: \%form);
424: $r->internal_redirect('/adm/switchserver?otherserver='.$otherserver.'&origurl='.$firsturl);
425: } else {
426: $r->print(&noswitch());
427: }
428: return OK;
429: }
430: # ------------------------------------------------------- Do the load balancing
431:
432: # ---------------------------------------------------------- Determine own load
433: my $loadlim = $r->dir_config('lonLoadLim');
434: my $loadavg;
435: {
436: my $loadfile=Apache::File->new('/proc/loadavg');
437: $loadavg=<$loadfile>;
438: }
439: $loadavg =~ s/\s.*//g;
440: my $loadpercent=sprintf("%.1f",100*$loadavg/$loadlim);
441: my $userloadpercent=&Apache::lonnet::userload();
442:
443: # ---------------------------------------------------------- Are we overloaded?
444: if ((($userloadpercent>100.0)||($loadpercent>100.0))) {
445: my $unloaded=Apache::lonnet::spareserver($loadpercent,$userloadpercent,1,$form{'udom'});
446: if (!$unloaded) {
447: ($unloaded) = &Apache::lonnet::choose_server($form{'udom'});
448: }
449: if ($unloaded) {
450: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',
451: undef,\%form);
452: $r->internal_redirect('/adm/switchserver?otherserver='.$unloaded.'&origurl='.$firsturl);
453: return OK;
454: }
455: }
456: &success($r,$form{'uname'},$form{'udom'},$authhost,$firsturl,undef,
457: \%form);
458: return OK;
459: }
460: }
461:
462: sub check_can_host {
463: my ($r,$form,$authhost,$domdesc) = @_;
464: return unless (ref($form) eq 'HASH');
465: my $canhost = 1;
466: my $lonhost = $r->dir_config('lonHostID');
467: my $udom = $form->{'udom'};
468: my @intdoms;
469: my $internet_names = &Apache::lonnet::get_internet_names($lonhost);
470: if (ref($internet_names) eq 'ARRAY') {
471: @intdoms = @{$internet_names};
472: }
473: my $uprimary_id = &Apache::lonnet::domain($udom,'primary');
474: my $uint_dom = &Apache::lonnet::internet_dom($uprimary_id);
475: unless ($uint_dom ne '' && grep(/^\Q$uint_dom\E$/,@intdoms)) {
476: my $machine_dom = &Apache::lonnet::host_domain($lonhost);
477: my $hostname = &Apache::lonnet::hostname($lonhost);
478: my $serverhomeID = &Apache::lonnet::get_server_homeID($hostname);
479: my $serverhomedom = &Apache::lonnet::host_domain($serverhomeID);
480: my %defdomdefaults = &Apache::lonnet::get_domain_defaults($serverhomedom);
481: my %udomdefaults = &Apache::lonnet::get_domain_defaults($udom);
482: my $loncaparev;
483: if ($authhost eq 'no_account_on_host') {
484: $loncaparev = &Apache::lonnet::get_server_loncaparev($machine_dom);
485: } else {
486: $loncaparev = &Apache::lonnet::get_server_loncaparev($machine_dom,$lonhost);
487: }
488: $canhost = &Apache::lonnet::can_host_session($udom,$lonhost,$loncaparev,
489: $udomdefaults{'remotesessions'},
490: $defdomdefaults{'hostedsessions'});
491: }
492: unless ($canhost) {
493: if ($authhost eq 'no_account_on_host') {
494: my $checkloginvia = 1;
495: my ($login_host,$hostname) =
496: &Apache::lonnet::choose_server($udom,$checkloginvia);
497: &Apache::loncommon::content_type($r,'text/html');
498: $r->send_http_header;
499: if ($login_host ne '') {
500: my $protocol = $Apache::lonnet::protocol{$login_host};
501: $protocol = 'http' if ($protocol ne 'https');
502: my $newurl = $protocol.'://'.$hostname.'/adm/createaccount';
503: $r->print(&Apache::loncommon::start_page('Create a user account in LON-CAPA').
504: '<h3>'.&mt('Account creation').'</h3>'.
505: &mt('You do not currently have a LON-CAPA account at this institution.').'<br />'.
506: '<p>'.&mt('You will be able to create one by logging into a LON-CAPA server within the [_1] domain.',$domdesc).'</p>'.
507: '<p>'.&mt('[_1]Log in[_2]','<a href="'.$newurl.'">','</a>').
508: &Apache::loncommon::end_page());
509: } else {
510: $r->print(&Apache::loncommon::start_page('Access to LON-CAPA unavailable').
511: '<h3>'.&mt('Account creation unavailable').'</h3>'.
512: &mt('You do not currently have a LON-CAPA account at this institution.').'<br />'.
513: '<p>'.&mt('Currently a LON-CAPA server is not available within the [_1] domain for you to log-in to, to create an account.',$domdesc).'</p>'.
514: &Apache::loncommon::end_page());
515: }
516: } else {
517: &success($r,$form->{'uname'},$udom,$authhost,'noredirect',undef,
518: $form);
519: my ($otherserver) = &Apache::lonnet::choose_server($udom);
520: $r->internal_redirect('/adm/switchserver?otherserver='.$otherserver);
521: }
522: }
523: return $canhost;
524: }
525:
526: sub noswitch {
527: my $result = &Apache::loncommon::start_page('Access to LON-CAPA unavailable').
528: '<h3>'.&mt('Session unavailable').'</h3>'.
529: &mt('This LON-CAPA server is unable to host your session.').'<br />'.
530: '<p>'.&mt('Currently no other LON-CAPA server is available to host your session either.').'</p>'.
531: &Apache::loncommon::end_page();
532: return $result;
533: }
534:
535: sub create_account {
536: my ($r,$form,$cancreate,$uname,$contact_name) = @_;
537: return unless((ref($form) eq 'HASH') && (ref($cancreate) eq 'ARRAY'));
538: my %domconfig =
539: &Apache::lonnet::get_dom('configuration',['usercreation'],$form->{'udom'});
540: if (&check_can_host($r,\%form,'no_account_on_host',$domdesc)) {
541: my $start_page =
542: &Apache::loncommon::start_page('Create a user account in LON-CAPA',
543: '',{'no_inline_link' => 1,});
544: my $domdesc = &Apache::lonnet::domain($form->{'udom'},'description');
545: my $lonhost = $r->dir_config('lonHostID');
546: my $origmail = $Apache::lonnet::perlvar{'lonSupportEMail'};
547: my $contacts =
548: &Apache::loncommon::build_recipient_list(undef,'helpdeskmail',
549: $form->{'udom'},$origmail);
550: my ($contact_email) = split(',',$contacts);
551: my $output =
552: &Apache::createaccount::username_check($uname,$form->{'udom'},
553: $domdesc,'',$lonhost,
554: $contact_email,$contact_name);
555: &Apache::loncommon::content_type($r,'text/html');
556: $r->send_http_header;
557: &Apache::createaccount::print_header($r,$start_page);
558: $r->print('<h3>'.&mt('Account creation').'</h3>'.
559: &mt('Although your username and password were authenticated, you do not currently have a LON-CAPA account at this institution.').'<br />'.
560: $output.&Apache::loncommon::end_page());
561: } else {
562: &failed($r,'Although your username and password were authenticated, you do not currently have a LON-CAPA account in this domain, and you are not permitted to create one.',$form);
563: }
564: return;
565: }
566:
567: 1;
568: __END__
569:
570:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>