Return to lonnotify.pm CVS log

Up to [LON-CAPA] / loncom / interface

Improvements to echo_form_input() and addition of set_form_elements() to facilitate movement back through a multi-page form using breadcrumb trail.  This type of use is implemented in lonnotify.

#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#
                                                                                
package Apache::lonnotify;
                                                                                
use strict;
use Apache::lonnet;
use Apache::loncommon;
use Apache::lonsupportreq;
use LONCAPA::Enrollment;
use Apache::Constants qw(:common :http);
use Apache::lonlocal;
use Mail::Send;
use HTML::TokeParser;
use HTML::Entities;

sub handler {
    my ($r) = @_;
    &Apache::loncommon::content_type($r,'text/html');
    $r->send_http_header;

    if ($r->header_only) {
        return OK;
    }
    my $cdom = $env{'request.role.domain'};
    unless (&Apache::lonnet::allowed('psa',$cdom)) {
        # Not allowed to broadcast e-mail system-wide 
        $env{'user.error.msg'}="/adm/notify:psa:0:0:Cannot broadcast e-mail systemwide";
        return HTTP_NOT_ACCEPTABLE;
    }

    &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},
                                            ['command']);
    my $command = $env{'form.command'};
    my $origin = $env{'form.origin'};

    &Apache::lonhtmlcommon::clear_breadcrumbs();
    my %ltext=&Apache::lonlocal::texthash(
               'note' => 'Notification E-mail',
    );
    my $function = &Apache::loncommon::get_users_function();
    my $loadcode;
    my $tablecolor = &Apache::loncommon::designparm($function.'.tabbg');
    if ((defined($env{'form.origin'})) && ($command eq 'compose' || $command eq 'pick_target' || $command eq 'pick_display')) {
        unless ($env{'form.origin'} eq '') {
            $loadcode = 'javascript:setFormElements(document.'.$env{'form.command'}.')';
            if (($command eq 'pick_target') && (
                     ($origin eq 'compose') || ($origin eq 'process'))) {
                if ($env{'form.coursepick'} eq 'category') {
                    $loadcode .= ';javascript:setCourseCat(document.'.$env{'form.command'}.')';
                }
            }
        }
    }
    my $loaditems = ' onLoad="'.$loadcode.'" '; 
    my $bodytag = &Apache::loncommon::bodytag('Broadcast e-mail to users',$function,$loaditems);
    my $html=&Apache::lonxml::xmlbegin();
    &Apache::lonhtmlcommon::add_breadcrumb
        ({href=>'/adm/notify',
          text=>"Broadcast E-mail"});
    if ($command eq 'process') {
        &print_request_receipt($r,$command,$cdom,$tablecolor,$bodytag,$html,\%ltext);
    } elsif ($command eq 'compose') {
        &print_composition_form($r,$command,$cdom,$tablecolor,$bodytag,$html,\%ltext);
    } elsif ($command eq 'pick_target') {
        &print_selection_form($r,$command,$cdom,$tablecolor,$bodytag,$html,\%ltext);
    } elsif ($command eq 'pick_display') {
        &print_display_option_form($r,$command,$cdom,$tablecolor,$bodytag,$html,\%ltext);
    } elsif ($command eq 'display') {
        &print_display($r,$command,$cdom,$tablecolor,$bodytag,$html,\%ltext);
    } else {
        &print_front_page($r,'front',$cdom,$tablecolor,$bodytag,$html,\%ltext);
    }
    return OK;
}

sub print_front_page {
    my ($r,$formname,$cdom,$tablecolor,$bodytag,$html,$ltext) = @_;
    my $breadcrumbs = &Apache::lonhtmlcommon::breadcrumbs
            (undef,'Broadcast e-mail to Domain','Broadcast_system_email');
    my $jscript = qq|
function next_page(caller) {
    if (caller == 'view') {
        document.front.command.value="pick_display"
    }
    else {
        document.front.command.value="pick_target"
    }
    document.front.submit()
}
    |; 
    my %lt=&Apache::lonlocal::texthash(
               'note' => 'Notification E-mail',
    );
    my $output = <<"ENDONE";
$html
<head>
 <title>LON-CAPA $lt{'note'}</title>
<script type"text/javascript">
$jscript
</script>
</head>
$bodytag
$breadcrumbs
<br />
ENDONE
    $output .= '<form name="'.$formname.'" method="post">'.
              '<input type="hidden" name="command" />';
    $output .= &Apache::lonhtmlcommon::start_pick_box();
    $output .= '<table cellspacing="8" cellpadding="8">'.
              '<tr><td><a href="javascript:next_page('."'new'".')">'.
              'Send a new e-mail message to selected users from this domain</a></td></tr><tr>'.
              '<td><a href="javascript:next_page('."'view'".')">'.
              'Display e-mail sent by Domain Coordinators in this domain'.
              '</a></td></tr></table>';
    $output .= &Apache::lonhtmlcommon::end_pick_box();
    $output .= qq(
</form>
</body>
</html>);
    $r->print($output);
    return;
}

