1: # The LearningOnline Network with CAPA
2: # Metadata display handler
3: #
4: # $Id: lonmeta.pm,v 1.100 2005/07/15 12:57:53 banghart Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27:
28:
29: package Apache::lonmeta;
30:
31: use strict;
32: use LONCAPA::lonmetadata();
33: use Apache::Constants qw(:common);
34: use Apache::lonnet;
35: use Apache::loncommon();
36: use Apache::lonhtmlcommon();
37: use Apache::lonmsg;
38: use Apache::lonpublisher;
39: use Apache::lonlocal;
40: use Apache::lonmysql;
41: use Apache::lonmsg;
42:
43:
44: ############################################################
45: ############################################################
46: ##
47: ## &get_dynamic_metadata_from_sql($url)
48: ##
49: ## Queries sql database for dynamic metdata
50: ## Returns a hash of hashes, with keys of urls which match $url
51: ## Returned fields are given below.
52: ##
53: ## Examples:
54: ##
55: ## %DynamicMetadata = &Apache::lonmeta::get_dynmaic_metadata_from_sql
56: ## ('/res/msu/korte/');
57: ##
58: ## $DynamicMetadata{'/res/msu/korte/example.problem'}->{$field}
59: ##
60: ############################################################
61: ############################################################
62: sub get_dynamic_metadata_from_sql {
63: my ($url) = shift();
64: my ($authordom,$author)=($url=~m:^/res/(\w+)/(\w+)/:);
65: if (! defined($authordom)) {
66: $authordom = shift();
67: }
68: if (! defined($author)) {
69: $author = shift();
70: }
71: if (! defined($authordom) || ! defined($author)) {
72: return ();
73: }
74: my @Fields = ('url','count','course',
75: 'goto','goto_list',
76: 'comefrom','comefrom_list',
77: 'sequsage','sequsage_list',
78: 'stdno','stdno_list',
79: 'dependencies',
80: 'avetries','avetries_list',
81: 'difficulty','difficulty_list',
82: 'disc','disc_list',
83: 'clear','technical','correct',
84: 'helpful','depth');
85: #
86: my $query = 'SELECT '.join(',',@Fields).
87: ' FROM metadata WHERE url LIKE "'.$url.'%"';
88: my $server = &Apache::lonnet::homeserver($author,$authordom);
89: my $reply = &Apache::lonnet::metadata_query($query,undef,undef,
90: ,[$server]);
91: return () if (! defined($reply) || ref($reply) ne 'HASH');
92: my $filename = $reply->{$server};
93: if (! defined($filename) || $filename =~ /^error/) {
94: return ();
95: }
96: my $max_time = time + 10; # wait 10 seconds for results at most
97: my %ReturnHash;
98: #
99: # Look for results
100: my $finished = 0;
101: while (! $finished && time < $max_time) {
102: my $datafile=$Apache::lonnet::perlvar{'lonDaemons'}.'/tmp/'.$filename;
103: if (! -e "$datafile.end") { next; }
104: my $fh;
105: if (!($fh=Apache::File->new($datafile))) { next; }
106: while (my $result = <$fh>) {
107: chomp($result);
108: next if (! $result);
109: my @Data =
110: map {
111: &Apache::lonnet::unescape($_);
112: } split(',',$result);
113: my $url = $Data[0];
114: for (my $i=0;$i<=$#Fields;$i++) {
115: $ReturnHash{$url}->{$Fields[$i]}=$Data[$i];
116: }
117: }
118: $finished = 1;
119: }
120: #
121: return %ReturnHash;
122: }
123:
124:
125: # Fetch and evaluate dynamic metadata
126: sub dynamicmeta {
127: my $url=&Apache::lonnet::declutter(shift);
128: $url=~s/\.meta$//;
129: my ($adomain,$aauthor)=($url=~/^(\w+)\/(\w+)\//);
130: my $regexp=$url;
131: $regexp=~s/(\W)/\\$1/g;
132: $regexp='___'.$regexp.'___';
133: my %evaldata=&Apache::lonnet::dump('nohist_resevaldata',$adomain,
134: $aauthor,$regexp);
135: my %DynamicData = &LONCAPA::lonmetadata::process_reseval_data(\%evaldata);
136: my %Data = &LONCAPA::lonmetadata::process_dynamic_metadata($url,
137: \%DynamicData);
138: #
139: # Deal with 'count' separately
140: $Data{'count'} = &access_count($url,$aauthor,$adomain);
141: #
142: # Debugging code I will probably need later
143: if (0) {
144: &Apache::lonnet::logthis('Dynamic Metadata');
145: while(my($k,$v)=each(%Data)){
146: &Apache::lonnet::logthis(' "'.$k.'"=>"'.$v.'"');
147: }
148: &Apache::lonnet::logthis('-------------------');
149: }
150: return %Data;
151: }
152:
153: sub access_count {
154: my ($src,$author,$adomain) = @_;
155: my %countdata=&Apache::lonnet::dump('nohist_accesscount',$adomain,
156: $author,$src);
157: if (! exists($countdata{$src})) {
158: return &mt('Not Available');
159: } else {
160: return $countdata{$src};
161: }
162: }
163:
164: # Try to make an alt tag if there is none
165: sub alttag {
166: my ($base,$src)=@_;
167: my $fullpath=&Apache::lonnet::hreflocation($base,$src);
168: my $alttag=&Apache::lonnet::metadata($fullpath,'title').' '.
169: &Apache::lonnet::metadata($fullpath,'subject').' '.
170: &Apache::lonnet::metadata($fullpath,'abstract');
171: $alttag=~s/\s+/ /gs;
172: $alttag=~s/\"//gs;
173: $alttag=~s/\'//gs;
174: $alttag=~s/\s+$//gs;
175: $alttag=~s/^\s+//gs;
176: if ($alttag) {
177: return $alttag;
178: } else {
179: return &mt('No information available');
180: }
181: }
182:
183: # Author display
184: sub authordisplay {
185: my ($aname,$adom)=@_;
186: return &Apache::loncommon::aboutmewrapper
187: (&Apache::loncommon::plainname($aname,$adom),
188: $aname,$adom,'preview').' <tt>['.$aname.'@'.$adom.']</tt>';
189: }
190:
191: # Pretty display
192: sub evalgraph {
193: my $value=shift;
194: if (! $value) {
195: return '';
196: }
197: my $val=int($value*10.+0.5)-10;
198: my $output='<table border="0" cellpadding="0" cellspacing="0"><tr>';
199: if ($val>=20) {
200: $output.='<td width="20" bgcolor="#555555">  </td>';
201: } else {
202: $output.='<td width="'.($val).'" bgcolor="#555555"> </td>'.
203: '<td width="'.(20-$val).'" bgcolor="#FF3333"> </td>';
204: }
205: $output.='<td bgcolor="#FFFF33"> </td>';
206: if ($val>20) {
207: $output.='<td width="'.($val-20).'" bgcolor="#33FF33"> </td>'.
208: '<td width="'.(40-$val).'" bgcolor="#555555"> </td>';
209: } else {
210: $output.='<td width="20" bgcolor="#555555">  </td>';
211: }
212: $output.='<td> ('.sprintf("%5.2f",$value).') </td></tr></table>';
213: return $output;
214: }
215:
216: sub diffgraph {
217: my $value=shift;
218: if (! $value) {
219: return '';
220: }
221: my $val=int(40.0*$value+0.5);
222: my @colors=('#FF9933','#EEAA33','#DDBB33','#CCCC33',
223: '#BBDD33','#CCCC33','#DDBB33','#EEAA33');
224: my $output='<table border="0" cellpadding="0" cellspacing="0"><tr>';
225: for (my $i=0;$i<8;$i++) {
226: if ($val>$i*5) {
227: $output.='<td width="5" bgcolor="'.$colors[$i].'"> </td>';
228: } else {
229: $output.='<td width="5" bgcolor="#555555"> </td>';
230: }
231: }
232: $output.='<td> ('.sprintf("%3.2f",$value).') </td></tr></table>';
233: return $output;
234: }
235:
236:
237: # The field names
238: sub fieldnames {
239: my $file_type=shift;
240: my %fields =
241: ('title' => 'Title',
242: 'author' =>'Author(s)',
243: 'authorspace' => 'Author Space',
244: 'modifyinguser' => 'Last Modifying User',
245: 'subject' => 'Subject',
246: 'keywords' => 'Keyword(s)',
247: 'notes' => 'Notes',
248: 'abstract' => 'Abstract',
249: 'lowestgradelevel' => 'Lowest Grade Level',
250: 'highestgradelevel' => 'Highest Grade Level');
251: if (! defined($file_type) || $file_type ne 'portfolio') {
252: %fields =
253: (%fields,
254: 'domain' => 'Domain',
255: 'standards' => 'Standards',
256: 'mime' => 'MIME Type',
257: 'language' => 'Language',
258: 'creationdate' => 'Creation Date',
259: 'lastrevisiondate' => 'Last Revision Date',
260: 'owner' => 'Publisher/Owner',
261: 'copyright' => 'Copyright/Distribution',
262: 'customdistributionfile' => 'Custom Distribution File',
263: 'sourceavail' => 'Source Available',
264: 'sourcerights' => 'Source Custom Distribution File',
265: 'obsolete' => 'Obsolete',
266: 'obsoletereplacement' => 'Suggested Replacement for Obsolete File',
267: 'count' => 'Network-wide number of accesses (hits)',
268: 'course' => 'Network-wide number of courses using resource',
269: 'course_list' => 'Network-wide courses using resource',
270: 'sequsage' => 'Number of resources using or importing resource',
271: 'sequsage_list' => 'Resources using or importing resource',
272: 'goto' => 'Number of resources that follow this resource in maps',
273: 'goto_list' => 'Resources that follow this resource in maps',
274: 'comefrom' => 'Number of resources that lead up to this resource in maps',
275: 'comefrom_list' => 'Resources that lead up to this resource in maps',
276: 'clear' => 'Material presented in clear way',
277: 'depth' => 'Material covered with sufficient depth',
278: 'helpful' => 'Material is helpful',
279: 'correct' => 'Material appears to be correct',
280: 'technical' => 'Resource is technically correct',
281: 'avetries' => 'Average number of tries till solved',
282: 'stdno' => 'Total number of students who have worked on this problem',
283: 'difficulty' => 'Degree of difficulty',
284: 'disc' => 'Degree of discrimination',
285: 'dependencies' => 'Resources used by this resource',
286: );
287: }
288: return &Apache::lonlocal::texthash(%fields);
289: }
290:
291: sub select_course {
292: my ($r)=@_;
293: $r->print('<h3>Instructor Selected Meta-Data</h3><br />');
294: $r->print('<form action="" method="post">');
295: $r->print('Select your course<br>'.$env{'user.domain'});
296: $r->print('<select name="metacourse" >');
297: $r->print('<input type="submit" >');
298: $r->print('</form>');
299:
300: foreach my $key (keys %env) {
301: if ($key =~ /\.metadata\./) {
302: $r->print('<option>');
303: $r->print($key);
304: $r->print('</option>');
305: }
306: }
307: $r->print('</select><br />');
308: $r->print('<input type="submit" >');
309: $r->print('</form>');
310: return 'ok';
311: }
312: # Pretty printing of metadata field
313:
314: sub prettyprint {
315: my ($type,$value,$target,$prefix,$form,$noformat)=@_;
316: # $target,$prefix,$form are optional and for filecrumbs only
317: if (! defined($value)) {
318: return ' ';
319: }
320: # Title
321: if ($type eq 'title') {
322: return '<font size="+1" face="arial">'.$value.'</font>';
323: }
324: # Dates
325: if (($type eq 'creationdate') ||
326: ($type eq 'lastrevisiondate')) {
327: return ($value?&Apache::lonlocal::locallocaltime(
328: &Apache::lonmysql::unsqltime($value)):
329: &mt('not available'));
330: }
331: # Language
332: if ($type eq 'language') {
333: return &Apache::loncommon::languagedescription($value);
334: }
335: # Copyright
336: if ($type eq 'copyright') {
337: return &Apache::loncommon::copyrightdescription($value);
338: }
339: # Copyright
340: if ($type eq 'sourceavail') {
341: return &Apache::loncommon::source_copyrightdescription($value);
342: }
343: # MIME
344: if ($type eq 'mime') {
345: return '<img src="'.&Apache::loncommon::icon($value).'" /> '.
346: &Apache::loncommon::filedescription($value);
347: }
348: # Person
349: if (($type eq 'author') ||
350: ($type eq 'owner') ||
351: ($type eq 'modifyinguser') ||
352: ($type eq 'authorspace')) {
353: $value=~s/(\w+)(\:|\@)(\w+)/&authordisplay($1,$3)/gse;
354: return $value;
355: }
356: # Gradelevel
357: if (($type eq 'lowestgradelevel') ||
358: ($type eq 'highestgradelevel')) {
359: return &Apache::loncommon::gradeleveldescription($value);
360: }
361: # Only for advance users below
362: if (! $env{'user.adv'}) {
363: return '<i>- '.&mt('not displayed').' -</i>';
364: }
365: # File
366: if (($type eq 'customdistributionfile') ||
367: ($type eq 'obsoletereplacement') ||
368: ($type eq 'goto_list') ||
369: ($type eq 'comefrom_list') ||
370: ($type eq 'sequsage_list') ||
371: ($type eq 'dependencies')) {
372: return '<ul><font size="-1">'.join("\n",map {
373: my $url = &Apache::lonnet::clutter($_);
374: my $title = &Apache::lonnet::gettitle($url);
375: if ($title eq '') {
376: $title = 'Untitled';
377: if ($url =~ /\.sequence$/) {
378: $title .= ' Sequence';
379: } elsif ($url =~ /\.page$/) {
380: $title .= ' Page';
381: } elsif ($url =~ /\.problem$/) {
382: $title .= ' Problem';
383: } elsif ($url =~ /\.html$/) {
384: $title .= ' HTML document';
385: } elsif ($url =~ m:/syllabus$:) {
386: $title .= ' Syllabus';
387: }
388: }
389: $_ = '<li>'.$title.' '.
390: &Apache::lonhtmlcommon::crumbs($url,$target,$prefix,$form,'-1',$noformat).
391: '</li>'
392: } split(/\s*\,\s*/,$value)).'</ul></font>';
393: }
394: # Evaluations
395: if (($type eq 'clear') ||
396: ($type eq 'depth') ||
397: ($type eq 'helpful') ||
398: ($type eq 'correct') ||
399: ($type eq 'technical')) {
400: return &evalgraph($value);
401: }
402: # Difficulty
403: if ($type eq 'difficulty' || $type eq 'disc') {
404: return &diffgraph($value);
405: }
406: # List of courses
407: if ($type=~/\_list/) {
408: my @Courses = split(/\s*\,\s*/,$value);
409: my $Str;
410: foreach my $course (@Courses) {
411: my %courseinfo = &Apache::lonnet::coursedescription($course);
412: if (! exists($courseinfo{'num'}) || $courseinfo{'num'} eq '') {
413: next;
414: }
415: if ($Str ne '') { $Str .= '<br />'; }
416: $Str .= '<a href="/public/'.$courseinfo{'domain'}.'/'.
417: $courseinfo{'num'}.'/syllabus" target="preview">'.
418: $courseinfo{'description'}.'</a>';
419: }
420: return $Str;
421: }
422: # No pretty print found
423: return $value;
424: }
425:
426: # Pretty input of metadata field
427: sub direct {
428: return shift;
429: }
430:
431: sub selectbox {
432: my ($name,$value,$functionref,@idlist)=@_;
433: if (! defined($functionref)) {
434: $functionref=\&direct;
435: }
436: my $selout='<select name="'.$name.'">';
437: foreach (@idlist) {
438: $selout.='<option value=\''.$_.'\'';
439: if ($_ eq $value) {
440: $selout.=' selected>'.&{$functionref}($_).'</option>';
441: }
442: else {$selout.='>'.&{$functionref}($_).'</option>';}
443: }
444: return $selout.'</select>';
445: }
446:
447: sub relatedfield {
448: my ($show,$relatedsearchflag,$relatedsep,$fieldname,$relatedvalue)=@_;
449: if (! $relatedsearchflag) {
450: return '';
451: }
452: if (! defined($relatedsep)) {
453: $relatedsep=' ';
454: }
455: if (! $show) {
456: return $relatedsep.' ';
457: }
458: return $relatedsep.'<input type="checkbox" name="'.$fieldname.'_related"'.
459: ($relatedvalue?' checked="1"':'').' />';
460: }
461:
462: sub prettyinput {
463: my ($type,$value,$fieldname,$formname,
464: $relatedsearchflag,$relatedsep,$relatedvalue,$size)=@_;
465: if (! defined($size)) {
466: $size = 80;
467: }
468: # Language
469: if ($type eq 'language') {
470: return &selectbox($fieldname,
471: $value,
472: \&Apache::loncommon::languagedescription,
473: (&Apache::loncommon::languageids)).
474: &relatedfield(0,$relatedsearchflag,$relatedsep);
475: }
476: # Copyright
477: if ($type eq 'copyright') {
478: return &selectbox($fieldname,
479: $value,
480: \&Apache::loncommon::copyrightdescription,
481: (&Apache::loncommon::copyrightids)).
482: &relatedfield(0,$relatedsearchflag,$relatedsep);
483: }
484: # Source Copyright
485: if ($type eq 'sourceavail') {
486: return &selectbox($fieldname,
487: $value,
488: \&Apache::loncommon::source_copyrightdescription,
489: (&Apache::loncommon::source_copyrightids)).
490: &relatedfield(0,$relatedsearchflag,$relatedsep);
491: }
492: # Gradelevels
493: if (($type eq 'lowestgradelevel') ||
494: ($type eq 'highestgradelevel')) {
495: return &Apache::loncommon::select_level_form($value,$fieldname).
496: &relatedfield(0,$relatedsearchflag,$relatedsep);
497: }
498: # Obsolete
499: if ($type eq 'obsolete') {
500: return '<input type="checkbox" name="'.$fieldname.'"'.
501: ($value?' checked="1"':'').' />'.
502: &relatedfield(0,$relatedsearchflag,$relatedsep);
503: }
504: # Obsolete replacement file
505: if ($type eq 'obsoletereplacement') {
506: return '<input type="text" name="'.$fieldname.
507: '" size="60" value="'.$value.'" /><a href="javascript:openbrowser'.
508: "('".$formname."','".$fieldname."'".
509: ",'')\">".&mt('Select').'</a>'.
510: &relatedfield(0,$relatedsearchflag,$relatedsep);
511: }
512: # Customdistribution file
513: if ($type eq 'customdistributionfile') {
514: return '<input type="text" name="'.$fieldname.
515: '" size="60" value="'.$value.'" /><a href="javascript:openbrowser'.
516: "('".$formname."','".$fieldname."'".
517: ",'rights')\">".&mt('Select').'</a>'.
518: &relatedfield(0,$relatedsearchflag,$relatedsep);
519: }
520: # Source Customdistribution file
521: if ($type eq 'sourcerights') {
522: return '<input type="text" name="'.$fieldname.
523: '" size="60" value="'.$value.'" /><a href="javascript:openbrowser'.
524: "('".$formname."','".$fieldname."'".
525: ",'rights')\">".&mt('Select').'</a>'.
526: &relatedfield(0,$relatedsearchflag,$relatedsep);
527: }
528: # Dates
529: if (($type eq 'creationdate') ||
530: ($type eq 'lastrevisiondate')) {
531: return
532: &Apache::lonhtmlcommon::date_setter($formname,$fieldname,$value).
533: &relatedfield(0,$relatedsearchflag,$relatedsep);
534: }
535: # No pretty input found
536: $value=~s/^\s+//gs;
537: $value=~s/\s+$//gs;
538: $value=~s/\s+/ /gs;
539: $value=~s/\"/\"\;/gs;
540: return
541: '<input type="text" name="'.$fieldname.'" size="'.$size.'" '.
542: 'value="'.$value.'" />'.
543: &relatedfield(1,$relatedsearchflag,$relatedsep,$fieldname,
544: $relatedvalue);
545: }
546:
547: # Main Handler
548: sub handler {
549: my $r=shift;
550: #
551: my $uri=$r->uri;
552: #
553: # Set document type
554: &Apache::loncommon::content_type($r,'text/html');
555: $r->send_http_header;
556: return OK if $r->header_only;
557: #
558: my ($resdomain,$resuser)=
559: (&Apache::lonnet::declutter($uri)=~/^(\w+)\/(\w+)\//);
560: my $html=&Apache::lonxml::xmlbegin();
561: $r->print($html.'<head><title>'.
562: 'Catalog Information'.
563: '</title></head>');
564: if ($uri=~m:/adm/bombs/(.*)$:) {
565: $r->print(&Apache::loncommon::bodytag('Error Messages'));
566: # Looking for all bombs?
567: &report_bombs($r,$uri);
568: } elsif ($uri=~/\/portfolio\//) {
569: $r->print(&Apache::loncommon::bodytag
570: ('Edit Portfolio File Information','','','',$resdomain));
571: &present_editable_metadata($r,$uri,'portfolio');
572: &select_course($r);
573:
574: } elsif ($uri=~/^\/\~/) {
575: # Construction space
576: $r->print(&Apache::loncommon::bodytag
577: ('Edit Catalog Information','','','',$resdomain));
578: &present_editable_metadata($r,$uri);
579: } else {
580: $r->print(&Apache::loncommon::bodytag
581: ('Catalog Information','','','',$resdomain));
582: &present_uneditable_metadata($r,$uri);
583: }
584: $r->print('</body></html>');
585: return OK;
586: }
587:
588: #####################################################
589: #####################################################
590: ### ###
591: ### Report Bombs ###
592: ### ###
593: #####################################################
594: #####################################################
595: sub report_bombs {
596: my ($r,$uri) = @_;
597: # Set document type
598: $uri =~ s:/adm/bombs/::;
599: $uri = &Apache::lonnet::declutter($uri);
600: $r->print('<h1>'.&Apache::lonnet::clutter($uri).'</h1>');
601: my ($domain,$author)=($uri=~/^(\w+)\/(\w+)\//);
602: if (&Apache::loncacc::constructaccess('/~'.$author.'/',$domain)) {
603: if ($env{'form.clearbombs'}) {
604: &Apache::lonmsg::clear_author_res_msg($uri);
605: }
606: my $clear=&mt('Clear all Messages in Subdirectory');
607: $r->print(<<ENDCLEAR);
608: <form method="post">
609: <input type="submit" name="clearbombs" value="$clear" />
610: </form>
611: ENDCLEAR
612: my %brokenurls =
613: &Apache::lonmsg::all_url_author_res_msg($author,$domain);
614: foreach (sort(keys(%brokenurls))) {
615: if ($_=~/^\Q$uri\E/) {
616: $r->print
617: ('<a href="'.&Apache::lonnet::clutter($_).'">'.$_.'</a>'.
618: &Apache::lonmsg::retrieve_author_res_msg($_).
619: '<hr />');
620: }
621: }
622: } else {
623: $r->print(&mt('Not authorized'));
624: }
625: return;
626: }
627:
628: #####################################################
629: #####################################################
630: ### ###
631: ### Uneditable Metadata Display ###
632: ### ###
633: #####################################################
634: #####################################################
635: sub present_uneditable_metadata {
636: my ($r,$uri) = @_;
637: #
638: my %content=();
639: # Read file
640: foreach (split(/\,/,&Apache::lonnet::metadata($uri,'keys'))) {
641: $content{$_}=&Apache::lonnet::metadata($uri,$_);
642: }
643: # Render Output
644: # displayed url
645: my ($thisversion)=($uri=~/\.(\d+)\.(\w+)\.meta$/);
646: $uri=~s/\.meta$//;
647: my $disuri=&Apache::lonnet::clutter($uri);
648: # version
649: my $currentversion=&Apache::lonnet::getversion($disuri);
650: my $versiondisplay='';
651: if ($thisversion) {
652: $versiondisplay=&mt('Version').': '.$thisversion.
653: ' ('.&mt('most recent version').': '.
654: ($currentversion>0 ?
655: $currentversion :
656: &mt('information not available')).')';
657: } else {
658: $versiondisplay='Version: '.$currentversion;
659: }
660: # crumbify displayed URL uri target prefix form size
661: $disuri=&Apache::lonhtmlcommon::crumbs($disuri,undef, undef, undef,'+1');
662: $disuri =~ s:<br />::g;
663: # obsolete
664: my $obsolete=$content{'obsolete'};
665: my $obsoletewarning='';
666: if (($obsolete) && ($env{'user.adv'})) {
667: $obsoletewarning='<p><font color="red">'.
668: &mt('This resource has been marked obsolete by the author(s)').
669: '</font></p>';
670: }
671: #
672: my %lt=&fieldnames();
673: my $table='';
674: my $title = $content{'title'};
675: if (! defined($title)) {
676: $title = 'Untitled Resource';
677: }
678: foreach ('title',
679: 'author',
680: 'subject',
681: 'keywords',
682: 'notes',
683: 'abstract',
684: 'lowestgradelevel',
685: 'highestgradelevel',
686: 'standards',
687: 'mime',
688: 'language',
689: 'creationdate',
690: 'lastrevisiondate',
691: 'owner',
692: 'copyright',
693: 'customdistributionfile',
694: 'sourceavail',
695: 'sourcerights',
696: 'obsolete',
697: 'obsoletereplacement') {
698: $table.='<tr><td bgcolor="#AAAAAA">'.$lt{$_}.
699: '</td><td bgcolor="#CCCCCC">'.
700: &prettyprint($_,$content{$_}).'</td></tr>';
701: delete $content{$_};
702: }
703: #
704: $r->print(<<ENDHEAD);
705: <h2>$title</h2>
706: <p>
707: $disuri<br />
708: $obsoletewarning
709: $versiondisplay
710: </p>
711: <table cellspacing="2" border="0">
712: $table
713: </table>
714: ENDHEAD
715: if ($env{'user.adv'}) {
716: &print_dynamic_metadata($r,$uri,\%content);
717: }
718: return;
719: }
720:
721: sub print_dynamic_metadata {
722: my ($r,$uri,$content) = @_;
723: #
724: my %content = %$content;
725: my %lt=&fieldnames();
726: #
727: my $description = 'Dynamic Metadata (updated periodically)';
728: $r->print('<h3>'.&mt($description).'</h3>'.
729: &mt('Processing'));
730: $r->rflush();
731: my %items=&fieldnames();
732: my %dynmeta=&dynamicmeta($uri);
733: #
734: # General Access and Usage Statistics
735: if (exists($dynmeta{'count'}) ||
736: exists($dynmeta{'sequsage'}) ||
737: exists($dynmeta{'comefrom'}) ||
738: exists($dynmeta{'goto'}) ||
739: exists($dynmeta{'course'})) {
740: $r->print('<h4>'.&mt('Access and Usage Statistics').'</h4>'.
741: '<table cellspacing="2" border="0">');
742: foreach ('count',
743: 'sequsage','sequsage_list',
744: 'comefrom','comefrom_list',
745: 'goto','goto_list',
746: 'course','course_list') {
747: $r->print('<tr><td bgcolor="#AAAAAA">'.$lt{$_}.'</td>'.
748: '<td bgcolor="#CCCCCC">'.
749: &prettyprint($_,$dynmeta{$_})."</td></tr>\n");
750: }
751: $r->print('</table>');
752: } else {
753: $r->print('<h4>'.&mt('No Access or Usages Statistics are available for this resource.').'</h4>');
754: }
755: #
756: # Assessment statistics
757: if ($uri=~/\.(problem|exam|quiz|assess|survey|form)$/) {
758: if (exists($dynmeta{'stdno'}) ||
759: exists($dynmeta{'avetries'}) ||
760: exists($dynmeta{'difficulty'}) ||
761: exists($dynmeta{'disc'})) {
762: # This is an assessment, print assessment data
763: $r->print('<h4>'.
764: &mt('Overall Assessment Statistical Data').
765: '</h4>'.
766: '<table cellspacing="2" border="0">');
767: $r->print('<tr><td bgcolor="#AAAAAA">'.$lt{'stdno'}.'</td>'.
768: '<td bgcolor="#CCCCCC">'.
769: &prettyprint('stdno',$dynmeta{'stdno'}).
770: '</td>'."</tr>\n");
771: foreach ('avetries','difficulty','disc') {
772: $r->print('<tr><td bgcolor="#AAAAAA">'.$lt{$_}.'</td>'.
773: '<td bgcolor="#CCCCCC">'.
774: &prettyprint($_,sprintf('%5.2f',$dynmeta{$_})).
775: '</td>'."</tr>\n");
776: }
777: $r->print('</table>');
778: }
779: if (exists($dynmeta{'stats'})) {
780: #
781: # New assessment statistics
782: $r->print('<h4>'.
783: &mt('Detailed Assessment Statistical Data').
784: '</h4>');
785: my $table = '<table cellspacing="2" border="0">'.
786: '<tr>'.
787: '<th>Course</th>'.
788: '<th>Section(s)</th>'.
789: '<th>Num Students</th>'.
790: '<th>Mean Tries</th>'.
791: '<th>Degree of Difficulty</th>'.
792: '<th>Degree of Discrimination</th>'.
793: '<th>Time of computation</th>'.
794: '</tr>'.$/;
795: foreach my $identifier (sort(keys(%{$dynmeta{'stats'}}))) {
796: my $data = $dynmeta{'stats'}->{$identifier};
797: my $course = $data->{'course'};
798: my %courseinfo = &Apache::lonnet::coursedescription($course);
799: if (! exists($courseinfo{'num'}) || $courseinfo{'num'} eq '') {
800: &Apache::lonnet::logthis('lookup for '.$course.' failed');
801: next;
802: }
803: $table .= '<tr>';
804: $table .=
805: '<td><nobr>'.$courseinfo{'description'}.'</nobr></td>';
806: $table .=
807: '<td align="right">'.$data->{'sections'}.'</td>';
808: $table .=
809: '<td align="right">'.$data->{'stdno'}.'</td>';
810: foreach ('avetries','difficulty','disc') {
811: $table .= '<td align="right">';
812: if (exists($data->{$_})) {
813: $table .= sprintf('%.2f',$data->{$_}).' ';
814: } else {
815: $table .= '';
816: }
817: $table .= '</td>';
818: }
819: $table .=
820: '<td><nobr>'.
821: &Apache::lonlocal::locallocaltime($data->{'timestamp'}).
822: '</nobr></td>';
823: $table .=
824: '</tr>'.$/;
825: }
826: $table .= '</table>'.$/;
827: $r->print($table);
828: } else {
829: $r->print('No new dynamic data found.');
830: }
831: } else {
832: $r->print('<h4>'.
833: &mt('No Assessment Statistical Data is available for this resource').
834: '</h4>');
835: }
836:
837: #
838: #
839: if (exists($dynmeta{'clear'}) ||
840: exists($dynmeta{'depth'}) ||
841: exists($dynmeta{'helpful'}) ||
842: exists($dynmeta{'correct'}) ||
843: exists($dynmeta{'technical'})){
844: $r->print('<h4>'.&mt('Evaluation Data').'</h4>'.
845: '<table cellspacing="2" border="0">');
846: foreach ('clear','depth','helpful','correct','technical') {
847: $r->print('<tr><td bgcolor="#AAAAAA">'.$lt{$_}.'</td>'.
848: '<td bgcolor="#CCCCCC">'.
849: &prettyprint($_,$dynmeta{$_})."</td></tr>\n");
850: }
851: $r->print('</table>');
852: } else {
853: $r->print('<h4>'.&mt('No Evaluation Data is available for this resource.').'</h4>');
854: }
855: $uri=~/^\/res\/(\w+)\/(\w+)\//;
856: if ((($env{'user.domain'} eq $1) && ($env{'user.name'} eq $2))
857: || ($env{'user.role.ca./'.$1.'/'.$2})) {
858: if (exists($dynmeta{'comments'})) {
859: $r->print('<h4>'.&mt('Evaluation Comments').' ('.
860: &mt('visible to author and co-authors only').
861: ')</h4>'.
862: '<blockquote>'.$dynmeta{'comments'}.'</blockquote>');
863: } else {
864: $r->print('<h4>'.&mt('There are no Evaluation Comments on this resource.').'</h4>');
865: }
866: my $bombs = &Apache::lonmsg::retrieve_author_res_msg($uri);
867: if (defined($bombs) && $bombs ne '') {
868: $r->print('<a name="bombs" /><h4>'.&mt('Error Messages').' ('.
869: &mt('visible to author and co-authors only').')'.
870: '</h4>'.$bombs);
871: } else {
872: $r->print('<h4>'.&mt('There are currently no Error Messages for this resource.').'</h4>');
873: }
874: }
875: #
876: # All other stuff
877: $r->print('<h3>'.
878: &mt('Additional Metadata (non-standard, parameters, exports)').
879: '</h3><table border="0" cellspacing="1">');
880: foreach (sort(keys(%content))) {
881: my $name=$_;
882: if ($name!~/\.display$/) {
883: my $display=&Apache::lonnet::metadata($uri,
884: $name.'.display');
885: if (! $display) {
886: $display=$name;
887: };
888: my $otherinfo='';
889: foreach ('name','part','type','default') {
890: if (defined(&Apache::lonnet::metadata($uri,
891: $name.'.'.$_))) {
892: $otherinfo.=' '.$_.'='.
893: &Apache::lonnet::metadata($uri,
894: $name.'.'.$_).'; ';
895: }
896: }
897: $r->print('<tr><td bgcolor="#bbccbb"><font size="-1" color="#556655">'.$display.'</font></td><td bgcolor="#ccddcc"><font size="-1" color="#556655">'.$content{$name});
898: if ($otherinfo) {
899: $r->print(' ('.$otherinfo.')');
900: }
901: $r->print("</font></td></tr>\n");
902: }
903: }
904: $r->print("</table>");
905: return;
906: }
907:
908: #####################################################
909: #####################################################
910: ### ###
911: ### Editable metadata display ###
912: ### ###
913: #####################################################
914: #####################################################
915: sub present_editable_metadata {
916: my ($r,$uri, $file_type) = @_;
917: # Construction Space Call
918: # Header
919: my $disuri=$uri;
920: my $fn=&Apache::lonnet::filelocation('',$uri);
921: $disuri=~s/^\/\~/\/priv\//;
922: $disuri=~s/\.meta$//;
923: my $target=$uri;
924: $target=~s/^\/\~/\/res\/$env{'request.role.domain'}\//;
925: $target=~s/\.meta$//;
926: my $bombs=&Apache::lonmsg::retrieve_author_res_msg($target);
927: if ($bombs) {
928: my $showdel=1;
929: if ($env{'form.delmsg'}) {
930: if (&Apache::lonmsg::del_url_author_res_msg($target) eq 'ok') {
931: $bombs=&mt('Messages deleted.');
932: $showdel=0;
933: } else {
934: $bombs=&mt('Error deleting messages');
935: }
936: }
937: if ($env{'form.clearmsg'}) {
938: my $cleardir=$target;
939: $cleardir=~s/\/[^\/]+$/\//;
940: if (&Apache::lonmsg::clear_author_res_msg($cleardir) eq 'ok') {
941: $bombs=&mt('Messages cleared.');
942: $showdel=0;
943: } else {
944: $bombs=&mt('Error clearing messages');
945: }
946: }
947: my $del=&mt('Delete Messages for this Resource');
948: my $clear=&mt('Clear all Messages in Subdirectory');
949: my $goback=&mt('Back to Source File');
950: $r->print(<<ENDBOMBS);
951: <h1>$disuri</h1>
952: <form method="post" name="defaultmeta">
953: ENDBOMBS
954: if ($showdel) {
955: $r->print(<<ENDDEL);
956: <input type="submit" name="delmsg" value="$del" />
957: <input type="submit" name="clearmsg" value="$clear" />
958: ENDDEL
959: } else {
960: $r->print('<a href="'.$disuri.'" />'.$goback.'</a>');
961: }
962: $r->print('<br />'.$bombs);
963: } else {
964: my $displayfile='Catalog Information for '.$disuri;
965: if ($disuri=~/\/default$/) {
966: my $dir=$disuri;
967: $dir=~s/default$//;
968: $displayfile=
969: &mt('Default Cataloging Information for Directory').' '.
970: $dir;
971: }
972: %Apache::lonpublisher::metadatafields=();
973: %Apache::lonpublisher::metadatakeys=();
974: my $result=&Apache::lonnet::getfile($fn);
975: if ($result == -1){
976: $r->print('Creating new '.$fn);
977: } else {
978: &Apache::lonpublisher::metaeval($result);
979: }
980: $r->print(<<ENDEDIT);
981: <h1>$displayfile</h1>
982: <form method="post" name="defaultmeta">
983: ENDEDIT
984: $r->print('<script language="JavaScript">'.
985: &Apache::loncommon::browser_and_searcher_javascript().
986: '</script>');
987: my %lt=&fieldnames($file_type);
988: my $output;
989: my @fields;
990: if ($file_type eq 'portfolio') {
991: @fields = ('author','title','subject','keywords','abstract','notes','lowestgradelevel',
992: 'highestgradelevel');
993: } else {
994: @fields = ('author','title','subject','keywords','abstract','notes',
995: 'copyright','customdistributionfile','language',
996: 'standards',
997: 'lowestgradelevel','highestgradelevel','sourceavail','sourcerights',
998: 'obsolete','obsoletereplacement');
999: }
1000: foreach (@fields) {
1001: if (defined($env{'form.new_'.$_})) {
1002: $Apache::lonpublisher::metadatafields{$_}=
1003: $env{'form.new_'.$_};
1004: }
1005: if (! $Apache::lonpublisher::metadatafields{'copyright'}) {
1006: $Apache::lonpublisher::metadatafields{'copyright'}=
1007: 'default';
1008: }
1009: $output.=('<p>'.$lt{$_}.': '.
1010: &prettyinput($_,
1011: $Apache::lonpublisher::metadatafields{$_},
1012: 'new_'.$_,'defaultmeta').'</p>');
1013: }
1014: if ($env{'form.store'}) {
1015: my $mfh;
1016: my $formname='store';
1017: my $file_content;
1018: foreach (sort keys %Apache::lonpublisher::metadatafields) {
1019: next if ($_ =~ /\./);
1020: my $unikey=$_;
1021: $unikey=~/^([A-Za-z]+)/;
1022: my $tag=$1;
1023: $tag=~tr/A-Z/a-z/;
1024: $file_content.= "\n\<$tag";
1025: foreach (split(/\,/,
1026: $Apache::lonpublisher::metadatakeys{$unikey})
1027: ) {
1028: my $value=
1029: $Apache::lonpublisher::metadatafields{$unikey.'.'.$_};
1030: $value=~s/\"/\'\'/g;
1031: $file_content.=' '.$_.'="'.$value.'"' ;
1032: # print $mfh ' '.$_.'="'.$value.'"';
1033: }
1034: $file_content.= '>'.
1035: &HTML::Entities::encode
1036: ($Apache::lonpublisher::metadatafields{$unikey},
1037: '<>&"').
1038: '</'.$tag.'>';
1039: }
1040: if ($fn =~ /\/portfolio\//) {
1041: $fn =~ /\/portfolio\/(.*)$/;
1042: my $new_fn = '/'.$1;
1043: $env{'form.'.$formname}=$file_content;
1044: $env{'form.'.$formname.'.filename'}=$new_fn;
1045: &Apache::lonnet::userfileupload('uploaddoc','',
1046: 'portfolio'.$env{'form.currentpath'});
1047: my $status =&Apache::lonnet::userfileupload($formname,'','portfolio');
1048: if (&Apache::lonnet::userfileupload($formname,'','portfolio') eq 'error: no uploaded file') {
1049: $r->print('<p><font color="red">'.
1050: &mt('Could not write metadata').', '.
1051: &mt('FAIL').'</font></p>');
1052: } else {
1053: $r->print('<p><font color="blue">'.&mt('Wrote Metadata').
1054: ' '.&Apache::lonlocal::locallocaltime(time).
1055: '</font></p>');
1056: }
1057: } else {
1058: if (! ($mfh=Apache::File->new('>'.$fn))) {
1059: $r->print('<p><font color="red">'.
1060: &mt('Could not write metadata').', '.
1061: &mt('FAIL').'</font></p>');
1062: } else {
1063: print $mfh $file_content;
1064: $r->print('<p><font color="blue">'.&mt('Wrote Metadata').
1065: ' '.&Apache::lonlocal::locallocaltime(time).
1066: '</font></p>');
1067: }
1068: }
1069: }
1070: $r->print($output.'<br /><input type="submit" name="store" value="'.
1071: &mt('Store Catalog Information').'">');
1072: }
1073: $r->print('</form>');
1074: return;
1075: }
1076:
1077: 1;
1078: __END__
1079:
1080:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>