1: # The LearningOnline Network
2: # User Authentication Module
3: #
4: # $Id: lonauth.pm,v 1.101.8.9.2.2 2012/02/09 22:01:34 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonauth;
30:
31: use strict;
32: use LONCAPA;
33: use Apache::Constants qw(:common);
34: use CGI qw(:standard);
35: use DynaLoader; # for Crypt::DES version
36: use Crypt::DES;
37: use Apache::loncommon();
38: use Apache::lonnet;
39: use Apache::lonmenu();
40: use Apache::createaccount;
41: use Fcntl qw(:flock);
42: use Apache::lonlocal;
43: use Apache::File();
44: use HTML::Entities;
45:
46: # ------------------------------------------------------------ Successful login
47: sub success {
48: my ($r, $username, $domain, $authhost, $lowerurl, $extra_env,
49: $form) = @_;
50:
51: # ------------------------------------------------------------ Get cookie ready
52: my $cookie =
53: &Apache::loncommon::init_user_environment($r, $username, $domain,
54: $authhost, $form,
55: {'extra_env' => $extra_env,});
56:
57: my $public=($username eq 'public' && $domain eq 'public');
58:
59: if ($public or $lowerurl eq 'noredirect') { return $cookie; }
60:
61: # -------------------------------------------------------------------- Log this
62:
63: &Apache::lonnet::log($domain,$username,$authhost,
64: "Login $ENV{'REMOTE_ADDR'}");
65:
66: # ------------------------------------------------- Check for critical messages
67:
68: my @what=&Apache::lonnet::dump('critical',$domain,$username);
69: if ($what[0]) {
70: if (($what[0] ne 'con_lost') && ($what[0]!~/^error\:/)) {
71: $lowerurl='/adm/email?critical=display';
72: }
73: }
74:
75: # ------------------------------------------------------------ Get cookie ready
76: $cookie="lonID=$cookie; path=/";
77: # -------------------------------------------------------- Menu script and info
78: my $destination = $lowerurl;
79:
80: if (defined($form->{role})) {
81: my $envkey = 'user.role.'.$form->{role};
82: my $now=time;
83: my $then=$env{'user.login.time'};
84: my $refresh=$env{'user.refresh.time'};
85: my $update=$env{'user.update.time'};
86: if (!$update) {
87: $update = $then;
88: }
89: if (exists($env{$envkey})) {
90: my ($role,$where,$trolecode,$tstart,$tend,$tremark,$tstatus);
91: &Apache::lonnet::role_status($envkey,$update,$refresh,$now,\$role,\$where,
92: \$trolecode,\$tstatus,\$tstart,\$tend);
93: if ($tstatus eq 'is') {
94: $destination .= ($destination =~ /\?/) ? '&' : '?';
95: my $newrole = &HTML::Entities::encode($form->{role},'"<>&');
96: $destination .= 'selectrole=1&'.$newrole.'=1';
97: }
98: }
99: }
100: if (defined($form->{symb})) {
101: my $destsymb = $form->{symb};
102: $destination .= ($destination =~ /\?/) ? '&' : '?';
103: if ($destsymb =~ /___/) {
104: # FIXME Need to deal with encrypted symbs and urls as needed.
105: my ($map,$resid,$desturl)=split(/___/,$destsymb);
106: unless ($desturl=~/^(adm|uploaded|editupload|public)/) {
107: $desturl = &Apache::lonnet::clutter($desturl);
108: }
109: $desturl = &HTML::Entities::encode($desturl,'"<>&');
110: $destsymb = &HTML::Entities::encode($destsymb,'"<>&');
111: $destination .= '&destinationurl='.$desturl.
112: '&destsymb='.$destsymb;
113: } else {
114: $destsymb = &HTML::Entities::encode($destsymb,'"<>&');
115: $destination .= '&destinationurl='.$destsymb;
116: }
117: }
118: if ($destination =~ m{^/adm/roles}) {
119: $destination .= ($destination =~ /\?/) ? '&' : '?';
120: $destination .= 'source=login';
121: }
122:
123: my $windowinfo=&Apache::lonmenu::open($env{'browser.os'});
124: my $startupremote=&Apache::lonmenu::startupremote($destination);
125: my $remoteinfo=&Apache::lonmenu::load_remote_msg($lowerurl);
126: my $setflags=&Apache::lonmenu::setflags();
127: my $maincall=&Apache::lonmenu::maincall();
128: my $brcrum = [{'href' => '',
129: 'text' => 'Successful Login'},];
130: my $start_page=&Apache::loncommon::start_page('Successful Login',
131: $startupremote,
132: {'no_inline_link' => 1,
133: 'bread_crumbs' => $brcrum,});
134: my $end_page =&Apache::loncommon::end_page();
135:
136: my $continuelink;
137: if ($env{'environment.remote'} eq 'off') {
138: $continuelink='<a href="'.$destination.'">'.&mt('Continue').'</a>';
139: }
140: # ------------------------------------------------- Output for successful login
141:
142: &Apache::loncommon::content_type($r,'text/html');
143: $r->header_out('Set-cookie' => $cookie);
144: $r->send_http_header;
145:
146: my %lt=&Apache::lonlocal::texthash(
147: 'wel' => 'Welcome',
148: 'pro' => 'Login problems?',
149: 'log' => 'loginproblems.html',
150: );
151: my $welcome = &mt('Welcome to the Learning[_1]Online[_2] Network with CAPA. Please wait while your session is being set up.','<i>','</i>');
152: $r->print(<<ENDSUCCESS);
153: $start_page
154: $setflags
155: $windowinfo
156: <h1>$lt{'wel'}</h1>
157: $welcome<p>
158: <a href="/adm/$lt{'log'}">$lt{'pro'}</a></p>
159: $remoteinfo
160: $maincall
161: $continuelink
162: $end_page
163: ENDSUCCESS
164: }
165:
166: # --------------------------------------------------------------- Failed login!
167:
168: sub failed {
169: my ($r,$message,$form) = @_;
170: my $start_page = &Apache::loncommon::start_page('Unsuccessful Login',undef,
171: {'no_inline_link' => 1,});
172: my $retry = '/adm/login?username='.$form->{'uname'}.
173: '&domain='.$form->{'udom'};
174: if (exists($form->{role})) {
175: $retry .= '&role='.$form->{role};
176: }
177: if (exists($form->{symb})) {
178: $retry .= '&symb='.$form->{symb};
179: }
180: my $end_page = &Apache::loncommon::end_page();
181: &Apache::loncommon::content_type($r,'text/html');
182: $r->send_http_header;
183: $r->print(
184: $start_page
185: .'<h1>'.&mt('Sorry ...').'</h1>'
186: .'<p class="LC_warning">'.&mt($message).'</p>'
187: .'<p>'.&mt('Please [_1]log in again[_2].','<a href="'.$retry.'">','</a>')
188: .'</p>'
189: .'<p><a href="/adm/loginproblems.html">'.&mt('Login problems?').'</a></p>'
190: .$end_page
191: );
192: }
193:
194: # ------------------------------------------------------------------ Rerouting!
195:
196: sub reroute {
197: my ($r) = @_;
198: &Apache::loncommon::content_type($r,'text/html');
199: $r->send_http_header;
200: my $msg='<h1>'.&mt('Sorry ...').'</h1>'
201: .&mt('Please [_1]log in again[_2].');
202: &Apache::loncommon::simple_error_page($r,'Rerouting',$msg);
203: }
204:
205: # ---------------------------------------------------------------- Main handler
206:
207: sub handler {
208: my $r = shift;
209: my $form;
210: # Are we re-routing?
211: if (-e '/home/httpd/html/lon-status/reroute.txt') {
212: &reroute($r);
213: return OK;
214: }
215:
216: &Apache::lonlocal::get_language_handle($r);
217:
218: # -------------------------------- Prevent users from attempting to login twice
219: my $handle = &Apache::lonnet::check_for_valid_session($r);
220: if ($handle ne '') {
221: my $lonidsdir=$r->dir_config('lonIDsDir');
222: if ($handle=~/^publicuser\_/) {
223: # For "public user" - remove it, we apparently really want to login
224: unlink($r->dir_config('lonIDsDir')."/$handle.id");
225: } else {
226: # Indeed, a valid token is found
227: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
228: &Apache::loncommon::content_type($r,'text/html');
229: $r->send_http_header;
230: my $start_page =
231: &Apache::loncommon::start_page('Already logged in');
232: my $end_page =
233: &Apache::loncommon::end_page();
234: my $dest = '/adm/roles';
235: if ($env{'form.firsturl'} ne '') {
236: $dest = $env{'form.firsturl'};
237: }
238: $r->print(
239: $start_page
240: .'<h1>'.&mt('You are already logged in!').'</h1>'
241: .'<p>'.&mt('Please either [_1]continue the current session[_2] or [_3]log out[_4].'
242: ,'<a href="'.$dest.'">','</a>','<a href="/adm/logout">','</a>')
243: .'</p>'
244: .$end_page
245: );
246: return OK;
247: }
248: }
249:
250: # ---------------------------------------------------- No valid token, continue
251:
252:
253: my $buffer;
254: if ($r->header_in('Content-length') > 0) {
255: $r->read($buffer,$r->header_in('Content-length'),0);
256: }
257: my %form;
258: foreach my $pair (split(/&/,$buffer)) {
259: my ($name,$value) = split(/=/,$pair);
260: $value =~ tr/+/ /;
261: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
262: $form{$name}=$value;
263: }
264:
265: if ((!$form{'uname'}) || (!$form{'upass0'}) || (!$form{'udom'})) {
266: &failed($r,'Username, password and domain need to be specified.',
267: \%form);
268: return OK;
269: }
270:
271: # split user logging in and "su"-user
272:
273: ($form{'uname'},$form{'suname'})=split(/\:/,$form{'uname'});
274: $form{'uname'} = &LONCAPA::clean_username($form{'uname'});
275: $form{'suname'}= &LONCAPA::clean_username($form{'suname'});
276: $form{'udom'} = &LONCAPA::clean_domain( $form{'udom'});
277:
278: my $role = $r->dir_config('lonRole');
279: my $domain = $r->dir_config('lonDefDomain');
280: my $prodir = $r->dir_config('lonUsersDir');
281: my $contact_name = &mt('LON-CAPA helpdesk');
282:
283: # ---------------------------------------- Get the information from login token
284:
285: my $tmpinfo=Apache::lonnet::reply('tmpget:'.$form{'logtoken'},
286: $form{'serverid'});
287:
288: if (($tmpinfo=~/^error/) || ($tmpinfo eq 'con_lost') ||
289: ($tmpinfo eq 'no_such_host')) {
290: &failed($r,'Information needed to verify your login information is missing, inaccessible or expired.',\%form);
291: return OK;
292: } else {
293: my $reply = &Apache::lonnet::reply('tmpdel:'.$form{'logtoken'},
294: $form{'serverid'});
295: if ( $reply ne 'ok' ) {
296: &failed($r,'Session could not be opened.',\%form);
297: &Apache::lonnet::logthis("ERROR got a reply of $reply when trying to contact ". $form{'serverid'}." to get login token");
298: return OK;
299: }
300: }
301:
302: if (!&Apache::lonnet::domain($form{'udom'})) {
303: &failed($r,'The domain you provided is not a valid LON-CAPA domain.',\%form);
304: return OK;
305: }
306:
307: my ($key,$firsturl,$rolestr,$symbstr)=split(/&/,$tmpinfo);
308: if ($rolestr) {
309: $rolestr = &unescape($rolestr);
310: }
311: if ($symbstr) {
312: $symbstr= &unescape($symbstr);
313: }
314: if ($rolestr =~ /^role=/) {
315: (undef,$form{'role'}) = split('=',$rolestr);
316: }
317: if ($symbstr =~ /^symb=/) {
318: (undef,$form{'symb'}) = split('=',$symbstr);
319: }
320:
321: my $keybin=pack("H16",$key);
322:
323: my $cipher;
324: if ($Crypt::DES::VERSION>=2.03) {
325: $cipher=new Crypt::DES $keybin;
326: }
327: else {
328: $cipher=new DES $keybin;
329: }
330: my $upass='';
331: for (my $i=0;$i<=2;$i++) {
332: my $chunk=
333: $cipher->decrypt(unpack("a8",pack("H16",substr($form{'upass'.$i},0,16))));
334:
335: $chunk.=
336: $cipher->decrypt(unpack("a8",pack("H16",substr($form{'upass'.$i},16,16))));
337:
338: $chunk=substr($chunk,1,ord(substr($chunk,0,1)));
339: $upass.=$chunk;
340: }
341:
342: # ---------------------------------------------------------------- Authenticate
343:
344: my %domconfig = &Apache::lonnet::get_dom('configuration',['usercreation'],$form{'udom'});
345: my $domdesc = &Apache::lonnet::domain($form{'udom'},'description');
346: my ($cancreate,$statustocreate) =
347: &Apache::createaccount::get_creation_controls($form{'udom'},$domconfig{'usercreation'});
348: my $defaultauth;
349: if (ref($cancreate) eq 'ARRAY') {
350: if (grep(/^login$/,@{$cancreate})) {
351: $defaultauth = 1;
352: }
353: }
354: my $clientcancheckhost = 1;
355: my $uname = $form{'uname'};
356: my $authhost=Apache::lonnet::authenticate($uname,$upass,
357: $form{'udom'},$defaultauth,
358: $clientcancheckhost);
359:
360: # --------------------------------------------------------------------- Failed?
361:
362: if ($authhost eq 'no_host') {
363: my $lc_uname = lc($uname);
364: if ($uname eq $lc_uname) {
365: &failed($r,'Username and/or password could not be authenticated.',
366: \%form);
367: return OK;
368: } else {
369: $authhost=Apache::lonnet::authenticate($lc_uname,$upass,
370: $form{'udom'},$defaultauth);
371: if ($authhost eq 'no_host') {
372: &failed($r,'Username (in lower case) and/or password could not be authenticated.',
373: \%form);
374: return OK;
375: } elsif ($authhost eq 'no_account_on_host') {
376: &create_account($r,\%form,$cancreate,$lc_uname,$contact_name,$domdesc);
377: return OK;
378: } else {
379: $form{'uname'} = $lc_uname;
380: }
381: }
382: } elsif ($authhost eq 'no_account_on_host') {
383: &create_account($r,\%form,$cancreate,$uname,$contact_name,$domdesc);
384: return OK;
385: }
386:
387: if (($firsturl eq '') ||
388: ($firsturl=~/^\/adm\/(logout|remote)/)) {
389: $firsturl='/adm/roles';
390: }
391: # --------------------------------- Are we attempting to login as somebody else?
392: if ($form{'suname'}) {
393: # ------------ see if the original user has enough privileges to pull this stunt
394: if (&Apache::lonnet::privileged($form{'uname'},$form{'udom'})) {
395: # ---------------------------------------------------- see if the su-user exists
396: unless (&Apache::lonnet::homeserver($form{'suname'},$form{'udom'})
397: eq 'no_host') {
398: &Apache::lonnet::logthis(&Apache::lonnet::homeserver($form{'suname'},$form{'udom'}));
399: # ------------------------------ see if the su-user is not too highly privileged
400: unless (&Apache::lonnet::privileged($form{'suname'},$form{'udom'})) {
401: # -------------------------------------------------------- actually switch users
402: &Apache::lonnet::logperm('User '.$form{'uname'}.' at '.$form{'udom'}.
403: ' logging in as '.$form{'suname'});
404: $form{'uname'}=$form{'suname'};
405: } else {
406: &Apache::lonnet::logthis('Attempted switch user to privileged user');
407: }
408: }
409: } else {
410: &Apache::lonnet::logthis('Non-privileged user attempting switch user');
411: }
412: }
413:
414: if ($r->dir_config("lonBalancer") eq 'yes') {
415: my $otherserver = &Apache::lonnet::spareserver(30000,undef,1,$form{'udom'});
416: if (!$otherserver) {
417: ($otherserver) = &Apache::lonnet::choose_server($form{'udom'});
418: }
419: if ($otherserver) {
420: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',undef,
421: \%form);
422: $r->internal_redirect('/adm/switchserver?otherserver='.$otherserver.'&origurl='.$firsturl);
423: } else {
424: $r->print(&noswitch());
425: }
426: return OK;
427: } else {
428: if (!&check_can_host($r,\%form,$authhost,$domdesc)) {
429: my ($otherserver) = &Apache::lonnet::choose_server($form{'udom'});
430: if ($otherserver) {
431: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',undef,
432: \%form);
433: $r->internal_redirect('/adm/switchserver?otherserver='.$otherserver.'&origurl='.$firsturl);
434: } else {
435: $r->print(&noswitch());
436: }
437: return OK;
438: }
439: # ------------------------------------------------------- Do the load balancing
440:
441: # ---------------------------------------------------------- Determine own load
442: my $loadlim = $r->dir_config('lonLoadLim');
443: my $loadavg;
444: {
445: my $loadfile=Apache::File->new('/proc/loadavg');
446: $loadavg=<$loadfile>;
447: }
448: $loadavg =~ s/\s.*//g;
449: my $loadpercent=sprintf("%.1f",100*$loadavg/$loadlim);
450: my $userloadpercent=&Apache::lonnet::userload();
451:
452: # ---------------------------------------------------------- Are we overloaded?
453: if ((($userloadpercent>100.0)||($loadpercent>100.0))) {
454: my $unloaded=Apache::lonnet::spareserver($loadpercent,$userloadpercent,1,$form{'udom'});
455: if (!$unloaded) {
456: ($unloaded) = &Apache::lonnet::choose_server($form{'udom'});
457: }
458: if ($unloaded) {
459: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',
460: undef,\%form);
461: $r->internal_redirect('/adm/switchserver?otherserver='.$unloaded.'&origurl='.$firsturl);
462: return OK;
463: }
464: }
465: &success($r,$form{'uname'},$form{'udom'},$authhost,$firsturl,undef,
466: \%form);
467: return OK;
468: }
469: }
470:
471: sub check_can_host {
472: my ($r,$form,$authhost,$domdesc) = @_;
473: return unless (ref($form) eq 'HASH');
474: my $canhost = 1;
475: my $lonhost = $r->dir_config('lonHostID');
476: my $udom = $form->{'udom'};
477: my @intdoms;
478: my $internet_names = &Apache::lonnet::get_internet_names($lonhost);
479: if (ref($internet_names) eq 'ARRAY') {
480: @intdoms = @{$internet_names};
481: }
482: my $uprimary_id = &Apache::lonnet::domain($udom,'primary');
483: my $uint_dom = &Apache::lonnet::internet_dom($uprimary_id);
484: unless ($uint_dom ne '' && grep(/^\Q$uint_dom\E$/,@intdoms)) {
485: my $machine_dom = &Apache::lonnet::host_domain($lonhost);
486: my $hostname = &Apache::lonnet::hostname($lonhost);
487: my $serverhomeID = &Apache::lonnet::get_server_homeID($hostname);
488: my $serverhomedom = &Apache::lonnet::host_domain($serverhomeID);
489: my %defdomdefaults = &Apache::lonnet::get_domain_defaults($serverhomedom);
490: my %udomdefaults = &Apache::lonnet::get_domain_defaults($udom);
491: my $loncaparev;
492: if ($authhost eq 'no_account_on_host') {
493: $loncaparev = &Apache::lonnet::get_server_loncaparev($machine_dom);
494: } else {
495: $loncaparev = &Apache::lonnet::get_server_loncaparev($machine_dom,$lonhost);
496: }
497: $canhost = &Apache::lonnet::can_host_session($udom,$lonhost,$loncaparev,
498: $udomdefaults{'remotesessions'},
499: $defdomdefaults{'hostedsessions'});
500: }
501: unless ($canhost) {
502: if ($authhost eq 'no_account_on_host') {
503: my $checkloginvia = 1;
504: my ($login_host,$hostname) =
505: &Apache::lonnet::choose_server($udom,$checkloginvia);
506: &Apache::loncommon::content_type($r,'text/html');
507: $r->send_http_header;
508: if ($login_host ne '') {
509: my $protocol = $Apache::lonnet::protocol{$login_host};
510: $protocol = 'http' if ($protocol ne 'https');
511: my $newurl = $protocol.'://'.$hostname.'/adm/createaccount';
512: $r->print(&Apache::loncommon::start_page('Create a user account in LON-CAPA').
513: '<h3>'.&mt('Account creation').'</h3>'.
514: &mt('You do not currently have a LON-CAPA account at this institution.').'<br />'.
515: '<p>'.&mt('You will be able to create one by logging into a LON-CAPA server within the [_1] domain.',$domdesc).'</p>'.
516: '<p>'.&mt('[_1]Log in[_2]','<a href="'.$newurl.'">','</a>').
517: &Apache::loncommon::end_page());
518: } else {
519: $r->print(&Apache::loncommon::start_page('Access to LON-CAPA unavailable').
520: '<h3>'.&mt('Account creation unavailable').'</h3>'.
521: &mt('You do not currently have a LON-CAPA account at this institution.').'<br />'.
522: '<p>'.&mt('Currently a LON-CAPA server is not available within the [_1] domain for you to log-in to, to create an account.',$domdesc).'</p>'.
523: &Apache::loncommon::end_page());
524: }
525: } else {
526: &success($r,$form->{'uname'},$udom,$authhost,'noredirect',undef,
527: $form);
528: my ($otherserver) = &Apache::lonnet::choose_server($udom);
529: $r->internal_redirect('/adm/switchserver?otherserver='.$otherserver);
530: }
531: }
532: return $canhost;
533: }
534:
535: sub noswitch {
536: my $result = &Apache::loncommon::start_page('Access to LON-CAPA unavailable').
537: '<h3>'.&mt('Session unavailable').'</h3>'.
538: &mt('This LON-CAPA server is unable to host your session.').'<br />'.
539: '<p>'.&mt('Currently no other LON-CAPA server is available to host your session either.').'</p>'.
540: &Apache::loncommon::end_page();
541: return $result;
542: }
543:
544: sub create_account {
545: my ($r,$form,$cancreate,$uname,$contact_name,$domdesc) = @_;
546: return unless((ref($form) eq 'HASH') && (ref($cancreate) eq 'ARRAY'));
547: my %domconfig =
548: &Apache::lonnet::get_dom('configuration',['usercreation'],$form->{'udom'});
549: if (&check_can_host($r,$form,'no_account_on_host',$domdesc)) {
550: my $start_page =
551: &Apache::loncommon::start_page('Create a user account in LON-CAPA',
552: '',{'no_inline_link' => 1,});
553: my $lonhost = $r->dir_config('lonHostID');
554: my $origmail = $Apache::lonnet::perlvar{'lonSupportEMail'};
555: my $contacts =
556: &Apache::loncommon::build_recipient_list(undef,'helpdeskmail',
557: $form->{'udom'},$origmail);
558: my ($contact_email) = split(',',$contacts);
559: my $output =
560: &Apache::createaccount::username_check($uname,$form->{'udom'},
561: $domdesc,'',$lonhost,
562: $contact_email,$contact_name);
563: &Apache::loncommon::content_type($r,'text/html');
564: $r->send_http_header;
565: &Apache::createaccount::print_header($r,$start_page);
566: $r->print('<h3>'.&mt('Account creation').'</h3>'.
567: &mt('Although your username and password were authenticated, you do not currently have a LON-CAPA account at this institution.').'<br />'.
568: $output.&Apache::loncommon::end_page());
569: } else {
570: &failed($r,'Although your username and password were authenticated, you do not currently have a LON-CAPA account in this domain, and you are not permitted to create one.',$form);
571: }
572: return;
573: }
574:
575: 1;
576: __END__
577:
578:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>