sub print_display_option_form {
    my ($r,$formname,$cdom,$tablecolor,$bodytag,$html,$ltext) = @_;
    &Apache::lonhtmlcommon::add_breadcrumb
         ({text=>"Display options"});
    my $breadcrumbs = &Apache::lonhtmlcommon::breadcrumbs
            (undef,'Broadcast e-mail display options','Broadcast_system_email');
    my $table_width = '';
    my $col_width = '200';
    my $cmd = 'display';
    my $submit_text = 'Display e-mail';
    my @roles = ('dc');
    my $now = time;
    my %lt=&Apache::lonlocal::texthash(
               'note' => 'Notification E-mail',
    );
    my $startdateform = &Apache::lonhtmlcommon::date_setter($formname,
                                                            'startdate',
                                                            $now);
    my $enddateform = &Apache::lonhtmlcommon::date_setter($formname,
                                                          'enddate',
                                                          $now);
    my %elements = (
        startdate_month => 'selectbox',
        startdate_hour => 'selectbox',
        enddate_month => 'selectbox',
        enddate_hour => 'selectbox',
        startdate_day => 'text',
        startdate_year => 'text',
        startdate_minute => 'text',
        startdate_second => 'text',
        enddate_day => 'text',
        enddate_year => 'text',
        enddate_minute => 'text',
        enddate_second => 'text',
        sender => 'checkbox',
    );
    my $jscript = &Apache::lonhtmlcommon::set_form_elements(\%elements);
    my $output = <<"ENDONE";
$html
<head>
 <title>LON-CAPA $lt{'note'}</title>
<script type"text/javascript">
$jscript
</script>
</head>
$bodytag
$breadcrumbs
<br />
<form method="post" name="$formname">
ENDONE
    $output .= &Apache::lonhtmlcommon::start_pick_box($table_width);
    $output .= &Apache::lonhtmlcommon::row_title($col_width,$tablecolor,&mt('Date range'));
    $output .= '<td><table><tr><td>Earliest to display: </td><td>'.
                $startdateform.'</td></tr>';
    $output .= '<tr><td>Latest to display: </td><td>'.$enddateform.
               '</td></tr></table></td>';
    $output .= &Apache::lonhtmlcommon::row_closure();
    $output .= &Apache::lonhtmlcommon::row_title($col_width,$tablecolor,&mt('Choose sender(s)'));
    my %personnel = &Apache::lonnet::get_domain_roles($cdom,\@roles);
    $output .= '<td>';
    my @domcc = ();
    foreach my $server (keys %personnel) {
        foreach my $user (sort(keys %{$personnel{$server}})) {
            my ($trole,$uname,$udom,$runame,$rudom,$rsec) = split(/:/,$user);
            unless (grep/^$uname:$udom$/,@domcc) {
                my %userinfo = &Apache::lonnet::get('environment',['lastname','firstname'],$udom,$uname);
                $output .= '<input type="checkbox" name="sender" value="'.$uname.':'.$udom.'" />&nbsp;'.$userinfo{firstname}.' '.$userinfo{lastname}.'&nbsp;&nbsp;('.$uname.':'.$udom.')';
                push (@domcc,$uname.':'.$udom);
            }
        }
    }
    $output .= '</td>';
    $output .= &Apache::lonhtmlcommon::row_closure();
    $output .= &Apache::lonhtmlcommon::submit_row($col_width,$tablecolor,&mt('Submit'),$cmd,$submit_text);
    $output .= &Apache::lonhtmlcommon::end_pick_box();
    $output .= qq(
<input type="hidden" name="sortby" value="date" />
</form>
</body>
</html>);
    $r->print($output);
    return;
}

