1: # The LearningOnline Network
2: # User Authentication Module
3: #
4: # $Id: lonauth.pm,v 1.111 2011/02/24 23:37:50 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonauth;
30:
31: use strict;
32: use LONCAPA;
33: use Apache::Constants qw(:common);
34: use CGI qw(:standard);
35: use DynaLoader; # for Crypt::DES version
36: use Crypt::DES;
37: use Apache::loncommon();
38: use Apache::lonnet;
39: use Apache::lonmenu();
40: use Apache::createaccount;
41: use Fcntl qw(:flock);
42: use Apache::lonlocal;
43: use Apache::File ();
44: use HTML::Entities;
45:
46: # ------------------------------------------------------------ Successful login
47: sub success {
48: my ($r, $username, $domain, $authhost, $lowerurl, $extra_env,
49: $form) = @_;
50:
51: # ------------------------------------------------------------ Get cookie ready
52: my $cookie =
53: &Apache::loncommon::init_user_environment($r, $username, $domain,
54: $authhost, $form,
55: {'extra_env' => $extra_env,});
56:
57: my $public=($username eq 'public' && $domain eq 'public');
58:
59: if ($public or $lowerurl eq 'noredirect') { return $cookie; }
60:
61: # -------------------------------------------------------------------- Log this
62:
63: &Apache::lonnet::log($domain,$username,$authhost,
64: "Login $ENV{'REMOTE_ADDR'}");
65:
66: # ------------------------------------------------- Check for critical messages
67:
68: my @what=&Apache::lonnet::dump('critical',$domain,$username);
69: if ($what[0]) {
70: if (($what[0] ne 'con_lost') && ($what[0]!~/^error\:/)) {
71: $lowerurl='/adm/email?critical=display';
72: }
73: }
74:
75: # ------------------------------------------------------------ Get cookie ready
76: $cookie="lonID=$cookie; path=/";
77: # -------------------------------------------------------- Menu script and info
78: my $destination = $lowerurl;
79:
80: if (defined($form->{role})) {
81: my $envkey = 'user.role.'.$form->{role};
82: my $now=time;
83: my $then=$env{'user.login.time'};
84: my $refresh=$env{'user.refresh.time'};
85: my $update=$env{'user.update.time'};
86: if (!$update) {
87: $update = $then;
88: }
89: if (exists($env{$envkey})) {
90: my ($role,$where,$trolecode,$tstart,$tend,$tremark,$tstatus);
91: &Apache::lonnet::role_status($envkey,$update,$refresh,$now,\$role,\$where,
92: \$trolecode,\$tstatus,\$tstart,\$tend);
93: if ($tstatus eq 'is') {
94: $destination .= ($destination =~ /\?/) ? '&' : '?';
95: my $newrole = &HTML::Entities::encode($form->{role},'"<>&');
96: $destination .= 'selectrole=1&'.$newrole.'=1';
97: }
98: }
99: }
100: if (defined($form->{symb})) {
101: my $destsymb = $form->{symb};
102: $destination .= ($destination =~ /\?/) ? '&' : '?';
103: if ($destsymb =~ /___/) {
104: # FIXME Need to deal with encrypted symbs and urls as needed.
105: my ($map,$resid,$desturl)=split(/___/,$destsymb);
106: unless ($desturl=~/^(adm|uploaded|editupload|public)/) {
107: $desturl = &Apache::lonnet::clutter($desturl);
108: }
109: $desturl = &HTML::Entities::encode($desturl,'"<>&');
110: $destsymb = &HTML::Entities::encode($destsymb,'"<>&');
111: $destination .= '&destinationurl='.$desturl.
112: '&destsymb='.$destsymb;
113: } else {
114: $destsymb = &HTML::Entities::encode($destsymb,'"<>&');
115: $destination .= '&destinationurl='.$destsymb;
116: }
117: }
118: if ($destination =~ m{^/adm/roles}) {
119: $destination .= ($destination =~ /\?/) ? '&' : '?';
120: $destination .= 'source=login';
121: }
122:
123: my $windowinfo = Apache::lonhtmlcommon::scripttag('self.name="loncapaclient";');
124: my $header = '<meta HTTP-EQUIV="Refresh" CONTENT="0; url='.$destination.'" />';
125: my $brcrum = [{'href' => '',
126: 'text' => 'Successful Login'},];
127: my $start_page=&Apache::loncommon::start_page('Successful Login',
128: $header,
129: {'bread_crumbs' => $brcrum,});
130: my $end_page =&Apache::loncommon::end_page();
131:
132: my $continuelink='<a href="'.$destination.'">'.&mt('Continue').'</a>';
133: # ------------------------------------------------- Output for successful login
134:
135: &Apache::loncommon::content_type($r,'text/html');
136: $r->header_out('Set-cookie' => $cookie);
137: $r->send_http_header;
138:
139: my %lt=&Apache::lonlocal::texthash(
140: 'wel' => 'Welcome',
141: 'mes' => 'Welcome to the Learning<i>Online</i> Network with CAPA. Please wait while your session is being set up.',
142: 'pro' => 'Login problems?',
143: 'log' => 'loginproblems.html',
144: );
145: $r->print(<<ENDSUCCESS);
146: $start_page
147: $windowinfo
148: <h1>$lt{'wel'}</h1>
149: $lt{'mes'}<p>
150: <a href="/adm/$lt{'log'}">$lt{'pro'}</a></p>
151: $continuelink
152: $end_page
153: ENDSUCCESS
154: }
155:
156: # --------------------------------------------------------------- Failed login!
157:
158: sub failed {
159: my ($r,$message,$form) = @_;
160: my $start_page = &Apache::loncommon::start_page('Unsuccessful Login',undef);
161: my $retry = '/adm/login?username='.$form->{'uname'}.
162: '&domain='.$form->{'udom'};
163: if (exists($form->{role})) {
164: $retry .= '&role='.$form->{role};
165: }
166: if (exists($form->{symb})) {
167: $retry .= '&symb='.$form->{symb};
168: }
169: my $end_page = &Apache::loncommon::end_page();
170: &Apache::loncommon::content_type($r,'text/html');
171: $r->send_http_header;
172: $r->print(
173: $start_page
174: .'<h1>'.&mt('Sorry ...').'</h1>'
175: .'<p class="LC_warning">'.&mt($message).'</p>'
176: .'<p>'.&mt('Please [_1]log in again[_2].','<a href="'.$retry.'">','</a>')
177: .'</p>'
178: .'<p><a href="/adm/loginproblems.html">'.&mt('Login problems?').'</a></p>'
179: .$end_page
180: );
181: }
182:
183: # ------------------------------------------------------------------ Rerouting!
184:
185: sub reroute {
186: my ($r) = @_;
187: &Apache::loncommon::content_type($r,'text/html');
188: $r->send_http_header;
189: my $msg='<h1>'.&mt('Sorry ...').'</h1>'
190: .&mt('Please [_1]log in again[_2].');
191: &Apache::loncommon::simple_error_page($r,'Rerouting',$msg);
192: }
193:
194: # ---------------------------------------------------------------- Main handler
195:
196: sub handler {
197: my $r = shift;
198: my $form;
199: # Are we re-routing?
200: if (-e '/home/httpd/html/lon-status/reroute.txt') {
201: &reroute($r);
202: return OK;
203: }
204:
205: &Apache::lonlocal::get_language_handle($r);
206:
207: # -------------------------------- Prevent users from attempting to login twice
208: my $handle = &Apache::lonnet::check_for_valid_session($r);
209: if ($handle ne '') {
210: my $lonidsdir=$r->dir_config('lonIDsDir');
211: if ($handle=~/^publicuser\_/) {
212: # For "public user" - remove it, we apparently really want to login
213: unlink($r->dir_config('lonIDsDir')."/$handle.id");
214: } else {
215: # Indeed, a valid token is found
216: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
217: &Apache::loncommon::content_type($r,'text/html');
218: $r->send_http_header;
219: my $start_page =
220: &Apache::loncommon::start_page('Already logged in');
221: my $end_page =
222: &Apache::loncommon::end_page();
223: my $dest = '/adm/roles';
224: if ($env{'form.firsturl'} ne '') {
225: $dest = $env{'form.firsturl'};
226: }
227: $r->print(
228: $start_page
229: .'<h1>'.&mt('You are already logged in!').'</h1>'
230: .'<p>'.&mt('Please either [_1]continue the current session[_2] or [_3]log out[_4].'
231: ,'<a href="'.$dest.'">','</a>','<a href="/adm/logout">','</a>')
232: .'</p>'
233: .$end_page
234: );
235: return OK;
236: }
237: }
238:
239: # ---------------------------------------------------- No valid token, continue
240:
241:
242: my $buffer;
243: if ($r->header_in('Content-length') > 0) {
244: $r->read($buffer,$r->header_in('Content-length'),0);
245: }
246: my %form;
247: foreach my $pair (split(/&/,$buffer)) {
248: my ($name,$value) = split(/=/,$pair);
249: $value =~ tr/+/ /;
250: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
251: $form{$name}=$value;
252: }
253:
254: if ((!$form{'uname'}) || (!$form{'upass0'}) || (!$form{'udom'})) {
255: &failed($r,'Username, password and domain need to be specified.',
256: \%form);
257: return OK;
258: }
259:
260: # split user logging in and "su"-user
261:
262: ($form{'uname'},$form{'suname'})=split(/\:/,$form{'uname'});
263: $form{'uname'} = &LONCAPA::clean_username($form{'uname'});
264: $form{'suname'}= &LONCAPA::clean_username($form{'suname'});
265: $form{'udom'} = &LONCAPA::clean_domain( $form{'udom'});
266:
267: my $role = $r->dir_config('lonRole');
268: my $domain = $r->dir_config('lonDefDomain');
269: my $prodir = $r->dir_config('lonUsersDir');
270: my $contact_name = &mt('LON-CAPA helpdesk');
271:
272: # ---------------------------------------- Get the information from login token
273:
274: my $tmpinfo=Apache::lonnet::reply('tmpget:'.$form{'logtoken'},
275: $form{'serverid'});
276:
277: if (($tmpinfo=~/^error/) || ($tmpinfo eq 'con_lost')) {
278: &failed($r,'Information needed to verify your login information is missing, inaccessible or expired.',\%form);
279: return OK;
280: } else {
281: my $reply = &Apache::lonnet::reply('tmpdel:'.$form{'logtoken'},
282: $form{'serverid'});
283: if ( $reply ne 'ok' ) {
284: &failed($r,'Session could not be opened.',\%form);
285: &Apache::lonnet::logthis("ERROR got a reply of $reply when trying to contact ". $form{'serverid'}." to get login token");
286: return OK;
287: }
288: }
289:
290: if (!&Apache::lonnet::domain($form{'udom'})) {
291: &failed($r,'The domain you provided is not a valid LON-CAPA domain.',\%form);
292: return OK;
293: }
294:
295: my ($key,$firsturl,$rolestr,$symbstr)=split(/&/,$tmpinfo);
296: if ($rolestr) {
297: $rolestr = &unescape($rolestr);
298: }
299: if ($symbstr) {
300: $symbstr= &unescape($symbstr);
301: }
302: if ($rolestr =~ /^role=/) {
303: (undef,$form{'role'}) = split('=',$rolestr);
304: }
305: if ($symbstr =~ /^symb=/) {
306: (undef,$form{'symb'}) = split('=',$symbstr);
307: }
308:
309: my $keybin=pack("H16",$key);
310:
311: my $cipher;
312: if ($Crypt::DES::VERSION>=2.03) {
313: $cipher=new Crypt::DES $keybin;
314: }
315: else {
316: $cipher=new DES $keybin;
317: }
318: my $upass='';
319: for (my $i=0;$i<=2;$i++) {
320: my $chunk=
321: $cipher->decrypt(unpack("a8",pack("H16",substr($form{'upass'.$i},0,16))));
322:
323: $chunk.=
324: $cipher->decrypt(unpack("a8",pack("H16",substr($form{'upass'.$i},16,16))));
325:
326: $chunk=substr($chunk,1,ord(substr($chunk,0,1)));
327: $upass.=$chunk;
328: }
329:
330: # ---------------------------------------------------------------- Authenticate
331: my @cancreate;
332: my %domconfig = &Apache::lonnet::get_dom('configuration',['usercreation'],$form{'udom'});
333: if (ref($domconfig{'usercreation'}) eq 'HASH') {
334: if (ref($domconfig{'usercreation'}{'cancreate'}) eq 'HASH') {
335: if (ref($domconfig{'usercreation'}{'cancreate'}{'selfcreate'}) eq 'ARRAY') {
336: @cancreate = @{$domconfig{'usercreation'}{'cancreate'}{'selfcreate'}};
337: } elsif (($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne 'none') &&
338: ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne '')) {
339: @cancreate = ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'});
340: }
341: }
342: }
343: my $defaultauth;
344: if (grep(/^login$/,@cancreate)) {
345: $defaultauth = 1;
346: }
347: my $clientcancheckhost = 1;
348: my $authhost=Apache::lonnet::authenticate($form{'uname'},$upass,
349: $form{'udom'},$defaultauth,
350: $clientcancheckhost);
351:
352: # --------------------------------------------------------------------- Failed?
353:
354: if ($authhost eq 'no_host') {
355: &failed($r,'Username and/or password could not be authenticated.',
356: \%form);
357: return OK;
358: } elsif ($authhost eq 'no_account_on_host') {
359: my %domconfig =
360: &Apache::lonnet::get_dom('configuration',['usercreation'],$form{'udom'});
361: if (grep(/^login$/,@cancreate)) {
362: my $domdesc = &Apache::lonnet::domain($form{'udom'},'description');
363: unless (&check_can_host($r,\%form,'no_account_on_host',$domdesc)) {
364: return OK;
365: }
366: my $start_page =
367: &Apache::loncommon::start_page('Create a user account in LON-CAPA');
368: my $lonhost = $r->dir_config('lonHostID');
369: my $origmail = $Apache::lonnet::perlvar{'lonSupportEMail'};
370: my $contacts =
371: &Apache::loncommon::build_recipient_list(undef,'helpdeskmail',
372: $form{'udom'},$origmail);
373: my ($contact_email) = split(',',$contacts);
374: my $output = &Apache::createaccount::username_check($form{'uname'},
375: $form{'udom'},$domdesc,'',
376: $lonhost,$contact_email,$contact_name);
377: &Apache::loncommon::content_type($r,'text/html');
378: $r->send_http_header;
379: &Apache::createaccount::print_header($r,$start_page);
380: $r->print('<h3>'.&mt('Account creation').'</h3>'.
381: &mt('Although your username and password were authenticated, you do not currently have a LON-CAPA account at this institution.').'<br />'.
382: $output.&Apache::loncommon::end_page());
383: return OK;
384: } else {
385: &failed($r,'Although your username and password were authenticated, you do not currently have a LON-CAPA account in this domain, and you are not permitted to create one.',\%form);
386: return OK;
387: }
388: }
389:
390: if (($firsturl eq '') ||
391: ($firsturl=~/^\/adm\/(logout|remote)/)) {
392: $firsturl='/adm/roles';
393: }
394: # --------------------------------- Are we attempting to login as somebody else?
395: if ($form{'suname'}) {
396: # ------------ see if the original user has enough privileges to pull this stunt
397: if (&Apache::lonnet::privileged($form{'uname'},$form{'udom'})) {
398: # ---------------------------------------------------- see if the su-user exists
399: unless (&Apache::lonnet::homeserver($form{'suname'},$form{'udom'})
400: eq 'no_host') {
401: &Apache::lonnet::logthis(&Apache::lonnet::homeserver($form{'suname'},$form{'udom'}));
402: # ------------------------------ see if the su-user is not too highly privileged
403: unless (&Apache::lonnet::privileged($form{'suname'},$form{'udom'})) {
404: # -------------------------------------------------------- actually switch users
405: &Apache::lonnet::logperm('User '.$form{'uname'}.' at '.$form{'udom'}.
406: ' logging in as '.$form{'suname'});
407: $form{'uname'}=$form{'suname'};
408: } else {
409: &Apache::lonnet::logthis('Attempted switch user to privileged user');
410: }
411: }
412: } else {
413: &Apache::lonnet::logthis('Non-privileged user attempting switch user');
414: }
415: }
416:
417: unless (&check_can_host($r,\%form,$authhost)) {
418: return OK;
419: }
420:
421: if ($r->dir_config("lonBalancer") eq 'yes') {
422: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',undef,
423: \%form);
424: my ($otherserver) = &Apache::lonnet::choose_server($form{'udom'});
425: $r->internal_redirect('/adm/switchserver?otherserver='.$otherserver.'&origurl='.$firsturl);
426: return OK;
427: } else {
428: # ------------------------------------------------------- Do the load balancing
429:
430: # ---------------------------------------------------------- Determine own load
431: my $loadlim = $r->dir_config('lonLoadLim');
432: my $loadavg;
433: {
434: my $loadfile=Apache::File->new('/proc/loadavg');
435: $loadavg=<$loadfile>;
436: }
437: $loadavg =~ s/\s.*//g;
438: my $loadpercent=sprintf("%.1f",100*$loadavg/$loadlim);
439: my $userloadpercent=&Apache::lonnet::userload();
440:
441: # ---------------------------------------------------------- Are we overloaded?
442: if ((($userloadpercent>100.0)||($loadpercent>100.0))) {
443: my $unloaded=Apache::lonnet::spareserver($loadpercent,$userloadpercent,1,$form{'udom'});
444: if ($unloaded) {
445: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',
446: undef,\%form);
447: $r->internal_redirect('/adm/switchserver?otherserver='.$unloaded.'&origurl='.$firsturl);
448: return OK;
449: }
450: }
451: &success($r,$form{'uname'},$form{'udom'},$authhost,$firsturl,undef,
452: \%form);
453: return OK;
454: }
455: }
456:
457: sub check_can_host {
458: my ($r,$form,$authhost,$domdesc) = @_;
459: return unless (ref($form) eq 'HASH');
460: my $canhost = 1;
461: my $lonhost = $r->dir_config('lonHostID');
462: my $udom = $form->{'udom'};
463: my @intdoms;
464: my $internet_names = &Apache::lonnet::get_internet_names($lonhost);
465: if (ref($internet_names) eq 'ARRAY') {
466: @intdoms = @{$internet_names};
467: }
468: my $uprimary_id = &Apache::lonnet::domain($udom,'primary');
469: my $uint_dom = &Apache::lonnet::internet_dom($uprimary_id);
470: unless ($uint_dom ne '' && grep(/^\Q$uint_dom\E$/,@intdoms)) {
471: my $machine_dom = &Apache::lonnet::host_domain($lonhost);
472: my $hostname = &Apache::lonnet::hostname($lonhost);
473: my $serverhomeID = &Apache::lonnet::get_server_homeID($hostname);
474: my $serverhomedom = &Apache::lonnet::host_domain($serverhomeID);
475: my %defdomdefaults = &Apache::lonnet::get_domain_defaults($serverhomedom);
476: my %udomdefaults = &Apache::lonnet::get_domain_defaults($udom);
477: my $loncaparev;
478: if ($authhost eq 'no_account_on_host') {
479: $loncaparev = &Apache::lonnet::get_server_loncaparev($machine_dom);
480: } else {
481: $loncaparev = &Apache::lonnet::get_server_loncaparev($machine_dom,$lonhost);
482: }
483: $canhost = &Apache::lonnet::can_host_session($udom,$lonhost,$loncaparev,
484: $udomdefaults{'remotesessions'},
485: $defdomdefaults{'hostedsessions'});
486: }
487: unless ($canhost) {
488: if ($authhost eq 'no_account_on_host') {
489: my ($login_host,$hostname) = &Apache::lonnet::choose_server($udom);
490: &Apache::loncommon::content_type($r,'text/html');
491: $r->send_http_header;
492: if ($login_host ne '') {
493: my $protocol = $Apache::lonnet::protocol{$login_host};
494: $protocol = 'http' if ($protocol ne 'https');
495: my $newurl = $protocol.'://'.$hostname.'/adm/createaccount';
496: $r->print(&Apache::loncommon::start_page('Create a user account in LON-CAPA').
497: '<h3>'.&mt('Account creation').'</h3>'.
498: &mt('You do not currently have a LON-CAPA account at this institution.').'<br />'.
499: '<p>'.&mt('You will be able to create one by logging into a LON-CAPA server within the [_1] domain.',$domdesc).'</p>'.
500: '<p>'.&mt('[_1]Log in[_2]','<a href="'.$newurl.'">','</a>').
501: &Apache::loncommon::end_page());
502: } else {
503: $r->print(&Apache::loncommon::start_page('Access to LON-CAPA unavailable').
504: '<h3>'.&mt('Account creation unavailable').'</h3>'.
505: &mt('You do not currently have a LON-CAPA account at this institution.').'<br />'.
506: '<p>'.&mt('Currently a LON-CAPA server is not available within the [_1] domain for you to log-in to, to create an account.',$domdesc).'</p>'.
507: &Apache::loncommon::end_page());
508: }
509: } else {
510: &success($r,$form->{'uname'},$udom,$authhost,'noredirect',undef,
511: $form);
512: my ($otherserver) = &Apache::lonnet::choose_server($udom);
513: $r->internal_redirect('/adm/switchserver?otherserver='.$otherserver);
514: }
515: }
516: return $canhost;
517: }
518:
519: 1;
520: __END__
521:
522:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>