1: # The LearningOnline Network with CAPA
2: # Navigate Maps Handler
3: #
4: # $Id: lonnavmaps.pm,v 1.60 2002/10/01 19:39:11 bowersj2 Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: # (Page Handler
29: #
30: # (TeX Content Handler
31: #
32: # 05/29/00,05/30 Gerd Kortemeyer)
33: # 08/30,08/31,09/06,09/14,09/15,09/16,09/19,09/20,09/21,09/23,
34: # 10/02,10/10,10/14,10/16,10/18,10/19,10/31,11/6,11/14,11/16 Gerd Kortemeyer)
35: #
36: # 3/1/1,6/1,17/1,29/1,30/1,2/8,9/21,9/24,9/25 Gerd Kortemeyer
37: # YEAR=2002
38: # 1/1 Gerd Kortemeyer
39: #
40:
41: package Apache::lonnavmaps;
42:
43: use strict;
44: use Apache::Constants qw(:common :http);
45: use Apache::lonnet();
46: use Apache::loncommon();
47: use HTML::TokeParser;
48: use GDBM_File;
49:
50: # -------------------------------------------------------------- Module Globals
51: my %hash;
52: my @rows;
53:
54: #
55: # These cache hashes need to be independent of user, resource and course
56: # (user and course can/should be in the keys)
57: #
58:
59: my %courserdatas;
60: my %userrdatas;
61:
62: #
63: # These global hashes are dependent on user, course and resource,
64: # and need to be initialized every time when a sheet is calculated
65: #
66: my %courseopt;
67: my %useropt;
68: my %parmhash;
69:
70: # This parameter keeps track of whether obtaining the user's information
71: # failed, which the colorizer in astatus can use
72: my $networkFailedFlag = 0;
73:
74: # ------------------------------------------------------------------ Euclid gcd
75:
76: sub euclid {
77: my ($e,$f)=@_;
78: my $a; my $b; my $r;
79: if ($e>$f) { $b=$e; $r=$f; } else { $r=$e; $b=$f; }
80: while ($r!=0) {
81: $a=$b; $b=$r;
82: $r=$a%$b;
83: }
84: return $b;
85: }
86:
87: # --------------------------------------------------------------------- Parmval
88:
89: # -------------------------------------------- Figure out a cascading parameter
90: #
91: # For this function to work
92: #
93: # * parmhash needs to be tied
94: # * courseopt and useropt need to be initialized for this user and course
95: #
96:
97: sub parmval {
98: my ($what,$symb)=@_;
99: my $cid=$ENV{'request.course.id'};
100: my $csec=$ENV{'request.course.sec'};
101: my $uname=$ENV{'user.name'};
102: my $udom=$ENV{'user.domain'};
103:
104: unless ($symb) { return ''; }
105: my $result='';
106:
107: my ($mapname,$id,$fn)=split(/\_\_\_/,$symb);
108:
109: # ----------------------------------------------------- Cascading lookup scheme
110: my $rwhat=$what;
111: $what=~s/^parameter\_//;
112: $what=~s/\_/\./;
113:
114: my $symbparm=$symb.'.'.$what;
115: my $mapparm=$mapname.'___(all).'.$what;
116: my $usercourseprefix=$uname.'_'.$udom.'_'.$cid;
117:
118: my $seclevel= $usercourseprefix.'.['.$csec.'].'.$what;
119: my $seclevelr=$usercourseprefix.'.['.$csec.'].'.$symbparm;
120: my $seclevelm=$usercourseprefix.'.['.$csec.'].'.$mapparm;
121:
122: my $courselevel= $usercourseprefix.'.'.$what;
123: my $courselevelr=$usercourseprefix.'.'.$symbparm;
124: my $courselevelm=$usercourseprefix.'.'.$mapparm;
125:
126: # ---------------------------------------------------------- first, check user
127: if (defined($uname)) {
128: if (defined($useropt{$courselevelr})) { return $useropt{$courselevelr}; }
129: if (defined($useropt{$courselevelm})) { return $useropt{$courselevelm}; }
130: if (defined($useropt{$courselevel})) { return $useropt{$courselevel}; }
131: }
132:
133: # ------------------------------------------------------- second, check course
134: if (defined($csec)) {
135: if (defined($courseopt{$seclevelr})) { return $courseopt{$seclevelr}; }
136: if (defined($courseopt{$seclevelm})) { return $courseopt{$seclevelm}; }
137: if (defined($courseopt{$seclevel})) { return $courseopt{$seclevel}; }
138: }
139:
140: if (defined($courseopt{$courselevelr})) { return $courseopt{$courselevelr}; }
141: if (defined($courseopt{$courselevelm})) { return $courseopt{$courselevelm}; }
142: if (defined($courseopt{$courselevel})) { return $courseopt{$courselevel}; }
143:
144: # ----------------------------------------------------- third, check map parms
145:
146: my $thisparm=$parmhash{$symbparm};
147: if (defined($thisparm)) { return $thisparm; }
148:
149: # ----------------------------------------------------- fourth , check default
150:
151: my $default=&Apache::lonnet::metadata($fn,$rwhat.'.default');
152: if (defined($default)) { return $default}
153:
154: # --------------------------------------------------- fifth , cascade up parts
155:
156: my ($space,@qualifier)=split(/\./,$rwhat);
157: my $qualifier=join('.',@qualifier);
158: unless ($space eq '0') {
159: my ($part,$id)=split(/\_/,$space);
160: if ($id) {
161: my $partgeneral=&parmval($part.".$qualifier",$symb);
162: if (defined($partgeneral)) { return $partgeneral; }
163: } else {
164: my $resourcegeneral=&parmval("0.$qualifier",$symb);
165: if (defined($resourcegeneral)) { return $resourcegeneral; }
166: }
167: }
168: return '';
169: }
170:
171:
172:
173: # ------------------------------------------------------------- Find out status
174: # return codes
175: # tcode (timecode)
176: # 1: will open later
177: # 2: is open and not past due yet
178: # 3: is past due date
179: # 4: due in the next 24 hours
180: #
181: # code (curent solved status)
182: # 1: not attempted
183: # 2: attempted but wrong, or incorrect by instructor
184: # 3: solved or correct by instructor
185: # 4: partially correct (one or more parts correct)
186: # "excused" needs to be supported, but is not yet.
187: sub astatus {
188: my $rid=shift;
189: my $code=0;
190: my $ctext='';
191: $rid=~/(\d+)\.(\d+)/;
192: my $symb=&Apache::lonnet::declutter($hash{'map_id_'.$1}).'___'.$2.'___'.
193: &Apache::lonnet::declutter($hash{'src_'.$rid});
194: my %duedate=();
195: my %opendate=();
196: my %answerdate=();
197: # need to always check part 0's open/due/answer status
198: foreach (sort(split(/\,/,&Apache::lonnet::metadata($hash{'src_'.$rid},'allpo\ssiblekeys')))) {
199: if ($_=~/^parameter\_(.*)\_opendate$/) {
200: my $part=$1;
201: $duedate{$part}=&parmval($part.'.duedate',$symb);
202: $opendate{$part}=&parmval($part.'.opendate',$symb);
203: $answerdate{$part}=&parmval($part.'.answerdate',$symb);
204: if (&parmval($part.'.opendate.type',$symb) eq 'date_interval') {
205: $opendate{$part}=$duedate{$part}-$opendate{$part};
206: }
207: if (&parmval($part.'.answerdate.type',$symb) eq 'date_interval') {
208: $answerdate{$part}=$duedate{$part}+$answerdate{$part};
209: }
210: }
211: }
212: my $now=time;
213: my $tcode=0;
214:
215: my %returnhash=&Apache::lonnet::restore($symb);
216:
217: foreach (sort(keys(%opendate))) {
218: my $duedate=$duedate{$_};
219: my $opendate=$opendate{$_};
220: my $answerdate=$answerdate{$_};
221: my $preface='';
222: unless ($_ eq '0') { $preface=' Part: '.$_.' '; }
223: if ($opendate) {
224: if ($now<$duedate || (!$duedate)) {
225: unless ($tcode==4) { $tcode=2; }
226: if ($duedate) {
227: $ctext.=$preface.'Due: '.localtime($duedate);
228: } else {
229: $ctext.=$preface.'No Due Date';
230: }
231: if ($now<$opendate) {
232: unless ($tcode) { $tcode=1; }
233: $ctext.=$preface.'Open: '.localtime($opendate);
234: }
235: if ($duedate && $duedate-$now<86400) {
236: $tcode=4;
237: $ctext.=$preface.'Due: '.localtime($duedate);
238: }
239: } else {
240: unless (($tcode==4) || ($tcode eq 2)) { $tcode=3; }
241: if ($now<$answerdate) {
242: $ctext.='Answer: '.localtime($duedate);
243: }
244: }
245: } else {
246: unless (($tcode==2) || ($tcode==4)) { $tcode=1; }
247: }
248:
249: my $status=$returnhash{'resource.'.$_.'.solved'};
250:
251: if ($status eq 'correct_by_student') {
252: if ($code==0||$code==3) { $code=3; } else { $code=4; }
253: $ctext.=' solved';
254: } elsif ($status eq 'correct_by_override') {
255: if ($code==0||$code==3) { $code=3; } else { $code=4; }
256: $ctext.=' override';
257: } elsif ($status eq 'incorrect_attempted') {
258: if ($code!=4 && $code!=3) { $code=2; }
259: if ($code==3) { $code=4; }
260: $ctext.=' ('.
261: ($returnhash{'resource.'.$_.'.tries'}?
262: $returnhash{'resource.'.$_.'.tries'}:'0');
263: my $numtries = &parmval($_.'.maxtries',$symb);
264: if ($numtries) { $ctext.='/'.$numtries.' tries'; }
265: $ctext.=')';
266: } elsif ($status eq 'incorrect_by_override') {
267: if ($code!=4 && $code!=3) { $code=2; }
268: if ($code==3) { $code=4; }
269: $ctext.=' override';
270: } elsif ($status eq 'excused') {
271: if ($code==0||$code==3) { $code=3; } else { $code=4; }
272: $ctext.=' excused';
273: } else {
274: if ($code==0) { $code=1; }
275: }
276: }
277:
278: return 'p'.$code.$tcode.'"'.$ctext.'"';
279: }
280:
281:
282: sub addresource {
283: my ($resource,$sofar,$rid,$showtypes,$indent,$linkid)=@_;
284: if ($showtypes eq 'problems') {
285: if ($resource!~/\.(problem|exam|quiz|assess|survey|form)$/) {
286: return;
287: }
288: }
289: my $brepriv=&Apache::lonnet::allowed('bre',$resource);
290: if ($hash{'src_'.$rid}) {
291: if (($brepriv eq '2') || ($brepriv eq 'F')) {
292: my $pprefix='';
293: if ($resource=~/\.(problem|exam|quiz|assess|survey|form)$/) {
294: $pprefix=&astatus($rid);
295: }
296: $$sofar++;
297: if ($indent) { $pprefix='i'.$indent.','.$pprefix; }
298: if ($linkid) { $pprefix='l'.$linkid.','.$pprefix; }
299: if (defined($rows[$$sofar])) {
300: $rows[$$sofar].='&'.$pprefix.$rid;
301: } else {
302: $rows[$$sofar]=$pprefix.$rid;
303: }
304: }
305: }
306: }
307:
308: sub followlinks () {
309: my ($rid,$sofar,$beenhere,$further,$showtypes,$indent,$linkid)=@_;
310: my $mincond=1;
311: my $next='';
312: foreach (split(/\,/,$hash{'to_'.$rid})) {
313: my $thiscond=
314: &Apache::lonnet::directcondval($hash{'condid_'.$hash{'undercond_'.$_}});
315: if ($thiscond>=$mincond) {
316: if ($next) {
317: $next.=','.$_.':'.$thiscond;
318: } else {
319: $next=$_.':'.$thiscond;
320: }
321: if ($thiscond>$mincond) { $mincond=$thiscond; }
322: }
323: }
324: my $col=0;
325: &Apache::lonxml::debug("following links -$next-");
326: foreach (split(/\,/,$next)) {
327: my ($nextlinkid,$condval)=split(/\:/,$_);
328: if ($condval>=$mincond) {
329: my $now=&tracetable($sofar,$hash{'goesto_'.$nextlinkid},
330: $beenhere,$showtypes,$indent,$linkid);
331: if ($now>$further) {
332: if ($col>0) {
333: my $string;
334: for(my $i=0;$i<$col;$i++) { $string.='&'; }
335: for(my $i=$further+1;$now-1>$i;$i++) {
336: $rows[$i]=$string.$rows[$i];
337: }
338: }
339: $further=$now;
340: }
341: }
342: $col++;
343: }
344: return $further;
345: }
346: # ------------------------------------------------------------ Build page table
347:
348: sub tracetable {
349: my ($sofar,$rid,$beenhere,$showtypes,$indent,$linkid)=@_;
350: my $newshowtypes=$showtypes;
351: my $further=$sofar;
352: # $Apache::lonxml::debug=1;
353: &Apache::lonxml::debug("$rid ; $linkid ; $sofar ; $beenhere ; ".$hash{'src_'.$rid});
354: if ($beenhere=~/\&$rid\&/) { return $further; }
355: $beenhere.=$rid.'&';
356:
357: if (defined($hash{'is_map_'.$rid})) {
358: $sofar++;
359: my $tprefix='';
360: if ($hash{'map_type_'.$hash{'map_pc_'.$hash{'src_'.$rid}}}
361: eq 'sequence') {
362: $tprefix='h';
363: } elsif ($hash{'map_type_'.$hash{'map_pc_'.$hash{'src_'.$rid}}}
364: eq 'page') {
365: $tprefix='j';
366: if ($indent) { $tprefix='i'.$indent.','.$tprefix; }
367: if ($linkid) { $tprefix='l'.$linkid.','.$tprefix; }
368: $newshowtypes='problems';
369: $indent++;
370: #if in a .page continue to link the encompising .page
371: if (!$linkid) { $linkid=$rid; }
372: }
373: if (defined($rows[$sofar])) {
374: $rows[$sofar].='&'.$tprefix.$rid;
375: } else {
376: $rows[$sofar]=$tprefix.$rid;
377: }
378: if ((defined($hash{'map_start_'.$hash{'src_'.$rid}})) &&
379: (defined($hash{'map_finish_'.$hash{'src_'.$rid}}))) {
380: my $frid=$hash{'map_finish_'.$hash{'src_'.$rid}};
381: $sofar=&tracetable($sofar,$hash{'map_start_'.$hash{'src_'.$rid}},
382: '&'.$frid.'&',$newshowtypes,$indent,$linkid);
383: &addresource($hash{'src_'.$frid},\$sofar,$frid,$newshowtypes,
384: $indent,$linkid);
385: if ($tprefix =~ /j$/) { $indent--; $linkid=''; }
386: }
387: } else {
388: &addresource($hash{'src_'.$rid},\$sofar,$rid,$showtypes,
389: $indent,$linkid);
390: }
391:
392: if (defined($hash{'to_'.$rid})) {
393: $further=&followlinks($rid,$sofar,$beenhere,$further,$showtypes,
394: $indent,$linkid);
395: }
396:
397: return $further;
398: }
399:
400: # ================================================================ Main Handler
401:
402: sub handler {
403: my $r=shift;
404:
405: &Apache::loncommon::get_unprocessed_cgi($ENV{QUERY_STRING});
406:
407: if ($ENV{'form.jtest'} ne "1")
408: {
409: return new_handle($r);
410: }
411:
412: # ------------------------------------------- Set document type for header only
413:
414: if ($r->header_only) {
415: if ($ENV{'browser.mathml'}) {
416: $r->content_type('text/xml');
417: } else {
418: $r->content_type('text/html');
419: }
420: $r->send_http_header;
421: return OK;
422: }
423: my $requrl=$r->uri;
424: my $hashtied;
425: # ----------------------------------------------------------------- Tie db file
426: my $fn;
427: if ($ENV{'request.course.fn'}) {
428: $fn=$ENV{'request.course.fn'};
429: if (-e "$fn.db") {
430: if ((tie(%hash,'GDBM_File',"$fn.db",&GDBM_READER(),0640)) &&
431: (tie(%parmhash,'GDBM_File',
432: $ENV{'request.course.fn'}.'_parms.db',
433: &GDBM_READER(),0640))) {
434: $hashtied=1;
435: }
436: }
437: }
438: if (!$hashtied) {
439: $ENV{'user.error.msg'}="$requrl:bre:0:0:Course not initialized";
440: return HTTP_NOT_ACCEPTABLE;
441: }
442:
443: # ------------------------------------------------------------------- Hash tied
444:
445: if ($ENV{'browser.mathml'}) {
446: $r->content_type('text/xml');
447: } else {
448: $r->content_type('text/html');
449: }
450: &Apache::loncommon::no_cache($r);
451: $r->send_http_header;
452:
453: my $firstres=$hash{'map_start_'.
454: &Apache::lonnet::clutter($ENV{'request.course.uri'})};
455: my $lastres=$hash{'map_finish_'.
456: &Apache::lonnet::clutter($ENV{'request.course.uri'})};
457: if (!(($firstres) && ($lastres))) {
458: $r->print('<html><body>Coursemap undefined.</body></html>');
459: } else {
460:
461: # ----------------------------------------------------------------- Render page
462: # -------------------------------------------------------------- Set parameters
463:
464:
465: # ---------------------------- initialize coursedata and userdata for this user
466: undef %courseopt;
467: undef %useropt;
468:
469: my $uname=$ENV{'user.name'};
470: my $udom=$ENV{'user.domain'};
471: my $uhome=$ENV{'user.home'};
472: my $cid=$ENV{'request.course.id'};
473: my $chome=$ENV{'course.'.$cid.'.home'};
474: my ($cdom,$cnum)=split(/\_/,$cid);
475:
476: my $userprefix=$uname.'_'.$udom.'_';
477:
478: unless ($uhome eq 'no_host') {
479: # ------------------------------------------------- Get coursedata (if present)
480: unless ((time-$courserdatas{$cid.'.last_cache'})<240) {
481: my $reply=&Apache::lonnet::reply('dump:'.$cdom.':'.$cnum.
482: ':resourcedata',$chome);
483: if ($reply!~/^error\:/) {
484: $courserdatas{$cid}=$reply;
485: $courserdatas{$cid.'.last_cache'}=time;
486: }
487: # check to see if network failed
488: elsif ( $reply=~/no.such.host/i || $reply=~/con.*lost/i )
489: {
490: $networkFailedFlag = 1;
491: }
492: }
493: foreach (split(/\&/,$courserdatas{$cid})) {
494: my ($name,$value)=split(/\=/,$_);
495: $courseopt{$userprefix.&Apache::lonnet::unescape($name)}=
496: &Apache::lonnet::unescape($value);
497: }
498: # --------------------------------------------------- Get userdata (if present)
499: unless ((time-$userrdatas{$uname.'___'.$udom.'.last_cache'})<240) {
500: my $reply=&Apache::lonnet::reply('dump:'.$udom.':'.$uname.':resourcedata',$uhome);
501: if ($reply!~/^error\:/) {
502: $userrdatas{$uname.'___'.$udom}=$reply;
503: $userrdatas{$uname.'___'.$udom.'.last_cache'}=time;
504: }
505: }
506: foreach (split(/\&/,$userrdatas{$uname.'___'.$udom})) {
507: my ($name,$value)=split(/\=/,$_);
508: $useropt{$userprefix.&Apache::lonnet::unescape($name)}=
509: &Apache::lonnet::unescape($value);
510: }
511: }
512:
513: @rows=();
514:
515: &tracetable(0,$firstres,'&','',0);
516:
517: # ------------------------------------------------------------------ Page parms
518:
519: my $j;
520: my $i;
521: my $lcm=1;
522: my $contents=0;
523:
524: # ---------------------------------------------- Go through table to get layout
525:
526: for ($i=0;$i<=$#rows;$i++) {
527: if ($rows[$i]) {
528: &Apache::lonxml::debug("Row $i is:".$rows[$i]);
529: $contents++;
530: my @colcont=split(/\&/,$rows[$i]);
531: $lcm*=($#colcont+1)/euclid($lcm,($#colcont+1));
532: }
533: }
534:
535:
536: unless ($contents) {
537: $r->print('<html><body>Empty Map.</body></html>');
538: } else {
539:
540: # ------------------------------------------------------------------ Build page
541:
542: my $currenturl=$ENV{'form.postdata'};
543: $currenturl=~s/^http\:\/\///;
544: $currenturl=~s/^[^\/]+//;
545:
546: # ---------------------------------------------------------------- Send headers
547:
548: my $date=localtime;
549: my $now=time;
550: # ----------------------------------------- Get email status and discussiontime
551:
552: my %emailstatus=&Apache::lonnet::dump('email_status');
553: my $logouttime=$emailstatus{'logout'};
554: my $courseleave=$emailstatus{'logout_'.$ENV{'request.course.id'}};
555: my $lastcheck=($courseleave>$logouttime?$courseleave:$logouttime);
556:
557: my %discussiontimes=&Apache::lonnet::dump('discussiontimes',
558: $cdom,$cnum);
559:
560: my %feedback=();
561: my %error=();
562: foreach my $msgid (split(/\&/,&Apache::lonnet::reply('keys:'.
563: $ENV{'user.domain'}.':'.
564: $ENV{'user.name'}.':nohist_email',
565: $ENV{'user.home'}))) {
566: $msgid=&Apache::lonnet::unescape($msgid);
567: my $plain=&Apache::lonnet::unescape(&Apache::lonnet::unescape($msgid));
568: if ($plain=~/(Error|Feedback) \[([^\]]+)\]/) {
569: my ($what,$url)=($1,$2);
570: my %status=
571: &Apache::lonnet::get('email_status',[$msgid]);
572: if ($status{$msgid}=~/^error\:/) {
573: $status{$msgid}='';
574: }
575:
576: if (($status{$msgid} eq 'new') ||
577: (!$status{$msgid})) {
578: if ($what eq 'Error') {
579: $error{$url}.=','.$msgid;
580: } else {
581: $feedback{$url}.=','.$msgid;
582: }
583: }
584: }
585: }
586: # ----------------------------------------------------------- Start Page Output
587: my $bodytagadd='';
588: $r->print(
589: '<html><head><title>Navigate Course Map</title></head>');
590: if (($currenturl=~/^\/res/) &&
591: ($currenturl!~/^\/res\/adm/)) {
592: $bodytagadd='onLoad="window.location.hash='."'curloc'".'"';
593: }
594: $r->print(&Apache::loncommon::bodytag('Navigate Course Map','',
595: $bodytagadd));
596: $r->print('<script>window.focus();</script>');
597: my $desc=$ENV{'course.'.$ENV{'request.course.id'}.'.description'};
598: if (defined($desc)) { $r->print("<h2>$desc</h2>\n"); }
599: $r->print("<h3>$date</h3>\n");
600: $r->rflush();
601: $r->print('<img src="/adm/lonMisc/chat.gif"> New discussion since '.
602: localtime($lastcheck).
603: '<br><img src="/adm/lonMisc/feedback.gif"> New message (click to open)<p>');
604: if (($currenturl=~/^\/res/) &&
605: ($currenturl!~/^\/res\/adm/)) {
606: $r->print('<a href="#curloc">Current Location</a><p>');
607: }
608:
609: # Handle a network error
610:
611: if ($networkFailedFlag)
612: {
613: $r->print('<H2>LON-CAPA network failure.</H2>'."\n");
614: $r->print("<p>LON-CAPA's network is having difficulties, some problem" .
615: " information, such as due dates, will not be available.");
616: }
617: # ----------------------------------------------------- The little content list
618: for ($i=0;$i<=$#rows;$i++) {
619: if ($rows[$i]) {
620: my @colcont=split(/\&/,$rows[$i]);
621: my $avespan=$lcm/($#colcont+1);
622: for ($j=0;$j<=$#colcont;$j++) {
623: my $rid=$colcont[$j];
624: if ($rid=~/^h(.+)/) {
625: $rid=$1;
626: $r->print(' <a href="#'.
627: $rid.'">'.$hash{'title_'.$rid}.
628: '</a><br>');
629: }
630: }
631: }
632: }
633: # ----------------------------------------------------------------- Start table
634: $r->print('<hr><table cols="'.$lcm.'" border="0">');
635: for ($i=0;$i<=$#rows;$i++) {
636: if ($rows[$i]) {
637: $r->print("\n<tr>");
638: my @colcont=split(/\&/,$rows[$i]);
639: my $avespan=$lcm/($#colcont+1);
640:
641: # for each item I wish to print on this row...
642: for ($j=0;$j<=$#colcont;$j++) {
643: my $indent;my $indentstr;
644: my $linkid;
645: my $rid=$colcont[$j];
646: $rid=~/(\d+)\.(\d+)$/;
647: my $src=
648: &Apache::lonnet::declutter($hash{'src_'.$1.'.'.$2});
649: my $symb=
650: &Apache::lonnet::declutter($hash{'map_id_'.$1}).'___'.$2.'___'.$src;
651: my $add='<td>';
652: my $adde='</td>';
653: my $hwk='<font color="#223322">';
654: my $hwke='</font>';
655: if ($rid=~/^l(\d+\.\d+),(.+)/) { $linkid=$1; $rid=$2; }
656: if ($rid=~/^i(\d+),(.+)/) { $indent=$1; $rid=$2; }
657: if ($rid=~/^h(.+)/) {
658: $rid=$1;
659: $add='<th bgcolor="#AAFF55"><a name="'.$rid.'">';
660: $adde='</th>';
661: if (($ENV{'user.adv'}) &&
662: ($parmhash{$symb.'.0.parameter_randompick'})) {
663: $adde=' (randomly select '.
664: $parmhash{$symb.'.0.parameter_randompick'}.
665: ')</th>';
666: }
667: }
668: if ($rid=~/^j(.+)/) { $rid=$1; }
669: if ($rid=~/^p(\d)(\d)\"([\w\: \(\)\/\,]*)\"(.+)/) {
670: # sub astatus describes what code/tcode mean
671: my $code=$1;
672: my $tcode=$2;
673: my $ctext=$3;
674: $rid=$4;
675:
676: # will open later
677: if ($tcode eq '1') {
678: $add='<td bgcolor="#AAAAAA">';
679: }
680:
681: # solved/correct
682: if ($code eq '3') {
683: $add='<td bgcolor="#AAFFAA">';
684: } elsif ($code eq '4') { # partially correct
685: $add='<td bgcolor="#E0FFAA">';
686: } else {
687: # not attempted
688:
689: # we end up here on network failure, so pick a neutral
690: # color if the network failed instead of bright red.
691: if ( $networkFailedFlag )
692: {
693: $add = '<td bgcolor="#AAAAAA">';
694: }
695: else
696: {
697: $add='<td bgcolor="#FFAAAA">';
698: }
699:
700: if ($tcode eq '2') { # open, not past due
701: $add='<td bgcolor="#FFFFAA">';
702: }
703:
704: if ($tcode eq '4') { # due in next 24 hours
705: $add='<td bgcolor="#FFFF33">';
706: $adde='</td>';
707: }
708: }
709: $hwk='<font color="#888811"><b>';
710: $hwke='</b></font>';
711: if ($code eq '1') {
712: $hwke='</b> ('.$ctext.')</font>';
713: }
714: if ($code eq '2' || $code eq '4') {
715: $hwk='<font color="#992222"><b>';
716: $hwke='</b> ('.$ctext.')</font>';
717: }
718: if ($code eq '3') {
719: $hwk='<font color="#229922"><b>';
720: $hwke='</b> ('.$ctext.')</font>';
721: }
722: if ($networkFailedFlag)
723: {
724: $hwke='</b> (status unavailable)</font>';
725: }
726: }
727: if ($rid && $hash{'src_'.$rid} eq $currenturl) {
728: $add=$add.'<a name="curloc"></a>'.
729: '<font color=red size=+2><b>> </b></font>';
730: $adde=
731: '<font color=red size=+2><b> <</b></font>'.$adde;
732: }
733: if ($discussiontimes{$symb}>$lastcheck) {
734: $adde=
735: '<img border=0 src="/adm/lonMisc/chat.gif">'.
736: $adde;
737: }
738: if ($error{$src}) {
739: foreach (split(/\,/,$error{$src})) {
740: if ($_) {
741: $adde=
742: ' <a href="/adm/email?display='.
743: &Apache::lonnet::escape($_).
744: '"><img src="/adm/lonMisc/bomb.gif" border=0></a>'
745: .$adde;
746: }
747: }
748: }
749: if ($feedback{$src}) {
750: foreach (split(/\,/,$feedback{$src})) {
751: if ($_) {
752: $adde=
753: ' <a href="/adm/email?display='.
754: &Apache::lonnet::escape($_).
755: '"><img src="/adm/lonMisc/feedback.gif" border=0></a>'
756: .$adde;
757: }
758: }
759: }
760: if ($indent) {
761: my $is=" ";
762: for(my $i=-1;$i<$indent;$i++) { $indentstr.=$is; }
763: }
764: if (!$linkid) { $linkid=$rid; }
765: if ($hash{'randomout_'.$rid}) {
766: $adde=' <i>(hidden)</i>'.$adde;
767: }
768: $r->print($add.$indentstr);
769: if ($rid) {
770: $r->print('<a href="'.$hash{'src_'.$linkid}.
771: (($hash{'src_'.$linkid}=~/\?/)?'&':'?').
772: 'symb='.&Apache::lonnet::escape($symb)
773: .'">'.
774: $hwk.$hash{'title_'.$rid}.$hwke.'</a>');
775: }
776: $r->print($adde);
777: }
778: $r->print('</tr>');
779: }
780: }
781: $r->print("\n</table>");
782: $r->print('</body></html>');
783: # -------------------------------------------------------------------- End page
784: }
785: # ------------------------------------------------------------- End render page
786: }
787: # ------------------------------------------------------------------ Untie hash
788: unless (untie(%hash)) {
789: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
790: "Could not untie coursemap $fn (browse).</font>");
791: }
792: unless (untie(%parmhash)) {
793: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
794: "Could not untie parmhash (browse).</font>");
795: }
796: return OK;
797: }
798:
799: sub new_handle {
800: my $r = shift;
801:
802: # Handle header-only request
803: if ($r->header_only) {
804: if ($ENV{'browser.mathml'}) {
805: $r->content_type('text/xml');
806: } else {
807: $r->content_type('text/html');
808: }
809: $r->send_http_header;
810: return OK;
811: }
812:
813: # Send header, don't cache this page
814: if ($ENV{'browser.mathml'}) {
815: $r->content_type('text/xml');
816: } else {
817: $r->content_type('text/html');
818: }
819: &Apache::loncommon::no_cache($r);
820: $r->send_http_header;
821:
822: # Header
823: $r->print(&Apache::loncommon::bodytag('Navigate Course Map','',
824: ''));
825: # Initialize the nav map
826: my $navmap = Apache::lonnavmaps::navmap->new(
827: $ENV{"request.course.fn"}.".db",
828: $ENV{"request.course.fn"}."_parms.db", 1);
829:
830:
831: if (!defined($navmap)) {
832: my $requrl = $r->uri;
833: $ENV{'user.error.msg'} = "$requrl:bre:0:0:Course not initialized";
834: return HTTP_NOT_ACCEPTABLE;
835: }
836:
837: # Check that it's defined
838: if (!($navmap->courseMapDefined())) {
839: $r->print('<font size="+2" color="red">Coursemap undefined.</font>' .
840: '</body></html>');
841: return OK;
842: }
843:
844: # Grab a resource object so we have access to the constants; this
845: # is technically not proper, but should be harmless
846: my $res = $navmap->firstResource();
847:
848: # Defines a status->color mapping, null string means don't color
849: my %colormap =
850: ( $res->NETWORK_FAILURE => '',
851: $res->CORRECT => '',
852: $res->EXCUSED => '#BBBBFF',
853: $res->PAST_DUE_ANSWER_LATER => '',
854: $res->PAST_DUE_NO_ANSWER => '',
855: $res->ANSWER_OPEN => '#CCFFCC',
856: $res->OPEN_LATER => '',
857: $res->TRIES_LEFT => '',
858: $res->INCORRECT => '',
859: $res->OPEN => '',
860: $res->NOTHING_SET => '' );
861: # And a special case in the nav map; what to do when the assignment
862: # is not yet done and due in less then 24 hours
863: my $hurryUpColor = "#FFCCCC";
864:
865: my %statusIconMap =
866: ( $res->NETWORK_FAILURE => '',
867: $res->NOTHING_SET => '',
868: $res->CORRECT => 'navmap.correct.gif',
869: $res->EXCUSED => 'navmap.correct.gif',
870: $res->PAST_DUE_NO_ANSWER => 'navmap.wrong.gif',
871: $res->PAST_DUE_ANSWER_LATER => 'navmap.wrong.gif',
872: $res->ANSWER_OPEN => 'navmap.wrong.gif',
873: $res->OPEN_LATER => '',
874: $res->TRIES_LEFT => 'navmap.open.gif',
875: $res->INCORRECT => 'navmap.wrong.gif',
876: $res->OPEN => 'navmap.open.gif' );
877:
878: my %condenseStatuses =
879: ( $res->NETWORK_FAILURE => 1,
880: $res->NOTHING_SET => 1,
881: $res->CORRECT => 1,
882: $res->OPEN => 1 );
883:
884: my %filterHash;
885: # Figure out what we're not displaying
886: foreach (split(/\,/, $ENV{"form.filter"})) {
887: if ($_) {
888: $filterHash{$_} = "1";
889: }
890: }
891:
892: # Begin the HTML table
893: # four cols: resource + indent, chat+feedback, icon, text string
894: $r->print('<table cellspacing="3" cellpadding="0" bgcolor="#FFFFFF">' ."\n");
895:
896: my $mapIterator = $navmap->getIterator(undef, undef, \%filterHash);
897: my $curRes = $mapIterator->next();
898: undef $res; # so we don't accidentally use it later
899: my $indentLevel = -1;
900: my $indentString = "<img src=\"/adm/lonIcons/whitespace1.gif\" width=\"25\" height=\"1\"/>";
901:
902: my $isNewBranch = 0;
903: my $now = time();
904: my $in24Hours = $now + 24 * 60 * 60;
905:
906: while ($curRes != $mapIterator->END_NAV_MAP) {
907: if ($curRes == $mapIterator->BEGIN_MAP() ||
908: $curRes == $mapIterator->BEGIN_BRANCH()) {
909: $indentLevel++;
910: }
911: if ($curRes == $mapIterator->END_MAP() ||
912: $curRes == $mapIterator->END_BRANCH()) {
913: $indentLevel--;
914: }
915: if ($curRes == $mapIterator->BEGIN_BRANCH()) {
916: $isNewBranch = 1;
917: }
918:
919: if (ref($curRes) && $curRes->src()) {
920:
921: # Step one: Decide which parts to show
922: my @parts;
923: if ($curRes->is_problem()) {
924: # Is it multipart?
925: @parts = @{$curRes->parts()};
926:
927: my $multipart = scalar(@parts) > 1;
928:
929: if ($multipart) {
930: # If it's multipart, see if part 0 is "open"
931: # if it is, display all parts, if it isn't,
932: # just display first
933: if (!$curRes->opendate("0")) {
934: @parts = ("0"); # just display the zero-th part
935: } else {
936: # Otherwise, only display part 0 if we want to
937: # attach feedback or email information to it
938: if (!$curRes->hasDiscussion() && !$curRes->getFeedback()) {
939: shift @parts;
940: } else {
941: # If there's discussion or feedback, that counts
942: # as a difference, so display the parts.
943:
944: # Now, we decide whether to condense the
945: # parts due to similarity
946: my $status = $curRes->status($parts[0]);
947: my $allSame = 1;
948: for (my $i = 1; $i < scalar(@parts); $i++) {
949: if ($curRes->status($parts[$i]) != $status){
950: $allSame = 0;
951: }
952: }
953:
954: # $allSame is true if all the statuses were
955: # the same. Now, if they are all the same and
956: # match one of the statuses to condense, then
957: # only display part 0.
958: if ($allSame && defined($condenseStatuses{$status})){
959: @parts = ("0");
960: }
961: }
962: }
963: }
964:
965: } else {
966: @parts[0] = "0"; # this is to get past foreach loop below
967: # you can consider a non-problem resource as a resource
968: # with only one part without loss
969: }
970:
971: # Step two: Show the parts
972: foreach my $part (@parts) {
973:
974: my $deltalevel = 0; # for inserting the branch icon
975:
976: # For each thing we're displaying...
977:
978: my $stack = $mapIterator->getStack();
979: my $src = getLinkForResource($stack);
980:
981: my $srcHasQuestion = $src =~ /\?/;
982: my $link = $src.
983: ($srcHasQuestion?'&':'?') .
984: 'symb='.&Apache::lonnet::escape($curRes->symb()).
985: '"';
986: my $title = $curRes->title();
987: my $partLabel = "";
988: my $newBranchText = "";
989:
990: # If this is a new branch, label it so
991: # (temporary, this should be an icon w/ alt text)
992: if ($isNewBranch) {
993: $newBranchText = "<img src=\"/adm/lonIcons/branch.gif\" border=\"0\">";
994: $isNewBranch = 0;
995: $deltalevel = 1;
996: }
997:
998: # links to open and close the folders
999: my $linkopen = "<a href=\"$link\">";
1000: my $linkclose = "</a>";
1001:
1002: my $icon = "html.gif";
1003: if ($curRes->is_problem()) {
1004: $icon = "problem.gif";
1005: }
1006:
1007: # Display the correct icon, link to open or shut map
1008: if ($curRes->is_map()) {
1009: my $mapId = $curRes->map_pc();
1010: my $nowOpen = !defined($filterHash{$mapId});
1011: $icon = $nowOpen ?
1012: "folder_opened.gif" : "folder_closed.gif";
1013: $linkopen = "<a href=\"/adm/navmaps?filter=";
1014: $linkopen .= $nowOpen ?
1015: addToFilter(\%filterHash, $mapId) :
1016: removeFromFilter(\%filterHash, $mapId);
1017: $linkopen .= "\">";
1018: $linkclose = "</a>";
1019:
1020: }
1021:
1022: my $colorizer = "";
1023: if ($curRes->is_problem()) {
1024: my $status = $curRes->status($part);
1025: my $color = $colormap{$status};
1026: if ($color ne "") {
1027: $colorizer = "bgcolor=\"$color\"";
1028: }
1029: }
1030:
1031: # FIRST ROW: The resource indentation, branch icon, and name
1032: $r->print(" <tr><td align=\"left\" valign=\"top\">\n");
1033:
1034: # print indentation
1035: for (my $i = 0; $i < $indentLevel - $deltalevel; $i++) {
1036: $r->print($indentString);
1037: }
1038:
1039: $r->print(" ${newBranchText}${linkopen}<img border=\"0\" src=\"" .
1040: "/adm/lonIcons/$icon\" alt=\"\">${linkclose}\n");
1041:
1042: if ($curRes->is_problem() && $part != "0") { $partLabel = " (Part $part)"; }
1043:
1044: $r->print(" <a href=\"$link\">$title$partLabel</a></td>");
1045:
1046: my $discussionHTML = ""; my $feedbackHTML = "";
1047:
1048: # SECOND ROW: Is there text or feedback?
1049: if ($curRes->hasDiscussion()) {
1050: $discussionHTML = $linkopen .
1051: '<img border="0" src="/adm/lonMisc/chat.gif" />' .
1052: $linkclose;
1053: }
1054:
1055: if ($curRes->getFeedback()) {
1056: my $feedback = $curRes->getFeedback();
1057: foreach (split(/\,/, $feedback)) {
1058: if ($_) {
1059: $feedbackHTML .= ' <a href="/adm/email?display='
1060: . &Apache::lonnet::escape($_) . '">'
1061: . '<img src="/adm/lonMisc/feedback.gif" '
1062: . 'border="0" /></a>';
1063: }
1064: }
1065: }
1066:
1067: $r->print("<td align=\"left\">$discussionHTML$feedbackHTML</td>");
1068:
1069: # THIRD ROW: Problem status icon
1070: if ($curRes->is_problem()) {
1071: my $icon = $statusIconMap{$curRes->status()};
1072: if ($icon) {
1073: $r->print("<td width=\"50\" align=\"right\">$linkopen<img src=\"/adm/lonIcons/$icon\" border=\"0\" />$linkclose</td>\n");
1074: } else {
1075: $r->print("<td></td>\n");
1076: }
1077: } else { # not problem, no icon
1078: $r->print("<td></td>\n");
1079: }
1080:
1081: # FOURTH ROW: Text description
1082: $r->print("<td $colorizer align=\"right\">\n");
1083:
1084: if ($curRes->kind() eq "res" and
1085: $curRes->is_problem() ) {
1086: $r->print (getDescription($curRes, $part));
1087: }
1088:
1089: $r->print("</td></tr>\n");
1090: }
1091: }
1092: $curRes = $mapIterator->next();
1093: }
1094:
1095: $r->print("</table></body></html>");
1096:
1097: $navmap->untieHashes();
1098:
1099: return OK;
1100: }
1101:
1102: # Convenience functions: Returns a string that adds or subtracts
1103: # the second argument from the first hash, appropriate for the
1104: # query string that determines which folders to recurse on
1105: sub addToFilter {
1106: my $hashIn = shift;
1107: my $addition = shift;
1108: my %hash = %$hashIn;
1109: $hash{$addition} = 1;
1110:
1111: return join (",", keys(%hash));
1112: }
1113:
1114: sub removeFromFilter {
1115: my $hashIn = shift;
1116: my $subtraction = shift;
1117: my %hash = %$hashIn;
1118:
1119: delete $hash{$subtraction};
1120: return join(",", keys(%hash));
1121: }
1122:
1123: # Convenience function: Given a stack returned from getStack on the iterator,
1124: # return the correct src() value.
1125: # Later, this should add an anchor when we start putting anchors in pages.
1126: sub getLinkForResource {
1127: my $stack = shift;
1128: my $res;
1129:
1130: # Check to see if there are any pages in the stack
1131: foreach $res (@$stack) {
1132: if (defined($res) && $res->is_page()) {
1133: return $res->src();
1134: }
1135: }
1136:
1137: # Failing that, return the src of the last resource that is defined
1138: # (when we first recurse on a map, it puts an undefined resource
1139: # on the bottom because $self->{HERE} isn't defined yet, and we
1140: # want the src for the map anyhow)
1141: foreach (@$stack) {
1142: if (defined($_)) { $res = $_; }
1143: }
1144:
1145: return $res->src();
1146: }
1147:
1148: # Convenience function: This seperates the logic of how to create
1149: # the problem text strings ("Due: DATE", "Open: DATE", "Not yet assigned",
1150: # etc.) into a seperate function. It takes a resource object as the
1151: # first parameter, and the part number of the resource as the second.
1152: # It's basically a big switch statement on the status of the resource.
1153:
1154: sub getDescription {
1155: my $res = shift;
1156: my $part = shift;
1157: my $status = $res->getDateStatus();
1158:
1159: if ($status == $res->NETWORK_FAILURE) { return ""; }
1160: if ($status == $res->NOTHING_SET) {
1161: return "Not currently assigned.";
1162: }
1163: if ($status == $res->OPEN_LATER) {
1164: return "Opens: " . timeToHumanString($res->opendate($part));
1165: }
1166: if ($status == $res->OPEN) {
1167: if ($res->duedate()) {
1168: return "Due: $status " . timeToHumanString($res->duedate($part));
1169: } else {
1170: return "Open, no due date";
1171: }
1172: }
1173: if ($status == $res->PAST_DUE_ANSWER_LATER) {
1174: return "Answer opens: " . timeToHumanString($res->answerdate($part));
1175: }
1176: if ($status == $res->PAST_DUE_NO_ANSWER) {
1177: return "Was Due: " . timeToHumanString($res->duedate($part));
1178: }
1179: if ($status == $res->ANSWER_OPEN) {
1180: return "Answer available";
1181: }
1182: if ($status == $res->EXCUSED) {
1183: return "Excused by instructor";
1184: }
1185: if ($status == $res->TRIES_LEFT) {
1186: my $tries = $res->tries();
1187: my $maxtries = $res->maxtries();
1188: my $triesString = "($tries of $maxtries tries used)";
1189: if ($res->duedate()) {
1190: return "Due: $status " . timeToHumanString($res->duedate($part)) .
1191: " $triesString";
1192: } else {
1193: return "No due date $triesString";
1194: }
1195: }
1196: }
1197:
1198: # I want to change this into something more human-friendly. For
1199: # now, this is a simple call to localtime. The final function
1200: # probably belongs in loncommon.
1201: sub timeToHumanString {
1202: my ($time) = @_;
1203: # zero, '0' and blank are bad times
1204: if ($time) {
1205: return localtime($time);
1206: } else {
1207: return 'Never';
1208: }
1209: }
1210:
1211: 1;
1212:
1213: package Apache::lonnavmaps::navmap;
1214:
1215: # LEFT:
1216: # * Actual handler code (multi-part)
1217: # * Branches (aieee!) (and conditionals)
1218:
1219: =pod
1220:
1221: lonnavmaps provides functions and objects for dealing with the compiled course hashes generated when a user enters the course, and also provides the Apache handler for the "Navigation Map" button.
1222:
1223: =head1 navmap object: Encapsulating the compiled nav map
1224:
1225: navmap is an object that encapsulates a compiled course map and provides a reasonable interface to it.
1226:
1227: Most notably it provides a way to navigate the map sensibly and a flexible iterator that makes it easy to write various renderers based on nav maps.
1228:
1229: You must obtain resource objects through the navmap object.
1230:
1231: =head2 Methods
1232:
1233: =over 4
1234:
1235: =item * B<new>(filename, parmHashFile, genCourseAndUserOptions, genMailDiscussStatus): Binds a new navmap object to the compiled course representation and parmHashFile. genCourseAndUserOptions is a flag saying whether the course options and user options hash should be generated. This is for when you are using the parameters of the resources that require them; see documentation in resource object documentation. genMailDiscussStatus causes the nav map to retreive information about the email and discussion status of resources. Returns the navmap object if this is successful, or B<undef> if not. You must check for undef; errors will occur when you try to use the other methods otherwise.
1236:
1237: =item * B<getIterator>(first, finish, filter, condition): See iterator documentation below.
1238:
1239: =cut
1240:
1241: use strict;
1242: use GDBM_File;
1243:
1244: sub new {
1245: # magic invocation to create a class instance
1246: my $proto = shift;
1247: my $class = ref($proto) || $proto;
1248: my $self = {};
1249:
1250: $self->{NAV_HASH_FILE} = shift;
1251: $self->{PARM_HASH_FILE} = shift;
1252: $self->{GENERATE_COURSE_USER_OPT} = shift;
1253: $self->{GENERATE_EMAIL_DISCUSS_STATUS} = shift;
1254:
1255: # Resource cache stores navmapresource's as we reference them. We generate
1256: # them on-demand so we don't pay for creating resources unless we use them.
1257: $self->{RESOURCE_CACHE} = {};
1258:
1259: # Network failure flag, if we accessed the course or user opt and
1260: # failed
1261: $self->{NETWORK_FAILURE} = 0;
1262:
1263: # tie the nav hash
1264: my %navmaphash;
1265: if (!(tie(%navmaphash, 'GDBM_File', $self->{NAV_HASH_FILE},
1266: &GDBM_READER(), 0640))) {
1267: return undef;
1268: }
1269: $self->{NAV_HASH} = \%navmaphash;
1270:
1271: my %parmhash;
1272: if (!(tie(%parmhash, 'GDBM_File', $self->{PARM_HASH_FILE},
1273: &GDBM_READER(), 0640)))
1274: {
1275: untie $self->{PARM_HASH};
1276: return undef;
1277: }
1278: $self->{PARM_HASH} = \%parmhash;
1279: $self->{HASH_TIED} = 1;
1280:
1281: # If the course opt hash and the user opt hash should be generated,
1282: # generate them
1283: if ($self->{GENERATE_COURSE_USER_OPT}) {
1284: my $uname=$ENV{'user.name'};
1285: my $udom=$ENV{'user.domain'};
1286: my $uhome=$ENV{'user.home'};
1287: my $cid=$ENV{'request.course.id'};
1288: my $chome=$ENV{'course.'.$cid.'.home'};
1289: my ($cdom,$cnum)=split(/\_/,$cid);
1290:
1291: my $userprefix=$uname.'_'.$udom.'_';
1292:
1293: my %courserdatas; my %useropt; my %courseopt;
1294: unless ($uhome eq 'no_host') {
1295: # ------------------------------------------------- Get coursedata (if present)
1296: unless ((time-$courserdatas{$cid.'.last_cache'})<240) {
1297: my $reply=&Apache::lonnet::reply('dump:'.$cdom.':'.$cnum.
1298: ':resourcedata',$chome);
1299: if ($reply!~/^error\:/) {
1300: $courserdatas{$cid}=$reply;
1301: $courserdatas{$cid.'.last_cache'}=time;
1302: }
1303: # check to see if network failed
1304: elsif ( $reply=~/no.such.host/i || $reply=~/con.*lost/i )
1305: {
1306: $self->{NETWORK_FAILURE} = 1;
1307: }
1308: }
1309: foreach (split(/\&/,$courserdatas{$cid})) {
1310: my ($name,$value)=split(/\=/,$_);
1311: $courseopt{$userprefix.&Apache::lonnet::unescape($name)}=
1312: &Apache::lonnet::unescape($value);
1313: }
1314: # --------------------------------------------------- Get userdata (if present)
1315: unless ((time-$userrdatas{$uname.'___'.$udom.'.last_cache'})<240) {
1316: my $reply=&Apache::lonnet::reply('dump:'.$udom.':'.$uname.':resourcedata',$uhome);
1317: if ($reply!~/^error\:/) {
1318: $userrdatas{$uname.'___'.$udom}=$reply;
1319: $userrdatas{$uname.'___'.$udom.'.last_cache'}=time;
1320: }
1321: # check to see if network failed
1322: elsif ( $reply=~/no.such.host/i || $reply=~/con.*lost/i )
1323: {
1324: $self->{NETWORK_FAILURE} = 1;
1325: }
1326: }
1327: foreach (split(/\&/,$userrdatas{$uname.'___'.$udom})) {
1328: my ($name,$value)=split(/\=/,$_);
1329: $useropt{$userprefix.&Apache::lonnet::unescape($name)}=
1330: &Apache::lonnet::unescape($value);
1331: }
1332: $self->{COURSE_OPT} = \%courseopt;
1333: $self->{USER_OPT} = \%useropt;
1334: }
1335: }
1336:
1337: if ($self->{GENERATE_EMAIL_DISCUSS_STATUS}) {
1338: my $cid=$ENV{'request.course.id'};
1339: my ($cdom,$cnum)=split(/\_/,$cid);
1340:
1341: my %emailstatus = &Apache::lonnet::dump('email_status');
1342: my $logoutTime = $emailstatus{'logout'};
1343: my $courseLeaveTime = $emailstatus{'logout_'.$ENV{'request.course.id'}};
1344: $self->{LAST_CHECK} = ($courseLeaveTime > $logoutTime ?
1345: $courseLeaveTime : $logoutTime);
1346: my %discussiontime = &Apache::lonnet::dump('discussiontimes',
1347: $cdom, $cnum);
1348: my %feedback=();
1349: my %error=();
1350: my $keys = &Apache::lonnet::reply('keys:'.
1351: $ENV{'user.domain'}.':'.
1352: $ENV{'user.name'}.':nohist_email',
1353: $ENV{'user.home'});
1354:
1355: foreach my $msgid (split(/\&/, $keys)) {
1356: $msgid=&Apache::lonnet::unescape($msgid);
1357: my $plain=&Apache::lonnet::unescape(&Apache::lonnet::unescape($msgid));
1358: if ($plain=~/(Error|Feedback) \[([^\]]+)\]/) {
1359: my ($what,$url)=($1,$2);
1360: my %status=
1361: &Apache::lonnet::get('email_status',[$msgid]);
1362: if ($status{$msgid}=~/^error\:/) {
1363: $status{$msgid}='';
1364: }
1365:
1366: if (($status{$msgid} eq 'new') ||
1367: (!$status{$msgid})) {
1368: if ($what eq 'Error') {
1369: $error{$url}.=','.$msgid;
1370: } else {
1371: $feedback{$url}.=','.$msgid;
1372: }
1373: }
1374: }
1375: }
1376:
1377: $self->{FEEDBACK} = \%feedback;
1378: $self->{ERROR_MSG} = \%error; # what is this? JB
1379: $self->{DISCUSSION_TIME} = \%discussiontime;
1380: $self->{EMAIL_STATUS} = \%emailstatus;
1381:
1382: }
1383:
1384: bless($self);
1385:
1386: return $self;
1387: }
1388:
1389: # Checks to see if coursemap is defined, matching test in old lonnavmaps
1390: sub courseMapDefined {
1391: my $self = shift;
1392: my $uri = &Apache::lonnet::clutter($ENV{'request.course.uri'});
1393:
1394: my $firstres = $self->{NAV_HASH}->{"map_start_$uri"};
1395: my $lastres = $self->{NAV_HASH}->{"map_finish_$uri"};
1396: return $firstres && $lastres;
1397: }
1398:
1399: sub getIterator {
1400: my $self = shift;
1401: my $iterator = Apache::lonnavmaps::iterator->new($self, shift, shift,
1402: shift, shift);
1403: return $iterator;
1404: }
1405:
1406: # unties the hash when done
1407: sub untieHashes {
1408: my $self = shift;
1409: untie %{$self->{NAV_HASH}} if ($self->{HASH_TIED});
1410: untie %{$self->{PARM_HASH}} if ($self->{HASH_TIED});
1411: $self->{HASH_TIED} = 0;
1412: }
1413:
1414: # when the object is destroyed, be sure to untie all the hashes we tied.
1415: sub DESTROY {
1416: my $self = shift;
1417: $self->untieHashes();
1418: }
1419:
1420: # Private function: Does the given resource (as a symb string) have
1421: # current discussion? Returns 0 if chat/mail data not extracted.
1422: sub hasDiscussion {
1423: my $self = shift;
1424: my $symb = shift;
1425: if (!defined($self->{DISCUSSION_TIME})) { return 0; }
1426:
1427: return $self->{DISCUSSION_TIME}->{$symb} >
1428: $self->{LAST_CHECK};
1429: }
1430:
1431: # Private function: Does the given resource (as a symb string) have
1432: # current feedback? Returns the string in the feedback hash, which
1433: # will be false if it does not exist.
1434: sub getFeedback {
1435: my $self = shift;
1436: my $symb = shift;
1437:
1438: if (!defined($self->{FEEDBACK})) { return ""; }
1439:
1440: return $self->{FEEDBACK}->{$symb};
1441: }
1442:
1443: =pod
1444:
1445: =item * B<getById>(id): Based on the ID of the resource (1.1, 3.2, etc.), get a resource object for that resource. This method, or other methods that use it (as in the resource object) is the only proper way to obtain a resource object.
1446:
1447: =cut
1448:
1449: # The strategy here is to cache the resource objects, and only construct them
1450: # as we use them. The real point is to prevent reading any more from the tied
1451: # hash then we have to, which should hopefully alleviate speed problems.
1452: # Caching is just an incidental detail I throw in because it makes sense.
1453:
1454: sub getById {
1455: my $self = shift;
1456: my $id = shift;
1457:
1458: if (defined ($self->{RESOURCE_CACHE}->{$id}))
1459: {
1460: return $self->{RESOURCE_CACHE}->{$id};
1461: }
1462:
1463: # resource handles inserting itself into cache.
1464: return Apache::lonnavmaps::resource->new($self, $id);
1465: }
1466:
1467: =pod
1468:
1469: =item * B<firstResource>(): Returns a resource object reference corresponding to the first resource in the navmap.
1470:
1471: =cut
1472:
1473: sub firstResource {
1474: my $self = shift;
1475: my $firstResource = $self->{NAV_HASH}->{'map_start_' .
1476: &Apache::lonnet::clutter($ENV{'request.course.uri'})};
1477: return $self->getById($firstResource);
1478: }
1479:
1480: =pod
1481:
1482: =item * B<finishResource>(): Returns a resource object reference corresponding to the last resource in the navmap.
1483:
1484: =cut
1485:
1486: sub finishResource {
1487: my $self = shift;
1488: my $firstResource = $self->{NAV_HASH}->{'map_finish_' .
1489: &Apache::lonnet::clutter($ENV{'request.course.uri'})};
1490: return $self->getById($firstResource);
1491: }
1492:
1493: # -------------------------------------------- Figure out a cascading parameter
1494: #
1495: # For this function to work
1496: #
1497: # * parmhash needs to be tied
1498: # * courseopt and useropt need to be initialized for this user and course
1499: #
1500:
1501: sub parmval {
1502: my $self = shift;
1503: my ($what,$symb)=@_;
1504: my $cid=$ENV{'request.course.id'};
1505: my $csec=$ENV{'request.course.sec'};
1506: my $uname=$ENV{'user.name'};
1507: my $udom=$ENV{'user.domain'};
1508:
1509: unless ($symb) { return ''; }
1510: my $result='';
1511:
1512: my ($mapname,$id,$fn)=split(/\_\_\_/,$symb);
1513:
1514: # ----------------------------------------------------- Cascading lookup scheme
1515: my $rwhat=$what;
1516: $what=~s/^parameter\_//;
1517: $what=~s/\_/\./;
1518:
1519: my $symbparm=$symb.'.'.$what;
1520: my $mapparm=$mapname.'___(all).'.$what;
1521: my $usercourseprefix=$uname.'_'.$udom.'_'.$cid;
1522:
1523: my $seclevel= $usercourseprefix.'.['.$csec.'].'.$what;
1524: my $seclevelr=$usercourseprefix.'.['.$csec.'].'.$symbparm;
1525: my $seclevelm=$usercourseprefix.'.['.$csec.'].'.$mapparm;
1526:
1527: my $courselevel= $usercourseprefix.'.'.$what;
1528: my $courselevelr=$usercourseprefix.'.'.$symbparm;
1529: my $courselevelm=$usercourseprefix.'.'.$mapparm;
1530:
1531: my $useropt = $self->{USER_OPT};
1532: my $courseopt = $self->{COURSE_OPT};
1533: my $parmhash = $self->{PARM_HASH};
1534:
1535: # ---------------------------------------------------------- first, check user
1536: if ($uname and defined($useropt)) {
1537: if (defined($$useropt{$courselevelr})) { return $$useropt{$courselevelr}; }
1538: if (defined($$useropt{$courselevelm})) { return $$useropt{$courselevelm}; }
1539: if (defined($$useropt{$courselevel})) { return $$useropt{$courselevel}; }
1540: }
1541:
1542: # ------------------------------------------------------- second, check course
1543: if ($csec and defined($courseopt)) {
1544: if (defined($$courseopt{$seclevelr})) { return $$courseopt{$seclevelr}; }
1545: if (defined($$courseopt{$seclevelm})) { return $$courseopt{$seclevelm}; }
1546: if (defined($$courseopt{$seclevel})) { return $$courseopt{$seclevel}; }
1547: }
1548:
1549: if (defined($courseopt)) {
1550: if (defined($$courseopt{$courselevelr})) { return $$courseopt{$courselevelr}; }
1551: if (defined($$courseopt{$courselevelm})) { return $$courseopt{$courselevelm}; }
1552: if (defined($$courseopt{$courselevel})) { return $$courseopt{$courselevel}; }
1553: }
1554:
1555: # ----------------------------------------------------- third, check map parms
1556:
1557: my $thisparm=$$parmhash{$symbparm};
1558: if (defined($thisparm)) { return $thisparm; }
1559:
1560: # ----------------------------------------------------- fourth , check default
1561:
1562: my $default=&Apache::lonnet::metadata($fn,$rwhat.'.default');
1563: if (defined($default)) { return $default}
1564:
1565: # --------------------------------------------------- fifth , cascade up parts
1566:
1567: my ($space,@qualifier)=split(/\./,$rwhat);
1568: my $qualifier=join('.',@qualifier);
1569: unless ($space eq '0') {
1570: my ($part,$id)=split(/\_/,$space);
1571: if ($id) {
1572: my $partgeneral=$self->parmval($part.".$qualifier",$symb);
1573: if (defined($partgeneral)) { return $partgeneral; }
1574: } else {
1575: my $resourcegeneral=$self->parmval("0.$qualifier",$symb);
1576: if (defined($resourcegeneral)) { return $resourcegeneral; }
1577: }
1578: }
1579: return '';
1580: }
1581:
1582:
1583: 1;
1584:
1585: package Apache::lonnavmaps::iterator;
1586:
1587: # This package must precede "navmap" because "navmap" uses it. In
1588: # order to keep the documentation order straight, the iterator is documented
1589: # after the navmap object.
1590:
1591: =pod
1592:
1593: =back
1594:
1595: =head1 navmap Iterator
1596:
1597: An I<iterator> encapsulates the logic required to traverse a data structure. navmap uses an iterator to traverse the course map according to the criteria you wish to use.
1598:
1599: To obtain an iterator, call the B<getIterator>() function of a B<navmap> object. (Do not instantiate Apache::lonnavmaps::iterator directly.) This will return a reference to the iterator:
1600:
1601: C<my $resourceIterator = $navmap-E<gt>getIterator();>
1602:
1603: To get the next thing from the iterator, call B<next>:
1604:
1605: C<my $nextThing = $resourceIterator-E<gt>next()>
1606:
1607: getIterator behaves as follows:
1608:
1609: =over 4
1610:
1611: =item B<getIterator>(nav_map, firstResource, finishResource, filterHash): All parameters are optional. firstResource is a resource reference corresponding to where the iterator should start. It defaults to navmap->firstResource() for the corresponding nav map. finishResource corresponds to where you want the iterator to end, defaulting to navmap->finishResource(). It is your responsibility to ensure that the iterator will actually get there. filterHash is a hash used as a set containing strings representing the resource IDs, defaulting to empty. Condition is a 1 or 0 that sets what to do with the filter hash: If a 1, then only resource that exist IN the filterHash will be recursed on. If it is a 0, only resources NOT in the filterHash will be recursed on. Defaults to 0.
1612:
1613: Thus, by default, all resources will be shown. Change the condition to a 1 without changing the hash, and only the top level of the map will be shown. Changing the condition to 1 and including some values in the hash will allow you to selectively examine parts of the navmap, while leaving it on 0 and adding things to the hash will allow you to selectively ignore parts of the nav map. See the handler code for examples.
1614:
1615: The iterator will return either a reference to a resource object, or a token representing something in the map, such as the beginning of a new branch. The possible tokens are:
1616:
1617: =over 4
1618:
1619: =item * some list of tokens here
1620:
1621: =back
1622:
1623: The tokens are retreivable via methods on the iterator object, i.e., $iterator->END_NAV_MAP. (Perl will automatically optimize these into constants.
1624:
1625: =cut
1626:
1627: # Here are the tokens for the iterator:
1628:
1629: sub END_NAV_MAP { return 0; } # Represents end of entire nav map
1630: sub BEGIN_MAP { return 1; } # begining of a new map
1631: sub END_MAP { return 2; } # end of the map
1632: sub BEGIN_BRANCH { return 3; } # beginning of a branch
1633: sub END_BRANCH { return 4; } # end of a branch
1634:
1635: # Params: nav map, start resource, end resource, filter, condition,
1636: # already seen hash ref
1637:
1638: sub new {
1639: # magic invocation to create a class instance
1640: my $proto = shift;
1641: my $class = ref($proto) || $proto;
1642: my $self = {};
1643:
1644: $self->{NAV_MAP} = shift;
1645: return undef unless ($self->{NAV_MAP});
1646:
1647: # Handle the parameters
1648: $self->{FIRST_RESOURCE} = shift || $self->{NAV_MAP}->firstResource();
1649: $self->{FINISH_RESOURCE} = shift || $self->{NAV_MAP}->finishResource();
1650:
1651: # If the given resources are just the ID of the resource, get the
1652: # objects
1653: if (!ref($self->{FIRST_RESOURCE})) { $self->{FIRST_RESOURCE} =
1654: $self->{NAV_MAP}->getById($self->{FIRST_RESOURCE}); }
1655: if (!ref($self->{FINISH_RESOURCE})) { $self->{FINISH_RESOURCE} =
1656: $self->{NAV_MAP}->getById($self->{FINISH_RESOURCE}); }
1657:
1658: $self->{FILTER} = shift;
1659:
1660: # A hash, used as a set, of resource already seen
1661: $self->{ALREADY_SEEN} = shift;
1662: if (!defined($self->{ALREADY_SEEN})) { $self->{ALREADY_SEEN} = {} };
1663:
1664: # Flag: Have we started yet? If not, the first action is to return BEGIN_MAP.
1665: $self->{STARTED} = 0;
1666:
1667: # Should we continue calling the recursive iterator, if any?
1668: $self->{RECURSIVE_ITERATOR_FLAG} = 0;
1669: # The recursive iterator, if any
1670: $self->{RECURSIVE_ITERATOR} = undef;
1671: # Are we recursing on a map, or a branch?
1672: $self->{RECURSIVE_MAP} = 1; # we'll manually unset this when recursing on branches
1673: # And the count of how deep it is, so that this iterator can keep track of
1674: # when to pick back up again.
1675: $self->{RECURSIVE_DEPTH} = 0;
1676:
1677: # For keeping track of our branches, we maintain our own stack
1678: $self->{BRANCH_STACK} = [];
1679: # If the size shrinks, we exhausted a branch
1680: $self->{BRANCH_STACK_SIZE} = 0;
1681: $self->{BRANCH_DEPTH} = 0;
1682:
1683: # For returning two things in a forced sequence
1684: $self->{FORCE_NEXT} = undef;
1685:
1686: # Start with the first resource
1687: push @{$self->{BRANCH_STACK}}, $self->{FIRST_RESOURCE};
1688: $self->{BRANCH_STACK_SIZE} = 1;
1689:
1690: bless($self);
1691: return $self;
1692: }
1693:
1694: # Note... this function is *touchy*. I strongly recommend tracing
1695: # through it with the debugger a few times on a non-trivial map before
1696: # modifying it. Order is *everything*.
1697: sub next {
1698: my $self = shift;
1699:
1700: # Iterator logic goes here
1701:
1702: # Is this return value pre-determined?
1703: if (defined($self->{FORCE_NEXT})) {
1704: my $tmp = $self->{FORCE_NEXT};
1705: $self->{FORCE_NEXT} = undef;
1706: return $tmp;
1707: }
1708:
1709: # Are we using a recursive iterator? If so, pull from that and
1710: # watch the depth; we want to resume our level at the correct time.
1711: if ($self->{RECURSIVE_ITERATOR_FLAG})
1712: {
1713: # grab the next from the recursive iterator
1714: my $next = $self->{RECURSIVE_ITERATOR}->next();
1715:
1716: # is it a begin or end map? Update depth if so
1717: if ($next == BEGIN_MAP() ) { $self->{RECURSIVE_DEPTH}++; }
1718: if ($next == END_MAP() ) { $self->{RECURSIVE_DEPTH}--; }
1719:
1720: # Are we back at depth 0? If so, stop recursing.
1721: if ($self->{RECURSIVE_DEPTH} == 0) {
1722: $self->{RECURSIVE_ITERATOR_FLAG} = 0;
1723: }
1724:
1725: return $next;
1726: }
1727:
1728: # Is there a current resource to grab? If not, then return
1729: # END_BRANCH and END_MAP in succession.
1730: if (scalar(@{$self->{BRANCH_STACK}}) == 0) {
1731: if ($self->{BRANCH_DEPTH} > 0) {
1732: $self->{FORCE_NEXT} = $self->END_MAP();
1733: $self->{BRANCH_DEPTH}--;
1734: return $self->END_BRANCH();
1735: } else {
1736: return $self->END_MAP();
1737: }
1738: }
1739:
1740: # Have we not yet begun? If not, return BEGIN_MAP and
1741: # remember that we've started.
1742: if ( !$self->{STARTED} ) {
1743: $self->{STARTED} = 1;
1744: return $self->BEGIN_MAP;
1745: }
1746:
1747: # Did the branch stack shrink since last run? If so,
1748: # we exhausted a branch last time, therefore, we're about
1749: # to start a new one. (We know because we already checked to see
1750: # if the stack was empty.)
1751: if ( scalar (@{$self->{BRANCH_STACK}}) < $self->{BRANCH_STACK_SIZE}) {
1752: $self->{BRANCH_STACK_SIZE} = scalar(@{$self->{BRANCH_STACK}});
1753: $self->{BRANCH_DEPTH}++;
1754: return $self->BEGIN_BRANCH();
1755: }
1756:
1757: # Remember the size for comparision next time.
1758: $self->{BRANCH_STACK_SIZE} = scalar(@{$self->{BRANCH_STACK}});
1759:
1760: # If the next resource we mean to return is going to need
1761: # a lower branch level, terminate branches until we get
1762: # there.
1763:
1764: # Get the next resource in the branch
1765: $self->{HERE} = pop @{$self->{BRANCH_STACK}};
1766:
1767: # Are we at the right depth? If not, close a branch and return
1768: # the current resource onto the branch stack
1769: if (defined($self->{HERE}->{DATA}->{ITERATOR_DEPTH})
1770: && $self->{HERE}->{DATA}->{ITERATOR_DEPTH} <
1771: $self->{BRANCH_DEPTH} ) {
1772: $self->{BRANCH_DEPTH}--;
1773: # return it so we can pick it up eventually
1774: push @{$self->{BRANCH_STACK}}, $self->{HERE};
1775: return $self->END_BRANCH();
1776: }
1777:
1778: # We always return it after this point and never before
1779: # (proof: look at just the return statements), so we
1780: # remember that we've seen this.
1781: $self->{ALREADY_SEEN}->{$self->{HERE}->{ID}} = 1;
1782:
1783: # Are we at the utter end? If so, return the END_NAV_MAP marker.
1784: if ($self->{HERE} == $self->{NAV_MAP}->finishResource() ) {
1785: $self->{FORCE_NEXT} = $self->END_NAV_MAP;
1786: return $self->{HERE};
1787: }
1788:
1789: # Get the next possible resources
1790: my $nextUnfiltered = $self->{HERE}->getNext();
1791: my $next = [];
1792:
1793: # filter the next possibilities to remove things we've
1794: # already seen. Also, remember what branch depth they should
1795: # be displayed at, since there's no other reliable way to tell.
1796: foreach (@$nextUnfiltered) {
1797: if (!defined($self->{ALREADY_SEEN}->{$_->{ID}})) {
1798: push @$next, $_;
1799: $_->{DATA}->{ITERATOR_DEPTH} =
1800: $self->{BRANCH_DEPTH} + 1;
1801: }
1802: }
1803:
1804: # Handle branch cases:
1805: # Nothing is available next: BRANCH_END
1806: # 1 thing next: standard non-branch
1807: # 2+ things next: have some branches
1808: my $nextCount = scalar(@$next);
1809: if ($nextCount == 0) {
1810: # Return this and on the next run, close the branch up if we're
1811: # in a branch
1812: if ($self->{BRANCH_DEPTH} > 0 ) {
1813: $self->{FORCE_NEXT} = $self->END_BRANCH();
1814: $self->{BRANCH_DEPTH}--;
1815: }
1816: return $self->{HERE};
1817: }
1818:
1819: while (@$next) {
1820: # copy the next possibilities over to the branch stack
1821: # in the right order
1822: push @{$self->{BRANCH_STACK}}, shift @$next;
1823: }
1824:
1825: if ($nextCount >= 2) {
1826: $self->{FORCE_NEXT} = $self->BEGIN_BRANCH();
1827: $self->{BRANCH_DEPTH}++;
1828: return $self->{HERE};
1829: }
1830:
1831: # If this is a map and we want to recurse down it... (not filtered out)
1832: if ($self->{HERE}->is_map() &&
1833: !defined($self->{FILTER}->{$self->{HERE}->map_pc()})) {
1834: $self->{RECURSIVE_ITERATOR_FLAG} = 1;
1835: my $firstResource = $self->{HERE}->map_start();
1836: my $finishResource = $self->{HERE}->map_finish();
1837:
1838: # Odd perl syntax here; $self->new allows one to create a new iterator
1839: # can't figure out how to ref this package directly correctly
1840: # isn't MAIN::new, __PACKAGE__::new or Apache::lonnavmaps::iterator->new
1841: $self->{RECURSIVE_ITERATOR} =
1842: Apache::lonnavmaps::iterator->new ($self->{NAV_MAP}, $firstResource,
1843: $finishResource, $self->{FILTER}, $self->{ALREADY_SEEN});
1844: # prime the new iterator with the first resource
1845: #push @{$self->{RECURSIVE_ITERATOR}->{BRANCH_STACK}}, $firstResource;
1846: }
1847:
1848: return $self->{HERE};
1849: }
1850:
1851: =pod
1852:
1853: The other method available on the iterator is B<getStack>, which returns an array populated with the current 'stack' of maps, as references to the resource objects. Example: This is useful when making the navigation map, as we need to check whether we are under a page map to see if we need to link directly to the resource, or to the page. The first elements in the array will correspond to the top of the stack (most inclusive map).
1854:
1855: =cut
1856:
1857: sub getStack {
1858: my $self=shift;
1859:
1860: my @stack;
1861:
1862: $self->populateStack(\@stack);
1863:
1864: return \@stack;
1865: }
1866:
1867: # Private method: Calls the iterators recursively to populate the stack.
1868: sub populateStack {
1869: my $self=shift;
1870: my $stack = shift;
1871:
1872: push @$stack, $self->{HERE};
1873:
1874: if ($self->{RECURSIVE_ITERATOR_FLAG}) {
1875: $self->{RECURSIVE_ITERATOR}->populateStack($stack);
1876: }
1877: }
1878:
1879: 1;
1880:
1881: package Apache::lonnavmaps::resource;
1882:
1883: use Apache::lonnet;
1884:
1885: =pod
1886:
1887: =head1 Object: resource
1888:
1889: A resource object encapsulates a resource in a resource map, allowing easy manipulation of the resource, querying the properties of the resource (including user properties), and represents a reference that can be used as the canonical representation of the resource by lonnavmap clients like renderers.
1890:
1891: A resource only makes sense in the context of a navmap, as some of the data is stored in the navmap object.
1892:
1893: You will probably never need to instantiate this object directly. Use Apache::lonnavmap::navmap, and use the "start" method to obtain the starting resource.
1894:
1895: =head2 Public Members
1896:
1897: resource objects have a hash called DATA ($resourceRef->{DATA}) that you can store whatever you want in. This allows you to easily do two-pass algorithms without worrying about managing your own resource->data hash.
1898:
1899: =head2 Methods
1900:
1901: =over 4
1902:
1903: =item * B<new>($navmapRef, $idString): The first arg is a reference to the parent navmap object. The second is the idString of the resource itself.
1904:
1905: =cut
1906:
1907: sub new {
1908: # magic invocation to create a class instance
1909: my $proto = shift;
1910: my $class = ref($proto) || $proto;
1911: my $self = {};
1912:
1913: $self->{NAV_MAP} = shift;
1914: $self->{ID} = shift;
1915:
1916: # Store this new resource in the parent nav map's cache.
1917: $self->{NAV_MAP}->{RESOURCE_CACHE}->{$self->{ID}} = $self;
1918:
1919: # A hash that can be used by two-pass algorithms to store data
1920: # about this resource in. Not used by the resource object
1921: # directly.
1922: $self->{DATA} = {};
1923:
1924: bless($self);
1925:
1926: return $self;
1927: }
1928:
1929: =pod
1930:
1931: =item * B<is_map>: Returns true if this is a map, false otherwise.
1932:
1933: =item * B<title>: Returns title.
1934:
1935: =item * B<type>: Returns the type of the resource, "start", "normal", or "finish".
1936:
1937: =item * B<problem>: Returns true if the resource is a problem type, false otherwise. (Looks at the extension on the src field.)
1938:
1939: =back
1940:
1941: =cut
1942:
1943: # private function: simplify the NAV_HASH lookups we keep doing
1944: # pass the name, and to automatically append my ID, pass a true val on the
1945: # second param
1946: sub navHash {
1947: my $self = shift;
1948: my $param = shift;
1949: my $id = shift;
1950: return $self->{NAV_MAP}->{NAV_HASH}->{$param . ($id?$self->{ID}:"")};
1951: }
1952:
1953: # These info functions can be used directly, as they don't return
1954: # resource information.
1955: sub title { my $self=shift; return $self->navHash("title_", 1); }
1956: sub type { my $self=shift; return $self->navHash("type_", 1); }
1957: sub goesto { my $self=shift; return $self->navHash("goesto_", 1); }
1958: # "to" can return a comma seperated list for branches
1959: sub to { my $self=shift; return $self->navHash("to_", 1); }
1960: sub kind { my $self=shift; return $self->navHash("kind_", 1); }
1961: sub src {
1962: my $self=shift;
1963: return $self->navHash("src_", 1);
1964: }
1965: sub symb {
1966: my $self=shift;
1967: (my $first, my $second) = $self->{ID} =~ /(\d+).(\d+)/;
1968: my $symbSrc = &Apache::lonnet::declutter($self->src());
1969: return &Apache::lonnet::declutter(
1970: $self->navHash('map_id_'.$first))
1971: . '___' . $second . '___' . $symbSrc;
1972: }
1973: sub is_problem {
1974: my $self=shift;
1975: my $src = $self->src();
1976: return ($src =~ /problem$/);
1977: }
1978: sub is_html {
1979: my $self=shift;
1980: my $src = $self->src();
1981: return ($src =~ /html$/);
1982: }
1983: sub is_sequence {
1984: my $self=shift;
1985: my $src = $self->src();
1986: return ($src =~ /sequence$/);
1987: }
1988: sub is_page {
1989: my $self=shift;
1990: my $src = $self->src();
1991: return ($src =~ /page$/);
1992: }
1993:
1994:
1995:
1996:
1997: # Move this into POD: In order to use these correctly, courseopt
1998: # and useropt need to be generated
1999: sub parmval {
2000: my $self = shift;
2001: my $what = shift;
2002: my $part = shift || "0";
2003: return $self->{NAV_MAP}->parmval($part.'.'.$what, $self->symb());
2004: }
2005:
2006: #####
2007: # Map Queries
2008: #####
2009:
2010: # These methods relate to whether or not the resource is a map, and the
2011: # attributes of that map.
2012:
2013: sub is_map { my $self=shift; return defined($self->navHash("is_map_", 1)); }
2014: sub map_finish {
2015: my $self = shift;
2016: my $src = $self->src();
2017: my $res = $self->navHash("map_finish_$src", 0);
2018: $res = $self->{NAV_MAP}->getById($res);
2019: return $res;
2020: }
2021: sub map_start {
2022: my $self = shift;
2023: my $src = $self->src();
2024: my $res = $self->navHash("map_start_$src", 0);
2025: $res = $self->{NAV_MAP}->getById($res);
2026: return $res;
2027: }
2028: sub map_pc {
2029: my $self = shift;
2030: my $src = $self->src();
2031: return $self->navHash("map_pc_$src", 0);
2032: }
2033: sub map_type {
2034: my $self = shift;
2035: my $pc = $self->map_pc();
2036: return $self->navHash("map_type_$pc", 0);
2037: }
2038:
2039:
2040:
2041: #####
2042: # Property queries
2043: #####
2044:
2045: # These functions will be responsible for returning the CORRECT
2046: # VALUE for the parameter, no matter what. So while they may look
2047: # like direct calls to parmval, they can be more then that.
2048: # So, for instance, the duedate function should use the "duedatetype"
2049: # information, rather then the resource object user.
2050:
2051: =pod
2052:
2053: =head2 Resource Parameters
2054:
2055: In order to use the resource parameters correctly, the nav map must have been instantiated with genCourseAndUserOptions set to true, so the courseopt and useropt is read correctly. Then, you can call these functions to get the relevant parameters for the resource. Each function defaults to "part 0", but can be directed to another part by passing the part as the second parameter.
2056:
2057: These methods are responsible for getting the parameter correct, not merely reflecting the contents of the GDBM hashes. As we move towards dates relative to other dates, these methods should be updated to reflect that. (Then, anybody using these methods won't have to update their code.)
2058:
2059: =over 4
2060:
2061: =item * B<acc>: Get the Client IP/Name Access Control information.
2062:
2063: =item * B<answerdate>: Get the answer-reveal date for the problem.
2064:
2065: =item * B<duedate>: Get the due date for the problem.
2066:
2067: =item * B<tries>: Get the number of tries the student has used on the problem.
2068:
2069: =item * B<maxtries>: Get the number of max tries allowed.
2070:
2071: =item * B<opendate>: Get the open date for the problem.
2072:
2073: =item * B<sig>: Get the significant figures setting.
2074:
2075: =item * B<tol>: Get the tolerance for the problem.
2076:
2077: =item * B<type>: Get the question type for the problem.
2078:
2079: =item * B<weight>: Get the weight for the problem.
2080:
2081: =back
2082:
2083: =cut
2084:
2085: sub acc {
2086: (my $self, my $part) = @_;
2087: return $self->parmval("acc", $part);
2088: }
2089: sub answerdate {
2090: (my $self, my $part) = @_;
2091: # Handle intervals
2092: if ($self->parmval("answerdate.type", $part) eq 'date_interval') {
2093: return $self->duedate($part) +
2094: $self->parmval("answerdate", $part);
2095: }
2096: return $self->parmval("answerdate", $part);
2097: }
2098: sub duedate {
2099: (my $self, my $part) = @_;
2100: return $self->parmval("duedate", $part);
2101: }
2102: sub maxtries {
2103: (my $self, my $part) = @_;
2104: return $self->parmval("maxtries", $part);
2105: }
2106: sub opendate {
2107: (my $self, my $part) = @_;
2108: if ($self->parmval("opendate.type", $part) eq 'date_interval') {
2109: return $self->duedate($part) -
2110: $self->parmval("opendate", $part);
2111: }
2112: return $self->parmval("opendate");
2113: }
2114: sub sig {
2115: (my $self, my $part) = @_;
2116: return $self->parmval("sig", $part);
2117: }
2118: sub tol {
2119: (my $self, my $part) = @_;
2120: return $self->parmval("tol", $part);
2121: }
2122: sub type {
2123: (my $self, my $part) = @_;
2124: return $self->parmval("type", $part);
2125: }
2126: sub weight {
2127: (my $self, my $part) = @_;
2128: return $self->parmval("weight", $part);
2129: }
2130: sub tries {
2131: my $self = shift;
2132: my $part = shift;
2133: $part = '0' if (!defined($part));
2134:
2135: # Make sure return hash is loaded, should error check
2136: $self->getReturnHash();
2137:
2138: my $tries = $self->{RETURN_HASH}->{'resource.'.$part.'.tries'};
2139: if (!defined($tries)) {return '0';}
2140: return $tries;
2141: }
2142:
2143: # Multiple things need this
2144: sub getReturnHash {
2145: my $self = shift;
2146:
2147: if (!defined($self->{RETURN_HASH})) {
2148: my %tmpHash = &Apache::lonnet::restore($self->symb());
2149: $self->{RETURN_HASH} = \%tmpHash;
2150: }
2151: }
2152:
2153: ######
2154: # Status queries
2155: ######
2156:
2157: # These methods query the status of problems.
2158:
2159: # If we need to count parts, this function determines the number of
2160: # parts from the metadata. When called, it returns a reference to a list
2161: # of strings corresponding to the parts. (Thus, using it in a scalar context
2162: # tells you how many parts you have in the problem:
2163: # $partcount = scalar($resource->countParts());
2164: # Don't use $self->{PARTS} directly because you don't know if it's been
2165: # computed yet.
2166:
2167: =pod
2168:
2169: =head2 Resource misc
2170:
2171: Misc. functions for the resource.
2172:
2173: =over 4
2174:
2175: =item * B<hasDiscussion>: Returns a false value if there has been discussion since the user last logged in, true if there has. Always returns false if the discussion data was not extracted when the nav map was constructed.
2176:
2177: =item * B<getFeedback>: Gets the feedback for the resource and returns the raw feedback string for the resource, or the null string if there is no feedback or the email data was not extracted when the nav map was constructed. Usually used like this:
2178:
2179: for (split(/\,/, $res->getFeedback())) {
2180: my $link = &Apache::lonnet::escape($_);
2181: ...
2182:
2183: and use the link as appropriate.
2184:
2185: =cut
2186:
2187: sub hasDiscussion {
2188: my $self = shift;
2189: return $self->{NAV_MAP}->hasDiscussion($self->symb());
2190: }
2191:
2192: sub getFeedback {
2193: my $self = shift;
2194: return $self->{NAV_MAP}->getFeedback($self->symb());
2195: }
2196:
2197: =pod
2198:
2199: =item * B<parts>(): Returns a list reference containing sorted strings corresponding to each part of the problem. To count the number of parts, use the list in a scalar context, and subtract one if greater then two. (One part problems have a part 0. Multi-parts have a part 0, plus a part for each part. You may or may not wish to filter out part 0.)
2200:
2201: =item * B<countParts>(): Returns the number of parts of the problem a student can answer. Thus, for single part problems, returns 1. For multipart, it returns the number of parts in the problem, not including psuedo-part 0.
2202:
2203: =back
2204:
2205: =cut
2206:
2207: sub parts {
2208: my $self = shift;
2209:
2210: $self->extractParts();
2211: return $self->{PARTS};
2212: }
2213:
2214: sub countParts {
2215: my $self = shift;
2216:
2217: my $parts = $self->parts();
2218:
2219: if (scalar(@{$parts}) == 1) { return 1;}
2220:
2221: return scalar(@{$parts}) - 1;
2222: }
2223:
2224: # Private function: Extracts the parts information and saves it
2225: sub extractParts {
2226: my $self = shift;
2227:
2228: return if ($self->{PARTS});
2229:
2230: $self->{PARTS} = [];
2231:
2232: # Retrieve part count
2233: foreach (split(/\,/,&Apache::lonnet::metadata($self->src(),
2234: 'allpossiblekeys'))) {
2235: if ($_ =~ /^parameter\_(.*)\_opendate$/) {
2236: push @{$self->{PARTS}}, $1;
2237: }
2238: }
2239:
2240: # Is this possible to do in one line? - Jeremy
2241: my @sortedParts = sort @{$self->{PARTS}};
2242: $self->{PARTS} = \@sortedParts;
2243:
2244: return;
2245: }
2246:
2247: =pod
2248:
2249: =head2 Resource Status
2250:
2251: Problem resources have status information, reflecting their various dates and completion statuses. You can obtain this information and import symbolic constants to represent the status.
2252:
2253: There are two aspects to the status: the date-related information and the completion information.
2254:
2255: Idiomatic usage of these two methods would probably look something like
2256:
2257: foreach ($resource->parts()) {
2258: my $dateStatus = $resource->getDateStatus($_);
2259: my $completionStatus = $resource->getCompletionStatus($_);
2260:
2261: ... use it here ...
2262: }
2263:
2264: =over 4
2265:
2266: =item * B<getDateStatus>($part): ($part defaults to 0). A convenience function that returns a symbolic constant telling you about the date status of the part. You should still check to see if there is a due date at all, if you care about that. The possible return values are:
2267:
2268: =back
2269:
2270: B<Date Codes>
2271:
2272: =over 4
2273:
2274: =item * B<OPEN_LATER>: The problem will be opened later.
2275:
2276: =item * B<OPEN>: Open and not yet due.
2277:
2278:
2279: =item * B<PAST_DUE_ANSWER_LATER>: The due date has passed, but the answer date has not yet arrived.
2280:
2281: =item * B<PAST_DUE_NO_ANSWER>: The due date has passed and there is no answer opening date set.
2282:
2283: =item * B<ANSWER_OPEN>: The answer date is here.
2284:
2285: =item * B<NETWORK_FAILURE>: The information is unknown due to network failure.
2286:
2287: =back
2288:
2289: =cut
2290:
2291: # Apparently the compiler optimizes these into constants automatically
2292: sub OPEN_LATER { return 0; }
2293: sub OPEN { return 1; }
2294: sub PAST_DUE_NO_ANSWER { return 2; }
2295: sub PAST_DUE_ANSWER_LATER { return 3; }
2296: sub ANSWER_OPEN { return 4; }
2297: sub NOTHING_SET { return 5; }
2298: sub NETWORK_FAILURE { return 100; }
2299:
2300: # getDateStatus gets the date status for a given problem part.
2301: # Because answer date, due date, and open date are fully independent
2302: # (i.e., it is perfectly possible to *only* have an answer date),
2303: # we have to completely cover the 3x3 maxtrix of (answer, due, open) x
2304: # (past, future, none given). This function handles this with a decision
2305: # tree. Read the comments to follow the decision tree.
2306:
2307: sub getDateStatus {
2308: my $self = shift;
2309: my $part = shift;
2310: $part = "0" if (!defined($part));
2311:
2312: # Always return network failure if there was one.
2313: return $self->NETWORK_FAILURE if ($self->{NAV_MAP}->{NETWORK_FAILURE});
2314:
2315: my $now = time();
2316:
2317: my $open = $self->opendate($part);
2318: my $due = $self->duedate($part);
2319: my $answer = $self->answerdate($part);
2320:
2321: if (!$open && !$due && !$answer) {
2322: # no data on the problem at all
2323: # should this be the same as "open later"? think multipart.
2324: return $self->NOTHING_SET;
2325: }
2326: if (!$open || $now < $open) {return $self->OPEN_LATER}
2327: if (!$due || $now < $due) {return $self->OPEN}
2328: if ($answer && $now < $answer) {return $self->PAST_DUE_ANSWER_LATER}
2329: if ($answer) { return $self->ANSWER_OPEN; }
2330: return PAST_DUE_NO_ANSWER;
2331: }
2332:
2333: =pod
2334:
2335: B<>
2336:
2337: =over 4
2338:
2339: =item * B<getCompletionStatus>($part): ($part defaults to 0.) A convenience function that returns a symbolic constant telling you about the completion status of the part, with the following possible results:
2340:
2341: =back
2342:
2343: B<Completion Codes>
2344:
2345: =over 4
2346:
2347: =item * B<NOT_ATTEMPTED>: Has not been attempted at all.
2348:
2349: =item * B<INCORRECT>: Attempted, but wrong by student.
2350:
2351: =item * B<INCORRECT_BY_OVERRIDE>: Attempted, but wrong by instructor override.
2352:
2353: =item * B<CORRECT>: Correct or correct by instructor.
2354:
2355: =item * B<CORRECT_BY_OVERRIDE>: Correct by instructor override.
2356:
2357: =item * B<EXCUSED>: Excused. Not yet implemented.
2358:
2359: =item * B<NETWORK_FAILURE>: Information not available due to network failure.
2360:
2361: =back
2362:
2363: =cut
2364:
2365: sub NOT_ATTEMPTED { return 10; }
2366: sub INCORRECT { return 11; }
2367: sub INCORRECT_BY_OVERRIDE { return 12; }
2368: sub CORRECT { return 13; }
2369: sub CORRECT_BY_OVERRIDE { return 14; }
2370: sub EXCUSED { return 15; }
2371:
2372: sub getCompletionStatus {
2373: my $self = shift;
2374: my $part = shift;
2375: $part = "0" if (!defined($part));
2376: return $self->NETWORK_FAILURE if ($self->{NAV_MAP}->{NETWORK_FAILURE});
2377:
2378: # Make sure return hash exists
2379: $self->getReturnHash();
2380:
2381: my $status = $self->{RETURN_HASH}->{'resource.'.$part.'.solved'};
2382:
2383: # Left as seperate if statements in case we ever do more with this
2384: if ($status eq 'correct_by_student') {return $self->CORRECT;}
2385: if ($status eq 'correct_by_override') {return $self->CORRECT_BY_OVERRIDE; }
2386: if ($status eq 'incorrect_attempted') {return $self->INCORRECT; }
2387: if ($status eq 'incorrect_by_override') {return $self->INCORRECT_BY_OVERRIDE; }
2388: if ($status eq 'excused') {return $self->EXCUSED; }
2389: return $self->NOT_ATTEMPTED;
2390: }
2391:
2392: =pod
2393:
2394: B<Composite Status>
2395:
2396: Along with directly returning the date or completion status, the resource object includes a convenience function B<status>() that will combine the two status tidbits into one composite status that can represent the status of the resource as a whole. The precise logic is documented in the comments of the status method. The following results may be returned, all available as methods on the resource object ($res->NETWORK_FAILURE()):
2397:
2398: =over 4
2399:
2400: =item * NETWORK_FAILURE: The network has failed and the information is not available.
2401:
2402: =item * NOTHING_SET: No dates have been set for this problem (part) at all. (Because only certain parts of a multi-part problem may be assigned, this can not be collapsed into "open later", as we don't know a given part will EVER be opened. For single part, this is the same as "OPEN_LATER".)
2403:
2404: =item * CORRECT: For any reason at all, the part is considered correct.
2405:
2406: =item * EXCUSED: For any reason at all, the problem is excused.
2407:
2408: =item * PAST_DUE_NO_ANSWER: The problem is past due, not considered correct, and no answer date is set.
2409:
2410: =item * PAST_DUE_ANSWER_LATER: The problem is past due, not considered correct, and an answer date in the future is set.
2411:
2412: =item * ANSWER_OPEN: The problem is past due, not correct, and the answer is now available.
2413:
2414: =item * OPEN_LATER: The problem is not yet open.
2415:
2416: =item * TRIES_LEFT: The problem is open, has been tried, is not correct, but there are tries left.
2417:
2418: =item * INCORRECT: The problem is open, and all tries have been used without getting the correct answer.
2419:
2420: =item * OPEN: The item is open and not yet tried.
2421:
2422: =back
2423:
2424: =cut
2425:
2426: sub TRIES_LEFT { return 10; }
2427:
2428: sub status {
2429: my $self = shift;
2430: my $part = shift;
2431: if (!defined($part)) { $part = "0"; }
2432: my $completionStatus = $self->getCompletionStatus($part);
2433: my $dateStatus = $self->getDateStatus($part);
2434:
2435: # What we have is a two-dimensional matrix with 4 entries on one
2436: # dimension and 5 entries on the other, which we want to colorize,
2437: # plus network failure and "no date data at all".
2438:
2439: if ($completionStatus == NETWORK_FAILURE) { return NETWORK_FAILURE; }
2440:
2441: # There are a few whole rows we can dispose of:
2442: if ($completionStatus == CORRECT ||
2443: $completionStatus == CORRECT_BY_OVERRIDE ) {
2444: return CORRECT();
2445: }
2446:
2447: # If it's EXCUSED, then return that no matter what
2448: if ($completionStatus == EXCUSED) {
2449: return EXCUSED;
2450: }
2451:
2452: if ($dateStatus == NOTHING_SET) {
2453: return NOTHING_SET;
2454: }
2455:
2456: # Now we're down to a 3 (incorrect, incorrect_override, not_attempted)
2457: # by 4 matrix (date status).
2458:
2459: if ($dateStatus == PAST_DUE_ANSWER_LATER ||
2460: $dateStatus == PAST_DUE_NO_ANSWER ) {
2461: return $dateStatus;
2462: }
2463:
2464: if ($dateStatus == ANSWER_OPEN) {
2465: return ANSWER_OPEN;
2466: }
2467:
2468: # Now: (incorrect, incorrect_override, not_attempted) x
2469: # (open_later), (open)
2470:
2471: if ($dateStatus == OPEN_LATER) {
2472: return OPEN_LATER;
2473: }
2474:
2475: # If it's WRONG...
2476: if ($completionStatus == INCORRECT || $completionStatus == INCORRECT_BY_OVERRIDE) {
2477: # and there are TRIES LEFT:
2478: if ($self->tries() < $self->maxtries()) {
2479: return TRIES_LEFT;
2480: }
2481: return INCORRECT; # otherwise, return orange; student can't fix this
2482: }
2483:
2484: # Otherwise, it's untried and open
2485: return OPEN;
2486: }
2487:
2488: =pod
2489:
2490: =head2 Resource/Nav Map Navigation
2491:
2492: =over 4
2493:
2494: =item * B<getNext>(): Gets the next resource in the navmap after this one.
2495:
2496: =cut
2497:
2498: # For the simple single-link case, to get from a resource to the next
2499: # resource, you need to look up the "to_" link in the nav hash, then
2500: # follow that with the "goesto_" link.
2501:
2502: sub getNext {
2503: my $self = shift;
2504: my $alreadySeenHash = shift;
2505: my @branches;
2506: my $to = $self->to();
2507: foreach my $branch ( split(/\,/, $to) ) {
2508: my $choice = $self->{NAV_MAP}->getById($branch);
2509: my $next = $choice->goesto();
2510: $next = $self->{NAV_MAP}->getById($next);
2511:
2512: # Don't remember it if we've already seen it
2513: if (!defined($alreadySeenHash) ||
2514: !defined($alreadySeenHash->{$next->{ID}})) {
2515: push @branches, $next;
2516: }
2517: }
2518: return \@branches;
2519: }
2520:
2521: =pod
2522:
2523: =back
2524:
2525: =cut
2526:
2527: 1;
2528:
2529: __END__
2530:
2531:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>