sub print_display {
    my ($r,$formname,$cdom,$tablecolor,$bodytag,$html,$ltext) = @_;
    &Apache::lonhtmlcommon::add_breadcrumb
         ({href=>"javascript:goBack('pick_display')",
          text=>"Display options"},
         {text=>"E-mail display"});
    my $breadcrumbs = &Apache::lonhtmlcommon::breadcrumbs
            (undef,'Display Broadcast e-mail','Broadcast_system_email');
    my $table_width = '';
    my $col_width = '200';
    my $rowColor1 = "#ffffff";
    my $rowColor2 = "#eeeeee";
    my $rowColor;
    my $msgcount = 0;
    my $start = &Apache::lonhtmlcommon::get_date_from_form('startdate');
    my $end = &Apache::lonhtmlcommon::get_date_from_form('enddate');
    my @senders = &Apache::loncommon::get_env_multiple('form.sender');
    my %sentmail = &Apache::lonnet::dcmaildump($cdom,$start,$end,\@senders);
    my %dcmail = ();
    my %Sortby = ();
    my $jscript = <<"ENDSCRIPT";
function changeSort(caller) {
    document.$formname.command.value = '$formname';
    document.$formname.sortby.value = caller;
    document.$formname.submit();
}
function goBack(target) {
    document.$formname.command.value = target;
    document.$formname.submit();
}

ENDSCRIPT
    my $output = <<"ENDONE";
$html
<head>
 <title>LON-CAPA $$ltext{'note'}</title>
 <script type"text/javascript">
$jscript
 </script>
</head>
$bodytag
$breadcrumbs
<br />
<form method="post" name="$formname">
ENDONE

    foreach my $server (keys(%sentmail)) {
        foreach my $msgid (keys(%{$sentmail{$server}})) {
            my %content = &unpackagemail($sentmail{$server}{$msgid});
            if (defined($dcmail{$msgid})) {
                foreach my $user (keys(%{$content{'recipients'}})) {
                    $dcmail{$msgid}{recipients}{$user} = $content{recipients}{$user};
                }
            } else {
                $msgcount ++;
                %{$dcmail{$msgid}} = ();
                foreach my $item (keys(%content)) {
                    if ($item eq 'recipients') {
                        foreach my $user (keys(%{$content{recipients}})) {
                            $dcmail{$msgid}{recipients}{$user} = $content{recipients}{$user};
                        }
                    } else {
                        $dcmail{$msgid}{$item} = $content{$item};
                    }
                }
            }
        }
    }
    $output .= &Apache::lonhtmlcommon::start_pick_box();
    if ($msgcount > 0) {
        my $rowNum = 0;
        $output .= '<tr><td><table cellpadding="4" cellspacing="2" width="100%">
                   <tr bgcolor="'.$tablecolor.'" align="center">
                   <td><b><a href="javascript:changeSort('."'date'".')">Date</a></b></td>
                   <td><b><a href="javascript:changeSort('."'subject'".')">Subject</a></b></td>
                   <td><b><a href="javascript:changeSort('."'sender'".')">Sender</a></b></td>
                   <td><b><a href="javascript:changeSort('."'message'".')">Message</a></b></td>
                   <td><b><a href="javascript:changeSort('."'recipients'".')">Recipients</a></b></td>
                   </tr>';
        if (($env{'form.sortby'} eq 'date') || ($env{'form.sortby'} eq '') || (!defined($env{'form.sortby'})) || (($env{'form.sortby'} eq 'sender') && (@senders <= 1))) {
            foreach my $msgid (sort(keys(%dcmail))) {
                if ($rowNum %2 == 1) {
                    $rowColor = $rowColor1;
                } else {
                    $rowColor = $rowColor2;
                }
                my $recipients = '';
                my ($date,$subj,$sname,$sdom,$cdom) = split(/:/,$msgid,5);
                $date = &Apache::lonlocal::locallocaltime($date);
                foreach my $user (sort(keys(%{$dcmail{$msgid}{recipients}}))) {
                    $recipients .= $dcmail{$msgid}{recipients}{$user}.', ';
                }
                $recipients =~ s/,\s$//;
                $output .= '<tr bgcolor="'.$rowColor.'"><td><small>'.$date.'</small></td><td><small>'.&cr_to_br($dcmail{$msgid}{subject}).'</small></td><td><small>'.$sname.':'.$sdom.'</small></td><td><small>'.&cr_to_br($dcmail{$msgid}{message}).'</small></td><td><small>'.$recipients.'</small></td></tr>'."\n";
                $rowNum ++;
            }
        } else {
            foreach my $msgid (sort(keys(%dcmail))) {
                my ($date,$subj,$sname,$sdom,$cdom) = split(/:/,$msgid,5);
                if ($env{'form.sortby'} eq 'subject') {
                    push @{$Sortby{$dcmail{$msgid}{subject}}},$msgid;
                } elsif ($env{'form.sortby'} eq 'message') {
                    push @{$Sortby{$dcmail{$msgid}{message}}},$msgid;
                } elsif ($env{'form.sortby'} eq 'recipients') {
                    my $recipients ='';
                    foreach my $user (sort(keys(%{$dcmail{$msgid}{recipients}}))) {
                        $recipients .= $dcmail{$msgid}{recipients}{$user}.', ';
                    }
                    $recipients =~ s/,\s$//;
                    push @{$Sortby{$recipients}},$msgid;
                } elsif ($env{'form.sortby'} eq 'sender') {
                    if (@senders > 1) {
                       push @{$Sortby{$sname.':'.$sdom}},$msgid;
                    }
                }
            }
            foreach my $key (sort(keys(%Sortby))) {
                foreach my $msgid (@{$Sortby{$key}}) {
                    if ($rowNum %2 == 1) {
                        $rowColor = $rowColor1;
                    } else {
                        $rowColor = $rowColor2;
                    }
                    my $recipients = '';
                    if ($env{'form.sortby'} eq 'recipients') {
                        $recipients = $key;
                    } else {
                        foreach my $user (sort(keys(%{$dcmail{$msgid}{recipients}}))) {
                            $recipients .= $dcmail{$msgid}{recipients}{$user}.', ';
                        }
                        $recipients =~ s/,\s$//;
                    }

                    my ($date,$subj,$sname,$sdom,$cdom) = split(/:/,$msgid,5);
                    $date = &Apache::lonlocal::locallocaltime($date);
                    $output .=  '<tr bgcolor="'.$rowColor.'"><td><small>'.$date.'</small></td><td><small>'.&cr_to_br($dcmail{$msgid}{subject}).'</small></td><td><small>'.$sname.':'.$sdom.'</small></td><td><small>'.&cr_to_br($dcmail{$msgid}{message}).'</small></td><td><small>'.$recipients.'</small></td></tr>'."\n";
                    $rowNum ++;
                }
            }
        }
        $output .= '</table></td></tr>';
    } else {
        $output .= '<tr bgcolor="#ffffff"><td>&nbsp;</td><td><br><center><i><b><small>&nbsp;&nbsp;No mail sent matching supplied criteria&nbsp;&nbsp;</small><br><br></b></i></td><td>&nbsp;</td></tr>';
    }
    $output .= &Apache::lonhtmlcommon::end_pick_box();
    $output .= &Apache::lonhtmlcommon::echo_form_input(['sortby','command','origin']);
    my $curr_sortby;
    if (defined($env{'form.sortby'})) {
        $curr_sortby = $env{'form.sortby'};
    } else {
        $curr_sortby = 'date';
    }
    $output .= qq(<input type="hidden" name="origin" value="$formname" />\n);
    $output .= qq(<input type="hidden" name="command" />\n);
    $output .= qq(<input type="hidden" name="sortby" value="$curr_sortby" />\n);
    $output .= qq(
</form>
</body>
</html>);
    $r->print($output);
    return;
}

