1: # The LearningOnline Network
2: # Login Screen
3: #
4: # $Id: lonlogin.pm,v 1.136 2010/03/31 23:11:48 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonlogin;
30:
31: use strict;
32: use Apache::Constants qw(:common);
33: use Apache::File ();
34: use Apache::lonnet;
35: use Apache::loncommon();
36: use Apache::lonauth();
37: use Apache::lonlocal;
38: use Apache::migrateuser();
39: use lib '/home/httpd/lib/perl/';
40: use LONCAPA;
41:
42: sub handler {
43: my $r = shift;
44:
45: &Apache::loncommon::get_unprocessed_cgi
46: (join('&',$ENV{'QUERY_STRING'},$env{'request.querystring'},
47: $ENV{'REDIRECT_QUERY_STRING'}),
48: ['interface','username','domain','firsturl','localpath','localres',
49: 'token','role','symb']);
50: if (!defined($env{'form.firsturl'})) {
51: &Apache::lonacc::get_posted_cgi($r,['firsturl']);
52: }
53:
54: # -- check if they are a migrating user
55: if (defined($env{'form.token'})) {
56: return &Apache::migrateuser::handler($r);
57: }
58:
59: &Apache::loncommon::no_cache($r);
60: &Apache::lonlocal::get_language_handle($r);
61: &Apache::loncommon::content_type($r,'text/html');
62: $r->send_http_header;
63: return OK if $r->header_only;
64:
65:
66: # Are we re-routing?
67: if (-e '/home/httpd/html/lon-status/reroute.txt') {
68: &Apache::lonauth::reroute($r);
69: return OK;
70: }
71:
72:
73: # -------------------------------- Prevent users from attempting to login twice
74: my $handle = &Apache::lonnet::check_for_valid_session($r);
75: if ($handle ne '') {
76: my $lonidsdir=$r->dir_config('lonIDsDir');
77: if ($handle=~/^publicuser\_/) {
78: # For "public user" - remove it, we apparently really want to login
79: unlink($r->dir_config('lonIDsDir')."/$handle.id");
80: } else {
81: # Indeed, a valid token is found
82: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
83: my $start_page =
84: &Apache::loncommon::start_page('Already logged in');
85: my $end_page =
86: &Apache::loncommon::end_page();
87: my $dest = '/adm/roles';
88: if ($env{'form.firsturl'} ne '') {
89: $dest = $env{'form.firsturl'};
90: }
91: $r->print(
92: $start_page
93: .'<h1>'.&mt('You are already logged in!').'</h1>'
94: .'<p>'.&mt('Please either [_1]continue the current session[_2] or [_3]log out[_4].',
95: '<a href="'.$dest.'">','</a>','<a href="/adm/logout">','</a>').'</p>'
96: .$end_page
97: );
98: return OK;
99: }
100: }
101:
102: # ---------------------------------------------------- No valid token, continue
103:
104: # ---------------------------- Not possible to really login to domain "public"
105: if ($env{'form.domain'} eq 'public') {
106: $env{'form.domain'}='';
107: $env{'form.username'}='';
108: }
109: # ----------------------------------------------------------- Process Interface
110: $env{'form.interface'}=~s/\W//g;
111:
112: my $httpbrowser=$ENV{"HTTP_USER_AGENT"};
113:
114: my $iconpath=
115: &Apache::loncommon::lonhttpdurl($r->dir_config('lonIconsURL'));
116:
117: my $lonhost = $r->dir_config('lonHostID');
118: my $domain = &Apache::lonnet::default_login_domain();
119: if ($lonhost ne '') {
120: my $redirect = &check_loginvia($domain,$lonhost);
121: if ($redirect) {
122: $r->print($redirect);
123: return OK;
124: }
125: }
126:
127: if (($env{'form.domain'}) &&
128: (&Apache::lonnet::domain($env{'form.domain'},'description'))) {
129: $domain=$env{'form.domain'};
130: }
131: my $role = $r->dir_config('lonRole');
132: my $loadlim = $r->dir_config('lonLoadLim');
133: my $servadm = $r->dir_config('lonAdmEMail');
134: my $tabdir = $r->dir_config('lonTabDir');
135: my $include = $r->dir_config('lonIncludes');
136: my $expire = $r->dir_config('lonExpire');
137: my $version = $r->dir_config('lonVersion');
138: my $host_name = &Apache::lonnet::hostname($lonhost);
139:
140: # --------------------------------------------- Default values for login fields
141:
142: my $authusername=($env{'form.username'}?$env{'form.username'}:'');
143: my $authdomain=($env{'form.domain'}?$env{'form.domain'}:$domain);
144:
145: # ---------------------------------------------------------- Determine own load
146: my $loadavg;
147: {
148: my $loadfile=Apache::File->new('/proc/loadavg');
149: $loadavg=<$loadfile>;
150: }
151: $loadavg =~ s/\s.*//g;
152: my $loadpercent=sprintf("%.1f",100*$loadavg/$loadlim);
153: my $userloadpercent=&Apache::lonnet::userload();
154:
155: # ------------------------------------------------------- Do the load balancing
156: my $otherserver= &Apache::lonnet::absolute_url($host_name);
157: my $firsturl=
158: ($env{'request.firsturl'}?$env{'request.firsturl'}:$env{'form.firsturl'});
159: # ---------------------------------------------------------- Are we overloaded?
160: if ((($userloadpercent>100.0)||($loadpercent>100.0))) {
161: my $unloaded=Apache::lonnet::spareserver($loadpercent,$userloadpercent);
162: if ($unloaded) { $otherserver=$unloaded; }
163: }
164:
165: # ----------------------------------------------------------- Get announcements
166: my $announcements=&Apache::lonnet::getannounce();
167: # -------------------------------------------------------- Set login parameters
168:
169: my @hexstr=('0','1','2','3','4','5','6','7',
170: '8','9','a','b','c','d','e','f');
171: my $lkey='';
172: for (0..7) {
173: $lkey.=$hexstr[rand(15)];
174: }
175:
176: my $ukey='';
177: for (0..7) {
178: $ukey.=$hexstr[rand(15)];
179: }
180:
181: my $lextkey=hex($lkey);
182: if ($lextkey>2147483647) { $lextkey-=4294967296; }
183:
184: my $uextkey=hex($ukey);
185: if ($uextkey>2147483647) { $uextkey-=4294967296; }
186:
187: # -------------------------------------------------------- Store away log token
188: my $tokenextras;
189: if ($env{'form.role'}) {
190: $tokenextras = '&role='.&escape($env{'form.role'});
191: }
192: if ($env{'form.symb'}) {
193: if (!$tokenextras) {
194: $tokenextras = '&';
195: }
196: $tokenextras .= '&symb='.&escape($env{'form.symb'});
197: }
198: my $logtoken=Apache::lonnet::reply(
199: 'tmpput:'.$ukey.$lkey.'&'.$firsturl.$tokenextras,
200: $lonhost);
201:
202: # ------------------- If we cannot talk to ourselves, we are in serious trouble
203:
204: if ($logtoken eq 'con_lost') {
205: my $spares='';
206: my $last;
207: foreach my $hostid (sort
208: {
209: &Apache::lonnet::hostname($a) cmp
210: &Apache::lonnet::hostname($b);
211: }
212: keys(%Apache::lonnet::spareid)) {
213: next if ($hostid eq $lonhost);
214: my $hostname = &Apache::lonnet::hostname($hostid);
215: next if ($last eq $hostname);
216: $spares.='<br /><font size="+1"><a href="http://'.
217: $hostname.
218: '/adm/login?domain='.$authdomain.'">'.
219: $hostname.'</a>'.
220: ' '.&mt('(preferred)').'</font>'.$/;
221: $last=$hostname;
222: }
223: $spares.= '<br />';
224: my %all_hostnames = &Apache::lonnet::all_hostnames();
225: foreach my $hostid (sort
226: {
227: &Apache::lonnet::hostname($a) cmp
228: &Apache::lonnet::hostname($b);
229: }
230: keys(%all_hostnames)) {
231: next if ($hostid eq $lonhost || $Apache::lonnet::spareid{$hostid});
232: my $hostname = &Apache::lonnet::hostname($hostid);
233: next if ($last eq $hostname);
234: $spares.='<br /><a href="http://'.
235: $hostname.
236: '/adm/login?domain='.$authdomain.'">'.
237: $hostname.'</a>';
238: $last=$hostname;
239: }
240: $r->print(
241: '<html>'
242: .'<head><title>'
243: .&mt('The LearningOnline Network with CAPA')
244: .'</title></head>'
245: .'<body bgcolor="#FFFFFF">'
246: .'<h1>'.&mt('The LearningOnline Network with CAPA').'</h1>'
247: .'<img src="/adm/lonKaputt/lonlogo_broken.gif" align="right" />'
248: .'<h3>'.&mt('This LON-CAPA server is temporarily not available for login.').'</h3>'
249: .'<p>'.&mt('Please attempt to login to one of the following servers:').'</p>'
250: .$spares
251: .'</body>'
252: .'</html>'
253: );
254: return OK;
255: }
256:
257: # ----------------------------------------------- Apparently we are in business
258: $servadm=~s/\,/\<br \/\>/g;
259:
260: # ----------------------------------------------------------- Front page design
261: my $pgbg=&Apache::loncommon::designparm('login.pgbg',$domain);
262: my $font=&Apache::loncommon::designparm('login.font',$domain);
263: my $link=&Apache::loncommon::designparm('login.link',$domain);
264: my $vlink=&Apache::loncommon::designparm('login.vlink',$domain);
265: my $alink=&Apache::loncommon::designparm('login.alink',$domain);
266: my $mainbg=&Apache::loncommon::designparm('login.mainbg',$domain);
267: my $logo=&Apache::loncommon::designparm('login.logo',$domain);
268: my $img=&Apache::loncommon::designparm('login.img',$domain);
269: my $domainlogo='<div>'.&Apache::loncommon::domainlogo($domain).'</div>';
270: my $login=&Apache::loncommon::designparm('login.login',$domain);
271: if ($login eq '') {
272: $login = $iconpath.'/'.&mt('userauthentication.gif');
273: }
274: my $showbanner = 1;
275: my $showmainlogo = 1;
276: if (defined(&Apache::loncommon::designparm('login.showlogo_img',$domain))) {
277: $showbanner = &Apache::loncommon::designparm('login.showlogo_img',$domain);
278: }
279: if (defined(&Apache::loncommon::designparm('login.showlogo_logo',$domain))) {
280: $showmainlogo = &Apache::loncommon::designparm('login.showlogo_logo',$domain);
281: }
282: my $showadminmail=&Apache::loncommon::designparm('login.adminmail',$domain);
283: my $showcoursecat =
284: &Apache::loncommon::designparm('login.coursecatalog',$domain);
285: my $loginheader =&Apache::loncommon::designparm('login.loginheader',$domain);
286: my $shownewuserlink =
287: &Apache::loncommon::designparm('login.newuser',$domain);
288: my $now=time;
289: my $js = (<<ENDSCRIPT);
290:
291: <script type="text/javascript" language="JavaScript">
292: // <![CDATA[
293: function send()
294: {
295: this.document.server.elements.uname.value
296: =this.document.client.elements.uname.value;
297:
298: this.document.server.elements.udom.value
299: =this.document.client.elements.udom.value;
300:
301: uextkey=this.document.client.elements.uextkey.value;
302: lextkey=this.document.client.elements.lextkey.value;
303: initkeys();
304:
305: this.document.server.elements.upass0.value
306: =crypted(this.document.client.elements.upass$now.value.substr(0,15));
307: this.document.server.elements.upass1.value
308: =crypted(this.document.client.elements.upass$now.value.substr(15,15));
309: this.document.server.elements.upass2.value
310: =crypted(this.document.client.elements.upass$now.value.substr(30,15));
311:
312: this.document.client.elements.uname.value='';
313: this.document.client.elements.upass$now.value='';
314:
315: this.document.server.submit();
316: return false;
317: }
318: // ]]>
319: </script>
320:
321: ENDSCRIPT
322:
323: # --------------------------------------------------- Print login screen header
324:
325: my %add_entries = (
326: bgcolor => "$mainbg",
327: text => "$font",
328: link => "$link",
329: vlink => "$vlink",
330: alink => "$alink",);
331:
332: $r->print(&Apache::loncommon::start_page('The LearningOnline Network with CAPA Login',$js,
333: { 'redirect' => [$expire,'/adm/roles'],
334: 'add_entries' => \%add_entries,
335: 'only_body' => 1,}));
336:
337: # ----------------------------------------------------------------------- Texts
338:
339: my %lt=&Apache::lonlocal::texthash(
340: 'un' => 'Username',
341: 'pw' => 'Password',
342: 'dom' => 'Domain',
343: 'perc' => 'percent',
344: 'load' => 'Server Load',
345: 'userload' => 'User Load',
346: 'catalog' => 'Course/Community Catalog',
347: 'log' => 'Log in',
348: 'help' => 'Log-in Help',
349: 'serv' => 'Server',
350: 'servadm' => 'Server Administration',
351: 'helpdesk' => 'Contact Helpdesk',
352: 'forgotpw' => 'Forgot password?',
353: 'newuser' => 'New User?',
354: );
355: # -------------------------------------------------- Change password field name
356:
357: my $forgotpw = &forgotpwdisplay(%lt);
358: $forgotpw .= '<br />' if $forgotpw;
359: my $loginhelp = &loginhelpdisplay($authdomain,%lt);
360: $loginhelp .= '<br />' if $loginhelp;
361:
362: # ---------------------------------------------------- Serve out DES JavaScript
363: {
364: my $jsh=Apache::File->new($include."/londes.js");
365: $r->print(<$jsh>);
366: }
367: # ---------------------------------------------------------- Serve rest of page
368:
369: $r->print(
370: '<div class="LC_loginpage_container">');
371:
372: #
373: # If the loadbalancing yielded just http:// because perhaps there's no loadbalancing?
374: # then just us a relative link to authenticate:
375: #
376:
377: $r->print(<<ENDSERVERFORM);
378: <form name="server" action="$otherserver/adm/authenticate" method="post" target="_top">
379: <input type="hidden" name="logtoken" value="$logtoken" />
380: <input type="hidden" name="serverid" value="$lonhost" />
381: <input type="hidden" name="uname" value="" />
382: <input type="hidden" name="upass0" value="" />
383: <input type="hidden" name="upass1" value="" />
384: <input type="hidden" name="upass2" value="" />
385: <input type="hidden" name="udom" value="" />
386: <input type="hidden" name="localpath" value="$env{'form.localpath'}" />
387: <input type="hidden" name="localres" value="$env{'form.localres'}" />
388: </form>
389: ENDSERVERFORM
390: my $coursecatalog;
391: if (($showcoursecat eq '') || ($showcoursecat)) {
392: $coursecatalog = &coursecatalog_link($lt{'catalog'}).'<br />';
393: }
394: my $newuserlink;
395: if ($shownewuserlink) {
396: $newuserlink = &newuser_link($lt{'newuser'}).'<br />';
397: }
398: my $logintitle;
399: if ($loginheader eq 'text') {
400: $logintitle ='<h2>'.$lt{'log'}.'</h2>';
401: } else {
402: $logintitle = '<img src="'.$login.'" alt="'.
403: &mt('User Authentication').'" />';
404: }
405:
406: my $noscript_warning='<noscript><span class="LC_warning"><b>'
407: .&mt('Use of LON-CAPA requires Javascript to be enabled in your web browser.')
408: .'</b></span></noscript>';
409: my $helpdeskscript;
410: my $contactblock = &contactdisplay(\%lt,$servadm,$showadminmail,
411: $authdomain,\$helpdeskscript);
412:
413: my $loginform=(<<LFORM);
414: <form name="client" action="" onsubmit="return(send())">
415: <input type="hidden" name="lextkey" value="$lextkey" />
416: <input type="hidden" name="uextkey" value="$uextkey" />
417: <b><label for="uname">$lt{'un'}</label>:</b><br />
418: <input type="text" name="uname" id="uname" size="15" value="$authusername" /><br />
419: <b><label for="upass$now">$lt{'pw'}</label>:</b><br />
420: <input type="password" name="upass$now" id="upass$now" size="15" /><br />
421: <b><label for="udom">$lt{'dom'}</label>:</b><br />
422: <input type="text" name="udom" id="udom" size="15" value="$authdomain" /><br />
423: <input type="submit" value="$lt{'log'}" />
424: </form>
425: LFORM
426:
427: if ($showbanner) {
428: $r->print(<<HEADER);
429: <!-- The LON-CAPA Header -->
430: <div style="background:$pgbg;margin:0;width:100%;">
431: <img src="$img" border="0" alt="The Learning Online Network with CAPA" />
432: </div>
433: HEADER
434: }
435: $r->print(<<ENDTOP);
436: <div class="LC_loginpage_space"> </div>
437: <div class="LC_loginpage_floatLeft">
438: <div class="LC_loginpage_loginContainer">
439: $logintitle
440: <table border="0" align="left" cellspacing="1" cellpadding="2" width="100%">
441: <tr>
442: <td>
443: $loginform
444: </td>
445: </tr>
446: </table>
447: $noscript_warning
448: </div>
449:
450: <div class="LC_loginpage_loginInfo">
451: $loginhelp
452: $forgotpw
453: $contactblock
454: $newuserlink
455: $coursecatalog
456: </div>
457: </div>
458: ENDTOP
459: if ($showmainlogo) {
460: $r->print(' <img src="'.$logo.'" alt="" />'."\n");
461: }
462: $r->print(<<ENDTOP);
463: $announcements
464: $domainlogo
465: <div class="LC_loginpage_space"> </div>
466: ENDTOP
467:
468: $r->print(<<ENDDOCUMENT);
469: <table border="0" cellspacing="0" cellpadding="0">
470: <tr>
471: <td align="left" valign="top">
472: <small><b>$lt{'dom'}: </b></small>
473: </td>
474: <td align="left" valign="top">
475: <small><tt> $domain</tt></small>
476: </td>
477: </tr>
478: <tr>
479: <td align="left" valign="top">
480: <small><b>$lt{'serv'}: </b></small>
481: </td>
482: <td align="left" valign="top">
483: <small><tt> $lonhost ($role)</tt></small>
484: </td>
485: </tr>
486: <tr>
487: <td align="left" valign="top">
488: <small><b>$lt{'load'}: </b></small>
489: </td>
490: <td align="left" valign="top">
491: <small><tt> $loadpercent $lt{'perc'}</tt></small>
492: </td>
493: </tr>
494: <tr>
495: <td align="left" valign="top">
496: <small><b>$lt{'userload'}: </b></small>
497: </td>
498: <td align="left" valign="top">
499: <small><tt> $userloadpercent $lt{'perc'}</tt></small>
500: </td>
501: </tr>
502: <tr>
503: <td colspan="2" align="left">
504: <small>$version</small>
505: </td>
506: </tr>
507: </table>
508: </div>
509:
510: <script type="text/javascript">
511: // <![CDATA[
512: // the if prevents the script error if the browser can not handle this
513: if ( document.client.uname ) { document.client.uname.focus(); }
514: // ]]>
515: </script>
516: $helpdeskscript
517:
518: ENDDOCUMENT
519: my %endargs = ( 'noredirectlink' => 1, );
520: $r->print(&Apache::loncommon::end_page(\%endargs));
521: return OK;
522: }
523:
524: sub check_loginvia {
525: my ($domain,$lonhost) = @_;
526: if ($domain eq '' || $lonhost eq '') {
527: return;
528: }
529: my %domconfhash = &Apache::loncommon::get_domainconf($domain);
530: my $loginvia = $domconfhash{$domain.'.login.loginvia_'.$lonhost};
531: my $loginvia_exempt = $domconfhash{$domain.'.login.loginvia_exempt_'.$lonhost};
532: my $output;
533: if ($loginvia ne '') {
534: my $noredirect;
535: my $ip = $ENV{'REMOTE_ADDR'};
536: if ($ip eq '127.0.0.1') {
537: $noredirect = 1;
538: } else {
539: if ($loginvia_exempt ne '') {
540: my @exempt = split(',',$loginvia_exempt);
541: if (grep(/^\Q$ip\E$/,@exempt)) {
542: $noredirect = 1;
543: }
544: }
545: }
546: unless ($noredirect) {
547: my ($newhost,$path);
548: if ($loginvia =~ /:/) {
549: ($newhost,$path) = split(':',$loginvia);
550: } else {
551: $newhost = $loginvia;
552: }
553: if ($newhost ne $lonhost) {
554: if (&Apache::lonnet::hostname($newhost) ne '') {
555: $output = &redirect_page($newhost,$path);
556: }
557: }
558: }
559: }
560: return $output;
561: }
562:
563: sub redirect_page {
564: my ($desthost,$path) = @_;
565: my $protocol = $Apache::lonnet::protocol{$desthost};
566: $protocol = 'http' if ($protocol ne 'https');
567: unless ($path =~ m{^/}) {
568: $path = '/'.$path;
569: }
570: my $url = $protocol.'://'.&Apache::lonnet::hostname($desthost).$path;
571: if ($env{'form.firsturl'} ne '') {
572: $url .='?firsturl='.$env{'form.firsturl'};
573: }
574: my $start_page = &Apache::loncommon::start_page('Switching Server ...',undef,
575: {'redirect' => [0,$url],});
576: my $end_page = &Apache::loncommon::end_page();
577: return $start_page.$end_page;
578: }
579:
580: sub contactdisplay {
581: my ($lt,$servadm,$showadminmail,$authdomain,$helpdeskscript) = @_;
582: my $contactblock;
583: my $showhelpdesk = 0;
584: my $requestmail = $Apache::lonnet::perlvar{'lonSupportEMail'};
585: if ($requestmail =~ m/^[^\@]+\@[^\@]+$/) {
586: $showhelpdesk = 1;
587: }
588: if ($servadm && $showadminmail) {
589: $contactblock .= $$lt{'servadm'}.':<br />'.
590: '<tt>'.$servadm.'</tt><br />';
591: }
592: if ($showhelpdesk) {
593: $contactblock .= '<a href="javascript:helpdesk()">'.$lt->{'helpdesk'}.'</a><br />';
594: my $thisurl = &escape('/adm/login');
595: $$helpdeskscript = <<"ENDSCRIPT";
596: <script type="text/javascript">
597: // <![CDATA[
598: function helpdesk() {
599: var codedom = document.client.udom.value;
600: if (codedom == '') {
601: codedom = "$authdomain";
602: }
603: var querystr = "origurl=$thisurl&codedom="+codedom;
604: document.location.href = "/adm/helpdesk?"+querystr;
605: return;
606: }
607: // ]]>
608: </script>
609: ENDSCRIPT
610: }
611: return $contactblock;
612: }
613:
614: sub forgotpwdisplay {
615: my (%lt) = @_;
616: my $prompt_for_resetpw = 1;
617: if ($prompt_for_resetpw) {
618: return '<a href="/adm/resetpw">'.$lt{'forgotpw'}.'</a>';
619: }
620: return;
621: }
622:
623: sub loginhelpdisplay {
624: my ($authdomain,%lt) = @_;
625: my $login_help = 1;
626: if ($login_help) {
627: my $dom = $authdomain;
628: if ($dom eq '') {
629: $dom = &Apache::lonnet::default_login_domain();
630: }
631: my %helpconfig = &Apache::lonnet::get_dom('configuration',['helpsettings'],$dom);
632: my $loginhelp_url = $helpconfig{'helpsettings'}{'loginhelpurl'};
633: if ($loginhelp_url ne '') {
634: return '<a href="'.$loginhelp_url.'">'.$lt{'help'}.'</a>';
635: } else {
636: return '<a href="/adm/loginproblems.html">'.$lt{'help'}.'</a>';
637: }
638: }
639: return;
640: }
641:
642: sub coursecatalog_link {
643: my ($linkname) = @_;
644: return <<"END";
645: <span class="LC_nobreak"><a href="/adm/coursecatalog">$linkname</a></span>
646: END
647: }
648:
649: sub newuser_link {
650: my ($linkname) = @_;
651: return '<a href="/adm/createaccount">'.$linkname.'</a>';
652: }
653:
654: 1;
655: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>