1: # The LearningOnline Network with CAPA
2: # Routines for messaging
3: #
4: # $Id: lonmsg.pm,v 1.222 2009/02/05 00:45:29 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonmsg;
30:
31: =pod
32:
33: =head1 NAME
34:
35: Apache::lonmsg: supports internal messaging
36:
37: =head1 SYNOPSIS
38:
39: lonmsg provides routines for sending messages.
40:
41: Right now, this document will cover just how to send a message, since
42: it is likely you will not need to programmatically read messages,
43: since lonmsg already implements that functionality.
44:
45: The routines used to package messages and unpackage messages are not
46: only used by lonmsg when creating/extracting messages for LON-CAPA's
47: internal messaging system, but also by lonnotify.pm which is available
48: for use by Domain Coordinators to broadcast standard e-mail to specified
49: users in their domain. The XML packaging used in the two cases is very
50: similar. The differences are the use of <recuser>$uname</recuser> and
51: <recdomain>$udom</recdomain> in stored internal messages, compared
52: with <recipient username="$uname:$udom">$email</recipient> in stored
53: Domain Coordinator e-mail for the storage of information about
54: recipients of the message/e-mail.
55:
56: =head1 SUBROUTINES
57:
58: =over
59:
60: =pod
61:
62: =item packagemsg()
63:
64: Package
65:
66: =item get_course_context()
67:
68: =item unpackagemsg()
69:
70: Unpack message into a hash
71:
72: =item buildmsgid()
73:
74: Get info out of msgid
75:
76: =item unpackmsgid()
77:
78: =item sendemail()
79:
80: =item sendnotification()
81:
82: Send notification emails
83:
84: =item newmail()
85:
86: Check for email
87:
88: =item author_res_msg()
89:
90: Automated message to the author of a resource
91:
92: =item * B<author_res_msg($filename, $message)>: Sends message $message to the owner
93: of the resource with the URI $filename.
94:
95: =item retrieve_author_res_msg()
96:
97: Retrieve author resource messages
98:
99: =item del_url_author_res_msg()
100:
101: Delete all author messages related to one URL
102:
103: =item clear_author_res_msg()
104:
105: Clear out all author messages in URL path
106:
107: =item all_url_author_res_msg()
108:
109: Return hash with URLs for which there is a resource message
110:
111: =item store_instructor_comment()
112:
113: Add a comment to the User Notes screen
114:
115: =item user_crit_msg_raw()
116:
117: Critical message to a user
118:
119: =item user_crit_msg()
120:
121: New routine that respects "forward" and calls old routine
122:
123: =item * B<user_crit_msg($user, $domain, $subject, $message, $sendback, $nosentstore,$recipid,$attachmenturl)>:
124: Sends a critical message $message to the $user at $domain. If $sendback
125: is true, a receipt will be sent to the current user when $user receives
126: the message.
127:
128: Additionally it will check if the user has a Forwarding address
129: set, and send the message to that address instead
130:
131: returns
132: - in array context a list of results for each message that was sent
133: - in scalar context a space seperated list of results for each
134: message sent
135:
136:
137: =item user_crit_received()
138:
139: Critical message received
140:
141: =item user_normal_msg_raw()
142:
143: Normal communication
144:
145: =item user_normal_msg()
146:
147: New routine that respects "forward" and calls old routine
148:
149: =item * B<user_normal_msg($user, $domain, $subject, $message, $citation,
150: $baseurl, $attachmenturl, $toperm, $sentmessage, $symb, $restitle,
151: $error,$nosentstore,$recipid)>:
152: Sends a message to the $user at $domain, with subject $subject and message $message.
153:
154: Additionally it will check if the user has a Forwarding address
155: set, and send the message to that address instead
156:
157: returns
158: - in array context a list of results for each message that was sent
159: - in scalar context a space seperated list of results for each
160: message sent
161:
162: =item store_sent_mail()
163:
164: =item store_recipients()
165:
166: =item foldersuffix()
167:
168: =item get_user_folders()
169:
170: User-defined folders
171:
172: =item secapply()
173:
174: =item B<decide_receiver($feedurl,$author,$question,$course,$policy,$defaultflag)>:
175:
176: Arguments
177: $feedurl - /res/ url of resource (only need if $author is true)
178: $author,$question,$course,$policy - all true/false parameters
179: if true will attempt to find the addresses of user that should receive
180: this type of feedback (author - feedback to author of resource $feedurl,
181: $question 'Resource Content Questions', $course 'Course Content Question',
182: $policy 'Course Policy')
183: (Additionally it also checks $env for whether the corresponding form.<name>
184: element exists, for ease of use in a html response context)
185:
186: $defaultflag - (internal should be left blank) if true gather addresses
187: that aren't for a section even if I have a section
188: (used for reccursion internally, first we look for
189: addresses for our specific section then we recurse
190: and look for non section addresses)
191:
192: Returns
193: $typestyle - string of html text, describing what addresses were found
194: %to - a hash, which keys are addresses of users to send messages to
195: the keys will look like name:domain
196:
197: =back
198:
199: =cut
200:
201: use strict;
202: use Apache::lonnet;
203: use HTML::TokeParser();
204: use Apache::lonlocal;
205: use Mail::Send;
206: use LONCAPA qw(:DEFAULT :match);
207:
208: {
209: my $uniq;
210: sub get_uniq {
211: $uniq++;
212: return $uniq;
213: }
214: }
215:
216:
217:
218: sub packagemsg {
219: my ($subject,$message,$citation,$baseurl,$attachmenturl,
220: $recuser,$recdomain,$msgid,$type,$crsmsgid,$symb,$error,$recipid)=@_;
221: $message =&HTML::Entities::encode($message,'<>&"');
222: $citation=&HTML::Entities::encode($citation,'<>&"');
223: $subject =&HTML::Entities::encode($subject,'<>&"');
224: #remove machine specification
225: $baseurl =~ s|^https?://[^/]+/|/|;
226: $baseurl =&HTML::Entities::encode($baseurl,'<>&"');
227: #remove machine specification
228: $attachmenturl =~ s|^https?://[^/]+/|/|;
229: $attachmenturl =&HTML::Entities::encode($attachmenturl,'<>&"');
230: my $course_context = &get_course_context();
231: my $now=time;
232: my $msgcount = &get_uniq();
233: unless(defined($msgid)) {
234: $msgid = &buildmsgid($now,$subject,$env{'user.name'},$env{'user.domain'},
235: $msgcount,$course_context,$symb,$error,$$);
236: }
237: my $result = '<sendername>'.$env{'user.name'}.'</sendername>'.
238: '<senderdomain>'.$env{'user.domain'}.'</senderdomain>'.
239: '<subject>'.$subject.'</subject>'.
240: '<time>'.&Apache::lonlocal::locallocaltime($now).'</time>';
241: if (defined($crsmsgid)) {
242: $result.= '<courseid>'.$course_context.'</courseid>'.
243: '<coursesec>'.$env{'request.course.sec'}.'</coursesec>'.
244: '<msgid>'.$msgid.'</msgid>'.
245: '<coursemsgid>'.$crsmsgid.'</coursemsgid>'.
246: '<message>'.$message.'</message>';
247: return ($msgid,$result);
248: }
249: $result .= '<servername>'.$ENV{'SERVER_NAME'}.'</servername>'.
250: '<host>'.$ENV{'HTTP_HOST'}.'</host>'.
251: '<client>'.$ENV{'REMOTE_ADDR'}.'</client>'.
252: '<browsertype>'.$env{'browser.type'}.'</browsertype>'.
253: '<browseros>'.$env{'browser.os'}.'</browseros>'.
254: '<browserversion>'.$env{'browser.version'}.'</browserversion>'.
255: '<browsermathml>'.$env{'browser.mathml'}.'</browsermathml>'.
256: '<browserraw>'.$ENV{'HTTP_USER_AGENT'}.'</browserraw>'.
257: '<courseid>'.$course_context.'</courseid>'.
258: '<coursesec>'.$env{'request.course.sec'}.'</coursesec>'.
259: '<role>'.$env{'request.role'}.'</role>'.
260: '<resource>'.$env{'request.filename'}.'</resource>'.
261: '<msgid>'.$msgid.'</msgid>';
262: if (defined($env{'form.group'})) {
263: $result .= '<group>'.$env{'form.group'}.'</group>';
264: }
265: if (ref($recuser) eq 'ARRAY') {
266: for (my $i=0; $i<@{$recuser}; $i++) {
267: if ($type eq 'dcmail') {
268: my ($username,$email) = split(/:/,$$recuser[$i]);
269: $username = &unescape($username);
270: $email = &unescape($email);
271: $username = &HTML::Entities::encode($username,'<>&"');
272: $email = &HTML::Entities::encode($email,'<>&"');
273: $result .= '<recipient username="'.$username.'">'.
274: $email.'</recipient>';
275: } else {
276: $result .= '<recuser>'.$$recuser[$i].'</recuser>'.
277: '<recdomain>'.$$recdomain[$i].'</recdomain>';
278: }
279: }
280: } else {
281: $result .= '<recuser>'.$recuser.'</recuser>'.
282: '<recdomain>'.$recdomain.'</recdomain>';
283: }
284: $result .= '<message>'.$message.'</message>';
285: if (defined($citation)) {
286: $result.='<citation>'.$citation.'</citation>';
287: }
288: if (defined($baseurl)) {
289: $result.= '<baseurl>'.$baseurl.'</baseurl>';
290: }
291: if (defined($attachmenturl)) {
292: $result.= '<attachmenturl>'.$attachmenturl.'</attachmenturl>';
293: }
294: if (defined($symb)) {
295: $result.= '<symb>'.$symb.'</symb>';
296: if ($course_context ne '') {
297: if ($course_context eq $env{'request.course.id'}) {
298: my $resource_title = &Apache::lonnet::gettitle($symb);
299: if (defined($resource_title)) {
300: $result .= '<resource_title>'.$resource_title.'</resource_title>';
301: }
302: }
303: }
304: }
305: if (defined($recipid)) {
306: $result.= '<recipid>'.$recipid.'</recipid>';
307: }
308: if ($env{'form.can_reply'} eq 'N') {
309: $result .= '<noreplies>1</noreplies>';
310: }
311: if ($env{'form.reply_to_addr'}) {
312: my ($replytoname,$replytodom) = split(/:/,$env{'form.reply_to_addr'});
313: if (!($replytoname eq $env{'user.name'} && $replytodom eq $env{'user.domain'})) {
314: if (&Apache::lonnet::homeserver($replytoname,$replytodom) ne 'no_host') {
315: $result .= '<replytoaddr>'.$env{'form.reply_to_addr'}.'</replytoaddr>';
316: }
317: }
318: }
319: return ($msgid,$result);
320: }
321:
322: sub get_course_context {
323: my $course_context;
324: my $msgkey;
325: if (defined($env{'form.replyid'})) {
326: $msgkey = $env{'form.replyid'};
327: } elsif (defined($env{'form.forwid'})) {
328: $msgkey = $env{'form.forwid'}
329: } elsif (defined($env{'form.multiforwid'})) {
330: $msgkey = $env{'form.multiforwid'};
331: }
332: if ($msgkey ne '') {
333: my ($sendtime,$shortsubj,$fromname,$fromdomain,$count,$origcid)=
334: split(/\:/,&unescape($msgkey));
335: $course_context = $origcid;
336: }
337: foreach my $key (keys(%env)) {
338: if ($key=~/^form\.(rep)?rec\_(.*)$/) {
339: my ($sendtime,$shortsubj,$fromname,$fromdomain,$count,$origcid) =
340: split(/\:/,&unescape($2));
341: $course_context = $origcid;
342: last;
343: }
344: }
345: if ($course_context eq '') {
346: $course_context = $env{'request.course.id'};
347: }
348: return $course_context;
349: }
350:
351:
352: sub unpackagemsg {
353: my ($message,$notoken,$noattachmentlink)=@_;
354: my %content=();
355: my $parser=HTML::TokeParser->new(\$message);
356: my $token;
357: while ($token=$parser->get_token) {
358: if ($token->[0] eq 'S') {
359: my $entry=$token->[1];
360: my $value=$parser->get_text('/'.$entry);
361: if (($entry eq 'recuser') || ($entry eq 'recdomain')) {
362: push(@{$content{$entry}},$value);
363: } elsif ($entry eq 'recipient') {
364: my $username = $token->[2]{'username'};
365: $username = &HTML::Entities::decode($username,'<>&"');
366: $content{$entry}{$username} = $value;
367: } else {
368: $content{$entry}=$value;
369: }
370: }
371: }
372: if (!exists($content{'recuser'})) { $content{'recuser'} = []; }
373: if (($content{'attachmenturl'}) && (!$noattachmentlink)) {
374: my ($fname)=($content{'attachmenturl'}=~m|/([^/]+)$|);
375: if ($notoken) {
376: $content{'message'}.='<p>'.&mt('Attachment').': <tt>'.$fname.'</tt>';
377: } else {
378: &Apache::lonnet::allowuploaded('/adm/msg',
379: $content{'attachmenturl'});
380: $content{'message'}.='<p>'.&mt('Attachment').
381: ': <a href="'.$content{'attachmenturl'}.'"><tt>'.
382: $fname.'</tt></a>';
383: }
384: }
385: return %content;
386: }
387:
388:
389: sub buildmsgid {
390: my ($now,$subject,$uname,$udom,$msgcount,$course_context,$symb,$error,$pid) = @_;
391: $subject=&escape($subject);
392: $symb = &escape($symb);
393: return(&escape($now.':'.$subject.':'.$uname.':'.
394: $udom.':'.$msgcount.':'.$course_context.':'.$pid.':'.$symb.':'.$error));
395: }
396:
397: sub unpackmsgid {
398: my ($msgid,$folder,$skipstatus,$status_cache)=@_;
399: $msgid=&unescape($msgid);
400: my ($sendtime,$shortsubj,$fromname,$fromdomain,$count,$fromcid,
401: $processid,$symb,$error) = split(/\:/,&unescape($msgid));
402: $shortsubj = &unescape($shortsubj);
403: $shortsubj = &HTML::Entities::decode($shortsubj);
404: $symb = &unescape($symb);
405: if (!defined($processid)) { $fromcid = ''; }
406: my %status=();
407: unless ($skipstatus) {
408: if (ref($status_cache)) {
409: $status{$msgid} = $status_cache->{$msgid};
410: } else {
411: my $suffix=&foldersuffix($folder);
412: %status=&Apache::lonnet::get('email_status'.$suffix,[$msgid]);
413: }
414: if ($status{$msgid}=~/^error\:/) { $status{$msgid}=''; }
415: unless ($status{$msgid}) { $status{$msgid}='new'; }
416: }
417: return ($sendtime,$shortsubj,$fromname,$fromdomain,$status{$msgid},$fromcid,$symb,$error);
418: }
419:
420:
421: sub sendemail {
422: my ($to,$subject,$body,$to_uname,$to_udom,$user_lh)=@_;
423: my $senderaddress='';
424: my $replytoaddress='';
425: if ($env{'form.can_reply'} eq 'N') {
426: my $lonhost = $Apache::lonnet::perlvar{'lonHostID'};
427: my $hostname = &Apache::lonnet::hostname($lonhost);
428: $replytoaddress = 'do-not-reply@'.$hostname;
429: } else {
430: my %senderemails;
431: my $have_sender;
432: if ($env{'form.reply_to_addr'}) {
433: my ($replytoname,$replytodom) = split(/:/,$env{'form.reply_to_addr'});
434: if (!($replytoname eq $env{'user.name'} && $replytodom eq $env{'user.domain'})) {
435: if (&Apache::lonnet::homeserver($replytoname,$replytodom) ne 'no_host') {
436: %senderemails =
437: &Apache::loncommon::getemails($replytoname,$replytodom);
438: $have_sender = 1;
439: }
440: }
441: }
442: if (!$have_sender) {
443: %senderemails=&Apache::loncommon::getemails();
444: }
445: foreach my $type ('permanentemail','critnotification','notification') {
446: if ($senderemails{$type}) {
447: ($senderaddress) = split(/,/,$senderemails{$type});
448: last if ($senderaddress);
449: }
450: }
451: }
452: $body=
453: "*** ".&mt_user($user_lh,'This is an automatic e-mail generated by the LON-CAPA system.')."\n".
454: "*** ".($senderaddress?&mt_user($user_lh,'You can reply to this e-mail'):&mt_user($user_lh,'Please do not reply to this address.')."\n*** ".
455: &mt_user($user_lh,'A reply will not be received by the recipient!'))."\n\n".$body;
456: my $msg = new Mail::Send;
457: $msg->to($to);
458: $msg->subject('[LON-CAPA] '.$subject);
459: if ($replytoaddress) {
460: $msg->add('Reply-to',$replytoaddress);
461: }
462: if ($senderaddress) {
463: $msg->add('From',$senderaddress);
464: }
465: if (my $fh = $msg->open()) {
466: print $fh $body;
467: $fh->close;
468: }
469: }
470:
471: # ==================================================== Send notification emails
472:
473: sub sendnotification {
474: my ($to,$touname,$toudom,$subj,$crit,$text,$msgid)=@_;
475: my $sender=$env{'environment.firstname'}.' '.$env{'environment.lastname'};
476: unless ($sender=~/\w/) {
477: $sender=$env{'user.name'}.':'.$env{'user.domain'};
478: }
479: my $critical=($crit?' critical':'');
480:
481: $text=~s/\<\;/\</gs;
482: $text=~s/\>\;/\>/gs;
483: my $homeserver = &Apache::lonnet::homeserver($touname,$toudom);
484: my $protocol = $Apache::lonnet::protocol{$homeserver};
485: $protocol = 'http' if ($protocol ne 'https');
486: my $url = $protocol.'://'.&Apache::lonnet::hostname($homeserver).
487: '/adm/email?username='.$touname.'&domain='.$toudom;
488: my ($sendtime,$shortsubj,$fromname,$fromdomain,$status,$fromcid,
489: $symb,$error) = &Apache::lonmsg::unpackmsgid($msgid);
490: my ($coursetext,$body,$bodybegin,$bodysubj,$bodyend);
491: my $user_lh = &Apache::loncommon::user_lang($touname,$toudom,$fromcid);
492: if ($fromcid ne '') {
493: $coursetext = "\n".&mt_user($user_lh,'Course').': ';
494: if ($env{'course.'.$fromcid.'.description'} ne '') {
495: $coursetext .= $env{'course.'.$fromcid.'.description'};
496: } else {
497: my %coursehash = &Apache::lonnet::coursedescription($fromcid,);
498: if ($coursehash{'description'} ne '') {
499: $coursetext .= $coursehash{'description'};
500: }
501: }
502: $coursetext .= "\n\n";
503: }
504: my @recipients = split(/,/,$to);
505: $bodybegin = $coursetext.
506: &mt_user($user_lh,
507: 'You received a'.$critical.' message from [_1] in LON-CAPA.',$sender).' ';
508: $bodysubj = &mt_user($user_lh,'The subject is
509:
510: [_1]
511:
512: ',$subj)."\n".
513: '=== '.&mt_user($user_lh,'Excerpt')." ============================================================
514: ";
515: $bodyend = "
516: ========================================================================
517:
518: ".&mt_user($user_lh,'Use
519:
520: [_1]
521:
522: to access the full message.',$url);
523: my %userenv = &Apache::lonnet::get('environment',['notifywithhtml'],$toudom,$touname);
524: my $subject = &mt_user($user_lh,"'New' $critical message from ").$sender;
525:
526: my ($blocked,$blocktext);
527: if (!$crit) {
528: my %setters;
529: my ($startblock,$endblock) =
530: &Apache::loncommon::blockcheck(\%setters,'com',$touname,$toudom);
531: if ($startblock && $endblock) {
532: $blocked = 1;
533: my $showstart = &Apache::lonlocal::locallocaltime($startblock);
534: my $showend = &Apache::lonlocal::locallocaltime($endblock);
535: $blocktext = &mt_user($user_lh,'LON-CAPA messages sent to you between [_1] and [_2] will be inaccessible until the end of this time period, because you are a student in a course with an active communications block.',$showstart,$showend);
536: }
537: }
538: if ($userenv{'notifywithhtml'} ne '') {
539: my @htmlexcerpt = split(/,/,$userenv{'notifywithhtml'});
540: foreach my $addr (@recipients) {
541: if ($blocked) {
542: $body = $bodybegin."\n".$blocktext."\n".$bodyend;
543: } else {
544: my $sendtext = $text;
545: if (!grep/^\Q$addr\E/,@htmlexcerpt) {
546: $sendtext =~ s/\<\/*[^\>]+\>//gs;
547: }
548: $body = $bodybegin.$bodysubj.$sendtext.$bodyend;
549: }
550: &sendemail($addr,$subject,$body,$touname,$toudom,$user_lh);
551: }
552: } else {
553: if ($blocked) {
554: $body = $bodybegin."\n".$blocktext."\n".$bodyend;
555: } else {
556: $text =~ s/\<\/*[^\>]+\>//gs;
557: $body = $bodybegin.$bodysubj.$text.$bodyend;
558: }
559: &sendemail($to,$subject,$body,$touname,$toudom,$user_lh);
560: }
561: }
562:
563:
564: sub newmail {
565: if ((time-$env{'user.mailcheck.time'})>300) {
566: my %what=&Apache::lonnet::get('email_status',['recnewemail']);
567: &Apache::lonnet::appenv({'user.mailcheck.time'=>time});
568: if ($what{'recnewemail'}>0) { return 1; }
569: }
570: return 0;
571: }
572:
573:
574:
575: sub author_res_msg {
576: my ($filename,$message)=@_;
577: unless ($message) { return 'empty'; }
578: $filename=&Apache::lonnet::declutter($filename);
579: my ($domain,$author,@dummy)=split(/\//,$filename);
580: my $homeserver=&Apache::lonnet::homeserver($author,$domain);
581: if ($homeserver ne 'no_host') {
582: my $id=unpack("%32C*",$message);
583: $message .= " <p>This error occurred on machine ".
584: $Apache::lonnet::perlvar{'lonHostID'}."</p>";
585: my $msgid;
586: ($msgid,$message)=&packagemsg($filename,$message);
587: return &Apache::lonnet::reply('put:'.$domain.':'.$author.
588: ':nohist_res_msgs:'.
589: &escape($filename.'_'.$id).'='.
590: &escape($message),$homeserver);
591: }
592: return 'no_host';
593: }
594:
595:
596:
597: sub retrieve_author_res_msg {
598: my $url=shift;
599: $url=&Apache::lonnet::declutter($url);
600: my ($domain,$author)=($url=~/^($match_domain)\/($match_username)\//);
601: my %errormsgs=&Apache::lonnet::dump('nohist_res_msgs',$domain,$author);
602: my $msgs='';
603: foreach (keys %errormsgs) {
604: if ($_=~/^\Q$url\E\_\d+$/) {
605: my %content=&unpackagemsg($errormsgs{$_});
606: $msgs.='<p><img src="/adm/lonMisc/bomb.gif" /><b>'.
607: $content{'time'}.'</b>: '.$content{'message'}.
608: '<br /></p>';
609: }
610: }
611: return $msgs;
612: }
613:
614:
615:
616:
617:
618: sub del_url_author_res_msg {
619: my $url=shift;
620: $url=&Apache::lonnet::declutter($url);
621: my ($domain,$author)=($url=~/^($match_domain)\/($match_username)\//);
622: my @delmsgs=();
623: foreach (&Apache::lonnet::getkeys('nohist_res_msgs',$domain,$author)) {
624: if ($_=~/^\Q$url\E\_\d+$/) {
625: push (@delmsgs,$_);
626: }
627: }
628: return &Apache::lonnet::del('nohist_res_msgs',\@delmsgs,$domain,$author);
629: }
630:
631:
632: sub clear_author_res_msg {
633: my $url=shift;
634: $url=&Apache::lonnet::declutter($url);
635: my ($domain,$author)=($url=~/^($match_domain)\/($match_username)\//);
636: my @delmsgs=();
637: foreach (&Apache::lonnet::getkeys('nohist_res_msgs',$domain,$author)) {
638: if ($_=~/^\Q$url\E/) {
639: push (@delmsgs,$_);
640: }
641: }
642: return &Apache::lonnet::del('nohist_res_msgs',\@delmsgs,$domain,$author);
643: }
644:
645:
646:
647: sub all_url_author_res_msg {
648: my ($author,$domain)=@_;
649: my %returnhash=();
650: foreach (&Apache::lonnet::getkeys('nohist_res_msgs',$domain,$author)) {
651: $_=~/^(.+)\_\d+/;
652: $returnhash{$1}=1;
653: }
654: return %returnhash;
655: }
656:
657:
658: sub store_instructor_comment {
659: my ($msg,$uname,$udom) = @_;
660: my $cid = $env{'request.course.id'};
661: my $cnum = $env{'course.'.$cid.'.num'};
662: my $cdom = $env{'course.'.$cid.'.domain'};
663: my $subject= &mt('Record').' ['.$uname.':'.$udom.']';
664: my $result = &user_normal_msg_raw($cnum,$cdom,$subject,$msg);
665: if ($result eq 'ok' || $result eq 'con_delayed') {
666:
667: }
668: return $result;
669: }
670:
671:
672: sub user_crit_msg_raw {
673: my ($user,$domain,$subject,$message,$sendback,$toperm,$sentmessage,
674: $nosentstore,$recipid,$attachmenturl)=@_;
675: # Check if allowed missing
676: my ($status,$packed_message);
677: my $msgid='undefined';
678: unless (($message)&&($user)&&($domain)) { $status='empty'; };
679: my $text=$message;
680: my $homeserver=&Apache::lonnet::homeserver($user,$domain);
681: if ($homeserver ne 'no_host') {
682: ($msgid,$packed_message)=&packagemsg($subject,$message,undef,undef,
683: $attachmenturl,undef,undef,undef,undef,undef,
684: undef,undef,$recipid);
685: if ($sendback) { $packed_message.='<sendback>true</sendback>'; }
686: $status=&Apache::lonnet::cput('critical', {$msgid => $packed_message},
687: $domain,$user);
688: if (defined($sentmessage)) {
689: $$sentmessage = $packed_message;
690: }
691: if (!$nosentstore) {
692: (undef,my $packed_message_no_citation) =
693: &packagemsg($subject,$message,undef,undef,$attachmenturl,$user,
694: $domain,$msgid);
695: if ($status eq 'ok' || $status eq 'con_delayed') {
696: &store_sent_mail($msgid,$packed_message_no_citation);
697: }
698: }
699: } else {
700: $status='no_host';
701: }
702:
703: # Notifications
704: my %userenv = &Apache::loncommon::getemails($user,$domain);
705: if ($userenv{'critnotification'}) {
706: &sendnotification($userenv{'critnotification'},$user,$domain,$subject,1,
707: $text,$msgid);
708: }
709: if ($toperm && $userenv{'permanentemail'}) {
710: &sendnotification($userenv{'permanentemail'},$user,$domain,$subject,1,
711: $text,$msgid);
712: }
713: # Log this
714: &Apache::lonnet::logthis(
715: 'Sending critical email '.$msgid.
716: ', log status: '.
717: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},
718: $env{'user.home'},
719: 'Sending critical '.$msgid.' to '.$user.' at '.$domain.' with status: '
720: .$status));
721: return $status;
722: }
723:
724:
725:
726: sub user_crit_msg {
727: my ($user,$domain,$subject,$message,$sendback,$toperm,$sentmessage,
728: $nosentstore,$recipid,$attachmenturl)=@_;
729: my @status;
730: my %userenv = &Apache::lonnet::get('environment',['msgforward'],
731: $domain,$user);
732: my $msgforward=$userenv{'msgforward'};
733: if ($msgforward) {
734: foreach my $addr (split(/\,/,$msgforward)) {
735: my ($forwuser,$forwdomain)=split(/\:/,$addr);
736: push(@status,
737: &user_crit_msg_raw($forwuser,$forwdomain,$subject,$message,
738: $sendback,$toperm,$sentmessage,$nosentstore,
739: $recipid,$attachmenturl));
740: }
741: } else {
742: push(@status,
743: &user_crit_msg_raw($user,$domain,$subject,$message,$sendback,
744: $toperm,$sentmessage,$nosentstore,$recipid,
745: $attachmenturl));
746: }
747: if (wantarray) {
748: return @status;
749: }
750: return join(' ',@status);
751: }
752:
753:
754: sub user_crit_received {
755: my $msgid=shift;
756: my %message=&Apache::lonnet::get('critical',[$msgid]);
757: my %contents=&unpackagemsg($message{$msgid},1);
758: my $destname = $contents{'sendername'};
759: my $destdom = $contents{'senderdomain'};
760: if ($contents{'replytoaddr'}) {
761: my ($repname,$repdom) = split(/:/,$contents{'replytoaddr'});
762: if (&Apache::lonnet::homeserver($repname,$repdom) ne 'no_host') {
763: $destname = $repname;
764: $destdom = $repdom;
765: }
766: }
767: my $status='rec: '.($contents{'sendback'}?
768: &user_normal_msg($destname,$destdom,&mt('Receipt').': '.$env{'user.name'}.
769: ' '.&mt('at').' '.$env{'user.domain'}.', '.
770: $contents{'subject'},&mt('User').' '.$env{'user.name'}.
771: ' '.&mt('at').' '.$env{'user.domain'}.
772: ' acknowledged receipt of message'."\n".' "'.
773: $contents{'subject'}.'"'."\n".&mt('dated').' '.
774: $contents{'time'}.".\n"
775: ):'no msg req');
776: $status.=' trans: '.
777: &Apache::lonnet::put(
778: 'nohist_email',{$contents{'msgid'} => $message{$msgid}});
779: $status.=' del: '.
780: &Apache::lonnet::del('critical',[$contents{'msgid'}]);
781: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},
782: $env{'user.home'},'Received critical message '.
783: $contents{'msgid'}.
784: ', '.$status);
785: return $status;
786: }
787:
788:
789:
790:
791: sub user_normal_msg_raw {
792: my ($user,$domain,$subject,$message,$citation,$baseurl,$attachmenturl,
793: $toperm,$currid,$newid,$sentmessage,$crsmsgid,$symb,$restitle,
794: $error,$nosentstore,$recipid)=@_;
795: # Check if allowed missing
796: my ($status,$packed_message);
797: my $msgid='undefined';
798: my $text=$message;
799: unless (($message)&&($user)&&($domain)) { $status='empty'; };
800: my $homeserver=&Apache::lonnet::homeserver($user,$domain);
801: if ($homeserver ne 'no_host') {
802: ($msgid,$packed_message)=
803: &packagemsg($subject,$message,$citation,$baseurl,
804: $attachmenturl,$user,$domain,$currid,
805: undef,$crsmsgid,$symb,$error,$recipid);
806:
807: # Store in user folder
808: $status=
809: &Apache::lonnet::cput('nohist_email',{$msgid => $packed_message},
810: $domain,$user);
811: # Save new message received time
812: &Apache::lonnet::put
813: ('email_status',{'recnewemail'=>time},$domain,$user);
814: # Into sent-mail folder if sent mail storage required
815: if (!$nosentstore) {
816: (undef,my $packed_message_no_citation) =
817: &packagemsg($subject,$message,undef,$baseurl,$attachmenturl,
818: $user,$domain,$currid,undef,$crsmsgid,$symb,$error);
819: if ($status eq 'ok' || $status eq 'con_delayed') {
820: &store_sent_mail($msgid,$packed_message_no_citation);
821: }
822: }
823: if (ref($newid) eq 'SCALAR') {
824: $$newid = $msgid;
825: }
826: if (ref($sentmessage) eq 'SCALAR') {
827: $$sentmessage = $packed_message;
828: }
829: # Notifications
830: my %userenv = &Apache::loncommon::getemails($user,$domain);
831: if ($userenv{'notification'}) {
832: &sendnotification($userenv{'notification'},$user,$domain,$subject,0,
833: $text,$msgid);
834: }
835: if ($toperm && $userenv{'permanentemail'}) {
836: if ((!$userenv{'notification'}) || ($userenv{'notification'} ne $userenv{'permanentemail'})) {
837: &sendnotification($userenv{'permanentemail'},$user,$domain,$subject,0,
838: $text,$msgid);
839: }
840: }
841: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},
842: $env{'user.home'},
843: 'Sending '.$msgid.' to '.$user.' at '.$domain.' with status: '.$status);
844: } else {
845: $status='no_host';
846: }
847: return $status;
848: }
849:
850: sub user_normal_msg {
851: my ($user,$domain,$subject,$message,$citation,$baseurl,$attachmenturl,
852: $toperm,$sentmessage,$symb,$restitle,$error,$nosentstore,$recipid)=@_;
853: my @status;
854: my %userenv = &Apache::lonnet::get('environment',['msgforward'],
855: $domain,$user);
856: my $msgforward=$userenv{'msgforward'};
857: if ($msgforward) {
858: foreach (split(/\,/,$msgforward)) {
859: my ($forwuser,$forwdomain)=split(/\:/,$_);
860: push(@status,
861: &user_normal_msg_raw($forwuser,$forwdomain,$subject,$message,
862: $citation,$baseurl,$attachmenturl,$toperm,
863: undef,undef,$sentmessage,undef,$symb,
864: $restitle,$error,$nosentstore,$recipid));
865: }
866: } else {
867: push(@status,&user_normal_msg_raw($user,$domain,$subject,$message,
868: $citation,$baseurl,$attachmenturl,$toperm,
869: undef,undef,$sentmessage,undef,$symb,
870: $restitle,$error,$nosentstore,$recipid));
871: }
872: if (wantarray) {
873: return @status;
874: }
875: return join(' ',@status);
876: }
877:
878: sub process_sent_mail {
879: my ($msgsubj,$subj_prefix,$numsent,$stamp,$msgname,$msgdom,$msgcount,$context,$pid,$savemsg,$recusers,$recudoms,$baseurl,$attachmenturl,$symb,$error,$senderuname,$senderdom,$recipid) = @_;
880: my $sentsubj;
881: if ($numsent > 1) {
882: $sentsubj = $subj_prefix.' ('.$numsent.' sent) '.$msgsubj;
883: } else {
884: if ($subj_prefix) {
885: $sentsubj = $subj_prefix.' ';
886: }
887: $sentsubj .= $msgsubj;
888: }
889: $sentsubj = &HTML::Entities::encode($sentsubj,'<>&"');
890: my $sentmsgid =
891: &buildmsgid($stamp,$sentsubj,$msgname,$msgdom,$msgcount,$context,$pid);
892: (undef,my $sentmessage) =
893: &packagemsg($msgsubj,$savemsg,undef,$baseurl,$attachmenturl,$recusers,
894: $recudoms,$sentmsgid,undef,undef,$symb,$error,$recipid);
895: my $status = &store_sent_mail($sentmsgid,$sentmessage,$senderuname,
896: $senderdom);
897: return $status;
898: }
899:
900: sub store_sent_mail {
901: my ($msgid,$message,$senderuname,$senderdom) = @_;
902: if ($senderuname eq '') {
903: $senderuname = $env{'user.name'};
904: }
905: if ($senderdom eq '') {
906: $senderdom = $env{'user.domain'};
907: }
908: my $status =' '.&Apache::lonnet::cput('nohist_email_sent',
909: {$msgid => $message},
910: $senderdom,$senderuname);
911: return $status;
912: }
913:
914: sub store_recipients {
915: my ($subject,$sendername,$senderdom,$reciphash) = @_;
916: my $context = &get_course_context();
917: my $now = time();
918: my $msgcount = &get_uniq();
919: my $recipid =
920: &buildmsgid($now,$subject,$sendername,$senderdom,$msgcount,$context,$$);
921: my %recipinfo = (
922: $recipid => $reciphash,
923: );
924: my $status = &Apache::lonnet::put('nohist_emailrecip',\%recipinfo,
925: $senderdom,$sendername);
926: if ($status eq 'ok') {
927: return ($recipid,$status);
928: } else {
929: return (undef,$status);
930: }
931: }
932:
933:
934: sub foldersuffix {
935: my $folder=shift;
936: unless ($folder) { return ''; }
937: my $suffix;
938: my %folderhash = &get_user_folders($folder);
939: if (ref($folderhash{$folder}) eq 'HASH') {
940: $suffix = '_'.&escape($folderhash{$folder}{'id'});
941: } else {
942: $suffix = '_'.&escape($folder);
943: }
944: return $suffix;
945: }
946:
947:
948: sub get_user_folders {
949: my ($folder) = @_;
950: my %userfolders =
951: &Apache::lonnet::dump('email_folders',undef,undef,$folder);
952: my $lock = "\0".'lock_counter'; # locks db while counter incremented
953: my $counter = "\0".'idcount'; # used in suffix for email db files
954: if (defined($userfolders{$lock})) {
955: delete($userfolders{$lock});
956: }
957: if (defined($userfolders{$counter})) {
958: delete($userfolders{$counter});
959: }
960: return %userfolders;
961: }
962:
963: sub secapply {
964: my $rec=shift;
965: my $defaultflag=shift;
966: $rec=~s/\s+//g;
967: $rec=~s/\@/\:/g;
968: my ($adr,$sections_or_groups)=($rec=~/^([^\(]+)\(([^\)]+)\)/);
969: if ($sections_or_groups) {
970: foreach my $item (split(/\;/,$sections_or_groups)) {
971: if (($item eq $env{'request.course.sec'}) ||
972: ($defaultflag && ($item eq '*'))) {
973: return $adr;
974: } elsif ($env{'request.course.groups'}) {
975: my @usersgroups = split(/:/,$env{'request.course.groups'});
976: if (grep(/^\Q$item\E$/,@usersgroups)) {
977: return $adr;
978: }
979: }
980: }
981: } else {
982: return $rec;
983: }
984: return '';
985: }
986:
987: sub decide_receiver {
988: my ($feedurl,$author,$question,$course,$policy,$defaultflag) = @_;
989: &Apache::lonenc::check_decrypt(\$feedurl);
990: my $typestyle='';
991: my %to=();
992: if ($env{'form.discuss'} eq 'author' ||$author) {
993: $typestyle.='Submitting as Author Feedback<br />';
994: $feedurl=~ m{^/res/($LONCAPA::domain_re)/($LONCAPA::username_re)/};
995: $to{$2.':'.$1}=1;
996: }
997: my $cid = $env{'request.course.id'};
998: if ($env{'form.discuss'} eq 'question' ||$question) {
999: $typestyle.=&mt('Submitting as Question').'<br />';
1000: foreach my $item (split(/\,/,$env{'course.'.$cid.'.question.email'})) {
1001: my $rec=&secapply($item,$defaultflag);
1002: if ($rec) { $to{$rec}=1; }
1003: }
1004: }
1005: if ($env{'form.discuss'} eq 'course' ||$course) {
1006: $typestyle.=&mt('Submitting as Comment').'<br />';
1007: foreach my $item (split(/\,/,$env{'course.'.$cid.'.comment.email'})) {
1008: my $rec=&secapply($item,$defaultflag);
1009: if ($rec) { $to{$rec}=1; }
1010: }
1011: }
1012: if ($env{'form.discuss'} eq 'policy' ||$policy) {
1013: $typestyle.=&mt('Submitting as Policy Feedback').'<br />';
1014: foreach my $item (split(/\,/,$env{'course.'.$cid.'.policy.email'})) {
1015: my $rec=&secapply($item,$defaultflag);
1016: if ($rec) { $to{$rec}=1; }
1017: }
1018: }
1019: if ((scalar(%to) eq '0') && (!$defaultflag)) {
1020: ($typestyle,%to)=
1021: &decide_receiver($feedurl,$author,$question,$course,$policy,1);
1022: }
1023: return ($typestyle,%to);
1024: }
1025:
1026: 1;
1027: __END__
1028:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to lonmsg.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / interface