sub print_selection_form {
    my ($r,$formname,$cdom,$tablecolor,$bodytag,$html,$ltext) = @_;
    my %coursecodes = ();
    my %codes = ();
    my @codetitles = ();
    my %cat_titles = ();
    my %cat_order = ();
    my %idlist = ();
    my %idnums = ();
    my %idlist_titles = ();
    my $caller = 'global';
    my $totcodes = 0;
    my $format_reply;
    my $jscript = '';
    my $table_width = '100%';
    my $col_width = '200';
    my %lt=&Apache::lonlocal::texthash(
               'note' => 'Notification E-mail', 
               'buil' => 'Building valid e-mail address from username, if missing from preferences:',
               'kerb' => 'Kerberos: enter default for each realm used in the domain, with comma separation of entries',
               'infs' => 'Internal, Filesystem and Local authentication: enter single default.',
               'comp' => 'Compose Message'
           );
    &Apache::lonhtmlcommon::add_breadcrumb
          ({text=>"Select Audience"});

    $totcodes = &Apache::lonsupportreq::retrieve_instcodes(\%coursecodes,$cdom,$totcodes);
    if ($totcodes > 0) {
        $format_reply = &Apache::lonnet::auto_instcode_format($caller,$cdom,\%coursecodes,\%codes,\@codetitles,\%cat_titles,\%cat_order);
        if ($format_reply eq 'ok') {
            my $numtypes = @codetitles;
            &Apache::lonsupportreq::build_code_selections(\%codes,\@codetitles,\%cat_titles,\%cat_order,\%idlist,\%idnums,\%idlist_titles);
            &Apache::lonsupportreq::javascript_code_selections($formname,$numtypes,\%cat_titles,\$jscript,\%idlist,\%idnums,\%idlist_titles,\@codetitles);
        }
    }

    my $breadcrumbs = &Apache::lonhtmlcommon::breadcrumbs
            (undef,'Choose e-mail audience','Broadcast_system_email');
    my $cb_jscript = &Apache::loncommon::coursebrowser_javascript($cdom);

    my %elements = (
                     roles => 'selectbox',
                     types => 'selectbox',
                     Year => 'selectbox',
                     coursepick => 'radio',
                     coursetotal => 'text',
                     courselist => 'text',
                     internal => 'text',
                     krb4 => 'text',
                     krb5 => 'text',
                     local => 'text',
                     unix => 'text',
                   );
    $jscript .= &Apache::lonhtmlcommon::set_form_elements(\%elements);
    if ($env{'form.coursepick'} eq 'category') {
        $jscript .= qq|
function setCourseCat(formname) {
    if (formname.Year.options[formname.Year.selectedIndex].value == -1) {
        return;
    }
    courseSet('Year');
    for (var j=0; j<formname.Semester.length; j++) {
        if (formname.Semester.options[j].value == "$env{'form.Semester'}") {
            formname.Semester.options[j].selected = true;
        }
    }
    if (formname.Semester.options[formname.Semester.selectedIndex].value == -1) {
        return;
    }
    courseSet('Semester');
    for (var j=0; j<formname.Department.length; j++) {
        if (formname.Department.options[j].value == "$env{'form.Department'}") {
            formname.Department.options[j].selected = true;
        }
    }
    if (formname.Department.options[formname.Department.selectedIndex].value == -1) {
        return;
    }
    courseSet('Department');
    for (var j=0; j<formname.Number.length; j++) {
        if (formname.Number.options[j].value == "$env{'form.Number'}") {
            formname.Number.options[j].selected = true;
        }
    }
}
|; 
    }
    my $output = <<"ENDONE";
$html
<head>
 <title>LON-CAPA $lt{'note'}</title>
<script type"text/javascript">
$jscript
</script>
$cb_jscript
</head>
$bodytag
$breadcrumbs
<br />
<form method="post" name="$formname">
ENDONE
   $output .= &Apache::lonhtmlcommon::start_pick_box($table_width);
   my @roles = ('ow','cc','in','ta','ep','st','cr');
   my %longtypes = ();
   my %authtypes = ();
   &form_elements(\%longtypes,\%authtypes);
   my $descrip = $lt{'buil'}.' 
<ul>
<li>'.$lt{'kerb'}.'<br />(e.g., MSU.EDU=msu.edu, MSUE.EDU=msue.msu.edu).</li>
<li>'.$lt{'infs'}.'</li>
</ul>'."\n";
   my $submit_text = $lt{'comp'};
   my $cmd = 'compose';
   $output .= &Apache::lonhtmlcommon::role_select_row(\@roles,$col_width,$tablecolor,'Roles');
   $output .= &Apache::lonhtmlcommon::course_select_row($col_width,$tablecolor,'Courses',$formname,$totcodes,\@codetitles,\%idlist,\%idlist_titles);
   $output .= &Apache::lonhtmlcommon::status_select_row(\%longtypes,$col_width,$tablecolor,&mt('Access status'));
   $output .= &Apache::lonhtmlcommon::email_default_row(\%authtypes,$col_width,$tablecolor,&mt('Username -> Email conversion'),$descrip);
   $output .= &Apache::lonhtmlcommon::submit_row($col_width,$tablecolor,&mt('Submit'),$cmd,$submit_text);
   $output .= &Apache::lonhtmlcommon::end_pick_box();
   $output .= qq(
</form>
</body>
</html>);
    $r->print($output);
    return;
}

