1: # The LearningOnline Network
2: # User Authentication Module
3: #
4: # $Id: lonauth.pm,v 1.82.2.1 2006/10/06 14:29:44 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonauth;
30:
31: use strict;
32: use LONCAPA;
33: use Apache::Constants qw(:common);
34: use CGI qw(:standard);
35: use CGI::Cookie();
36: use DynaLoader; # for Crypt::DES version
37: use Crypt::DES;
38: use Apache::loncommon();
39: use Apache::lonnet;
40: use Apache::lonmenu();
41: use Fcntl qw(:flock);
42: use Apache::lonlocal;
43:
44: my %FORM;
45:
46: # ------------------------------------------------------------ Successful login
47:
48: sub success {
49: my ($r, $username, $domain, $authhost, $lowerurl, $extra_env) = @_;
50: my $lonids=$r->dir_config('lonIDsDir');
51:
52: my $public=($username eq 'public' && $domain eq 'public');
53:
54: # See if old ID present, if so, remove
55:
56: my ($filename,$cookie,$userroles);
57: my $now=time;
58:
59: if ($public) {
60: my $max_public=100;
61: my $oldest;
62: my $oldest_time=0;
63: for(my $next=1;$next<=$max_public;$next++) {
64: if (-e $lonids."/publicuser_$next.id") {
65: my $mtime=(stat($lonids."/publicuser_$next.id"))[9];
66: if ($mtime<$oldest_time || !$oldest_time) {
67: $oldest_time=$mtime;
68: $oldest=$next;
69: }
70: } else {
71: $cookie="publicuser_$next";
72: last;
73: }
74: }
75: if (!$cookie) { $cookie="publicuser_$oldest"; }
76: } else {
77: opendir(DIR,$lonids);
78: while ($filename=readdir(DIR)) {
79: if ($filename=~/^$username\_\d+\_$domain\_$authhost\.id$/) {
80: unlink($lonids.'/'.$filename);
81: }
82: }
83: closedir(DIR);
84:
85: # Give them a new cookie
86:
87: $cookie="$username\_$now\_$domain\_$authhost";
88:
89: # Initialize roles
90:
91: $userroles=&Apache::lonnet::rolesinit($domain,$username,$authhost);
92: }
93: # ------------------------------------ Check browser type and MathML capability
94:
95: my ($httpbrowser,$clientbrowser,$clientversion,$clientmathml,
96: $clientunicode,$clientos) = &Apache::loncommon::decode_user_agent($r);
97:
98: # -------------------------------------- Any accessibility options to remember?
99: if (($FORM{'interface'}) && ($FORM{'remember'} eq 'true')) {
100: foreach ('imagesuppress','appletsuppress',
101: 'embedsuppress','fontenhance','blackwhite') {
102: if ($FORM{$_} eq 'true') {
103: &Apache::lonnet::put('environment',{$_ => 'on'},
104: $domain,$username);
105: } else {
106: &Apache::lonnet::del('environment',[$_],$domain,$username);
107: }
108: }
109: }
110: # ------------------------------------------------------------- Get environment
111:
112: my %userenv=Apache::lonnet::dump('environment',$domain,$username);
113: my ($tmp) = keys(%userenv);
114: if ($tmp !~ /^(con_lost|error|no_such_host)/i) {
115: # default remote control to off
116: if ($userenv{'remote'} ne 'on') { $userenv{'remote'} = 'off'; }
117: } else {
118: undef(%userenv);
119: }
120: if (($userenv{'interface'}) && (!$FORM{'interface'})) {
121: $FORM{'interface'}=$userenv{'interface'};
122: }
123: $env{'environment.remote'}=$userenv{'remote'};
124: if ($userenv{'texengine'} eq 'ttm') { $clientmathml=1; }
125:
126: # --------------- Do not trust query string to be put directly into environment
127: foreach ('imagesuppress','appletsuppress',
128: 'embedsuppress','fontenhance','blackwhite',
129: 'interface','localpath','localres') {
130: $FORM{$_}=~s/[\n\r\=]//gs;
131: }
132: # --------------------------------------------------------- Write first profile
133:
134: {
135: my %initial_env =
136: ("user.name" => $username,
137: "user.domain" => $domain,
138: "user.home" => $authhost,
139: "browser.type" => $clientbrowser,
140: "browser.version" => $clientversion,
141: "browser.mathml" => $clientmathml,
142: "browser.unicode" => $clientunicode,
143: "browser.os" => $clientos,
144: "server.domain" => $r->dir_config('lonDefDomain'),
145: "request.course.fn" => '',
146: "request.course.uri" => '',
147: "request.course.sec" => '',
148: "request.role" => 'cm',
149: "request.role.adv" => $env{'user.adv'},
150: "request.host" => $ENV{'REMOTE_ADDR'},);
151:
152: if ($FORM{'localpath'}) {
153: $initial_env{"browser.localpath"} = $FORM{'localpath'};
154: $initial_env{"browser.localres"} = $FORM{'localres'};
155: }
156:
157: if ($public) {
158: $initial_env{"environment.remote"} = "off";
159: }
160: if ($FORM{'interface'}) {
161: $FORM{'interface'}=~s/\W//gs;
162: $initial_env{"browser.interface"} = $FORM{'interface'};
163: $env{'browser.interface'}=$FORM{'interface'};
164: foreach my $option ('imagesuppress','appletsuppress',
165: 'embedsuppress','fontenhance','blackwhite') {
166: if (($FORM{$option} eq 'true') ||
167: ($userenv{$option} eq 'on')) {
168: $initial_env{"browser.$option"} = "on";
169: }
170: }
171: }
172:
173: $env{'user.environment'} = "$lonids/$cookie.id";
174: open(my $idf,">$lonids/$cookie.id");
175: unless (flock($idf,LOCK_EX)) {
176: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
177: 'Could not obtain exclusive lock in lonauth: '.$!);
178: close($idf);
179: return 'error: '.$!;
180: }
181:
182: &add_to_env($idf,\%initial_env);
183: &add_to_env($idf,\%userenv,'environment.');
184: &add_to_env($idf,$userroles);
185: &add_to_env($idf,$extra_env);
186: close($idf);
187: }
188: $env{'request.role'}='cm';
189: $env{'request.role.adv'}=$env{'user.adv'};
190: $env{'browser.type'}=$clientbrowser;
191: # -------------------------------------------------------------------- Log this
192:
193: &Apache::lonnet::log($domain,$username,$authhost,
194: "Login $ENV{'REMOTE_ADDR'}");
195:
196: # ------------------------------------------------- Check for critical messages
197:
198: my @what=&Apache::lonnet::dump('critical',$domain,$username);
199: if ($what[0]) {
200: if (($what[0] ne 'con_lost') && ($what[0]!~/^error\:/)) {
201: $lowerurl='/adm/email?critical=display';
202: }
203: }
204:
205: # ------------------------------------------------------------ Get cookie ready
206:
207: if ($public or $lowerurl eq 'noredirect') { return $cookie; }
208:
209: $cookie="lonID=$cookie; path=/";
210: # -------------------------------------------------------- Menu script and info
211: my $windowinfo=&Apache::lonmenu::open($clientos);
212: my $startupremote=&Apache::lonmenu::startupremote($lowerurl);
213: my $remoteinfo=&Apache::lonmenu::load_remote_msg($lowerurl);
214: my $setflags=&Apache::lonmenu::setflags();
215: my $maincall=&Apache::lonmenu::maincall();
216: my $start_page=&Apache::loncommon::start_page('Successful Login',
217: $startupremote,
218: {'no_inline_link' => 1,});
219: my $end_page =&Apache::loncommon::end_page();
220:
221: my $continuelink;
222: if (($env{'browser.interface'} eq 'textual') ||
223: ($env{'environment.remote'} eq 'off')) {
224: $continuelink="<a href=\"$lowerurl\">".&mt('Continue')."</a>";
225: }
226: # ------------------------------------------------- Output for successful login
227:
228: &Apache::loncommon::content_type($r,'text/html');
229: $r->header_out('Set-cookie' => $cookie);
230: $r->send_http_header;
231:
232: my %lt=&Apache::lonlocal::texthash(
233: 'wel' => 'Welcome',
234: 'mes' => 'Welcome to the Learning<i>Online</i> Network with CAPA. Please wait while your session is being set up',
235: 'pro' => 'Problems',
236: 'log' => 'loginproblems.html',
237: );
238: $r->print(<<ENDSUCCESS);
239: $start_page
240: $setflags
241: $windowinfo
242: <h1>$lt{'wel'}</h1>
243: $lt{'mes'}.<p>
244: <a href="/adm/$lt{'log'}">$lt{'pro'}?</a></p>
245: $remoteinfo
246: $maincall
247: $continuelink
248: $end_page
249: ENDSUCCESS
250: }
251:
252: sub add_to_env {
253: my ($idf,$env_data,$prefix) = @_;
254: while (my ($key,$value) = each(%$env_data)) {
255: print $idf (&escape($prefix.$key).'='.&escape($value)."\n");
256: $env{$prefix.$key} = $value;
257: }
258: }
259:
260: # --------------------------------------------------------------- Failed login!
261:
262: sub failed {
263: my ($r,$message) = @_;
264: my $start_page = &Apache::loncommon::start_page('Unsuccessful Login',undef,
265: {'no_inline_link' => 1,});
266: my $end_page = &Apache::loncommon::end_page();
267:
268: my %lt=('sorry' => &mt('Sorry ...'),
269: 'please' =>
270: &mt('Please [_1]log in again[_2].',
271: "<a href=\"/adm/login?username=$FORM{'uname'}&domain=$FORM{'udom'}\">",
272: '</a>'),
273: 'problemspage' => &mt('loginproblems.html'),
274: 'problems' => 'Problems',
275: );
276: &Apache::loncommon::content_type($r,'text/html');
277: $r->send_http_header;
278:
279: $r->print(<<ENDFAILED);
280: $start_page
281: <h1>$lt{'sorry'}</h1>
282: <p><b>$message</b></p>
283: <p>$lt{'please'}</p>
284: <p>
285: <a href="/adm/$lt{'problemspage'}">$lt{'problems'}</a></p>
286: $end_page
287: ENDFAILED
288: }
289:
290: # ------------------------------------------------------------------ Rerouting!
291:
292: sub reroute {
293: my ($r) = @_;
294: &Apache::loncommon::content_type($r,'text/html');
295: $r->send_http_header;
296: my $msg='<h1>Sorry ...</h1>
297: Please <a href="/">log in again</a>.';
298: &Apache::loncommon::simple_error_page($r,'Rerouting',$msg);
299: }
300:
301: # ---------------------------------------------------------------- Main handler
302:
303: sub handler {
304: my $r = shift;
305:
306: # Are we re-routing?
307: if (-e '/home/httpd/html/lon-status/reroute.txt') {
308: &reroute($r);
309: return OK;
310: }
311:
312: &Apache::lonlocal::get_language_handle($r);
313:
314: # -------------------------------- Prevent users from attempting to login twice
315: my %cookies=CGI::Cookie->parse($r->header_in('Cookie'));
316: my $lonid=$cookies{'lonID'};
317: my $cookie;
318: if ($lonid) {
319: my $handle=$lonid->value;
320: $handle=~s/\W//g;
321: my $lonidsdir=$r->dir_config('lonIDsDir');
322: if ((-e "$lonidsdir/$handle.id") && ($handle ne '')) {
323: # Indeed, a valid token is found
324: &Apache::loncommon::content_type($r,'text/html');
325: $r->send_http_header;
326: my $start_page =
327: &Apache::loncommon::start_page('Already logged in');
328: my $end_page =
329: &Apache::loncommon::end_page();
330: $r->print(<<ENDFAILED);
331: $start_page
332: <h1>You are already logged in</h1>
333: <p>Please either <a href="/adm/roles">continue the current session</a> or
334: <a href="/adm/logout">logout</a>.</p>
335: <p>
336: <a href="/adm/loginproblems.html">Problems?</a></p>
337: $end_page
338: ENDFAILED
339: return OK;
340: }
341: }
342:
343: # ---------------------------------------------------- No valid token, continue
344:
345:
346: my $buffer;
347: if ($r->header_in('Content-length') > 0) {
348: $r->read($buffer,$r->header_in('Content-length'),0);
349: }
350: my @pairs=split(/&/,$buffer);
351: my $pair; my $name; my $value;
352: undef %FORM;
353: %FORM=();
354: foreach $pair (@pairs) {
355: ($name,$value) = split(/=/,$pair);
356: $value =~ tr/+/ /;
357: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
358: $FORM{$name}=$value;
359: }
360:
361: if ((!$FORM{'uname'}) || (!$FORM{'upass0'}) || (!$FORM{'udom'})) {
362: failed($r,'Username, password and domain need to be specified.');
363: return OK;
364: }
365:
366: # split user logging in and "su"-user
367:
368: ($FORM{'uname'},$FORM{'suname'})=split(/\:/,$FORM{'uname'});
369: $FORM{'uname'} =~ s/\W//g;
370: $FORM{'suname'} =~ s/\W//g;
371: $FORM{'udom'} =~ s/\W//g;
372:
373: my $role = $r->dir_config('lonRole');
374: my $domain = $r->dir_config('lonDefDomain');
375: my $prodir = $r->dir_config('lonUsersDir');
376:
377: # ---------------------------------------- Get the information from login token
378:
379: my $tmpinfo=Apache::lonnet::reply('tmpget:'.$FORM{'logtoken'},
380: $FORM{'serverid'});
381:
382: if (($tmpinfo=~/^error/) || ($tmpinfo eq 'con_lost')) {
383: failed($r,'Information needed to verify your login information is missing, inaccessible or expired.');
384: return OK;
385: } else {
386: my $reply = &Apache::lonnet::reply('tmpdel:'.$FORM{'logtoken'},
387: $FORM{'serverid'});
388: if ( $reply ne 'ok' ) {
389: &failed($r,'Session could not be opened.');
390: &Apache::lonnet::logthis("ERROR got a reply of $reply when trying to contact ". $FORM{'serverid'}." to get login token");
391: return OK;
392: }
393: }
394: my ($key,$firsturl)=split(/&/,$tmpinfo);
395:
396: my $keybin=pack("H16",$key);
397:
398: my $cipher;
399: if ($Crypt::DES::VERSION>=2.03) {
400: $cipher=new Crypt::DES $keybin;
401: }
402: else {
403: $cipher=new DES $keybin;
404: }
405: my $upass='';
406: for (my $i=0;$i<=2;$i++) {
407: my $chunk=
408: $cipher->decrypt(unpack("a8",pack("H16",substr($FORM{'upass'.$i},0,16))));
409:
410: $chunk.=
411: $cipher->decrypt(unpack("a8",pack("H16",substr($FORM{'upass'.$i},16,16))));
412:
413: $chunk=substr($chunk,1,ord(substr($chunk,0,1)));
414: $upass.=$chunk;
415: }
416:
417: # ---------------------------------------------------------------- Authenticate
418: my $authhost=Apache::lonnet::authenticate($FORM{'uname'},
419: $upass,
420: $FORM{'udom'});
421:
422: # --------------------------------------------------------------------- Failed?
423:
424: if ($authhost eq 'no_host') {
425: failed($r,'Username and/or password could not be authenticated.');
426: return OK;
427: }
428:
429: if (($firsturl eq '') ||
430: ($firsturl=~/^\/adm\/(logout|remote)/)) {
431: $firsturl='/adm/roles';
432: }
433: # --------------------------------- Are we attempting to login as somebody else?
434: if ($FORM{'suname'}) {
435: # ------------ see if the original user has enough privileges to pull this stunt
436: if (&Apache::lonnet::privileged($FORM{'uname'},$FORM{'udom'})) {
437: # ---------------------------------------------------- see if the su-user exists
438: unless (&Apache::lonnet::homeserver($FORM{'suname'},$FORM{'udom'})
439: eq 'no_host') {
440: &Apache::lonnet::logthis(&Apache::lonnet::homeserver($FORM{'suname'},$FORM{'udom'}));
441: # ------------------------------ see if the su-user is not too highly privileged
442: unless (&Apache::lonnet::privileged($FORM{'suname'},$FORM{'udom'})) {
443: # -------------------------------------------------------- actually switch users
444: &Apache::lonnet::logperm('User '.$FORM{'uname'}.' at '.$FORM{'udom'}.
445: ' logging in as '.$FORM{'suname'});
446: $FORM{'uname'}=$FORM{'suname'};
447: } else {
448: &Apache::lonnet::logthis('Attempted switch user to privileged user');
449: }
450: }
451: } else {
452: &Apache::lonnet::logthis('Non-privileged user attempting switch user');
453: }
454: }
455: if ($r->dir_config("lonBalancer") eq 'yes') {
456: &success($r,$FORM{'uname'},$FORM{'udom'},$authhost,'noredirect');
457: $r->internal_redirect('/adm/switchserver');
458: } else {
459: &success($r,$FORM{'uname'},$FORM{'udom'},$authhost,$firsturl);
460: }
461: return OK;
462: }
463:
464: 1;
465: __END__
466:
467:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>