Return to randomlylabel.pm CVS log

Up to [LON-CAPA] / loncom / homework

- hey, lets actually send that http header

#!/usr/bin/perl
# The LearningOnline Network with CAPA
# randomlabel.png: composite together text and images into 1 image
#
# $Id: randomlylabel.pm,v 1.12.2.1 2004/02/11 21:52:56 albertel Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#
###

package Apache::randomlylabel;

use strict;
use Image::Magick;
use Apache::Constants qw(:common);
use Apache::loncommon();
use GD;

sub get_image {
    my ($imgsrc,$set_trans)=@_;
    my $image;
    if ($imgsrc !~ /\.(png|jpg|jpeg)$/i) {
	my $conv_image = Image::Magick->new;
	my $current_figure = $conv_image->Read('filename'=>$imgsrc);
	$conv_image->Set('magick'=>'png');
	my @blobs=$conv_image->ImageToBlob();
	undef $conv_image;
	$image = GD::Image->new($blobs[0]);
    } else {
	GD::Image->trueColor(1);
	$image = GD::Image->new($imgsrc);
    }
    if ($set_trans && defined($image)) {
	my $white=$image->colorExact(255,255,255);
	if ($white != -1) { $image->transparent($white); }
    }
    return $image;
}

sub handler {
    my $r = shift;
    $r->content_type('image/png');
    $r->send_http_header;
    my (undef,$id) = split(/=/,$ENV{'QUERY_STRING'});
    my $image=&get_image(&Apache::lonnet::unescape($ENV{"cgi.$id.BGIMG"}),0);
    if (! defined($image)) {
        &Apache::lonnet::logthis('Unable to create image object for -'.$id.'-'.
				 $ENV{"cgi.$id.BGIMG"});
        return OK;
    }
    #binmode(STDOUT);
    my $black;
    if (!($black=$image->colorResolve(0,0,0))) {
	$black = $image->colorClosestHWB(0,0,0);
    }
    for(my $i=0;$i<$ENV{"cgi.$id.ICOUNT"};$i++) {
	my $subimage=&get_image(&Apache::lonnet::unescape($ENV{"cgi.$id.IMG$i"}),1);
	if (!defined($subimage)) {
            &Apache::lonnet::logthis('Unable to create image object for '.
                                 $ENV{"cgi.$id.BGIMG"});
            next;
        }
	$image->copy($subimage,$ENV{"cgi.$id.IX$i"},$ENV{"cgi.$id.IY$i"},
		     0,0,$subimage->getBounds());
    }
    my $height=GD::Font->Giant->height;
    for(my $i=0;$i<$ENV{"cgi.$id.COUNT"};$i++) {
	$image->string(gdGiantFont,$ENV{"cgi.$id.X$i"},
		       $ENV{"cgi.$id.Y$i"}-$height,
		       &Apache::lonnet::unescape($ENV{"cgi.$id.LB$i"}),$black);
    }
    for(my $i=0;$i<$ENV{"cgi.$id.LINECOUNT"};$i++) {
	my ($x1,$y1,$x2,$y2,$color,$width)=split(':',$ENV{"cgi.$id.LINE$i"});
	my (undef,$red,undef,$green,undef,$blue)=split(/(..)/,$color);
	$red=hex($red);$green=hex($green);$blue=hex($blue);
	my $imcolor;
	if (!($imcolor = $image->colorResolve($red,$green,$blue))) {
	    $imcolor = $image->colorClosestHWB($red,$green,$blue);
	}
	$image->setThickness($width);
       	$image->line($x1,$y1,$x2,$y2,$imcolor);
    }
    for(my $i=0;$i<$ENV{"cgi.$id.BOXCOUNT"};$i++) {
	my ($x1,$y1,$x2,$y2,$color,$width)=split(':',$ENV{"cgi.$id.BOX$i"});
	if ($x1 > $x2) { my $temp=$x1;$x1=$x2;$x2=$temp; }
	if ($y1 > $y2) { my $temp=$y1;$y1=$y2;$y2=$temp; }
	my (undef,$red,undef,$green,undef,$blue)=split(/(..)/,$color);
	$red=hex($red);$green=hex($green);$blue=hex($blue);
	my $imcolor;
	if (!($imcolor = $image->colorResolve($red,$green,$blue))) {
	    $imcolor = $image->colorClosestHWB($red,$green,$blue);
	}
	$image->setThickness($width);
       	$image->rectangle($x1,$y1,$x2,$y2,$imcolor);
    }
    $image->setThickness(1);
    $r->print($image->png);
    return OK;
}

1;