sub print_composition_form {
    my ($r,$formname,$cdom,$tablecolor,$bodytag,$html,$ltext) = @_;
    &Apache::lonhtmlcommon::add_breadcrumb
        ({href=>"javascript:goBack('pick_target')",
          text=>"Select Audience"},
         {text=>"Compose Message"});
    my $jscript = &Apache::loncommon::check_uncheck_jscript();
    $jscript .= qq|
function goBack(target) {
    document.$formname.command.value = target;
    document.$formname.submit();
}
|;
    my $breadcrumbs = (&Apache::lonhtmlcommon::breadcrumbs
        (undef,'Broadcast e-mail to users','Broadcast_system_email'));

    my %lt=&Apache::lonlocal::texthash(
                      'note' => 'Notification E-mail',
                      'nore' => 'No recipients identified',
                      'emad' => 'e-mail address',
                   );
    my %elements = (
                     subject => 'text',
                     message => 'text',
                     sender => 'text',
                     recipient => 'checkbox',
                   );
    $jscript .= &Apache::lonhtmlcommon::set_form_elements(\%elements);

    $r->print(<<ENDONE);
$html
<head>
 <title>LON-CAPA $lt{'note'}</title>
<script type="text/javascript">
$jscript
</script>
</head>
$bodytag $breadcrumbs
<br /> 
ENDONE
    my $coursefilter = $env{'form.coursepick'};
    my %courses = ();
    if ($coursefilter eq 'all') {
        %courses = &Apache::lonnet::courseiddump($cdom,'.','.','.','.','.');
    } elsif ($coursefilter eq 'category') {
        my $instcode = '';
        my @cats = ('Semester','Year','Department','Number');
        foreach my $category (@cats) {
            if (defined($env{'form.'.$category})) {
                unless ($env{'form.'.$category} eq '-1') {
                    $instcode .= $env{'form.'.$category};
                }
            }
        }
        if ($instcode eq '') {
            $instcode = '.';
        }
        %courses = &Apache::lonnet::courseiddump($cdom,'.','.',$instcode,'.','.');
    } elsif ($coursefilter eq 'specific') {
        if ($env{'form.coursetotal'} > 1) {
            my @course_ids = split(/&&/,$env{'form.courselist'});
            foreach (@course_ids) {
                $courses{$_} = '';
            }
        } else {
            $courses{$env{'form.courselist'}} = '';
        }
    }

    my @types = &Apache::loncommon::get_env_multiple('form.types');
    my @roles = &Apache::loncommon::get_env_multiple('form.roles');

    my %longtypes = ();
    my %authtypes = ();
    my %email_defaults = ();
    my $table_width = '100%';
    my $col_width = '200';

    &form_elements(\%longtypes,\%authtypes);
    foreach my $auth (keys(%authtypes)) {
        if (exists($env{'form.'.$auth})) {
             my $default = $env{'form.'.$auth};
             $default =~ s/^,+//;
             $default =~ s/,+$//;
             if ($auth =~ /^krb/) {
                 %{$email_defaults{$auth}} = ();
                 if ($default =~ /,/) {
                     my @items = split(/,/,$default);
                     foreach my $item (@items) {
                         my ($realm,$value) = split(/=/,$item);
                         $email_defaults{$auth}{$realm} = $value;
                     }
                 } else {
                     my ($realm,$value) = split(/=/,$default);
                     $email_defaults{$auth}{$realm} = $value;
                 }
             } else {
                 $email_defaults{$auth} = $default;
             }
         }
    }

    my $sender = &get_user_info($env{'user.name'},%email_defaults);

    my %recipients = ();
    my %users = ();
    my %access = ();
    my @sections = ();
    my $totalrecip = 0;
    my @unmatched = ();
    foreach my $role (@roles) {
        %{$users{$role}} = ();
    }
    foreach my $type (@types) {
        $access{$type} = $type;
    }
    foreach my $course_id (keys(%courses)) {
        my ($cdom,$cnum) = split(/_/,$course_id);
        &Apache::loncommon::get_course_users($cdom,$cnum,\%access,\@roles,\@sections,\%users);
    }
    foreach my $role (keys(%users)) {
        foreach my $user (keys(%{$users{$role}})) {
            unless (defined($recipients{$user})) {
                $recipients{$user} = &get_user_info($user,%email_defaults);
                if ($recipients{$user} eq '') {
                    push @unmatched, $user;
                } else {
                    $totalrecip ++;
                } 
            }
        }
    }
    my $output  = '<form name="'.$formname.'" method="post">'."\n";
  
    if ($totalrecip > 0) {
        $output .= &Apache::lonhtmlcommon::start_pick_box($table_width);
        $output .= &Apache::lonhtmlcommon::row_title($col_width,$tablecolor,&mt('Subject'));
        $output .= ' <td><input type="text" name="subject" size="30" /></td>';
        $output .= &Apache::lonhtmlcommon::row_closure();
        $output .= &Apache::lonhtmlcommon::row_title($col_width,$tablecolor,&mt('Message'));
        $output .= '  <td><textarea name="message" id="message"
                      cols="60" rows="10" wrap="hard"></textarea></td>';
        $output .= &Apache::lonhtmlcommon::row_closure();
        $output .= &Apache::lonhtmlcommon::row_title($col_width,$tablecolor,&mt('Recipients'));
        $output .= '<td><input type="button" value="check all" 
                    onclick="javascript:checkAll(document.compose.recipient)" />
                    &nbsp;&nbsp;<input type="button" value="uncheck all"
                    onclick="javascript:uncheckAll(document.compose.recipient)" />
                    <br /><table border="0">';
        if (keys(%recipients) > 0) {
            $output .= '<tr><td>&nbsp;</td><td><small><b>username:domain</b></small></td><td>&nbsp;&nbsp;</td><td><small><b>'.$lt{'emad'}.'</b></small></td></tr>';
        }
        foreach my $username (sort(keys(%recipients))) {
            if ($recipients{$username} =~ /\@/) {
                my $value=&Apache::lonnet::escape($username).':'.&Apache::lonnet::escape($recipients{$username});
                $output .= '<tr><td><input type="checkbox" name="recipient" value="'.$value.'" /></td><td>'.$username.'</td><td>&nbsp;&nbsp;</td><td>'.$recipients{$username}.'</td></tr>';
            }
        }
        $output .= '</table>';
        if (@unmatched) {
            $output .= '<br /><br />'.&mt('Could not determine e-mail addresses for the following users:').'<ul>';
            foreach my $username (sort @unmatched) {
                $output .= '<li>'.$username.'</li>';
            }
            $output .= '</ul>';
        }
        $output .= '</td>';
        $output .= &Apache::lonhtmlcommon::row_closure();
        $output .= &Apache::lonhtmlcommon::row_title($col_width,$tablecolor,&mt('Sender e-mail address'));
        $output .= '<td><input type="text" name="sender" value="'.$sender.'" /></td>';
        $output .= &Apache::lonhtmlcommon::row_closure();
        $output .= &Apache::lonhtmlcommon::submit_row($col_width,$tablecolor,&mt('Submit'),'process',&mt('Send Message'));
        $output .= &Apache::lonhtmlcommon::end_pick_box();
    } else {
        $output .= $lt{'nore'}."\n".
                   '<input type="hidden" name="command" value="" />'."\n";
    }
    $output .= '<input type="hidden" name="origin" value="'.$formname.'" />'."\n";
    $output .= &Apache::lonhtmlcommon::echo_form_input(['command','origin','subject','message','recipient','sender'],);
    $output .= '</form></body></html>';
    $r->print($output);
    return;
}


