File:
[LON-CAPA] /
loncom /
interface /
lonnavmaps.pm
Revision
1.207:
download - view:
text,
annotated -
select for diffs
Wed Jun 18 15:14:23 2003 UTC (21 years ago) by
bowersj2
Branches:
MAIN
CVS tags:
HEAD
Fix bug 1776: Navmaps should not display "attempted" problems in red
when there is less then 24 hours before the due date. Once the problems
are "attempted" the student can do no more about it.
Also cleaned up a couple of other pieces of the code.
1: # The LearningOnline Network with CAPA
2: # Navigate Maps Handler
3: #
4: # $Id: lonnavmaps.pm,v 1.207 2003/06/18 15:14:23 bowersj2 Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: # (Page Handler
29: #
30: # (TeX Content Handler
31: #
32: # 05/29/00,05/30 Gerd Kortemeyer)
33: # 08/30,08/31,09/06,09/14,09/15,09/16,09/19,09/20,09/21,09/23,
34: # 10/02,10/10,10/14,10/16,10/18,10/19,10/31,11/6,11/14,11/16 Gerd Kortemeyer)
35: #
36: # 3/1/1,6/1,17/1,29/1,30/1,2/8,9/21,9/24,9/25 Gerd Kortemeyer
37: # YEAR=2002
38: # 1/1 Gerd Kortemeyer
39: # Oct-Nov Jeremy Bowers
40: # YEAR=2003
41: # Jeremy Bowers ... lots of days
42:
43: package Apache::lonnavmaps;
44:
45: use strict;
46: use Apache::Constants qw(:common :http);
47: use Apache::loncommon();
48: use Apache::lonmenu();
49: use POSIX qw (floor strftime);
50: use Data::Dumper; # for debugging, not always used
51:
52: # symbolic constants
53: sub SYMB { return 1; }
54: sub URL { return 2; }
55: sub NOTHING { return 3; }
56:
57: # Some data
58:
59: my $resObj = "Apache::lonnavmaps::resource";
60:
61: # Keep these mappings in sync with lonquickgrades, which uses the colors
62: # instead of the icons.
63: my %statusIconMap =
64: ( $resObj->NETWORK_FAILURE => '',
65: $resObj->NOTHING_SET => '',
66: $resObj->CORRECT => 'navmap.correct.gif',
67: $resObj->EXCUSED => 'navmap.correct.gif',
68: $resObj->PAST_DUE_NO_ANSWER => 'navmap.wrong.gif',
69: $resObj->PAST_DUE_ANSWER_LATER => 'navmap.wrong.gif',
70: $resObj->ANSWER_OPEN => 'navmap.wrong.gif',
71: $resObj->OPEN_LATER => '',
72: $resObj->TRIES_LEFT => 'navmap.open.gif',
73: $resObj->INCORRECT => 'navmap.wrong.gif',
74: $resObj->OPEN => 'navmap.open.gif',
75: $resObj->ATTEMPTED => 'navmap.ellipsis.gif',
76: $resObj->ANSWER_SUBMITTED => '' );
77:
78: my %iconAltTags =
79: ( 'navmap.correct.gif' => 'Correct',
80: 'navmap.wrong.gif' => 'Incorrect',
81: 'navmap.open.gif' => 'Open' );
82:
83: # Defines a status->color mapping, null string means don't color
84: my %colormap =
85: ( $resObj->NETWORK_FAILURE => '',
86: $resObj->CORRECT => '',
87: $resObj->EXCUSED => '#3333FF',
88: $resObj->PAST_DUE_ANSWER_LATER => '',
89: $resObj->PAST_DUE_NO_ANSWER => '',
90: $resObj->ANSWER_OPEN => '#006600',
91: $resObj->OPEN_LATER => '',
92: $resObj->TRIES_LEFT => '',
93: $resObj->INCORRECT => '',
94: $resObj->OPEN => '',
95: $resObj->NOTHING_SET => '',
96: $resObj->ATTEMPTED => '',
97: $resObj->ANSWER_SUBMITTED => ''
98: );
99: # And a special case in the nav map; what to do when the assignment
100: # is not yet done and due in less then 24 hours
101: my $hurryUpColor = "#FF0000";
102:
103: sub handler {
104: my $r = shift;
105: real_handler($r);
106: }
107:
108: sub real_handler {
109: my $r = shift;
110:
111: # Handle header-only request
112: if ($r->header_only) {
113: if ($ENV{'browser.mathml'}) {
114: $r->content_type('text/xml');
115: } else {
116: $r->content_type('text/html');
117: }
118: $r->send_http_header;
119: return OK;
120: }
121:
122: # Send header, don't cache this page
123: if ($ENV{'browser.mathml'}) {
124: $r->content_type('text/xml');
125: } else {
126: $r->content_type('text/html');
127: }
128: &Apache::loncommon::no_cache($r);
129: $r->send_http_header;
130:
131: # Create the nav map
132: my $navmap = Apache::lonnavmaps::navmap->new(
133: $ENV{"request.course.fn"}.".db",
134: $ENV{"request.course.fn"}."_parms.db", 1, 1);
135:
136:
137: if (!defined($navmap)) {
138: my $requrl = $r->uri;
139: $ENV{'user.error.msg'} = "$requrl:bre:0:0:Course not initialized";
140: return HTTP_NOT_ACCEPTABLE;
141: }
142:
143: $r->print("<html><head>\n");
144: $r->print("<title>Navigate Course Contents</title>");
145: # ------------------------------------------------------------ Get query string
146: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},['register']);
147:
148: # ----------------------------------------------------- Force menu registration
149: my $addentries='';
150: if ($ENV{'form.register'}) {
151: $addentries=' onLoad="'.&Apache::lonmenu::loadevents().
152: '" onUnload="'.&Apache::lonmenu::unloadevents().'"';
153: $r->print(&Apache::lonmenu::registerurl(1));
154: }
155:
156: # Header
157: $r->print('</head>'.
158: &Apache::loncommon::bodytag('Navigate Course Contents','',
159: $addentries,'','',$ENV{'form.register'}));
160: $r->print('<script>window.focus();</script>');
161:
162: $r->rflush();
163:
164: # Now that we've displayed some stuff to the user, init the navmap
165: $navmap->init();
166:
167: $r->rflush();
168:
169: # Check that it's defined
170: if (!($navmap->courseMapDefined())) {
171: $r->print('<font size="+2" color="red">Coursemap undefined.</font>' .
172: '</body></html>');
173: return OK;
174: }
175:
176: # See if there's only one map in the top-level, if we don't
177: # already have a filter... if so, automatically display it
178: if ($ENV{QUERY_STRING} !~ /filter/) {
179: my $iterator = $navmap->getIterator(undef, undef, undef, 0);
180: my $depth = 1;
181: $iterator->next();
182: my $curRes = $iterator->next();
183: my $sequenceCount = 0;
184: my $sequenceId;
185: while ($depth > 0) {
186: if ($curRes == $iterator->BEGIN_MAP()) { $depth++; }
187: if ($curRes == $iterator->END_MAP()) { $depth--; }
188:
189: if (ref($curRes) && $curRes->is_sequence()) {
190: $sequenceCount++;
191: $sequenceId = $curRes->map_pc();
192: }
193:
194: $curRes = $iterator->next();
195: }
196:
197: if ($sequenceCount == 1) {
198: # The automatic iterator creation in the render call
199: # will pick this up. We know the condition because
200: # the defined($ENV{'form.filter'}) also ensures this
201: # is a fresh call.
202: $ENV{'form.filter'} = "$sequenceId";
203: }
204: }
205:
206: my $jumpToFirstHomework = 0;
207: # Check to see if the student is jumping to next open, do-able problem
208: if ($ENV{QUERY_STRING} eq 'jumpToFirstHomework') {
209: $jumpToFirstHomework = 1;
210: # Find the next homework problem that they can do.
211: my $iterator = $navmap->getIterator(undef, undef, undef, 1);
212: my $depth = 1;
213: $iterator->next();
214: my $curRes = $iterator->next();
215: my $foundDoableProblem = 0;
216: my $problemRes;
217:
218: while ($depth > 0 && !$foundDoableProblem) {
219: if ($curRes == $iterator->BEGIN_MAP()) { $depth++; }
220: if ($curRes == $iterator->END_MAP()) { $depth--; }
221:
222: if (ref($curRes) && $curRes->is_problem()) {
223: my $status = $curRes->status();
224: if ($curRes->completable()) {
225: $problemRes = $curRes;
226: $foundDoableProblem = 1;
227:
228: # Pop open all previous maps
229: my $stack = $iterator->getStack();
230: pop @$stack; # last resource in the stack is the problem
231: # itself, which we don't need in the map stack
232: my @mapPcs = map {$_->map_pc()} @$stack;
233: $ENV{'form.filter'} = join(',', @mapPcs);
234:
235: # Mark as both "here" and "jump"
236: $ENV{'form.postsymb'} = $curRes->symb();
237: }
238: }
239: } continue {
240: $curRes = $iterator->next();
241: }
242:
243: # If we found no problems, print a note to that effect.
244: if (!$foundDoableProblem) {
245: $r->print("<font size='+2'>All homework assignments have been completed.</font><br /><br />");
246: }
247: } else {
248: $r->print("<a href='navmaps?jumpToFirstHomework'>" .
249: "Go To My First Homework Problem</a> ");
250: }
251:
252: my $suppressEmptySequences = 0;
253: my $filterFunc = undef;
254: my $resource_no_folder_link = 0;
255:
256: # Display only due homework.
257: my $showOnlyHomework = 0;
258: if ($ENV{QUERY_STRING} eq 'showOnlyHomework') {
259: $showOnlyHomework = 1;
260: $suppressEmptySequences = 1;
261: $filterFunc = sub { my $res = shift;
262: return $res->completable() || $res->is_map();
263: };
264: $r->print("<p><font size='+2'>Uncompleted Homework</font></p>");
265: $ENV{'form.filter'} = '';
266: $ENV{'form.condition'} = 1;
267: $resource_no_folder_link = 1;
268: } else {
269: $r->print("<a href='navmaps?showOnlyHomework'>" .
270: "Show Only Uncompleted Homework</a> ");
271: }
272:
273: # renderer call
274: my $renderArgs = { 'cols' => [0,1,2,3],
275: 'url' => '/adm/navmaps',
276: 'navmap' => $navmap,
277: 'suppressNavmap' => 1,
278: 'suppressEmptySequences' => $suppressEmptySequences,
279: 'filterFunc' => $filterFunc,
280: 'resource_no_folder_link' => $resource_no_folder_link,
281: 'r' => $r};
282: my $render = render($renderArgs);
283: $navmap->untieHashes();
284:
285: # If no resources were printed, print a reassuring message so the
286: # user knows there was no error.
287: if ($renderArgs->{'counter'} == 0) {
288: if ($showOnlyHomework) {
289: $r->print("<p><font size='+1'>All homework is currently completed.</font></p>");
290: } else { # both jumpToFirstHomework and normal use the same: course must be empty
291: $r->print("<p><font size='+1'>This course is empty.</font></p>");
292: }
293: }
294:
295: $r->print("</body></html>");
296: $r->rflush();
297:
298: return OK;
299: }
300:
301: # Convenience functions: Returns a string that adds or subtracts
302: # the second argument from the first hash, appropriate for the
303: # query string that determines which folders to recurse on
304: sub addToFilter {
305: my $hashIn = shift;
306: my $addition = shift;
307: my %hash = %$hashIn;
308: $hash{$addition} = 1;
309:
310: return join (",", keys(%hash));
311: }
312:
313: sub removeFromFilter {
314: my $hashIn = shift;
315: my $subtraction = shift;
316: my %hash = %$hashIn;
317:
318: delete $hash{$subtraction};
319: return join(",", keys(%hash));
320: }
321:
322: # Convenience function: Given a stack returned from getStack on the iterator,
323: # return the correct src() value.
324: # Later, this should add an anchor when we start putting anchors in pages.
325: sub getLinkForResource {
326: my $stack = shift;
327: my $res;
328:
329: # Check to see if there are any pages in the stack
330: foreach $res (@$stack) {
331: if (defined($res) && $res->is_page()) {
332: return $res->src();
333: }
334: }
335:
336: # Failing that, return the src of the last resource that is defined
337: # (when we first recurse on a map, it puts an undefined resource
338: # on the bottom because $self->{HERE} isn't defined yet, and we
339: # want the src for the map anyhow)
340: foreach (@$stack) {
341: if (defined($_)) { $res = $_; }
342: }
343:
344: return $res->src();
345: }
346:
347: # Convenience function: This seperates the logic of how to create
348: # the problem text strings ("Due: DATE", "Open: DATE", "Not yet assigned",
349: # etc.) into a seperate function. It takes a resource object as the
350: # first parameter, and the part number of the resource as the second.
351: # It's basically a big switch statement on the status of the resource.
352:
353: sub getDescription {
354: my $res = shift;
355: my $part = shift;
356: my $status = $res->status($part);
357:
358: if ($status == $res->NETWORK_FAILURE) {
359: return "Having technical difficulties; please check status later";
360: }
361: if ($status == $res->NOTHING_SET) {
362: return "Not currently assigned.";
363: }
364: if ($status == $res->OPEN_LATER) {
365: return "Open " . timeToHumanString($res->opendate($part));
366: }
367: if ($status == $res->OPEN) {
368: if ($res->duedate($part)) {
369: return "Due " . timeToHumanString($res->duedate($part));
370: } else {
371: return "Open, no due date";
372: }
373: }
374: if ($status == $res->PAST_DUE_ANSWER_LATER) {
375: return "Answer open " . timeToHumanString($res->answerdate($part));
376: }
377: if ($status == $res->PAST_DUE_NO_ANSWER) {
378: return "Was due " . timeToHumanString($res->duedate($part));
379: }
380: if ($status == $res->ANSWER_OPEN) {
381: return "Answer available";
382: }
383: if ($status == $res->EXCUSED) {
384: return "Excused by instructor";
385: }
386: if ($status == $res->ATTEMPTED) {
387: return "Answer submitted, not yet graded.";
388: }
389: if ($status == $res->TRIES_LEFT) {
390: my $tries = $res->tries($part);
391: my $maxtries = $res->maxtries($part);
392: my $triesString = "";
393: if ($tries && $maxtries) {
394: $triesString = "<font size=\"-1\"><i>($tries of $maxtries tries used)</i></font>";
395: if ($maxtries > 1 && $maxtries - $tries == 1) {
396: $triesString = "<b>$triesString</b>";
397: }
398: }
399: if ($res->duedate()) {
400: return "Due " . timeToHumanString($res->duedate($part)) .
401: " $triesString";
402: } else {
403: return "No due date $triesString";
404: }
405: }
406: if ($status == $res->ANSWER_SUBMITTED) {
407: return 'Answer submitted';
408: }
409: }
410:
411: # Convenience function, so others can use it: Is the problem due in less then
412: # 24 hours, and still can be done?
413:
414: sub dueInLessThen24Hours {
415: my $res = shift;
416: my $part = shift;
417: my $status = $res->status($part);
418:
419: return ($status == $res->OPEN() ||
420: $status == $res->TRIES_LEFT()) &&
421: $res->duedate() && $res->duedate() < time()+(24*60*60) &&
422: $res->duedate() > time();
423: }
424:
425: # Convenience function, so others can use it: Is there only one try remaining for the
426: # part, with more then one try to begin with, not due yet and still can be done?
427: sub lastTry {
428: my $res = shift;
429: my $part = shift;
430:
431: my $tries = $res->tries($part);
432: my $maxtries = $res->maxtries($part);
433: return $tries && $maxtries && $maxtries > 1 &&
434: $maxtries - $tries == 1 && $res->duedate() &&
435: $res->duedate() > time();
436: }
437:
438: # This puts a human-readable name on the ENV variable.
439:
440: sub advancedUser {
441: return $ENV{'request.role.adv'};
442: }
443:
444:
445: # timeToHumanString takes a time number and converts it to a
446: # human-readable representation, meant to be used in the following
447: # manner:
448: # print "Due $timestring"
449: # print "Open $timestring"
450: # print "Answer available $timestring"
451: # Very, very, very, VERY English-only... goodness help a localizer on
452: # this func...
453: sub timeToHumanString {
454: my ($time) = @_;
455: # zero, '0' and blank are bad times
456: if (!$time) {
457: return 'never';
458: }
459:
460: my $now = time();
461:
462: my @time = localtime($time);
463: my @now = localtime($now);
464:
465: # Positive = future
466: my $delta = $time - $now;
467:
468: my $minute = 60;
469: my $hour = 60 * $minute;
470: my $day = 24 * $hour;
471: my $week = 7 * $day;
472: my $inPast = 0;
473:
474: # Logic in comments:
475: # Is it now? (extremely unlikely)
476: if ( $delta == 0 ) {
477: return "this instant";
478: }
479:
480: if ($delta < 0) {
481: $inPast = 1;
482: $delta = -$delta;
483: }
484:
485: if ( $delta > 0 ) {
486:
487: my $tense = $inPast ? " ago" : "";
488: my $prefix = $inPast ? "" : "in ";
489:
490: # Less then a minute
491: if ( $delta < $minute ) {
492: if ($delta == 1) { return "${prefix}1 second$tense"; }
493: return "$prefix$delta seconds$tense";
494: }
495:
496: # Less then an hour
497: if ( $delta < $hour ) {
498: # If so, use minutes
499: my $minutes = floor($delta / 60);
500: if ($minutes == 1) { return "${prefix}1 minute$tense"; }
501: return "$prefix$minutes minutes$tense";
502: }
503:
504: # Is it less then 24 hours away? If so,
505: # display hours + minutes
506: if ( $delta < $hour * 24) {
507: my $hours = floor($delta / $hour);
508: my $minutes = floor(($delta % $hour) / $minute);
509: my $hourString = "$hours hours";
510: my $minuteString = ", $minutes minutes";
511: if ($hours == 1) {
512: $hourString = "1 hour";
513: }
514: if ($minutes == 1) {
515: $minuteString = ", 1 minute";
516: }
517: if ($minutes == 0) {
518: $minuteString = "";
519: }
520: return "$prefix$hourString$minuteString$tense";
521: }
522:
523: # Less then 5 days away, display day of the week and
524: # HH:MM
525: if ( $delta < $day * 5 ) {
526: my $timeStr = strftime("%A, %b %e at %I:%M %P", localtime($time));
527: $timeStr =~ s/12:00 am/midnight/;
528: $timeStr =~ s/12:00 pm/noon/;
529: return ($inPast ? "last " : "next ") .
530: $timeStr;
531: }
532:
533: # Is it this year?
534: if ( $time[5] == $now[5]) {
535: # Return on Month Day, HH:MM meridian
536: my $timeStr = strftime("on %A, %b %e at %I:%M %P", localtime($time));
537: $timeStr =~ s/12:00 am/midnight/;
538: $timeStr =~ s/12:00 pm/noon/;
539: return $timeStr;
540: }
541:
542: # Not this year, so show the year
543: my $timeStr = strftime("on %A, %b %e %G at %I:%M %P", localtime($time));
544: $timeStr =~ s/12:00 am/midnight/;
545: $timeStr =~ s/12:00 pm/noon/;
546: return $timeStr;
547: }
548: }
549:
550:
551: =pod
552:
553: =head1 NAME
554:
555: Apache::lonnavmap - Subroutines to handle and render the navigation maps
556:
557: =head1 SYNOPSIS
558:
559: The main handler generates the navigational listing for the course,
560: the other objects export this information in a usable fashion for
561: other modules.
562:
563: =head1 Subroutine: render
564:
565: The navmap renderer package provides a sophisticated rendering of the
566: standard navigation maps interface into HTML. The provided nav map
567: handler is actually just a glorified call to this.
568:
569: Because of the large number of parameters this function presents,
570: instead of passing it arguments as is normal, pass it in an anonymous
571: hash with the given options. This is because there is no obvious order
572: you may wish to override these in and a hash is easier to read and
573: understand then "undef, undef, undef, 1, undef, undef, renderButton,
574: undef, 0" when you mostly want default behaviors.
575:
576: The package provides a function called 'render', called as
577: Apache::lonnavmaps::render({}).
578:
579: =head2 Overview of Columns
580:
581: The renderer will build an HTML table for the navmap and return
582: it. The table is consists of several columns, and a row for each
583: resource (or possibly each part). You tell the renderer how many
584: columns to create and what to place in each column, optionally using
585: one or more of the prepared columns, and the renderer will assemble
586: the table.
587:
588: Any additional generally useful column types should be placed in the
589: renderer code here, so anybody can use it anywhere else. Any code
590: specific to the current application (such as the addition of <input>
591: elements in a column) should be placed in the code of the thing using
592: the renderer.
593:
594: At the core of the renderer is the array reference COLS (see Example
595: section below for how to pass this correctly). The COLS array will
596: consist of entries of one of two types of things: Either an integer
597: representing one of the pre-packaged column types, or a sub reference
598: that takes a resource reference, a part number, and a reference to the
599: argument hash passed to the renderer, and returns a string that will
600: be inserted into the HTML representation as it.
601:
602: The pre-packaged column names are refered to by constants in the
603: Apache::lonnavmaps namespace. The following currently exist:
604:
605: =over 4
606:
607: =item * B<resource>:
608:
609: The general info about the resource: Link, icon for the type, etc. The
610: first column in the standard nav map display. This column also accepts
611: the following parameters in the renderer hash:
612:
613: =over 4
614:
615: =item * B<resource_nolink>:
616:
617: If true, the resource will not be linked. Default: false, resource
618: will have links.
619:
620: =item * B<resource_part_count>:
621:
622: If true (default), the resource will show a part count if the full
623: part list is not displayed. If false, the resource will never show a
624: part count.
625:
626: =item * B<resource_no_folder_link>:
627:
628: If true, the resource's folder will not be clickable to open or close
629: it. Default is false. True implies printCloseAll is false, since you
630: can't close or open folders when this is on anyhow.
631:
632: =back
633:
634: =item B<communication_status>:
635:
636: Whether there is discussion on the resource, email for the user, or
637: (lumped in here) perl errors in the execution of the problem. This is
638: the second column in the main nav map.
639:
640: =item B<quick_status>:
641:
642: An icon for the status of a problem, with four possible states:
643: Correct, incorrect, open, or none (not open yet, not a problem). The
644: third column of the standard navmap.
645:
646: =item B<long_status>:
647:
648: A text readout of the details of the current status of the problem,
649: such as "Due in 22 hours". The fourth column of the standard navmap.
650:
651: =back
652:
653: If you add any others please be sure to document them here.
654:
655: An example of a column renderer that will show the ID number of a
656: resource, along with the part name if any:
657:
658: sub {
659: my ($resource, $part, $params) = @_;
660: if ($part) { return '<td>' . $resource->{ID} . ' ' . $part . '</td>'; }
661: return '<td>' . $resource->{ID} . '</td>';
662: }
663:
664: Note these functions are responsible for the TD tags, which allow them
665: to override vertical and horizontal alignment, etc.
666:
667: =head2 Parameters
668:
669: Most of these parameters are only useful if you are *not* using the
670: folder interface (i.e., the default first column), which is probably
671: the common case. If you are using this interface, then you should be
672: able to get away with just using 'cols' (to specify the columns
673: shown), 'url' (necessary for the folders to link to the current screen
674: correctly), and possibly 'queryString' if your app calls for it. In
675: that case, maintaining the state of the folders will be done
676: automatically.
677:
678: =over 4
679:
680: =item * B<iterator>:
681:
682: A reference to a fresh ::iterator to use from the navmaps. The
683: rendering will reflect the options passed to the iterator, so you can
684: use that to just render a certain part of the course, if you like. If
685: one is not passed, the renderer will attempt to construct one from
686: ENV{'form.filter'} and ENV{'form.condition'} information, plus the
687: 'iterator_map' parameter if any.
688:
689: =item * B<iterator_map>:
690:
691: If you are letting the renderer do the iterator handling, you can
692: instruct the renderer to render only a particular map by passing it
693: the source of the map you want to process, like
694: '/res/103/jerf/navmap.course.sequence'.
695:
696: =item * B<navmap>:
697:
698: A reference to a navmap, used only if an iterator is not passed in. If
699: this is necessary to make an iterator but it is not passed in, a new
700: one will be constructed based on ENV info. This is useful to do basic
701: error checking before passing it off to render.
702:
703: =item * B<r>:
704:
705: The standard Apache response object. This must be passed to the
706: renderer or the course hash will be locked.
707:
708: =item * B<cols>:
709:
710: An array reference
711:
712: =item * B<showParts>:
713:
714: A flag. If yes (default), a line for the resource itself, and a line
715: for each part will be displayed. If not, only one line for each
716: resource will be displayed.
717:
718: =item * B<condenseParts>:
719:
720: A flag. If yes (default), if all parts of the problem have the same
721: status and that status is Nothing Set, Correct, or Network Failure,
722: then only one line will be displayed for that resource anyhow. If no,
723: all parts will always be displayed. If showParts is 0, this is
724: ignored.
725:
726: =item * B<jumpCount>:
727:
728: A string identifying the URL to place the anchor 'curloc' at. Default
729: to no anchor at all. It is the responsibility of the renderer user to
730: ensure that the #curloc is in the URL. By default, determined through
731: the use of the ENV{} 'jump' information, and should normally "just
732: work" correctly.
733:
734: =item * B<here>:
735:
736: A Symb identifying where to place the 'here' marker. Default empty,
737: which means no marker.
738:
739: =item * B<indentString>:
740:
741: A string identifying the indentation string to use. By default, this
742: is a 25 pixel whitespace image with no alt text.
743:
744: =item * B<queryString>:
745:
746: A string which will be prepended to the query string used when the
747: folders are opened or closed.
748:
749: =item * B<url>:
750:
751: The url the folders will link to, which should be the current
752: page. Required if the resource info column is shown.
753:
754: =item * B<currentJumpIndex>:
755:
756: Describes the currently-open row number to cause the browser to jump
757: to, because the user just opened that folder. By default, pulled from
758: the Jump information in the ENV{'form.*'}.
759:
760: =item * B<printKey>:
761:
762: If true, print the key that appears on the top of the standard
763: navmaps. Default is false.
764:
765: =item * B<printCloseAll>:
766:
767: If true, print the "Close all folders" or "open all folders"
768: links. Default is true.
769:
770: =item * B<filterFunc>:
771:
772: A function that takes the resource object as its only parameter and
773: returns a true or false value. If true, the resource is displayed. If
774: false, it is simply skipped in the display. By default, all resources
775: are shown.
776:
777: =item * B<suppressEmptySequences>:
778:
779: If you're using a filter function, and displaying sequences to orient
780: the user, then frequently some sequences will be empty. Setting this to
781: true will cause those sequences not to display, so as not to confuse the
782: user into thinking that if the sequence is there there should be things
783: under it.
784:
785: =item * B<suppressNavmaps>:
786:
787: If true, will not display Navigate Content resources. Default to
788: false.
789:
790: =back
791:
792: =head2 Additional Info
793:
794: In addition to the parameters you can pass to the renderer, which will
795: be passed through unchange to the column renderers, the renderer will
796: generate the following information which your renderer may find
797: useful:
798:
799: If you want to know how many rows were printed, the 'counter' element
800: of the hash passed into the render function will contain the
801: count. You may want to check whether any resources were printed at
802: all.
803:
804: =over 4
805:
806: =back
807:
808: =cut
809:
810: sub resource { return 0; }
811: sub communication_status { return 1; }
812: sub quick_status { return 2; }
813: sub long_status { return 3; }
814:
815: # Data for render_resource
816:
817: sub render_resource {
818: my ($resource, $part, $params) = @_;
819:
820: my $nonLinkedText = ''; # stuff after resource title not in link
821:
822: my $link = $params->{"resourceLink"};
823: my $src = $resource->src();
824: my $it = $params->{"iterator"};
825: my $filter = $it->{FILTER};
826:
827: my $title = $resource->compTitle();
828: if ($src =~ /^\/uploaded\//) {
829: $nonLinkedText=$title;
830: $title = '';
831: }
832: my $partLabel = "";
833: my $newBranchText = "";
834:
835: # If this is a new branch, label it so
836: if ($params->{'isNewBranch'}) {
837: $newBranchText = "<img src='/adm/lonIcons/branch.gif' border='0' />";
838: }
839:
840: # links to open and close the folder
841: my $linkopen = "<a href='$link'>";
842: my $linkclose = "</a>";
843:
844: # Default icon: unknown page
845: my $icon = "<img src='/adm/lonIcons/unknown.gif' alt='' border='0' />";
846:
847: if ($resource->is_problem()) {
848: if ($part eq '0' || $params->{'condensed'}) {
849: $icon = '<img src="/adm/lonIcons/problem.gif" alt="" border="0" />';
850: } else {
851: $icon = $params->{'indentString'};
852: }
853: } else {
854: my $curfext= (split (/\./,$resource->src))[-1];
855: my $embstyle = &Apache::loncommon::fileembstyle($curfext);
856: # The unless conditional that follows is a bit of overkill
857: if (!(!defined($embstyle) || $embstyle eq 'unk' || $embstyle eq 'hdn')) {
858: $icon = "<img src='/adm/lonIcons/$curfext.gif' alt='' border='0' />";
859: }
860: }
861:
862: # Display the correct map icon to open or shut map
863: if ($resource->is_map()) {
864: my $mapId = $resource->map_pc();
865: my $nowOpen = !defined($filter->{$mapId});
866: if ($it->{CONDITION}) {
867: $nowOpen = !$nowOpen;
868: }
869:
870: my $folderType = $resource->is_sequence() ? 'folder' : 'page';
871:
872: if (!$params->{'resource_no_folder_link'}) {
873: $icon = "navmap.$folderType." . ($nowOpen ? 'closed' : 'open') . '.gif';
874: $icon = "<img src='/adm/lonIcons/$icon' alt='' border='0' />";
875:
876: $linkopen = "<a href='" . $params->{'url'} . '?' .
877: $params->{'queryString'} . '&filter=';
878: $linkopen .= ($nowOpen xor $it->{CONDITION}) ?
879: addToFilter($filter, $mapId) :
880: removeFromFilter($filter, $mapId);
881: $linkopen .= "&condition=" . $it->{CONDITION} . '&hereType='
882: . $params->{'hereType'} . '&here=' .
883: &Apache::lonnet::escape($params->{'here'}) .
884: '&jump=' .
885: &Apache::lonnet::escape($resource->symb()) .
886: "&folderManip=1'>";
887: } else {
888: # Don't allow users to manipulate folder
889: $icon = "navmap.$folderType." . ($nowOpen ? 'closed' : 'open') .
890: '.nomanip.gif';
891: $icon = "<img src='/adm/lonIcons/$icon' alt='' border='0' />";
892:
893: $linkopen = "";
894: $linkclose = "";
895: }
896: }
897:
898: if ($resource->randomout()) {
899: $nonLinkedText .= ' <i>(hidden)</i> ';
900: }
901:
902: # We're done preparing and finally ready to start the rendering
903: my $result = "<td align='left' valign='center'>";
904:
905: my $indentLevel = $params->{'indentLevel'};
906: if ($newBranchText) { $indentLevel--; }
907:
908: # print indentation
909: for (my $i = 0; $i < $indentLevel; $i++) {
910: $result .= $params->{'indentString'};
911: }
912:
913: # Decide what to display
914: $result .= "$newBranchText$linkopen$icon$linkclose";
915:
916: my $curMarkerBegin = '';
917: my $curMarkerEnd = '';
918:
919: # Is this the current resource?
920: if (!$params->{'displayedHereMarker'} &&
921: $resource->symb() eq $params->{'here'} ) {
922: $curMarkerBegin = '<font color="red" size="+2">> </font>';
923: $curMarkerEnd = '<font color="red" size="+2"><</font>';
924: $params->{'displayedHereMarker'} = 1;
925: }
926:
927: if ($resource->is_problem() && $part ne '0' &&
928: !$params->{'condensed'}) {
929: $partLabel = " (Part $part)";
930: $title = "";
931: }
932:
933: if ($params->{'condensed'} && $resource->countParts() > 1) {
934: $nonLinkedText .= ' (' . $resource->countParts() . ' parts)';
935: }
936:
937: if (!$params->{'resource_nolink'} && $src !~ /^\/uploaded\// &&
938: !$resource->is_sequence()) {
939: $result .= " $curMarkerBegin<a href='$link'>$title$partLabel</a>$curMarkerEnd $nonLinkedText</td>";
940: } else {
941: $result .= " $curMarkerBegin$title$partLabel$curMarkerEnd $nonLinkedText</td>";
942: }
943:
944: return $result;
945: }
946:
947: sub render_communication_status {
948: my ($resource, $part, $params) = @_;
949: my $discussionHTML = ""; my $feedbackHTML = ""; my $errorHTML = "";
950:
951: my $link = $params->{"resourceLink"};
952: my $linkopen = "<a href='$link'>";
953: my $linkclose = "</a>";
954:
955: if ($resource->hasDiscussion()) {
956: $discussionHTML = $linkopen .
957: '<img border="0" src="/adm/lonMisc/chat.gif" />' .
958: $linkclose;
959: }
960:
961: if ($resource->getFeedback()) {
962: my $feedback = $resource->getFeedback();
963: foreach (split(/\,/, $feedback)) {
964: if ($_) {
965: $feedbackHTML .= ' <a href="/adm/email?display='
966: . &Apache::lonnet::escape($_) . '">'
967: . '<img src="/adm/lonMisc/feedback.gif" '
968: . 'border="0" /></a>';
969: }
970: }
971: }
972:
973: if ($resource->getErrors()) {
974: my $errors = $resource->getErrors();
975: foreach (split(/,/, $errors)) {
976: if ($_) {
977: $errorHTML .= ' <a href="/adm/email?display='
978: . &Apache::lonnet::escape($_) . '">'
979: . '<img src="/adm/lonMisc/bomb.gif" '
980: . 'border="0" /></a>';
981: }
982: }
983: }
984:
985: if ($params->{'multipart'} && $part != '0') {
986: $discussionHTML = $feedbackHTML = $errorHTML = '';
987: }
988:
989: return "<td width=\"75\" align=\"left\" valign=\"center\">$discussionHTML$feedbackHTML$errorHTML </td>";
990:
991: }
992: sub render_quick_status {
993: my ($resource, $part, $params) = @_;
994: my $result = "";
995: my $firstDisplayed = !$params->{'condensed'} &&
996: $params->{'multipart'} && $part eq "0";
997:
998: my $link = $params->{"resourceLink"};
999: my $linkopen = "<a href='$link'>";
1000: my $linkclose = "</a>";
1001:
1002: if ($resource->is_problem() &&
1003: !$firstDisplayed) {
1004: my $icon = $statusIconMap{$resource->status($part)};
1005: my $alt = $iconAltTags{$icon};
1006: if ($icon) {
1007: $result .= "<td width='30' valign='center' width='50' align='right'>$linkopen<img width='25' height='25' src='/adm/lonIcons/$icon' border='0' alt='$alt' />$linkclose</td>\n";
1008: } else {
1009: $result .= "<td width='30'> </td>\n";
1010: }
1011: } else { # not problem, no icon
1012: $result .= "<td width='30'> </td>\n";
1013: }
1014:
1015: return $result;
1016: }
1017: sub render_long_status {
1018: my ($resource, $part, $params) = @_;
1019: my $result = "<td align='right' valign='center'>\n";
1020: my $firstDisplayed = !$params->{'condensed'} &&
1021: $params->{'multipart'} && $part eq "0";
1022:
1023: my $color;
1024: if ($resource->is_problem() && ($resource->countParts() <= 1) ) {
1025: $color = $colormap{$resource->status};
1026:
1027: if (dueInLessThen24Hours($resource, $part) ||
1028: lastTry($resource, $part)) {
1029: $color = $hurryUpColor;
1030: }
1031: }
1032:
1033: if ($resource->kind() eq "res" &&
1034: $resource->is_problem() &&
1035: !$firstDisplayed) {
1036: if ($color) {$result .= "<font color=\"$color\"><b>"; }
1037: $result .= getDescription($resource, $part);
1038: if ($color) {$result .= "</b></font>"; }
1039: }
1040: if ($resource->is_map() && advancedUser() && $resource->randompick()) {
1041: $result .= '(randomly select ' . $resource->randompick() .')';
1042: }
1043:
1044: return $result;
1045: }
1046:
1047: my @preparedColumns = (\&render_resource, \&render_communication_status,
1048: \&render_quick_status, \&render_long_status);
1049:
1050: sub setDefault {
1051: my ($val, $default) = @_;
1052: if (!defined($val)) { return $default; }
1053: return $val;
1054: }
1055:
1056: sub render {
1057: my $args = shift;
1058: &Apache::loncommon::get_unprocessed_cgi($ENV{QUERY_STRING});
1059: my $result = '';
1060:
1061: # Configure the renderer.
1062: my $cols = $args->{'cols'};
1063: if (!defined($cols)) {
1064: # no columns, no nav maps.
1065: return '';
1066: }
1067: my $mustCloseNavMap = 0;
1068: my $navmap;
1069: if (defined($args->{'navmap'})) {
1070: $navmap = $args->{'navmap'};
1071: }
1072:
1073: my $r = $args->{'r'};
1074: my $queryString = $args->{'queryString'};
1075: my $jump = $args->{'jump'};
1076: my $here = $args->{'here'};
1077: my $suppressNavmap = setDefault($args->{'suppressNavmap'}, 0);
1078: my $currentJumpDelta = 2; # change this to change how many resources are displayed
1079: # before the current resource when using #current
1080:
1081: # If we were passed 'here' information, we are not rendering
1082: # after a folder manipulation, and we were not passed an
1083: # iterator, make sure we open the folders to show the "here"
1084: # marker
1085: my $filterHash = {};
1086: # Figure out what we're not displaying
1087: foreach (split(/\,/, $ENV{"form.filter"})) {
1088: if ($_) {
1089: $filterHash->{$_} = "1";
1090: }
1091: }
1092:
1093: # Filter: Remember filter function and add our own filter: Refuse
1094: # to show hidden resources unless the user can see them.
1095: my $userCanSeeHidden = advancedUser();
1096: my $filterFunc = setDefault($args->{'filterFunc'},
1097: sub {return 1;});
1098: if (!$userCanSeeHidden) {
1099: # Without renaming the filterfunc, the server seems to go into
1100: # an infinite loop
1101: my $oldFilterFunc = $filterFunc;
1102: $filterFunc = sub { my $res = shift; return !$res->randomout() &&
1103: &$oldFilterFunc($res);};
1104: }
1105:
1106: my $condition = 0;
1107: if ($ENV{'form.condition'}) {
1108: $condition = 1;
1109: }
1110:
1111: if (!$ENV{'form.folderManip'} && !defined($args->{'iterator'})) {
1112: # Step 1: Check to see if we have a navmap
1113: if (!defined($navmap)) {
1114: $navmap = Apache::lonnavmaps::navmap->new(
1115: $ENV{"request.course.fn"}.".db",
1116: $ENV{"request.course.fn"}."_parms.db", 1, 1);
1117: $mustCloseNavMap = 1;
1118: }
1119: $navmap->init();
1120:
1121: # Step two: Locate what kind of here marker is necessary
1122: # Determine where the "here" marker is and where the screen jumps to.
1123:
1124: if ($ENV{'form.postsymb'}) {
1125: $here = $jump = $ENV{'form.postsymb'};
1126: } elsif ($ENV{'form.postdata'}) {
1127: # couldn't find a symb, is there a URL?
1128: my $currenturl = $ENV{'form.postdata'};
1129: #$currenturl=~s/^http\:\/\///;
1130: #$currenturl=~s/^[^\/]+//;
1131:
1132: $here = $jump = &Apache::lonnet::symbread($currenturl);
1133: }
1134:
1135: # Step three: Ensure the folders are open
1136: my $mapIterator = $navmap->getIterator(undef, undef, undef, 1);
1137: my $depth = 1;
1138: $mapIterator->next(); # discard the first BEGIN_MAP
1139: my $curRes = $mapIterator->next();
1140: my $found = 0;
1141:
1142: # We only need to do this if we need to open the maps to show the
1143: # current position. This will change the counter so we can't count
1144: # for the jump marker with this loop.
1145: while ($depth > 0 && !$found) {
1146: if ($curRes == $mapIterator->BEGIN_MAP()) { $depth++; }
1147: if ($curRes == $mapIterator->END_MAP()) { $depth--; }
1148:
1149: if (ref($curRes) && $curRes->symb() eq $here) {
1150: my $mapStack = $mapIterator->getStack();
1151:
1152: # Ensure the parent maps are open
1153: for my $map (@{$mapStack}) {
1154: if ($condition) {
1155: undef $filterHash->{$map->map_pc()};
1156: } else {
1157: $filterHash->{$map->map_pc()} = 1;
1158: }
1159: }
1160: $found = 1;
1161: }
1162:
1163: $curRes = $mapIterator->next();
1164: }
1165: }
1166:
1167: if ( !defined($args->{'iterator'}) && $ENV{'form.folderManip'} ) { # we came from a user's manipulation of the nav page
1168: # If this is a click on a folder or something, we want to preserve the "here"
1169: # from the querystring, and get the new "jump" marker
1170: $here = $ENV{'form.here'};
1171: $jump = $ENV{'form.jump'};
1172: }
1173:
1174: my $it = $args->{'iterator'};
1175: if (!defined($it)) {
1176: # Construct a default iterator based on $ENV{'form.'} information
1177:
1178: # Step 1: Check to see if we have a navmap
1179: if (!defined($navmap)) {
1180: $navmap = Apache::lonnavmaps::navmap->new($r,
1181: $ENV{"request.course.fn"}.".db",
1182: $ENV{"request.course.fn"}."_parms.db", 1, 1);
1183: $mustCloseNavMap = 1;
1184: }
1185: # Paranoia: Make sure it's ready
1186: $navmap->init();
1187:
1188: # See if we're being passed a specific map
1189: if ($args->{'iterator_map'}) {
1190: my $map = $args->{'iterator_map'};
1191: $map = $navmap->getResourceByUrl($map);
1192: my $firstResource = $map->map_start();
1193: my $finishResource = $map->map_finish();
1194:
1195: $args->{'iterator'} = $it = $navmap->getIterator($firstResource, $finishResource, $filterHash, $condition);
1196: } else {
1197: $args->{'iterator'} = $it = $navmap->getIterator(undef, undef, $filterHash, $condition);
1198: }
1199: }
1200:
1201: # (re-)Locate the jump point, if any
1202: # Note this does not take filtering or hidden into account... need
1203: # to be fixed?
1204: my $mapIterator = $navmap->getIterator(undef, undef, $filterHash, 0);
1205: my $depth = 1;
1206: $mapIterator->next();
1207: my $curRes = $mapIterator->next();
1208: my $foundJump = 0;
1209: my $counter = 0;
1210:
1211: while ($depth > 0 && !$foundJump) {
1212: if ($curRes == $mapIterator->BEGIN_MAP()) { $depth++; }
1213: if ($curRes == $mapIterator->END_MAP()) { $depth--; }
1214: if (ref($curRes)) { $counter++; }
1215:
1216: if (ref($curRes) && $jump eq $curRes->symb()) {
1217:
1218: # This is why we have to use the main iterator instead of the
1219: # potentially faster DFS: The count has to be the same, so
1220: # the order has to be the same, which DFS won't give us.
1221: $args->{'currentJumpIndex'} = $counter;
1222: $foundJump = 1;
1223: }
1224:
1225: $curRes = $mapIterator->next();
1226: }
1227:
1228: my $showParts = setDefault($args->{'showParts'}, 1);
1229: my $condenseParts = setDefault($args->{'condenseParts'}, 1);
1230: # keeps track of when the current resource is found,
1231: # so we can back up a few and put the anchor above the
1232: # current resource
1233: my $printKey = $args->{'printKey'};
1234: my $printCloseAll = $args->{'printCloseAll'};
1235: if (!defined($printCloseAll)) { $printCloseAll = 1; }
1236:
1237: # Print key?
1238: if ($printKey) {
1239: $result .= '<table border="0" cellpadding="2" cellspacing="0">';
1240: my $date=localtime;
1241: $result.='<tr><td align="right" valign="bottom">Key: </td>';
1242: if ($navmap->{LAST_CHECK}) {
1243: $result .=
1244: '<img src="/adm/lonMisc/chat.gif"> New discussion since '.
1245: strftime("%A, %b %e at %I:%M %P", localtime($navmap->{LAST_CHECK})).
1246: '</td><td align="center" valign="bottom"> '.
1247: '<img src="/adm/lonMisc/feedback.gif"> New message (click to open)<p>'.
1248: '</td>';
1249: } else {
1250: $result .= '<td align="center" valign="bottom"> '.
1251: '<img src="/adm/lonMisc/chat.gif"> Discussions</td><td align="center" valign="bottom">'.
1252: ' <img src="/adm/lonMisc/feedback.gif"> New message (click to open)'.
1253: '</td>';
1254: }
1255:
1256: $result .= '</tr></table>';
1257: }
1258:
1259: if ($printCloseAll && !$args->{'resource_no_folder_link'}) {
1260: if ($condition) {
1261: $result.="<a href=\"navmaps?condition=0&filter=&$queryString" .
1262: "&here=" . Apache::lonnet::escape($here) .
1263: "\">Close All Folders</a>";
1264: } else {
1265: $result.="<a href=\"navmaps?condition=1&filter=&$queryString" .
1266: "&here=" . Apache::lonnet::escape($here) .
1267: "\">Open All Folders</a>";
1268: }
1269: $result .= "<br /><br />\n";
1270: }
1271:
1272: if ($r) {
1273: $r->print($result);
1274: $r->rflush();
1275: $result = "";
1276: }
1277: # End parameter setting
1278:
1279: # Data
1280: $result .= '<table cellspacing="0" cellpadding="3" border="0" bgcolor="#FFFFFF">' ."\n";
1281: my $res = "Apache::lonnavmaps::resource";
1282: my %condenseStatuses =
1283: ( $res->NETWORK_FAILURE => 1,
1284: $res->NOTHING_SET => 1,
1285: $res->CORRECT => 1 );
1286: my @backgroundColors = ("#FFFFFF", "#F6F6F6");
1287:
1288: # Shared variables
1289: $args->{'counter'} = 0; # counts the rows
1290: $args->{'indentLevel'} = 0;
1291: $args->{'isNewBranch'} = 0;
1292: $args->{'condensed'} = 0;
1293: $args->{'indentString'} = setDefault($args->{'indentString'}, "<img src='/adm/lonIcons/whitespace1.gif' width='25' height='1' alt='' border='0' />");
1294: $args->{'displayedHereMarker'} = 0;
1295:
1296: # If we're suppressing empty sequences, look for them here. Use DFS for speed,
1297: # since structure actually doesn't matter, except what map has what resources.
1298: if ($args->{'suppressEmptySequences'}) {
1299: my $dfsit = Apache::lonnavmaps::DFSiterator->new($navmap,
1300: $it->{FIRST_RESOURCE},
1301: $it->{FINISH_RESOURCE},
1302: {}, undef, 1);
1303: $depth = 0;
1304: $dfsit->next();
1305: my $curRes = $dfsit->next();
1306: while ($depth > -1) {
1307: if ($curRes == $dfsit->BEGIN_MAP()) { $depth++; }
1308: if ($curRes == $dfsit->END_MAP()) { $depth--; }
1309:
1310: if (ref($curRes)) {
1311: # Parallel pre-processing: Do sequences have non-filtered-out children?
1312: if ($curRes->is_map()) {
1313: $curRes->{DATA}->{HAS_VISIBLE_CHILDREN} = 0;
1314: # Sequences themselves do not count as visible children,
1315: # unless those sequences also have visible children.
1316: # This means if a sequence appears, there's a "promise"
1317: # that there's something under it if you open it, somewhere.
1318: } else {
1319: # Not a sequence: if it's filtered, ignore it, otherwise
1320: # rise up the stack and mark the sequences as having children
1321: if (&$filterFunc($curRes)) {
1322: for my $sequence (@{$dfsit->getStack()}) {
1323: $sequence->{DATA}->{HAS_VISIBLE_CHILDREN} = 1;
1324: }
1325: }
1326: }
1327: }
1328: } continue {
1329: $curRes = $dfsit->next();
1330: }
1331: }
1332:
1333: my $displayedJumpMarker = 0;
1334: # Set up iteration.
1335: $depth = 1;
1336: $it->next(); # discard initial BEGIN_MAP
1337: $curRes = $it->next();
1338: my $now = time();
1339: my $in24Hours = $now + 24 * 60 * 60;
1340: my $rownum = 0;
1341:
1342: # export "here" marker information
1343: $args->{'here'} = $here;
1344:
1345: while ($depth > 0) {
1346: if ($curRes == $it->BEGIN_MAP()) { $depth++; }
1347: if ($curRes == $it->END_MAP()) { $depth--; }
1348:
1349: # Maintain indentation level.
1350: if ($curRes == $it->BEGIN_MAP() ||
1351: $curRes == $it->BEGIN_BRANCH() ) {
1352: $args->{'indentLevel'}++;
1353: }
1354: if ($curRes == $it->END_MAP() ||
1355: $curRes == $it->END_BRANCH() ) {
1356: $args->{'indentLevel'}--;
1357: }
1358: # Notice new branches
1359: if ($curRes == $it->BEGIN_BRANCH()) {
1360: $args->{'isNewBranch'} = 1;
1361: }
1362:
1363: # If this isn't an actual resource, continue on
1364: if (!ref($curRes)) {
1365: next;
1366: }
1367:
1368: # If this has been filtered out, continue on
1369: if (!(&$filterFunc($curRes))) {
1370: $args->{'isNewBranch'} = 0; # Don't falsely remember this
1371: next;
1372: }
1373:
1374: # If this is an empty sequence and we're filtering them, continue on
1375: if ($curRes->is_map() && $args->{'suppressEmptySequences'} &&
1376: !$curRes->{DATA}->{HAS_VISIBLE_CHILDREN}) {
1377: next;
1378: }
1379:
1380: # If we're suppressing navmaps and this is a navmap, continue on
1381: if ($suppressNavmap && $curRes->src() =~ /^\/adm\/navmaps/) {
1382: next;
1383: }
1384:
1385: $args->{'counter'}++;
1386:
1387: # Does it have multiple parts?
1388: $args->{'multipart'} = 0;
1389: $args->{'condensed'} = 0;
1390: my @parts;
1391:
1392: # Decide what parts to show.
1393: if ($curRes->is_problem() && $showParts) {
1394: @parts = @{$curRes->parts()};
1395: $args->{'multipart'} = $curRes->multipart();
1396:
1397: if ($condenseParts) { # do the condensation
1398: if (!$curRes->opendate("0")) {
1399: @parts = ();
1400: $args->{'condensed'} = 1;
1401: }
1402: if (!$args->{'condensed'}) {
1403: # Decide whether to condense based on similarity
1404: my $status = $curRes->status($parts[0]);
1405: my $due = $curRes->duedate($parts[0]);
1406: my $open = $curRes->opendate($parts[0]);
1407: my $statusAllSame = 1;
1408: my $dueAllSame = 1;
1409: my $openAllSame = 1;
1410: for (my $i = 1; $i < scalar(@parts); $i++) {
1411: if ($curRes->status($parts[$i]) != $status){
1412: $statusAllSame = 0;
1413: }
1414: if ($curRes->duedate($parts[$i]) != $due ) {
1415: $dueAllSame = 0;
1416: }
1417: if ($curRes->opendate($parts[$i]) != $open) {
1418: $openAllSame = 0;
1419: }
1420: }
1421: # $*allSame is true if all the statuses were
1422: # the same. Now, if they are all the same and
1423: # match one of the statuses to condense, or they
1424: # are all open with the same due date, or they are
1425: # all OPEN_LATER with the same open date, display the
1426: # status of the first non-zero part (to get the 'correct'
1427: # status right, since 0 is never 'correct' or 'open').
1428: if (($statusAllSame && defined($condenseStatuses{$status})) ||
1429: ($dueAllSame && $status == $curRes->OPEN && $statusAllSame)||
1430: ($openAllSame && $status == $curRes->OPEN_LATER && $statusAllSame) ){
1431: @parts = ($parts[0]);
1432: $args->{'condensed'} = 1;
1433: }
1434: }
1435: # Multipart problem with one part: always "condense" (happens
1436: # to match the desirable behavior)
1437: if ($curRes->countParts() == 1) {
1438: @parts = ($parts[0]);
1439: $args->{'condensed'} = 1;
1440: }
1441: }
1442: }
1443:
1444: # If the multipart problem was condensed, "forget" it was multipart
1445: if (scalar(@parts) == 1) {
1446: $args->{'multipart'} = 0;
1447: } else {
1448: # Add part 0 so we display it correctly.
1449: unshift @parts, '0';
1450: }
1451:
1452: # Now, we've decided what parts to show. Loop through them and
1453: # show them.
1454: foreach my $part (@parts) {
1455: $rownum ++;
1456: my $backgroundColor = $backgroundColors[$rownum % scalar(@backgroundColors)];
1457:
1458: $result .= " <tr bgcolor='$backgroundColor'>\n";
1459:
1460: # Set up some data about the parts that the cols might want
1461: my $filter = $it->{FILTER};
1462: my $stack = $it->getStack();
1463: my $src = getLinkForResource($stack);
1464:
1465: my $srcHasQuestion = $src =~ /\?/;
1466: $args->{"resourceLink"} = $src.
1467: ($srcHasQuestion?'&':'?') .
1468: 'symb=' . &Apache::lonnet::escape($curRes->symb());
1469:
1470: # Now, display each column.
1471: foreach my $col (@$cols) {
1472: my $colHTML = '';
1473: if (ref($col)) {
1474: $colHTML .= &$col($curRes, $part, $args);
1475: } else {
1476: $colHTML .= &{$preparedColumns[$col]}($curRes, $part, $args);
1477: }
1478:
1479: # If this is the first column and it's time to print
1480: # the anchor, do so
1481: if ($col == $cols->[0] &&
1482: $args->{'counter'} == $args->{'currentJumpIndex'} -
1483: $currentJumpDelta) {
1484: # Jam the anchor after the <td> tag;
1485: # necessary for valid HTML (which Mozilla requires)
1486: $colHTML =~ s/\>/\>\<a name="curloc" \/\>/;
1487: $displayedJumpMarker = 1;
1488: }
1489: $result .= $colHTML . "\n";
1490: }
1491: $result .= " </tr>\n";
1492: $args->{'isNewBranch'} = 0;
1493: }
1494:
1495: if ($r && $rownum % 20 == 0) {
1496: $r->print($result);
1497: $result = "";
1498: $r->rflush();
1499: }
1500: } continue {
1501: $curRes = $it->next();
1502: }
1503:
1504: # Print out the part that jumps to #curloc if it exists
1505: # delay needed because the browser is processing the jump before
1506: # it finishes rendering, so it goes to the wrong place!
1507: # onload might be better, but this routine has no access to that.
1508: # On mozilla, the 0-millisecond timeout seems to prevent this;
1509: # it's quite likely this might fix other browsers, too, and
1510: # certainly won't hurt anything.
1511: if ($displayedJumpMarker) {
1512: $result .= "<script>setTimeout(\"location += '#curloc';\", 0)</script>\n";
1513: }
1514:
1515: $result .= "</table>";
1516:
1517: if ($r) {
1518: $r->print($result);
1519: $result = "";
1520: $r->rflush();
1521: }
1522:
1523: if ($mustCloseNavMap) { $navmap->untieHashes(); }
1524:
1525: return $result;
1526: }
1527:
1528: 1;
1529:
1530: package Apache::lonnavmaps::navmap;
1531:
1532: =pod
1533:
1534: lonnavmaps provides functions and objects for dealing with the
1535: compiled course hashes generated when a user enters the course, the
1536: Apache handler for the "Navigation Map" button, and a flexible
1537: prepared renderer for navigation maps that are easy to use anywhere.
1538:
1539: =head1 Object: navmap
1540:
1541: Encapsulating the compiled nav map
1542:
1543: navmap is an object that encapsulates a compiled course map and
1544: provides a reasonable interface to it.
1545:
1546: Most notably it provides a way to navigate the map sensibly and a
1547: flexible iterator that makes it easy to write various renderers based
1548: on nav maps.
1549:
1550: You must obtain resource objects through the navmap object.
1551:
1552: =head2 Methods
1553:
1554: =over 4
1555:
1556: =item * B<new>(navHashFile, parmHashFile, genCourseAndUserOptions,
1557: genMailDiscussStatus):
1558:
1559: Binds a new navmap object to the compiled nav map hash and parm hash
1560: given as filenames. genCourseAndUserOptions is a flag saying whether
1561: the course options and user options hash should be generated. This is
1562: for when you are using the parameters of the resources that require
1563: them; see documentation in resource object
1564: documentation. genMailDiscussStatus causes the nav map to retreive
1565: information about the email and discussion status of
1566: resources. Returns the navmap object if this is successful, or
1567: B<undef> if not. You must check for undef; errors will occur when you
1568: try to use the other methods otherwise.
1569:
1570: =item * B<getIterator>(first, finish, filter, condition):
1571:
1572: See iterator documentation below.
1573:
1574: =cut
1575:
1576: use strict;
1577: use GDBM_File;
1578:
1579: sub new {
1580: # magic invocation to create a class instance
1581: my $proto = shift;
1582: my $class = ref($proto) || $proto;
1583: my $self = {};
1584:
1585: $self->{NAV_HASH_FILE} = shift;
1586: $self->{PARM_HASH_FILE} = shift;
1587: $self->{GENERATE_COURSE_USER_OPT} = shift;
1588: $self->{GENERATE_EMAIL_DISCUSS_STATUS} = shift;
1589:
1590: # Resource cache stores navmap resources as we reference them. We generate
1591: # them on-demand so we don't pay for creating resources unless we use them.
1592: $self->{RESOURCE_CACHE} = {};
1593:
1594: # Network failure flag, if we accessed the course or user opt and
1595: # failed
1596: $self->{NETWORK_FAILURE} = 0;
1597:
1598: # tie the nav hash
1599:
1600: my %navmaphash;
1601: my %parmhash;
1602: if (!(tie(%navmaphash, 'GDBM_File', $self->{NAV_HASH_FILE},
1603: &GDBM_READER(), 0640))) {
1604: return undef;
1605: }
1606:
1607: if (!(tie(%parmhash, 'GDBM_File', $self->{PARM_HASH_FILE},
1608: &GDBM_READER(), 0640)))
1609: {
1610: untie %{$self->{PARM_HASH}};
1611: return undef;
1612: }
1613:
1614: $self->{NAV_HASH} = \%navmaphash;
1615: $self->{PARM_HASH} = \%parmhash;
1616: $self->{INITED} = 0;
1617:
1618: bless($self);
1619:
1620: return $self;
1621: }
1622:
1623: sub init {
1624: my $self = shift;
1625: if ($self->{INITED}) { return; }
1626:
1627: # If the course opt hash and the user opt hash should be generated,
1628: # generate them
1629: if ($self->{GENERATE_COURSE_USER_OPT}) {
1630: my $uname=$ENV{'user.name'};
1631: my $udom=$ENV{'user.domain'};
1632: my $uhome=$ENV{'user.home'};
1633: my $cid=$ENV{'request.course.id'};
1634: my $chome=$ENV{'course.'.$cid.'.home'};
1635: my ($cdom,$cnum)=split(/\_/,$cid);
1636:
1637: my $userprefix=$uname.'_'.$udom.'_';
1638:
1639: my %courserdatas; my %useropt; my %courseopt; my %userrdatas;
1640: unless ($uhome eq 'no_host') {
1641: # ------------------------------------------------- Get coursedata (if present)
1642: unless ((time-$courserdatas{$cid.'.last_cache'})<240) {
1643: my $reply=&Apache::lonnet::reply('dump:'.$cdom.':'.$cnum.
1644: ':resourcedata',$chome);
1645: # Check for network failure
1646: if ( $reply =~ /no.such.host/i || $reply =~ /con_lost/i) {
1647: $self->{NETWORK_FAILURE} = 1;
1648: } elsif ($reply!~/^error\:/) {
1649: $courserdatas{$cid}=$reply;
1650: $courserdatas{$cid.'.last_cache'}=time;
1651: }
1652: }
1653: foreach (split(/\&/,$courserdatas{$cid})) {
1654: my ($name,$value)=split(/\=/,$_);
1655: $courseopt{$userprefix.&Apache::lonnet::unescape($name)}=
1656: &Apache::lonnet::unescape($value);
1657: }
1658: # --------------------------------------------------- Get userdata (if present)
1659: unless ((time-$userrdatas{$uname.'___'.$udom.'.last_cache'})<240) {
1660: my $reply=&Apache::lonnet::reply('dump:'.$udom.':'.$uname.':resourcedata',$uhome);
1661: if ($reply!~/^error\:/) {
1662: $userrdatas{$uname.'___'.$udom}=$reply;
1663: $userrdatas{$uname.'___'.$udom.'.last_cache'}=time;
1664: }
1665: # check to see if network failed
1666: elsif ( $reply=~/no.such.host/i || $reply=~/con.*lost/i )
1667: {
1668: $self->{NETWORK_FAILURE} = 1;
1669: }
1670: }
1671: foreach (split(/\&/,$userrdatas{$uname.'___'.$udom})) {
1672: my ($name,$value)=split(/\=/,$_);
1673: $useropt{$userprefix.&Apache::lonnet::unescape($name)}=
1674: &Apache::lonnet::unescape($value);
1675: }
1676: $self->{COURSE_OPT} = \%courseopt;
1677: $self->{USER_OPT} = \%useropt;
1678: }
1679: }
1680:
1681: if ($self->{GENERATE_EMAIL_DISCUSS_STATUS}) {
1682: my $cid=$ENV{'request.course.id'};
1683: my ($cdom,$cnum)=split(/\_/,$cid);
1684:
1685: my %emailstatus = &Apache::lonnet::dump('email_status');
1686: my $logoutTime = $emailstatus{'logout'};
1687: my $courseLeaveTime = $emailstatus{'logout_'.$ENV{'request.course.id'}};
1688: $self->{LAST_CHECK} = (($courseLeaveTime > $logoutTime) ?
1689: $courseLeaveTime : $logoutTime);
1690: my %discussiontime = &Apache::lonnet::dump('discussiontimes',
1691: $cdom, $cnum);
1692: my %feedback=();
1693: my %error=();
1694: my $keys = &Apache::lonnet::reply('keys:'.
1695: $ENV{'user.domain'}.':'.
1696: $ENV{'user.name'}.':nohist_email',
1697: $ENV{'user.home'});
1698:
1699: foreach my $msgid (split(/\&/, $keys)) {
1700: $msgid=&Apache::lonnet::unescape($msgid);
1701: my $plain=&Apache::lonnet::unescape(&Apache::lonnet::unescape($msgid));
1702: if ($plain=~/(Error|Feedback) \[([^\]]+)\]/) {
1703: my ($what,$url)=($1,$2);
1704: my %status=
1705: &Apache::lonnet::get('email_status',[$msgid]);
1706: if ($status{$msgid}=~/^error\:/) {
1707: $status{$msgid}='';
1708: }
1709:
1710: if (($status{$msgid} eq 'new') ||
1711: (!$status{$msgid})) {
1712: if ($what eq 'Error') {
1713: $error{$url}.=','.$msgid;
1714: } else {
1715: $feedback{$url}.=','.$msgid;
1716: }
1717: }
1718: }
1719: }
1720:
1721: $self->{FEEDBACK} = \%feedback;
1722: $self->{ERROR_MSG} = \%error; # what is this? JB
1723: $self->{DISCUSSION_TIME} = \%discussiontime;
1724: $self->{EMAIL_STATUS} = \%emailstatus;
1725:
1726: }
1727:
1728: $self->{PARM_CACHE} = {};
1729: $self->{INITED} = 1;
1730: }
1731:
1732: # Internal function: Takes a key to look up in the nav hash and implements internal
1733: # memory caching of that key.
1734: sub navhash {
1735: my $self = shift; my $key = shift;
1736: return $self->{NAV_HASH}->{$key};
1737: }
1738:
1739: # Checks to see if coursemap is defined, matching test in old lonnavmaps
1740: sub courseMapDefined {
1741: my $self = shift;
1742: my $uri = &Apache::lonnet::clutter($ENV{'request.course.uri'});
1743:
1744: my $firstres = $self->navhash("map_start_$uri");
1745: my $lastres = $self->navhash("map_finish_$uri");
1746: return $firstres && $lastres;
1747: }
1748:
1749: sub getIterator {
1750: my $self = shift;
1751: my $iterator = Apache::lonnavmaps::iterator->new($self, shift, shift,
1752: shift, undef, shift);
1753: return $iterator;
1754: }
1755:
1756: # unties the hash when done
1757: sub untieHashes {
1758: my $self = shift;
1759: untie %{$self->{NAV_HASH}};
1760: untie %{$self->{PARM_HASH}};
1761: }
1762:
1763: # Private method: Does the given resource (as a symb string) have
1764: # current discussion? Returns 0 if chat/mail data not extracted.
1765: sub hasDiscussion {
1766: my $self = shift;
1767: my $symb = shift;
1768: if (!defined($self->{DISCUSSION_TIME})) { return 0; }
1769:
1770: #return defined($self->{DISCUSSION_TIME}->{$symb});
1771: return $self->{DISCUSSION_TIME}->{$symb} >
1772: $self->{LAST_CHECK};
1773: }
1774:
1775: # Private method: Does the given resource (as a symb string) have
1776: # current feedback? Returns the string in the feedback hash, which
1777: # will be false if it does not exist.
1778: sub getFeedback {
1779: my $self = shift;
1780: my $symb = shift;
1781:
1782: if (!defined($self->{FEEDBACK})) { return ""; }
1783:
1784: return $self->{FEEDBACK}->{$symb};
1785: }
1786:
1787: # Private method: Get the errors for that resource (by source).
1788: sub getErrors {
1789: my $self = shift;
1790: my $src = shift;
1791:
1792: if (!defined($self->{ERROR_MSG})) { return ""; }
1793: return $self->{ERROR_MSG}->{$src};
1794: }
1795:
1796: =pod
1797:
1798: =item * B<getById>(id):
1799:
1800: Based on the ID of the resource (1.1, 3.2, etc.), get a resource
1801: object for that resource. This method, or other methods that use it
1802: (as in the resource object) is the only proper way to obtain a
1803: resource object.
1804:
1805: =item * B<getBySymb>(symb):
1806:
1807: Based on the symb of the resource, get a resource object for that
1808: resource. This is one of the proper ways to get a resource object.
1809:
1810: =item * B<getMapByMapPc>(map_pc):
1811:
1812: Based on the map_pc of the resource, get a resource object for
1813: the given map. This is one of the proper ways to get a resource object.
1814:
1815: =cut
1816:
1817: # The strategy here is to cache the resource objects, and only construct them
1818: # as we use them. The real point is to prevent reading any more from the tied
1819: # hash then we have to, which should hopefully alleviate speed problems.
1820: # Caching is just an incidental detail I throw in because it makes sense.
1821:
1822: sub getById {
1823: my $self = shift;
1824: my $id = shift;
1825:
1826: if (defined ($self->{RESOURCE_CACHE}->{$id}))
1827: {
1828: return $self->{RESOURCE_CACHE}->{$id};
1829: }
1830:
1831: # resource handles inserting itself into cache.
1832: # Not clear why the quotes are necessary, but as of this
1833: # writing it doesn't work without them.
1834: return "Apache::lonnavmaps::resource"->new($self, $id);
1835: }
1836:
1837: sub getBySymb {
1838: my $self = shift;
1839: my $symb = shift;
1840: my ($mapUrl, $id, $filename) = split (/___/, $symb);
1841: my $map = $self->getResourceByUrl($mapUrl);
1842: return $self->getById($map->map_pc() . '.' . $id);
1843: }
1844:
1845: sub getByMapPc {
1846: my $self = shift;
1847: my $map_pc = shift;
1848: my $map_id = $self->{NAV_HASH}->{'map_id_' . $map_pc};
1849: $map_id = $self->{NAV_HASH}->{'ids_' . $map_id};
1850: return $self->getById($map_id);
1851: }
1852:
1853: =pod
1854:
1855: =item * B<firstResource>():
1856:
1857: Returns a resource object reference corresponding to the first
1858: resource in the navmap.
1859:
1860: =cut
1861:
1862: sub firstResource {
1863: my $self = shift;
1864: my $firstResource = $self->navhash('map_start_' .
1865: &Apache::lonnet::clutter($ENV{'request.course.uri'}));
1866: return $self->getById($firstResource);
1867: }
1868:
1869: =pod
1870:
1871: =item * B<finishResource>():
1872:
1873: Returns a resource object reference corresponding to the last resource
1874: in the navmap.
1875:
1876: =cut
1877:
1878: sub finishResource {
1879: my $self = shift;
1880: my $firstResource = $self->navhash('map_finish_' .
1881: &Apache::lonnet::clutter($ENV{'request.course.uri'}));
1882: return $self->getById($firstResource);
1883: }
1884:
1885: # Parmval reads the parm hash and cascades the lookups. parmval_real does
1886: # the actual lookup; parmval caches the results.
1887: sub parmval {
1888: my $self = shift;
1889: my ($what,$symb)=@_;
1890: my $hashkey = $what."|||".$symb;
1891:
1892: if (defined($self->{PARM_CACHE}->{$hashkey})) {
1893: return $self->{PARM_CACHE}->{$hashkey};
1894: }
1895:
1896: my $result = $self->parmval_real($what, $symb);
1897: $self->{PARM_CACHE}->{$hashkey} = $result;
1898: return $result;
1899: }
1900:
1901: sub parmval_real {
1902: my $self = shift;
1903: my ($what,$symb) = @_;
1904:
1905: my $cid=$ENV{'request.course.id'};
1906: my $csec=$ENV{'request.course.sec'};
1907: my $uname=$ENV{'user.name'};
1908: my $udom=$ENV{'user.domain'};
1909:
1910: unless ($symb) { return ''; }
1911: my $result='';
1912:
1913: my ($mapname,$id,$fn)=split(/\_\_\_/,$symb);
1914:
1915: # ----------------------------------------------------- Cascading lookup scheme
1916: my $rwhat=$what;
1917: $what=~s/^parameter\_//;
1918: $what=~s/\_/\./;
1919:
1920: my $symbparm=$symb.'.'.$what;
1921: my $mapparm=$mapname.'___(all).'.$what;
1922: my $usercourseprefix=$uname.'_'.$udom.'_'.$cid;
1923:
1924: my $seclevel= $usercourseprefix.'.['.$csec.'].'.$what;
1925: my $seclevelr=$usercourseprefix.'.['.$csec.'].'.$symbparm;
1926: my $seclevelm=$usercourseprefix.'.['.$csec.'].'.$mapparm;
1927:
1928: my $courselevel= $usercourseprefix.'.'.$what;
1929: my $courselevelr=$usercourseprefix.'.'.$symbparm;
1930: my $courselevelm=$usercourseprefix.'.'.$mapparm;
1931:
1932: my $useropt = $self->{USER_OPT};
1933: my $courseopt = $self->{COURSE_OPT};
1934: my $parmhash = $self->{PARM_HASH};
1935:
1936: # ---------------------------------------------------------- first, check user
1937: if ($uname and defined($useropt)) {
1938: if (defined($$useropt{$courselevelr})) { return $$useropt{$courselevelr}; }
1939: if (defined($$useropt{$courselevelm})) { return $$useropt{$courselevelm}; }
1940: if (defined($$useropt{$courselevel})) { return $$useropt{$courselevel}; }
1941: }
1942:
1943: # ------------------------------------------------------- second, check course
1944: if ($csec and defined($courseopt)) {
1945: if (defined($$courseopt{$seclevelr})) { return $$courseopt{$seclevelr}; }
1946: if (defined($$courseopt{$seclevelm})) { return $$courseopt{$seclevelm}; }
1947: if (defined($$courseopt{$seclevel})) { return $$courseopt{$seclevel}; }
1948: }
1949:
1950: if (defined($courseopt)) {
1951: if (defined($$courseopt{$courselevelr})) { return $$courseopt{$courselevelr}; }
1952: if (defined($$courseopt{$courselevelm})) { return $$courseopt{$courselevelm}; }
1953: if (defined($$courseopt{$courselevel})) { return $$courseopt{$courselevel}; }
1954: }
1955:
1956: # ----------------------------------------------------- third, check map parms
1957:
1958: my $thisparm=$$parmhash{$symbparm};
1959: if (defined($thisparm)) { return $thisparm; }
1960:
1961: # ----------------------------------------------------- fourth , check default
1962:
1963: my $default=&Apache::lonnet::metadata($fn,$rwhat.'.default');
1964: if (defined($default)) { return $default}
1965:
1966: # --------------------------------------------------- fifth , cascade up parts
1967:
1968: my ($space,@qualifier)=split(/\./,$rwhat);
1969: my $qualifier=join('.',@qualifier);
1970: unless ($space eq '0') {
1971: my @parts=split(/_/,$space);
1972: my $id=pop(@parts);
1973: my $part=join('_',@parts);
1974: if ($part eq '') { $part='0'; }
1975: my $partgeneral=$self->parmval($part.".$qualifier",$symb);
1976: if (defined($partgeneral)) { return $partgeneral; }
1977: }
1978: return '';
1979: }
1980:
1981: =pod
1982:
1983: =item * B<getResourceByUrl>(url):
1984:
1985: Retrieves a resource object by URL of the resource. If passed a
1986: resource object, it will simply return it, so it is safe to use this
1987: method in code like "$res = $navmap->getResourceByUrl($res)", if
1988: you're not sure if $res is already an object, or just a URL. If the
1989: resource appears multiple times in the course, only the first instance
1990: will be returned. As a result, this is probably useful only for maps.
1991:
1992: =item * B<retrieveResources>(map, filterFunc, recursive, bailout):
1993:
1994: The map is a specification of a map to retreive the resources from,
1995: either as a url or as an object. The filterFunc is a reference to a
1996: function that takes a resource object as its one argument and returns
1997: true if the resource should be included, or false if it should not
1998: be. If recursive is true, the map will be recursively examined,
1999: otherwise it will not be. If bailout is true, the function will return
2000: as soon as it finds a resource, if false it will finish. By default,
2001: the map is the top-level map of the course, filterFunc is a function
2002: that always returns 1, recursive is true, bailout is false. The
2003: resources will be returned in a list containing the resource objects
2004: for the corresponding resources, with B<no structure information> in
2005: the list; regardless of branching, recursion, etc., it will be a flat
2006: list.
2007:
2008: Thus, this is suitable for cases where you don't want the structure,
2009: just a list of all resources. It is also suitable for finding out how
2010: many resources match a given description; for this use, if all you
2011: want to know is if I<any> resources match the description, the bailout
2012: parameter will allow you to avoid potentially expensive enumeration of
2013: all matching resources.
2014:
2015: =item * B<hasResources>(map, filterFunc, recursive):
2016:
2017: Convience method for
2018:
2019: scalar(retrieveResources($map, $filterFunc, $recursive, 1)) > 0
2020:
2021: which will tell whether the map has resources matching the description
2022: in the filter function.
2023:
2024: =cut
2025:
2026: sub getResourceByUrl {
2027: my $self = shift;
2028: my $resUrl = shift;
2029:
2030: if (ref($resUrl)) { return $resUrl; }
2031:
2032: $resUrl = &Apache::lonnet::clutter($resUrl);
2033: my $resId = $self->{NAV_HASH}->{'ids_' . $resUrl};
2034: if ($resId =~ /,/) {
2035: $resId = (split (/,/, $resId))[0];
2036: }
2037: if (!$resId) { return ''; }
2038: return $self->getById($resId);
2039: }
2040:
2041: sub retrieveResources {
2042: my $self = shift;
2043: my $map = shift;
2044: my $filterFunc = shift;
2045: if (!defined ($filterFunc)) {
2046: $filterFunc = sub {return 1;};
2047: }
2048: my $recursive = shift;
2049: if (!defined($recursive)) { $recursive = 1; }
2050: my $bailout = shift;
2051: if (!defined($bailout)) { $bailout = 0; }
2052:
2053: # Create the necessary iterator.
2054: if (!ref($map)) { # assume it's a url of a map.
2055: $map = $self->getResourceByUrl($map);
2056: }
2057:
2058: # Check the map's validity.
2059: if (!$map || !$map->is_map()) {
2060: # Oh, to throw an exception.... how I'd love that!
2061: return ();
2062: }
2063:
2064: # Get an iterator.
2065: my $it = $self->getIterator($map->map_start(), $map->map_finish(),
2066: !$recursive);
2067:
2068: my @resources = ();
2069:
2070: # Run down the iterator and collect the resources.
2071: my $depth = 1;
2072: $it->next();
2073: my $curRes = $it->next();
2074:
2075: while ($depth > 0) {
2076: if ($curRes == $it->BEGIN_MAP()) {
2077: $depth++;
2078: }
2079: if ($curRes == $it->END_MAP()) {
2080: $depth--;
2081: }
2082:
2083: if (ref($curRes)) {
2084: if (!&$filterFunc($curRes)) {
2085: next;
2086: }
2087:
2088: push @resources, $curRes;
2089:
2090: if ($bailout) {
2091: return @resources;
2092: }
2093: }
2094:
2095: $curRes = $it->next();
2096: }
2097:
2098: return @resources;
2099: }
2100:
2101: sub hasResource {
2102: my $self = shift;
2103: my $map = shift;
2104: my $filterFunc = shift;
2105: my $recursive = shift;
2106:
2107: return scalar($self->retrieveResources($map, $filterFunc, $recursive, 1)) > 0;
2108: }
2109:
2110: 1;
2111:
2112: package Apache::lonnavmaps::iterator;
2113:
2114: =pod
2115:
2116: =back
2117:
2118: =head1 Object: navmap Iterator
2119:
2120: An I<iterator> encapsulates the logic required to traverse a data
2121: structure. navmap uses an iterator to traverse the course map
2122: according to the criteria you wish to use.
2123:
2124: To obtain an iterator, call the B<getIterator>() function of a
2125: B<navmap> object. (Do not instantiate Apache::lonnavmaps::iterator
2126: directly.) This will return a reference to the iterator:
2127:
2128: C<my $resourceIterator = $navmap-E<gt>getIterator();>
2129:
2130: To get the next thing from the iterator, call B<next>:
2131:
2132: C<my $nextThing = $resourceIterator-E<gt>next()>
2133:
2134: getIterator behaves as follows:
2135:
2136: =over 4
2137:
2138: =item * B<getIterator>(firstResource, finishResource, filterHash, condition, forceTop, returnTopMap):
2139:
2140: All parameters are optional. firstResource is a resource reference
2141: corresponding to where the iterator should start. It defaults to
2142: navmap->firstResource() for the corresponding nav map. finishResource
2143: corresponds to where you want the iterator to end, defaulting to
2144: navmap->finishResource(). filterHash is a hash used as a set
2145: containing strings representing the resource IDs, defaulting to
2146: empty. Condition is a 1 or 0 that sets what to do with the filter
2147: hash: If a 0, then only resources that exist IN the filterHash will be
2148: recursed on. If it is a 1, only resources NOT in the filterHash will
2149: be recursed on. Defaults to 0. forceTop is a boolean value. If it is
2150: false (default), the iterator will only return the first level of map
2151: that is not just a single, 'redirecting' map. If true, the iterator
2152: will return all information, starting with the top-level map,
2153: regardless of content. returnTopMap, if true (default false), will
2154: cause the iterator to return the top-level map object (resource 0.0)
2155: before anything else.
2156:
2157: Thus, by default, only top-level resources will be shown. Change the
2158: condition to a 1 without changing the hash, and all resources will be
2159: shown. Changing the condition to 1 and including some values in the
2160: hash will allow you to selectively suppress parts of the navmap, while
2161: leaving it on 0 and adding things to the hash will allow you to
2162: selectively add parts of the nav map. See the handler code for
2163: examples.
2164:
2165: The iterator will return either a reference to a resource object, or a
2166: token representing something in the map, such as the beginning of a
2167: new branch. The possible tokens are:
2168:
2169: =over 4
2170:
2171: =item * BEGIN_MAP:
2172:
2173: A new map is being recursed into. This is returned I<after> the map
2174: resource itself is returned.
2175:
2176: =item * END_MAP:
2177:
2178: The map is now done.
2179:
2180: =item * BEGIN_BRANCH:
2181:
2182: A branch is now starting. The next resource returned will be the first
2183: in that branch.
2184:
2185: =item * END_BRANCH:
2186:
2187: The branch is now done.
2188:
2189: =back
2190:
2191: The tokens are retreivable via methods on the iterator object, i.e.,
2192: $iterator->END_MAP.
2193:
2194: Maps can contain empty resources. The iterator will automatically skip
2195: over such resources, but will still treat the structure
2196: correctly. Thus, a complicated map with several branches, but
2197: consisting entirely of empty resources except for one beginning or
2198: ending resource, will cause a lot of BRANCH_STARTs and BRANCH_ENDs,
2199: but only one resource will be returned.
2200:
2201: =back
2202:
2203: =cut
2204:
2205: # Here are the tokens for the iterator:
2206:
2207: sub BEGIN_MAP { return 1; } # begining of a new map
2208: sub END_MAP { return 2; } # end of the map
2209: sub BEGIN_BRANCH { return 3; } # beginning of a branch
2210: sub END_BRANCH { return 4; } # end of a branch
2211: sub FORWARD { return 1; } # go forward
2212: sub BACKWARD { return 2; }
2213:
2214: sub min {
2215: (my $a, my $b) = @_;
2216: if ($a < $b) { return $a; } else { return $b; }
2217: }
2218:
2219: # In the CVS repository, documentation of this algorithm is included
2220: # in /doc/lonnavdocs, as a PDF and .tex source. Markers like **1**
2221: # will reference the same location in the text as the part of the
2222: # algorithm is running through.
2223:
2224: sub new {
2225: # magic invocation to create a class instance
2226: my $proto = shift;
2227: my $class = ref($proto) || $proto;
2228: my $self = {};
2229:
2230: $self->{NAV_MAP} = shift;
2231: return undef unless ($self->{NAV_MAP});
2232:
2233: # Handle the parameters
2234: $self->{FIRST_RESOURCE} = shift || $self->{NAV_MAP}->firstResource();
2235: $self->{FINISH_RESOURCE} = shift || $self->{NAV_MAP}->finishResource();
2236:
2237: # If the given resources are just the ID of the resource, get the
2238: # objects
2239: if (!ref($self->{FIRST_RESOURCE})) { $self->{FIRST_RESOURCE} =
2240: $self->{NAV_MAP}->getById($self->{FIRST_RESOURCE}); }
2241: if (!ref($self->{FINISH_RESOURCE})) { $self->{FINISH_RESOURCE} =
2242: $self->{NAV_MAP}->getById($self->{FINISH_RESOURCE}); }
2243:
2244: $self->{FILTER} = shift;
2245:
2246: # A hash, used as a set, of resource already seen
2247: $self->{ALREADY_SEEN} = shift;
2248: if (!defined($self->{ALREADY_SEEN})) { $self->{ALREADY_SEEN} = {} };
2249: $self->{CONDITION} = shift;
2250:
2251: # Do we want to automatically follow "redirection" maps?
2252: $self->{FORCE_TOP} = shift;
2253:
2254: # Do we want to return the top-level map object (resource 0.0)?
2255: $self->{RETURN_0} = shift;
2256: # have we done that yet?
2257: $self->{HAVE_RETURNED_0} = 0;
2258:
2259: # Now, we need to pre-process the map, by walking forward and backward
2260: # over the parts of the map we're going to look at.
2261:
2262: # The processing steps are exactly the same, except for a few small
2263: # changes, so I bundle those up in the following list of two elements:
2264: # (direction_to_iterate, VAL_name, next_resource_method_to_call,
2265: # first_resource).
2266: # This prevents writing nearly-identical code twice.
2267: my @iterations = ( [FORWARD(), 'TOP_DOWN_VAL', 'getNext',
2268: 'FIRST_RESOURCE'],
2269: [BACKWARD(), 'BOT_UP_VAL', 'getPrevious',
2270: 'FINISH_RESOURCE'] );
2271:
2272: my $maxDepth = 0; # tracks max depth
2273:
2274: # If there is only one resource in this map, and it's a map, we
2275: # want to remember that, so the user can ask for the first map
2276: # that isn't just a redirector.
2277: my $resource; my $resourceCount = 0;
2278:
2279: # **1**
2280:
2281: foreach my $pass (@iterations) {
2282: my $direction = $pass->[0];
2283: my $valName = $pass->[1];
2284: my $nextResourceMethod = $pass->[2];
2285: my $firstResourceName = $pass->[3];
2286:
2287: my $iterator = Apache::lonnavmaps::DFSiterator->new($self->{NAV_MAP},
2288: $self->{FIRST_RESOURCE},
2289: $self->{FINISH_RESOURCE},
2290: {}, undef, 0, $direction);
2291:
2292: # prime the recursion
2293: $self->{$firstResourceName}->{DATA}->{$valName} = 0;
2294: my $depth = 0;
2295: $iterator->next();
2296: my $curRes = $iterator->next();
2297: while ($depth > -1) {
2298: if ($curRes == $iterator->BEGIN_MAP()) { $depth++; }
2299: if ($curRes == $iterator->END_MAP()) { $depth--; }
2300:
2301: if (ref($curRes)) {
2302: # If there's only one resource, this will save it
2303: # we have to filter empty resources from consideration here,
2304: # or even "empty", redirecting maps have two (start & finish)
2305: # or three (start, finish, plus redirector)
2306: if($direction == FORWARD && $curRes->src()) {
2307: $resource = $curRes; $resourceCount++;
2308: }
2309: my $resultingVal = $curRes->{DATA}->{$valName};
2310: my $nextResources = $curRes->$nextResourceMethod();
2311: my $nextCount = scalar(@{$nextResources});
2312:
2313: if ($nextCount == 1) { # **3**
2314: my $current = $nextResources->[0]->{DATA}->{$valName} || 999999999;
2315: $nextResources->[0]->{DATA}->{$valName} = min($resultingVal, $current);
2316: }
2317:
2318: if ($nextCount > 1) { # **4**
2319: foreach my $res (@{$nextResources}) {
2320: my $current = $res->{DATA}->{$valName} || 999999999;
2321: $res->{DATA}->{$valName} = min($current, $resultingVal + 1);
2322: }
2323: }
2324: }
2325:
2326: # Assign the final val (**2**)
2327: if (ref($curRes) && $direction == BACKWARD()) {
2328: my $finalDepth = min($curRes->{DATA}->{TOP_DOWN_VAL},
2329: $curRes->{DATA}->{BOT_UP_VAL});
2330:
2331: $curRes->{DATA}->{DISPLAY_DEPTH} = $finalDepth;
2332: if ($finalDepth > $maxDepth) {$maxDepth = $finalDepth;}
2333: }
2334: } continue {
2335: $curRes = $iterator->next();
2336: }
2337: }
2338:
2339: # Check: Was this only one resource, a map?
2340: if ($resourceCount == 1 && $resource->is_map() && !$self->{FORCE_TOP}) {
2341: my $firstResource = $resource->map_start();
2342: my $finishResource = $resource->map_finish();
2343: return
2344: Apache::lonnavmaps::iterator->new($self->{NAV_MAP}, $firstResource,
2345: $finishResource, $self->{FILTER},
2346: $self->{ALREADY_SEEN},
2347: $self->{CONDITION}, 0);
2348:
2349: }
2350:
2351: # Set up some bookkeeping information.
2352: $self->{CURRENT_DEPTH} = 0;
2353: $self->{MAX_DEPTH} = $maxDepth;
2354: $self->{STACK} = [];
2355: $self->{RECURSIVE_ITERATOR_FLAG} = 0;
2356:
2357: for (my $i = 0; $i <= $self->{MAX_DEPTH}; $i++) {
2358: push @{$self->{STACK}}, [];
2359: }
2360:
2361: # Prime the recursion w/ the first resource **5**
2362: push @{$self->{STACK}->[0]}, $self->{FIRST_RESOURCE};
2363: $self->{ALREADY_SEEN}->{$self->{FIRST_RESOURCE}->{ID}} = 1;
2364:
2365: bless ($self);
2366:
2367: return $self;
2368: }
2369:
2370: sub next {
2371: my $self = shift;
2372:
2373: # If we want to return the top-level map object, and haven't yet,
2374: # do so.
2375: if ($self->{RETURN_0} && !$self->{HAVE_RETURNED_0}) {
2376: $self->{HAVE_RETURNED_0} = 1;
2377: return $self->{NAV_MAP}->getById('0.0');
2378: }
2379:
2380: if ($self->{RECURSIVE_ITERATOR_FLAG}) {
2381: # grab the next from the recursive iterator
2382: my $next = $self->{RECURSIVE_ITERATOR}->next();
2383:
2384: # is it a begin or end map? If so, update the depth
2385: if ($next == BEGIN_MAP() ) { $self->{RECURSIVE_DEPTH}++; }
2386: if ($next == END_MAP() ) { $self->{RECURSIVE_DEPTH}--; }
2387:
2388: # Are we back at depth 0? If so, stop recursing
2389: if ($self->{RECURSIVE_DEPTH} == 0) {
2390: $self->{RECURSIVE_ITERATOR_FLAG} = 0;
2391: }
2392:
2393: return $next;
2394: }
2395:
2396: if (defined($self->{FORCE_NEXT})) {
2397: my $tmp = $self->{FORCE_NEXT};
2398: $self->{FORCE_NEXT} = undef;
2399: return $tmp;
2400: }
2401:
2402: # Have we not yet begun? If not, return BEGIN_MAP and
2403: # remember we've started.
2404: if ( !$self->{STARTED} ) {
2405: $self->{STARTED} = 1;
2406: return $self->BEGIN_MAP();
2407: }
2408:
2409: # Here's the guts of the iterator.
2410:
2411: # Find the next resource, if any.
2412: my $found = 0;
2413: my $i = $self->{MAX_DEPTH};
2414: my $newDepth;
2415: my $here;
2416: while ( $i >= 0 && !$found ) {
2417: if ( scalar(@{$self->{STACK}->[$i]}) > 0 ) { # **6**
2418: $here = pop @{$self->{STACK}->[$i]}; # **7**
2419: $found = 1;
2420: $newDepth = $i;
2421: }
2422: $i--;
2423: }
2424:
2425: # If we still didn't find anything, we're done.
2426: if ( !$found ) {
2427: # We need to get back down to the correct branch depth
2428: if ( $self->{CURRENT_DEPTH} > 0 ) {
2429: $self->{CURRENT_DEPTH}--;
2430: return END_BRANCH();
2431: } else {
2432: return END_MAP();
2433: }
2434: }
2435:
2436: # If this is not a resource, it must be an END_BRANCH marker we want
2437: # to return directly.
2438: if (!ref($here)) { # **8**
2439: if ($here == END_BRANCH()) { # paranoia, in case of later extension
2440: $self->{CURRENT_DEPTH}--;
2441: return $here;
2442: }
2443: }
2444:
2445: # Otherwise, it is a resource and it's safe to store in $self->{HERE}
2446: $self->{HERE} = $here;
2447:
2448: # Get to the right level
2449: if ( $self->{CURRENT_DEPTH} > $newDepth ) {
2450: push @{$self->{STACK}->[$newDepth]}, $here;
2451: $self->{CURRENT_DEPTH}--;
2452: return END_BRANCH();
2453: }
2454: if ( $self->{CURRENT_DEPTH} < $newDepth) {
2455: push @{$self->{STACK}->[$newDepth]}, $here;
2456: $self->{CURRENT_DEPTH}++;
2457: return BEGIN_BRANCH();
2458: }
2459:
2460: # If we made it here, we have the next resource, and we're at the
2461: # right branch level. So let's examine the resource for where
2462: # we can get to from here.
2463:
2464: # So we need to look at all the resources we can get to from here,
2465: # categorize them if we haven't seen them, remember if we have a new
2466: my $nextUnfiltered = $here->getNext();
2467: my $maxDepthAdded = -1;
2468:
2469: for (@$nextUnfiltered) {
2470: if (!defined($self->{ALREADY_SEEN}->{$_->{ID}})) {
2471: my $depth = $_->{DATA}->{DISPLAY_DEPTH};
2472: push @{$self->{STACK}->[$depth]}, $_;
2473: $self->{ALREADY_SEEN}->{$_->{ID}} = 1;
2474: if ($maxDepthAdded < $depth) { $maxDepthAdded = $depth; }
2475: }
2476: }
2477:
2478: # Is this the end of a branch? If so, all of the resources examined above
2479: # led to lower levels then the one we are currently at, so we push a END_BRANCH
2480: # marker onto the stack so we don't forget.
2481: # Example: For the usual A(BC)(DE)F case, when the iterator goes down the
2482: # BC branch and gets to C, it will see F as the only next resource, but it's
2483: # one level lower. Thus, this is the end of the branch, since there are no
2484: # more resources added to this level or above.
2485: # We don't do this if the examined resource is the finish resource,
2486: # because the condition given above is true, but the "END_MAP" will
2487: # take care of things and we should already be at depth 0.
2488: my $isEndOfBranch = $maxDepthAdded < $self->{CURRENT_DEPTH};
2489: if ($isEndOfBranch && $here != $self->{FINISH_RESOURCE}) { # **9**
2490: push @{$self->{STACK}->[$self->{CURRENT_DEPTH}]}, END_BRANCH();
2491: }
2492:
2493: # That ends the main iterator logic. Now, do we want to recurse
2494: # down this map (if this resource is a map)?
2495: if ($self->{HERE}->is_map() &&
2496: (defined($self->{FILTER}->{$self->{HERE}->map_pc()}) xor $self->{CONDITION})) {
2497: $self->{RECURSIVE_ITERATOR_FLAG} = 1;
2498: my $firstResource = $self->{HERE}->map_start();
2499: my $finishResource = $self->{HERE}->map_finish();
2500:
2501: $self->{RECURSIVE_ITERATOR} =
2502: Apache::lonnavmaps::iterator->new($self->{NAV_MAP}, $firstResource,
2503: $finishResource, $self->{FILTER},
2504: $self->{ALREADY_SEEN}, $self->{CONDITION});
2505: }
2506:
2507: # If this is a blank resource, don't actually return it.
2508: # Should you ever find you need it, make sure to add an option to the code
2509: # that you can use; other things depend on this behavior.
2510: my $browsePriv = $self->{HERE}->browsePriv();
2511: if (!$self->{HERE}->src() ||
2512: (!($browsePriv eq 'F') && !($browsePriv eq '2')) ) {
2513: return $self->next();
2514: }
2515:
2516: return $self->{HERE};
2517:
2518: }
2519:
2520: =pod
2521:
2522: The other method available on the iterator is B<getStack>, which
2523: returns an array populated with the current 'stack' of maps, as
2524: references to the resource objects. Example: This is useful when
2525: making the navigation map, as we need to check whether we are under a
2526: page map to see if we need to link directly to the resource, or to the
2527: page. The first elements in the array will correspond to the top of
2528: the stack (most inclusive map).
2529:
2530: =cut
2531:
2532: sub getStack {
2533: my $self=shift;
2534:
2535: my @stack;
2536:
2537: $self->populateStack(\@stack);
2538:
2539: return \@stack;
2540: }
2541:
2542: # Private method: Calls the iterators recursively to populate the stack.
2543: sub populateStack {
2544: my $self=shift;
2545: my $stack = shift;
2546:
2547: push @$stack, $self->{HERE} if ($self->{HERE});
2548:
2549: if ($self->{RECURSIVE_ITERATOR_FLAG}) {
2550: $self->{RECURSIVE_ITERATOR}->populateStack($stack);
2551: }
2552: }
2553:
2554: 1;
2555:
2556: package Apache::lonnavmaps::DFSiterator;
2557:
2558: # Not documented in the perldoc: This is a simple iterator that just walks
2559: # through the nav map and presents the resources in a depth-first search
2560: # fashion, ignorant of conditionals, randomized resources, etc. It presents
2561: # BEGIN_MAP and END_MAP, but does not understand branches at all. It is
2562: # useful for pre-processing of some kind, and is in fact used by the main
2563: # iterator that way, but that's about it.
2564: # One could imagine merging this into the init routine of the main iterator,
2565: # but this might as well be left seperate, since it is possible some other
2566: # use might be found for it. - Jeremy
2567:
2568: # Unlike the main iterator, this DOES return all resources, even blank ones.
2569: # The main iterator needs them to correctly preprocess the map.
2570:
2571: sub BEGIN_MAP { return 1; } # begining of a new map
2572: sub END_MAP { return 2; } # end of the map
2573: sub FORWARD { return 1; } # go forward
2574: sub BACKWARD { return 2; }
2575:
2576: # Params: Nav map ref, first resource id/ref, finish resource id/ref,
2577: # filter hash ref (or undef), already seen hash or undef, condition
2578: # (as in main iterator), direction FORWARD or BACKWARD (undef->forward).
2579: sub new {
2580: # magic invocation to create a class instance
2581: my $proto = shift;
2582: my $class = ref($proto) || $proto;
2583: my $self = {};
2584:
2585: $self->{NAV_MAP} = shift;
2586: return undef unless ($self->{NAV_MAP});
2587:
2588: $self->{FIRST_RESOURCE} = shift || $self->{NAV_MAP}->firstResource();
2589: $self->{FINISH_RESOURCE} = shift || $self->{NAV_MAP}->finishResource();
2590:
2591: # If the given resources are just the ID of the resource, get the
2592: # objects
2593: if (!ref($self->{FIRST_RESOURCE})) { $self->{FIRST_RESOURCE} =
2594: $self->{NAV_MAP}->getById($self->{FIRST_RESOURCE}); }
2595: if (!ref($self->{FINISH_RESOURCE})) { $self->{FINISH_RESOURCE} =
2596: $self->{NAV_MAP}->getById($self->{FINISH_RESOURCE}); }
2597:
2598: $self->{FILTER} = shift;
2599:
2600: # A hash, used as a set, of resource already seen
2601: $self->{ALREADY_SEEN} = shift;
2602: if (!defined($self->{ALREADY_SEEN})) { $self->{ALREADY_SEEN} = {} };
2603: $self->{CONDITION} = shift;
2604: $self->{DIRECTION} = shift || FORWARD();
2605:
2606: # Flag: Have we started yet?
2607: $self->{STARTED} = 0;
2608:
2609: # Should we continue calling the recursive iterator, if any?
2610: $self->{RECURSIVE_ITERATOR_FLAG} = 0;
2611: # The recursive iterator, if any
2612: $self->{RECURSIVE_ITERATOR} = undef;
2613: # Are we recursing on a map, or a branch?
2614: $self->{RECURSIVE_MAP} = 1; # we'll manually unset this when recursing on branches
2615: # And the count of how deep it is, so that this iterator can keep track of
2616: # when to pick back up again.
2617: $self->{RECURSIVE_DEPTH} = 0;
2618:
2619: # For keeping track of our branches, we maintain our own stack
2620: $self->{STACK} = [];
2621:
2622: # Start with the first resource
2623: if ($self->{DIRECTION} == FORWARD) {
2624: push @{$self->{STACK}}, $self->{FIRST_RESOURCE};
2625: } else {
2626: push @{$self->{STACK}}, $self->{FINISH_RESOURCE};
2627: }
2628:
2629: bless($self);
2630: return $self;
2631: }
2632:
2633: sub next {
2634: my $self = shift;
2635:
2636: # Are we using a recursive iterator? If so, pull from that and
2637: # watch the depth; we want to resume our level at the correct time.
2638: if ($self->{RECURSIVE_ITERATOR_FLAG}) {
2639: # grab the next from the recursive iterator
2640: my $next = $self->{RECURSIVE_ITERATOR}->next();
2641:
2642: # is it a begin or end map? Update depth if so
2643: if ($next == BEGIN_MAP() ) { $self->{RECURSIVE_DEPTH}++; }
2644: if ($next == END_MAP() ) { $self->{RECURSIVE_DEPTH}--; }
2645:
2646: # Are we back at depth 0? If so, stop recursing.
2647: if ($self->{RECURSIVE_DEPTH} == 0) {
2648: $self->{RECURSIVE_ITERATOR_FLAG} = 0;
2649: }
2650:
2651: return $next;
2652: }
2653:
2654: # Is there a current resource to grab? If not, then return
2655: # END_MAP, which will end the iterator.
2656: if (scalar(@{$self->{STACK}}) == 0) {
2657: return $self->END_MAP();
2658: }
2659:
2660: # Have we not yet begun? If not, return BEGIN_MAP and
2661: # remember that we've started.
2662: if ( !$self->{STARTED} ) {
2663: $self->{STARTED} = 1;
2664: return $self->BEGIN_MAP;
2665: }
2666:
2667: # Get the next resource in the branch
2668: $self->{HERE} = pop @{$self->{STACK}};
2669:
2670: # remember that we've seen this, so we don't return it again later
2671: $self->{ALREADY_SEEN}->{$self->{HERE}->{ID}} = 1;
2672:
2673: # Get the next possible resources
2674: my $nextUnfiltered;
2675: if ($self->{DIRECTION} == FORWARD()) {
2676: $nextUnfiltered = $self->{HERE}->getNext();
2677: } else {
2678: $nextUnfiltered = $self->{HERE}->getPrevious();
2679: }
2680: my $next = [];
2681:
2682: # filter the next possibilities to remove things we've
2683: # already seen.
2684: foreach (@$nextUnfiltered) {
2685: if (!defined($self->{ALREADY_SEEN}->{$_->{ID}})) {
2686: push @$next, $_;
2687: }
2688: }
2689:
2690: while (@$next) {
2691: # copy the next possibilities over to the stack
2692: push @{$self->{STACK}}, shift @$next;
2693: }
2694:
2695: # If this is a map and we want to recurse down it... (not filtered out)
2696: if ($self->{HERE}->is_map() &&
2697: (defined($self->{FILTER}->{$self->{HERE}->map_pc()}) xor $self->{CONDITION})) {
2698: $self->{RECURSIVE_ITERATOR_FLAG} = 1;
2699: my $firstResource = $self->{HERE}->map_start();
2700: my $finishResource = $self->{HERE}->map_finish();
2701:
2702: $self->{RECURSIVE_ITERATOR} =
2703: Apache::lonnavmaps::DFSiterator->new ($self->{NAV_MAP}, $firstResource,
2704: $finishResource, $self->{FILTER}, $self->{ALREADY_SEEN},
2705: $self->{CONDITION}, $self->{DIRECTION});
2706: }
2707:
2708: return $self->{HERE};
2709: }
2710:
2711: # Identical to the full iterator methods of the same name. Hate to copy/paste
2712: # but I also hate to "inherit" either iterator from the other.
2713:
2714: sub getStack {
2715: my $self=shift;
2716:
2717: my @stack;
2718:
2719: $self->populateStack(\@stack);
2720:
2721: return \@stack;
2722: }
2723:
2724: # Private method: Calls the iterators recursively to populate the stack.
2725: sub populateStack {
2726: my $self=shift;
2727: my $stack = shift;
2728:
2729: push @$stack, $self->{HERE} if ($self->{HERE});
2730:
2731: if ($self->{RECURSIVE_ITERATOR_FLAG}) {
2732: $self->{RECURSIVE_ITERATOR}->populateStack($stack);
2733: }
2734: }
2735:
2736: 1;
2737:
2738: package Apache::lonnavmaps::resource;
2739:
2740: use Apache::lonnet;
2741:
2742: =pod
2743:
2744: =head1 Object: resource
2745:
2746: A resource object encapsulates a resource in a resource map, allowing
2747: easy manipulation of the resource, querying the properties of the
2748: resource (including user properties), and represents a reference that
2749: can be used as the canonical representation of the resource by
2750: lonnavmap clients like renderers.
2751:
2752: A resource only makes sense in the context of a navmap, as some of the
2753: data is stored in the navmap object.
2754:
2755: You will probably never need to instantiate this object directly. Use
2756: Apache::lonnavmaps::navmap, and use the "start" method to obtain the
2757: starting resource.
2758:
2759: Resource objects respect the parameter_hiddenparts, which suppresses
2760: various parts according to the wishes of the map author. As of this
2761: writing, there is no way to override this parameter, and suppressed
2762: parts will never be returned, nor will their response types or ids be
2763: stored.
2764:
2765: =head2 Public Members
2766:
2767: resource objects have a hash called DATA ($resourceRef->{DATA}) that
2768: you can store whatever you want in. This allows you to easily do
2769: two-pass algorithms without worrying about managing your own
2770: resource->data hash.
2771:
2772: =head2 Methods
2773:
2774: =over 4
2775:
2776: =item * B<new>($navmapRef, $idString):
2777:
2778: The first arg is a reference to the parent navmap object. The second
2779: is the idString of the resource itself. Very rarely, if ever, called
2780: directly. Use the nav map->getByID() method.
2781:
2782: =back
2783:
2784: =cut
2785:
2786: sub new {
2787: # magic invocation to create a class instance
2788: my $proto = shift;
2789: my $class = ref($proto) || $proto;
2790: my $self = {};
2791:
2792: $self->{NAV_MAP} = shift;
2793: $self->{ID} = shift;
2794:
2795: # Store this new resource in the parent nav map's cache.
2796: $self->{NAV_MAP}->{RESOURCE_CACHE}->{$self->{ID}} = $self;
2797: $self->{RESOURCE_ERROR} = 0;
2798:
2799: # A hash that can be used by two-pass algorithms to store data
2800: # about this resource in. Not used by the resource object
2801: # directly.
2802: $self->{DATA} = {};
2803:
2804: bless($self);
2805:
2806: return $self;
2807: }
2808:
2809: # private function: simplify the NAV_HASH lookups we keep doing
2810: # pass the name, and to automatically append my ID, pass a true val on the
2811: # second param
2812: sub navHash {
2813: my $self = shift;
2814: my $param = shift;
2815: my $id = shift;
2816: return $self->{NAV_MAP}->navhash($param . ($id?$self->{ID}:""));
2817: }
2818:
2819: =pod
2820:
2821: B<Metadata Retreival>
2822:
2823: These are methods that help you retrieve metadata about the resource:
2824: Method names are based on the fields in the compiled course
2825: representation.
2826:
2827: =over 4
2828:
2829: =item * B<compTitle>:
2830:
2831: Returns a "composite title", that is equal to $res->title() if the
2832: resource has a title, and is otherwise the last part of the URL (e.g.,
2833: "problem.problem").
2834:
2835: =item * B<ext>:
2836:
2837: Returns true if the resource is external.
2838:
2839: =item * B<goesto>:
2840:
2841: Returns the "goesto" value from the compiled nav map. (It is likely
2842: you want to use B<getNext> instead.)
2843:
2844: =item * B<kind>:
2845:
2846: Returns the kind of the resource from the compiled nav map.
2847:
2848: =item * B<randomout>:
2849:
2850: Returns true if this resource was chosen to NOT be shown to the user
2851: by the random map selection feature. In other words, this is usually
2852: false.
2853:
2854: =item * B<randompick>:
2855:
2856: Returns true for a map if the randompick feature is being used on the
2857: map. (?)
2858:
2859: =item * B<src>:
2860:
2861: Returns the source for the resource.
2862:
2863: =item * B<symb>:
2864:
2865: Returns the symb for the resource.
2866:
2867: =item * B<title>:
2868:
2869: Returns the title of the resource.
2870:
2871: =item * B<to>:
2872:
2873: Returns the "to" value from the compiled nav map. (It is likely you
2874: want to use B<getNext> instead.)
2875:
2876: =back
2877:
2878: =cut
2879:
2880: # These info functions can be used directly, as they don't return
2881: # resource information.
2882: sub comesfrom { my $self=shift; return $self->navHash("comesfrom_", 1); }
2883: sub ext { my $self=shift; return $self->navHash("ext_", 1) eq 'true:'; }
2884: sub from { my $self=shift; return $self->navHash("from_", 1); }
2885: sub goesto { my $self=shift; return $self->navHash("goesto_", 1); }
2886: sub kind { my $self=shift; return $self->navHash("kind_", 1); }
2887: sub randomout { my $self=shift; return $self->navHash("randomout_", 1); }
2888: sub randompick {
2889: my $self = shift;
2890: return $self->{NAV_MAP}->{PARM_HASH}->{$self->symb .
2891: '.0.parameter_randompick'};
2892: }
2893: sub src {
2894: my $self=shift;
2895: return $self->navHash("src_", 1);
2896: }
2897: sub symb {
2898: my $self=shift;
2899: (my $first, my $second) = $self->{ID} =~ /(\d+).(\d+)/;
2900: my $symbSrc = &Apache::lonnet::declutter($self->src());
2901: return &Apache::lonnet::declutter(
2902: $self->navHash('map_id_'.$first))
2903: . '___' . $second . '___' . $symbSrc;
2904: }
2905: sub title { my $self=shift; return $self->navHash("title_", 1); }
2906: sub to { my $self=shift; return $self->navHash("to_", 1); }
2907: sub compTitle {
2908: my $self = shift;
2909: my $title = $self->title();
2910: $title=~s/\&colon\;/\:/gs;
2911: if (!$title) {
2912: $title = $self->src();
2913: $title = substr($title, rindex($title, '/') + 1);
2914: }
2915: return $title;
2916: }
2917: =pod
2918:
2919: B<Predicate Testing the Resource>
2920:
2921: These methods are shortcuts to deciding if a given resource has a given property.
2922:
2923: =over 4
2924:
2925: =item * B<is_map>:
2926:
2927: Returns true if the resource is a map type.
2928:
2929: =item * B<is_problem>:
2930:
2931: Returns true if the resource is a problem type, false
2932: otherwise. (Looks at the extension on the src field; might need more
2933: to work correctly.)
2934:
2935: =item * B<is_page>:
2936:
2937: Returns true if the resource is a page.
2938:
2939: =item * B<is_sequence>:
2940:
2941: Returns true if the resource is a sequence.
2942:
2943: =back
2944:
2945: =cut
2946:
2947:
2948: sub is_html {
2949: my $self=shift;
2950: my $src = $self->src();
2951: return ($src =~ /html$/);
2952: }
2953: sub is_map { my $self=shift; return defined($self->navHash("is_map_", 1)); }
2954: sub is_page {
2955: my $self=shift;
2956: my $src = $self->src();
2957: return $self->navHash("is_map_", 1) &&
2958: $self->navHash("map_type_" . $self->map_pc()) eq 'page';
2959: }
2960: sub is_problem {
2961: my $self=shift;
2962: my $src = $self->src();
2963: return ($src =~ /problem$/);
2964: }
2965: sub is_sequence {
2966: my $self=shift;
2967: my $src = $self->src();
2968: return $self->navHash("is_map_", 1) &&
2969: $self->navHash("map_type_" . $self->map_pc()) eq 'sequence';
2970: }
2971:
2972: # Private method: Shells out to the parmval in the nav map, handler parts.
2973: sub parmval {
2974: my $self = shift;
2975: my $what = shift;
2976: my $part = shift;
2977: if (!defined($part)) {
2978: $part = '0';
2979: }
2980: return $self->{NAV_MAP}->parmval($part.'.'.$what, $self->symb());
2981: }
2982:
2983: =pod
2984:
2985: B<Map Methods>
2986:
2987: These methods are useful for getting information about the map
2988: properties of the resource, if the resource is a map (B<is_map>).
2989:
2990: =over 4
2991:
2992: =item * B<map_finish>:
2993:
2994: Returns a reference to a resource object corresponding to the finish
2995: resource of the map.
2996:
2997: =item * B<map_pc>:
2998:
2999: Returns the pc value of the map, which is the first number that
3000: appears in the resource ID of the resources in the map, and is the
3001: number that appears around the middle of the symbs of the resources in
3002: that map.
3003:
3004: =item * B<map_start>:
3005:
3006: Returns a reference to a resource object corresponding to the start
3007: resource of the map.
3008:
3009: =item * B<map_type>:
3010:
3011: Returns a string with the type of the map in it.
3012:
3013: =back
3014:
3015: =cut
3016:
3017: sub map_finish {
3018: my $self = shift;
3019: my $src = $self->src();
3020: $src = Apache::lonnet::clutter($src);
3021: my $res = $self->navHash("map_finish_$src", 0);
3022: $res = $self->{NAV_MAP}->getById($res);
3023: return $res;
3024: }
3025: sub map_pc {
3026: my $self = shift;
3027: my $src = $self->src();
3028: return $self->navHash("map_pc_$src", 0);
3029: }
3030: sub map_start {
3031: my $self = shift;
3032: my $src = $self->src();
3033: $src = Apache::lonnet::clutter($src);
3034: my $res = $self->navHash("map_start_$src", 0);
3035: $res = $self->{NAV_MAP}->getById($res);
3036: return $res;
3037: }
3038: sub map_type {
3039: my $self = shift;
3040: my $pc = $self->map_pc();
3041: return $self->navHash("map_type_$pc", 0);
3042: }
3043:
3044: #####
3045: # Property queries
3046: #####
3047:
3048: # These functions will be responsible for returning the CORRECT
3049: # VALUE for the parameter, no matter what. So while they may look
3050: # like direct calls to parmval, they can be more then that.
3051: # So, for instance, the duedate function should use the "duedatetype"
3052: # information, rather then the resource object user.
3053:
3054: =pod
3055:
3056: =head2 Resource Parameters
3057:
3058: In order to use the resource parameters correctly, the nav map must
3059: have been instantiated with genCourseAndUserOptions set to true, so
3060: the courseopt and useropt is read correctly. Then, you can call these
3061: functions to get the relevant parameters for the resource. Each
3062: function defaults to part "0", but can be directed to another part by
3063: passing the part as the parameter.
3064:
3065: These methods are responsible for getting the parameter correct, not
3066: merely reflecting the contents of the GDBM hashes. As we move towards
3067: dates relative to other dates, these methods should be updated to
3068: reflect that. (Then, anybody using these methods will not have to update
3069: their code.)
3070:
3071: =over 4
3072:
3073: =item * B<acc>:
3074:
3075: Get the Client IP/Name Access Control information.
3076:
3077: =item * B<answerdate>:
3078:
3079: Get the answer-reveal date for the problem.
3080:
3081: =item * B<duedate>:
3082:
3083: Get the due date for the problem.
3084:
3085: =item * B<tries>:
3086:
3087: Get the number of tries the student has used on the problem.
3088:
3089: =item * B<maxtries>:
3090:
3091: Get the number of max tries allowed.
3092:
3093: =item * B<opendate>:
3094:
3095: Get the open date for the problem.
3096:
3097: =item * B<sig>:
3098:
3099: Get the significant figures setting.
3100:
3101: =item * B<tol>:
3102:
3103: Get the tolerance for the problem.
3104:
3105: =item * B<tries>:
3106:
3107: Get the number of tries the user has already used on the problem.
3108:
3109: =item * B<type>:
3110:
3111: Get the question type for the problem.
3112:
3113: =item * B<weight>:
3114:
3115: Get the weight for the problem.
3116:
3117: =back
3118:
3119: =cut
3120:
3121: sub acc {
3122: (my $self, my $part) = @_;
3123: return $self->parmval("acc", $part);
3124: }
3125: sub answerdate {
3126: (my $self, my $part) = @_;
3127: # Handle intervals
3128: if ($self->parmval("answerdate.type", $part) eq 'date_interval') {
3129: return $self->duedate($part) +
3130: $self->parmval("answerdate", $part);
3131: }
3132: return $self->parmval("answerdate", $part);
3133: }
3134: sub awarded { my $self = shift; return $self->queryRestoreHash('awarded', shift); }
3135: sub duedate {
3136: (my $self, my $part) = @_;
3137: return $self->parmval("duedate", $part);
3138: }
3139: sub maxtries {
3140: (my $self, my $part) = @_;
3141: return $self->parmval("maxtries", $part);
3142: }
3143: sub opendate {
3144: (my $self, my $part) = @_;
3145: if ($self->parmval("opendate.type", $part) eq 'date_interval') {
3146: return $self->duedate($part) -
3147: $self->parmval("opendate", $part);
3148: }
3149: return $self->parmval("opendate");
3150: }
3151: sub problemstatus {
3152: (my $self, my $part) = @_;
3153: return $self->parmval("problemstatus", $part);
3154: }
3155: sub sig {
3156: (my $self, my $part) = @_;
3157: return $self->parmval("sig", $part);
3158: }
3159: sub tol {
3160: (my $self, my $part) = @_;
3161: return $self->parmval("tol", $part);
3162: }
3163: sub tries {
3164: my $self = shift;
3165: my $tries = $self->queryRestoreHash('tries', shift);
3166: if (!defined($tries)) { return '0';}
3167: return $tries;
3168: }
3169: sub type {
3170: (my $self, my $part) = @_;
3171: return $self->parmval("type", $part);
3172: }
3173: sub weight {
3174: my $self = shift; my $part = shift;
3175: return $self->parmval("weight", $part);
3176: }
3177:
3178: # Multiple things need this
3179: sub getReturnHash {
3180: my $self = shift;
3181:
3182: if (!defined($self->{RETURN_HASH})) {
3183: my %tmpHash = &Apache::lonnet::restore($self->symb());
3184: $self->{RETURN_HASH} = \%tmpHash;
3185: }
3186: }
3187:
3188: ######
3189: # Status queries
3190: ######
3191:
3192: # These methods query the status of problems.
3193:
3194: # If we need to count parts, this function determines the number of
3195: # parts from the metadata. When called, it returns a reference to a list
3196: # of strings corresponding to the parts. (Thus, using it in a scalar context
3197: # tells you how many parts you have in the problem:
3198: # $partcount = scalar($resource->countParts());
3199: # Don't use $self->{PARTS} directly because you don't know if it's been
3200: # computed yet.
3201:
3202: =pod
3203:
3204: =head2 Resource misc
3205:
3206: Misc. functions for the resource.
3207:
3208: =over 4
3209:
3210: =item * B<hasDiscussion>:
3211:
3212: Returns a false value if there has been discussion since the user last
3213: logged in, true if there has. Always returns false if the discussion
3214: data was not extracted when the nav map was constructed.
3215:
3216: =item * B<getFeedback>:
3217:
3218: Gets the feedback for the resource and returns the raw feedback string
3219: for the resource, or the null string if there is no feedback or the
3220: email data was not extracted when the nav map was constructed. Usually
3221: used like this:
3222:
3223: for (split(/\,/, $res->getFeedback())) {
3224: my $link = &Apache::lonnet::escape($_);
3225: ...
3226:
3227: and use the link as appropriate.
3228:
3229: =cut
3230:
3231: sub hasDiscussion {
3232: my $self = shift;
3233: return $self->{NAV_MAP}->hasDiscussion($self->symb());
3234: }
3235:
3236: sub getFeedback {
3237: my $self = shift;
3238: my $source = $self->src();
3239: if ($source =~ /^\/res\//) { $source = substr $source, 5; }
3240: return $self->{NAV_MAP}->getFeedback($source);
3241: }
3242:
3243: sub getErrors {
3244: my $self = shift;
3245: my $source = $self->src();
3246: if ($source =~ /^\/res\//) { $source = substr $source, 5; }
3247: return $self->{NAV_MAP}->getErrors($source);
3248: }
3249:
3250: =pod
3251:
3252: =item * B<parts>():
3253:
3254: Returns a list reference containing sorted strings corresponding to
3255: each part of the problem. Single part problems have only a part '0'.
3256: Multipart problems do not return their part '0', since they typically
3257: do not really matter.
3258:
3259: =item * B<countParts>():
3260:
3261: Returns the number of parts of the problem a student can answer. Thus,
3262: for single part problems, returns 1. For multipart, it returns the
3263: number of parts in the problem, not including psuedo-part 0.
3264:
3265: =item * B<multipart>():
3266:
3267: Returns true if the problem is multipart, false otherwise. Use this instead
3268: of countParts if all you want is multipart/not multipart.
3269:
3270: =item * B<responseType>($part):
3271:
3272: Returns the response type of the part, without the word "response" on the
3273: end. Example return values: 'string', 'essay', 'numeric', etc.
3274:
3275: =item * B<responseIds>($part):
3276:
3277: Retreives the response IDs for the given part as an array reference containing
3278: strings naming the response IDs. This may be empty.
3279:
3280: =back
3281:
3282: =cut
3283:
3284: sub parts {
3285: my $self = shift;
3286:
3287: if ($self->ext) { return []; }
3288:
3289: $self->extractParts();
3290: return $self->{PARTS};
3291: }
3292:
3293: sub countParts {
3294: my $self = shift;
3295:
3296: my $parts = $self->parts();
3297:
3298: # If I left this here, then it's not necessary.
3299: #my $delta = 0;
3300: #for my $part (@$parts) {
3301: # if ($part eq '0') { $delta--; }
3302: #}
3303:
3304: if ($self->{RESOURCE_ERROR}) {
3305: return 0;
3306: }
3307:
3308: return scalar(@{$parts}); # + $delta;
3309: }
3310:
3311: sub multipart {
3312: my $self = shift;
3313: return $self->countParts() > 1;
3314: }
3315:
3316: sub responseType {
3317: my $self = shift;
3318: my $part = shift;
3319:
3320: $self->extractParts();
3321: return $self->{RESPONSE_TYPE}->{$part};
3322: }
3323:
3324: sub responseIds {
3325: my $self = shift;
3326: my $part = shift;
3327:
3328: $self->extractParts();
3329: return $self->{RESPONSE_IDS}->{$part};
3330: }
3331:
3332: # Private function: Extracts the parts information, both part names and
3333: # part types, and saves it.
3334: sub extractParts {
3335: my $self = shift;
3336:
3337: return if (defined($self->{PARTS}));
3338: return if ($self->ext);
3339:
3340: $self->{PARTS} = [];
3341:
3342: my %parts;
3343:
3344: # Retrieve part count, if this is a problem
3345: if ($self->is_problem()) {
3346: my $metadata = &Apache::lonnet::metadata($self->src(), 'packages');
3347: if (!$metadata) {
3348: $self->{RESOURCE_ERROR} = 1;
3349: $self->{PARTS} = [];
3350: $self->{PART_TYPE} = {};
3351: return;
3352: }
3353: foreach (split(/\,/,$metadata)) {
3354: if ($_ =~ /^part_(.*)$/) {
3355: my $part = $1;
3356: # This floods the logs if it blows up
3357: if (defined($parts{$part})) {
3358: Apache::lonnet::logthis("$part multiply defined in metadata for " . $self->symb());
3359: }
3360:
3361: # check to see if part is turned off.
3362:
3363: if (!Apache::loncommon::check_if_partid_hidden($part, $self->symb())) {
3364: $parts{$part} = 1;
3365: }
3366: }
3367: }
3368:
3369:
3370: my @sortedParts = sort keys %parts;
3371: $self->{PARTS} = \@sortedParts;
3372:
3373: my %responseIdHash;
3374: my %responseTypeHash;
3375:
3376:
3377: # Init the responseIdHash
3378: foreach (@{$self->{PARTS}}) {
3379: $responseIdHash{$_} = [];
3380: }
3381:
3382: # Now, the unfortunate thing about this is that parts, part name, and
3383: # response if are delimited by underscores, but both the part
3384: # name and response id can themselves have underscores in them.
3385: # So we have to use our knowlege of part names to figure out
3386: # where the part names begin and end, and even then, it is possible
3387: # to construct ambiguous situations.
3388: foreach (split /,/, $metadata) {
3389: if ($_ =~ /^([a-zA-Z]+)response_(.*)/) {
3390: my $responseType = $1;
3391: my $partStuff = $2;
3392: my $partIdSoFar = '';
3393: my @partChunks = split /_/, $partStuff;
3394: my $i = 0;
3395:
3396: for ($i = 0; $i < scalar(@partChunks); $i++) {
3397: if ($partIdSoFar) { $partIdSoFar .= '_'; }
3398: $partIdSoFar .= $partChunks[$i];
3399: if ($parts{$partIdSoFar}) {
3400: my @otherChunks = @partChunks[$i+1..$#partChunks];
3401: my $responseId = join('_', @otherChunks);
3402: push @{$responseIdHash{$partIdSoFar}}, $responseId;
3403: $responseTypeHash{$partIdSoFar} = $responseType;
3404: last;
3405: }
3406: }
3407: }
3408: }
3409:
3410: $self->{RESPONSE_IDS} = \%responseIdHash;
3411: $self->{RESPONSE_TYPES} = \%responseTypeHash;
3412: }
3413:
3414: return;
3415: }
3416:
3417: =pod
3418:
3419: =head2 Resource Status
3420:
3421: Problem resources have status information, reflecting their various
3422: dates and completion statuses.
3423:
3424: There are two aspects to the status: the date-related information and
3425: the completion information.
3426:
3427: Idiomatic usage of these two methods would probably look something
3428: like
3429:
3430: foreach ($resource->parts()) {
3431: my $dateStatus = $resource->getDateStatus($_);
3432: my $completionStatus = $resource->getCompletionStatus($_);
3433:
3434: or
3435:
3436: my $status = $resource->status($_);
3437:
3438: ... use it here ...
3439: }
3440:
3441: Which you use depends on exactly what you are looking for. The
3442: status() function has been optimized for the nav maps display and may
3443: not precisely match what you need elsewhere.
3444:
3445: The symbolic constants shown below can be accessed through the
3446: resource object: C<$res->OPEN>.
3447:
3448: =over 4
3449:
3450: =item * B<getDateStatus>($part):
3451:
3452: ($part defaults to 0). A convenience function that returns a symbolic
3453: constant telling you about the date status of the part. The possible
3454: return values are:
3455:
3456: =back
3457:
3458: B<Date Codes>
3459:
3460: =over 4
3461:
3462: =item * B<OPEN_LATER>:
3463:
3464: The problem will be opened later.
3465:
3466: =item * B<OPEN>:
3467:
3468: Open and not yet due.
3469:
3470:
3471: =item * B<PAST_DUE_ANSWER_LATER>:
3472:
3473: The due date has passed, but the answer date has not yet arrived.
3474:
3475: =item * B<PAST_DUE_NO_ANSWER>:
3476:
3477: The due date has passed and there is no answer opening date set.
3478:
3479: =item * B<ANSWER_OPEN>:
3480:
3481: The answer date is here.
3482:
3483: =item * B<NETWORK_FAILURE>:
3484:
3485: The information is unknown due to network failure.
3486:
3487: =back
3488:
3489: =cut
3490:
3491: # Apparently the compiler optimizes these into constants automatically
3492: sub OPEN_LATER { return 0; }
3493: sub OPEN { return 1; }
3494: sub PAST_DUE_NO_ANSWER { return 2; }
3495: sub PAST_DUE_ANSWER_LATER { return 3; }
3496: sub ANSWER_OPEN { return 4; }
3497: sub NOTHING_SET { return 5; }
3498: sub NETWORK_FAILURE { return 100; }
3499:
3500: # getDateStatus gets the date status for a given problem part.
3501: # Because answer date, due date, and open date are fully independent
3502: # (i.e., it is perfectly possible to *only* have an answer date),
3503: # we have to completely cover the 3x3 maxtrix of (answer, due, open) x
3504: # (past, future, none given). This function handles this with a decision
3505: # tree. Read the comments to follow the decision tree.
3506:
3507: sub getDateStatus {
3508: my $self = shift;
3509: my $part = shift;
3510: $part = "0" if (!defined($part));
3511:
3512: # Always return network failure if there was one.
3513: return $self->NETWORK_FAILURE if ($self->{NAV_MAP}->{NETWORK_FAILURE});
3514:
3515: my $now = time();
3516:
3517: my $open = $self->opendate($part);
3518: my $due = $self->duedate($part);
3519: my $answer = $self->answerdate($part);
3520:
3521: if (!$open && !$due && !$answer) {
3522: # no data on the problem at all
3523: # should this be the same as "open later"? think multipart.
3524: return $self->NOTHING_SET;
3525: }
3526: if (!$open || $now < $open) {return $self->OPEN_LATER}
3527: if (!$due || $now < $due) {return $self->OPEN}
3528: if ($answer && $now < $answer) {return $self->PAST_DUE_ANSWER_LATER}
3529: if ($answer) { return $self->ANSWER_OPEN; }
3530: return PAST_DUE_NO_ANSWER;
3531: }
3532:
3533: =pod
3534:
3535: B<>
3536:
3537: =over 4
3538:
3539: =item * B<getCompletionStatus>($part):
3540:
3541: ($part defaults to 0.) A convenience function that returns a symbolic
3542: constant telling you about the completion status of the part, with the
3543: following possible results:
3544:
3545: =back
3546:
3547: B<Completion Codes>
3548:
3549: =over 4
3550:
3551: =item * B<NOT_ATTEMPTED>:
3552:
3553: Has not been attempted at all.
3554:
3555: =item * B<INCORRECT>:
3556:
3557: Attempted, but wrong by student.
3558:
3559: =item * B<INCORRECT_BY_OVERRIDE>:
3560:
3561: Attempted, but wrong by instructor override.
3562:
3563: =item * B<CORRECT>:
3564:
3565: Correct or correct by instructor.
3566:
3567: =item * B<CORRECT_BY_OVERRIDE>:
3568:
3569: Correct by instructor override.
3570:
3571: =item * B<EXCUSED>:
3572:
3573: Excused. Not yet implemented.
3574:
3575: =item * B<NETWORK_FAILURE>:
3576:
3577: Information not available due to network failure.
3578:
3579: =item * B<ATTEMPTED>:
3580:
3581: Attempted, and not yet graded.
3582:
3583: =back
3584:
3585: =cut
3586:
3587: sub NOT_ATTEMPTED { return 10; }
3588: sub INCORRECT { return 11; }
3589: sub INCORRECT_BY_OVERRIDE { return 12; }
3590: sub CORRECT { return 13; }
3591: sub CORRECT_BY_OVERRIDE { return 14; }
3592: sub EXCUSED { return 15; }
3593: sub ATTEMPTED { return 16; }
3594:
3595: sub getCompletionStatus {
3596: my $self = shift;
3597: return $self->NETWORK_FAILURE if ($self->{NAV_MAP}->{NETWORK_FAILURE});
3598:
3599: my $status = $self->queryRestoreHash('solved', shift);
3600:
3601: # Left as seperate if statements in case we ever do more with this
3602: if ($status eq 'correct_by_student') {return $self->CORRECT;}
3603: if ($status eq 'correct_by_override') {return $self->CORRECT_BY_OVERRIDE; }
3604: if ($status eq 'incorrect_attempted') {return $self->INCORRECT; }
3605: if ($status eq 'incorrect_by_override') {return $self->INCORRECT_BY_OVERRIDE; }
3606: if ($status eq 'excused') {return $self->EXCUSED; }
3607: if ($status eq 'ungraded_attempted') {return $self->ATTEMPTED; }
3608: return $self->NOT_ATTEMPTED;
3609: }
3610:
3611: sub queryRestoreHash {
3612: my $self = shift;
3613: my $hashentry = shift;
3614: my $part = shift;
3615: $part = "0" if (!defined($part) || $part eq '');
3616: return $self->NETWORK_FAILURE if ($self->{NAV_MAP}->{NETWORK_FAILURE});
3617:
3618: $self->getReturnHash();
3619:
3620: return $self->{RETURN_HASH}->{'resource.'.$part.'.'.$hashentry};
3621: }
3622:
3623: =pod
3624:
3625: B<Composite Status>
3626:
3627: Along with directly returning the date or completion status, the
3628: resource object includes a convenience function B<status>() that will
3629: combine the two status tidbits into one composite status that can
3630: represent the status of the resource as a whole. This method represents
3631: the concept of the thing we want to display to the user on the nav maps
3632: screen, which is a combination of completion and open status. The precise logic is
3633: documented in the comments of the status method. The following results
3634: may be returned, all available as methods on the resource object
3635: ($res->NETWORK_FAILURE): In addition to the return values that match
3636: the date or completion status, this function can return "ANSWER_SUBMITTED"
3637: if that problemstatus parameter value is set to No, suppressing the
3638: incorrect/correct feedback.
3639:
3640: =over 4
3641:
3642: =item * B<NETWORK_FAILURE>:
3643:
3644: The network has failed and the information is not available.
3645:
3646: =item * B<NOTHING_SET>:
3647:
3648: No dates have been set for this problem (part) at all. (Because only
3649: certain parts of a multi-part problem may be assigned, this can not be
3650: collapsed into "open later", as we do not know a given part will EVER
3651: be opened. For single part, this is the same as "OPEN_LATER".)
3652:
3653: =item * B<CORRECT>:
3654:
3655: For any reason at all, the part is considered correct.
3656:
3657: =item * B<EXCUSED>:
3658:
3659: For any reason at all, the problem is excused.
3660:
3661: =item * B<PAST_DUE_NO_ANSWER>:
3662:
3663: The problem is past due, not considered correct, and no answer date is
3664: set.
3665:
3666: =item * B<PAST_DUE_ANSWER_LATER>:
3667:
3668: The problem is past due, not considered correct, and an answer date in
3669: the future is set.
3670:
3671: =item * B<ANSWER_OPEN>:
3672:
3673: The problem is past due, not correct, and the answer is now available.
3674:
3675: =item * B<OPEN_LATER>:
3676:
3677: The problem is not yet open.
3678:
3679: =item * B<TRIES_LEFT>:
3680:
3681: The problem is open, has been tried, is not correct, but there are
3682: tries left.
3683:
3684: =item * B<INCORRECT>:
3685:
3686: The problem is open, and all tries have been used without getting the
3687: correct answer.
3688:
3689: =item * B<OPEN>:
3690:
3691: The item is open and not yet tried.
3692:
3693: =item * B<ATTEMPTED>:
3694:
3695: The problem has been attempted.
3696:
3697: =item * B<ANSWER_SUBMITTED>:
3698:
3699: An answer has been submitted, but the student should not see it.
3700:
3701: =back
3702:
3703: =cut
3704:
3705: sub TRIES_LEFT { return 20; }
3706: sub ANSWER_SUBMITTED { return 21; }
3707:
3708: sub status {
3709: my $self = shift;
3710: my $part = shift;
3711: if (!defined($part)) { $part = "0"; }
3712: my $completionStatus = $self->getCompletionStatus($part);
3713: my $dateStatus = $self->getDateStatus($part);
3714:
3715: # What we have is a two-dimensional matrix with 4 entries on one
3716: # dimension and 5 entries on the other, which we want to colorize,
3717: # plus network failure and "no date data at all".
3718:
3719: if ($completionStatus == NETWORK_FAILURE) { return NETWORK_FAILURE; }
3720:
3721: my $suppressFeedback = lc($self->parmval("problemstatus", $part)) eq 'no';
3722:
3723: # There are a few whole rows we can dispose of:
3724: if ($completionStatus == CORRECT ||
3725: $completionStatus == CORRECT_BY_OVERRIDE ) {
3726: return $suppressFeedback? ANSWER_SUBMITTED : CORRECT;
3727: }
3728:
3729: if ($completionStatus == ATTEMPTED) {
3730: return ATTEMPTED;
3731: }
3732:
3733: # If it's EXCUSED, then return that no matter what
3734: if ($completionStatus == EXCUSED) {
3735: return EXCUSED;
3736: }
3737:
3738: if ($dateStatus == NOTHING_SET) {
3739: return NOTHING_SET;
3740: }
3741:
3742: # Now we're down to a 4 (incorrect, incorrect_override, not_attempted)
3743: # by 4 matrix (date statuses).
3744:
3745: if ($dateStatus == PAST_DUE_ANSWER_LATER ||
3746: $dateStatus == PAST_DUE_NO_ANSWER ) {
3747: return $dateStatus;
3748: }
3749:
3750: if ($dateStatus == ANSWER_OPEN) {
3751: return ANSWER_OPEN;
3752: }
3753:
3754: # Now: (incorrect, incorrect_override, not_attempted) x
3755: # (open_later), (open)
3756:
3757: if ($dateStatus == OPEN_LATER) {
3758: return OPEN_LATER;
3759: }
3760:
3761: # If it's WRONG...
3762: if ($completionStatus == INCORRECT || $completionStatus == INCORRECT_BY_OVERRIDE) {
3763: # and there are TRIES LEFT:
3764: if ($self->tries($part) < $self->maxtries($part) || !$self->maxtries($part)) {
3765: return TRIES_LEFT;
3766: }
3767: return $suppressFeedback ? ANSWER_SUBMITTED : INCORRECT; # otherwise, return orange; student can't fix this
3768: }
3769:
3770: # Otherwise, it's untried and open
3771: return OPEN;
3772: }
3773:
3774: =pod
3775:
3776: B<Completable>
3777:
3778: The completable method represents the concept of I<whether the student can
3779: currently do the problem>. If the student can do the problem, which means
3780: that it is open, there are tries left, and if the problem is manually graded
3781: or the grade is suppressed via problemstatus, the student has not tried it
3782: yet, then the method returns 1. Otherwise, it returns 0, to indicate that
3783: either the student has tried it and there is no feedback, or that for
3784: some reason it is no longer completable (not open yet, successfully completed,
3785: out of tries, etc.). As an example, this is used as the filter for the
3786: "Uncompleted Homework" option for the nav maps.
3787:
3788: If this does not quite meet your needs, do not fiddle with it (unless you are
3789: fixing it to better match the student's conception of "completable" because
3790: it's broken somehow)... make a new method.
3791:
3792: =cut
3793:
3794: sub completable {
3795: my $self = shift;
3796: if (!$self->is_problem()) { return 0; }
3797: my $partCount = $self->countParts();
3798:
3799: foreach my $part (@{$self->parts()}) {
3800: if ($part eq '0' && $partCount != 1) { next; }
3801: my $status = $self->status($part);
3802: # "If any of the parts are open, or have tries left (implies open),
3803: # and it is not "attempted" (manually graded problem), it is
3804: # not "complete"
3805: if (!(($status == OPEN() || $status == TRIES_LEFT())
3806: && $self->getCompletionStatus($part) != ATTEMPTED()
3807: && $status != ANSWER_SUBMITTED())) {
3808: return 0;
3809: }
3810: }
3811:
3812: # If all the parts were complete, so was this problem.
3813: return 1;
3814: }
3815:
3816: =pod
3817:
3818: =head2 Resource/Nav Map Navigation
3819:
3820: =over 4
3821:
3822: =item * B<getNext>():
3823:
3824: Retreive an array of the possible next resources after this
3825: one. Always returns an array, even in the one- or zero-element case.
3826:
3827: =item * B<getPrevious>():
3828:
3829: Retreive an array of the possible previous resources from this
3830: one. Always returns an array, even in the one- or zero-element case.
3831:
3832: =cut
3833:
3834: sub getNext {
3835: my $self = shift;
3836: my @branches;
3837: my $to = $self->to();
3838: foreach my $branch ( split(/,/, $to) ) {
3839: my $choice = $self->{NAV_MAP}->getById($branch);
3840: my $next = $choice->goesto();
3841: $next = $self->{NAV_MAP}->getById($next);
3842:
3843: push @branches, $next;
3844: }
3845: return \@branches;
3846: }
3847:
3848: sub getPrevious {
3849: my $self = shift;
3850: my @branches;
3851: my $from = $self->from();
3852: foreach my $branch ( split /,/, $from) {
3853: my $choice = $self->{NAV_MAP}->getById($branch);
3854: my $prev = $choice->comesfrom();
3855: $prev = $self->{NAV_MAP}->getById($prev);
3856:
3857: push @branches, $prev;
3858: }
3859: return \@branches;
3860: }
3861:
3862: sub browsePriv {
3863: my $self = shift;
3864: if (defined($self->{BROWSE_PRIV})) {
3865: return $self->{BROWSE_PRIV};
3866: }
3867:
3868: $self->{BROWSE_PRIV} = &Apache::lonnet::allowed('bre', $self->src());
3869: }
3870:
3871: =pod
3872:
3873: =back
3874:
3875: =cut
3876:
3877: 1;
3878:
3879: __END__
3880:
3881:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to lonnavmaps.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / interface