sub print_request_receipt {
    my ($r,$formname,$dom,$tablecolor,$bodytag,$html,$ltext) =@_;
    my @recipients = &Apache::loncommon::get_env_multiple('form.recipient');
    my $subject = $env{'form.subject'};
    my $message = $env{'form.message'};
    my $from = $env{'form.sender'};
    my $jscript = <<ENDSCRIPT;
function goBack(target) {
    document.$formname.command.value = target;
    document.$formname.submit();
}
ENDSCRIPT
    &Apache::lonhtmlcommon::add_breadcrumb
        ({href=>"javascript:goBack('pick_target')",
          text=>"Select audience"});
    &Apache::lonhtmlcommon::add_breadcrumb
        ({href=>"javascript:goBack('compose')",
          text=>"Compose Message"});
    &Apache::lonhtmlcommon::add_breadcrumb
        ({href=>"/adm/notify?command=process",
          text=>"Outcome"});
    my $breadcrumbs = &Apache::lonhtmlcommon::breadcrumbs
            (undef,'E-mail Delivery','Broadcast_system_email');
    my $output = <<ENDONE;
$html
<head>
 <title>LON-CAPA Notification E-mail</title>
<script type="text/javascript">
$jscript
</script>
</head>
$bodytag
$breadcrumbs
<br />
<form name="$formname" method="post">
ENDONE
    $output .= &Apache::lonhtmlcommon::start_pick_box();
    my @deliveries = ();
    &broadcast_email(\@recipients,$subject,$from,$message,\@deliveries);
    if (@deliveries > 0) {
        &store_mail($subject,$message,$dom,\@deliveries);
        $output .= '<tr>
                     <td>
                      <table cellpadding="4" cellspacing="2" width="100%">
                       <tr bgcolor="'.$tablecolor.'" align="center">
                        <td><b>Status</b></td>
                        <td><b>Subject</b></td>
                        <td><b>Message</b></td>
                        <td><b>Recipients</b></td>
                       </tr>
                       <tr bgcolor="#eeeeee">
                        <td valign="middle">Sent</td>
                        <td valign="middle">'.&cr_to_br($subject).'</td>
                        <td valign="middle">'.&cr_to_br($message).'</td>
                        <td>';
        foreach my $person (@deliveries) {
            my ($username,$email) = split(/:/,$person);
            $output .= &Apache::lonnet::unescape($email).'&nbsp;('.&Apache::lonnet::unescape($username).')<br />'."\n";
        }
        $output .= '</td>
                   </tr>
                  </table>
                 </td>
                </tr>';
        &store_mail($subject,$message,$dom,\@deliveries);
    } else {
        $output .= 'No mail sent - no recipients identified'; 
    }
    $output .= &Apache::lonhtmlcommon::end_pick_box();
    $output .= '<br /><a href="/adm/notify">Send another message?</a>'."\n";
    $output .= '<input type="hidden" name="command" />'."\n".
               '<input type="hidden" name="origin" value="'.$formname.'" />'."\n";
    $output .= &Apache::lonhtmlcommon::echo_form_input(['command','origin']);
    $output .= '
</form>
</body>
</html>';
    $r->print($output);
    return;
}

sub broadcast_email {
    my ($recipients,$subject,$from,$message,$deliveries,$ltext)=@_;
# Should implement staggered delivery for large numbers of recipients?.
    foreach my $user (@{$recipients}) {
        my $msg = new Mail::Send;
        my ($username,$to) = split(/:/,$user);
        $username = &Apache::lonnet::unescape($username);
        $to = &Apache::lonnet::unescape($to);
        $msg->to($to);
        $msg->subject($subject);
        $msg->add('From',"$from");
        if (my $fh = $msg->open()) {
            print $fh $message;
            $fh->close;
            push(@{$deliveries},$user); 
        }
    }
}

sub get_user_info {
    my ($user,%email_defaults) = @_;
    my ($uname,$udom) = split(/:/,$user);
    my @emailtypes = ('permanentemail','critnotification','notification');
    my %userinfo = &Apache::lonnet::get('environment',\@emailtypes,$udom,$uname);
    my $email = '';
    foreach my $type (@emailtypes) {
        $email = $userinfo{$type};
        if ($email =~ /\@/) {
            last;
        }
    }
    if ($email eq '') {
        my $authinfo  = &Apache::lonnet::queryauthenticate($uname,$udom);
        my ($authtype,$autharg) = split(/:/,$authinfo);
        if ($authtype =~ /^krb/) {
            if (defined($email_defaults{$authtype}{$autharg})) {
                $email = $uname.'@'.$email_defaults{$authtype}{$autharg};
            }
        } else {
            if ((defined($email_defaults{$authtype})) && ($email_defaults{$authtype} ne '')) {
                $email = $uname.'@'.$email_defaults{$authtype};
            }
        }
    }
    return $email;
}

sub form_elements {
   my ($longtypes,$authtypes,$ltext) = @_;
   %{$longtypes} = (
                   active => 'Currently has access',
                   previous => 'Previously had access',
                   future => 'Will have future access',
                   );
   %{$authtypes} = (
                   krb4 => 'Kerberos 4',
                   krb5 => 'Kerberos 5',
                   internal => 'Internal (LON-CAPA)',
                   unix => 'Filesystem (UNIX)',
                   local => 'Local/Customized',
                   );
   return;
}

sub store_mail {
    my ($subject,$message,$domain,$recipients,$attachmenturl,$ltext) = @_;
    my %servers = ();
    my $msgid=&packagemail($subject,$message,$domain,
                           $recipients,\%servers,$attachmenturl);
# Store in dc email db files on appropriate servers.
    foreach my $server (keys(%servers)) {
        unless (&Apache::lonnet::dcmailput($domain,$msgid,\%servers,$server) eq 'ok') {
            &Apache::lonnet::logthis('Storage of dc mail failed for domain'.$domain.' for server: '.
                      $server.'.  Message ID was '.$msgid);
        }
    }
}

sub packagemail {
    my ($subject,$message,$dom,$recipients,$servers,$attachmenturl,$ltext) = @_;
    my %record = ();
    my $partsubj=$subject;
    $partsubj=&Apache::lonnet::escape($partsubj);
    $message =&HTML::Entities::encode($message,'<>&"');
    $subject =&HTML::Entities::encode($subject,'<>&"');
    #remove machine specification
    $attachmenturl =~ s|^http://[^/]+/|/|;
    $attachmenturl =&HTML::Entities::encode($attachmenturl,'<>&"');
    my $now=time;
    my $msgid= &Apache::lonnet::escape($now).':'.$partsubj.':'.
           &Apache::lonnet::escape($env{'user.name'}).':'.
           &Apache::lonnet::escape($env{'user.domain'}).':'.
           &Apache::lonnet::escape($dom).':'.$$;
    my $result='<sendername>'.$env{'user.name'}.'</sendername>'.
           '<senderdomain>'.$env{'user.domain'}.'</senderdomain>'.
           '<time>'.&Apache::lonlocal::locallocaltime($now).'</time>'.
           '<servername>'.$ENV{'SERVER_NAME'}.'</servername>'.
           '<host>'.$ENV{'HTTP_HOST'}.'</host>'.
           '<client>'.$ENV{'REMOTE_ADDR'}.'</client>'.
           '<msgid>'.$msgid.'</msgid>'.
           '<dcdomain>'.$dom.'</dcdomain>'.
           '<subject>'.$subject.'</subject>'.
           '<message>'.$message.'</message>'."\n";
    if (defined($attachmenturl)) {
        $result.= '<attachmenturl>'.$attachmenturl.'</attachmenturl>';
    }
    foreach my $recip (@{$recipients}) {
        my ($username,$email) = split(/:/,$recip);
        $username = &Apache::lonnet::unescape($username);
        $email = &Apache::lonnet::unescape($email);
        my ($uname,$udom) = split(/:/,$username);
        my $uhom=&Apache::lonnet::homeserver($uname,$udom);
        if ($uhom ne 'no_host') {
            $username = &HTML::Entities::encode($username,'<>&"');
            $email = &HTML::Entities::encode($email,'<>&"');
            $record{$uhom} .= '<recipient username="'.$username.'">'.
                              $email.'</recipient>';
        }
    }
    foreach my $server (keys(%record)) {
        $$servers{$server} = $result.$record{$server};
    }
    return $msgid;
}

sub unpackagemail {
    my ($message,$notoken,$ltext)=@_;
    my $parser=HTML::TokeParser->new(\$message);
    my $token;
    my %content=();
    %{$content{recipients}} = ();
    while ($token=$parser->get_token()) {
        if ($token->[0] eq 'S') {
            my $entry=$token->[1];
            my $value=$parser->get_text('/'.$entry);
            my ($username,$email);
            if ($entry eq 'recipient') {
                $username = $token->[2]{'username'};
                $username = &HTML::Entities::decode($username,'<>&"');
                $content{recipients}{$username} = 
                      &HTML::Entities::decode($value,'<>&"');
            } elsif ($entry eq 'subject' || $entry eq 'message') {
                $content{$entry}=&HTML::Entities::decode($value,'<>&"');
            } else {
                $content{$entry}=$value;
            }
        }
    }
    if ($content{'attachmenturl'}) {
        my ($fname)=($content{'attachmenturl'}=~m|/([^/]+)$|);
        if ($notoken) {
            $content{'message'}.='<p>'.&mt('Attachment').': <tt>'.$fname.'</tt>';       } else {
            &Apache::lonnet::allowuploaded('/adm/notify',
                                          $content{'attachmenturl'});
            $content{'message'}.='<p>'.&mt('Attachment').
               ': <a href="'.$content{'attachmenturl'}.'"><tt>'.
               $fname.'</tt></a>';
        }
    }
    return %content;
}

sub cr_to_br {
    my $incoming = shift;
    $incoming =~ s/\n/\<br \/\>/g;
    return $incoming;
}

1;