1: # The LearningOnline Network
2: # RSS Feeder
3: #
4: # $Id: lonrss.pm,v 1.23 2006/05/18 22:30:11 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonrss;
30:
31: use strict;
32: use LONCAPA;
33: use Apache::Constants qw(:common);
34: use Apache::loncommon;
35: use Apache::lonnet;
36: use Apache::lontexconvert;
37: use Apache::lonlocal;
38: use Apache::lonhtmlcommon;
39:
40:
41: sub filterfeedname {
42: my $filename=shift;
43: $filename=~s/(\_rss\.html|\.rss)$//;
44: $filename=~s/\W//g;
45: $filename=~s/\_rssfeed$//;
46: $filename=~s/^nohist\_//;
47: return $filename;
48: }
49:
50: sub feedname {
51: return 'nohist_'.&filterfeedname(shift).'_rssfeed';
52: }
53:
54: sub displayfeedname {
55: my ($rawname,$uname,$udom)=@_;
56: my $filterfilename=&filterfeedname($rawname);
57: # do we have a stored name?
58: my %stored=&Apache::lonnet::get('nohist_all_rss_feeds',[$filterfilename,'feed_display_option_'.$filterfilename],$udom,$uname);
59: if ($stored{$filterfilename}) { return ($stored{$filterfilename},$stored{'feed_display_option_'.$filterfilename}); }
60: # no, construct a name
61: my $name=$filterfilename;
62: if ($name=~/^CourseBlog/) {
63: $name=&mt('Course Blog');
64: if ($env{'course.'.$env{'request.course.id'}.'.description'}) {
65: $name.=' '.$env{'course.'.$env{'request.course.id'}.'.description'};
66: }
67: } else {
68: $name=~s/\_/ /g;
69: }
70: return ($name,$stored{'feed_display_option_'.$filterfilename});
71: }
72:
73: sub namefeed {
74: my ($rawname,$uname,$udom,$newname)=@_;
75: return &Apache::lonnet::put('nohist_all_rss_feeds',
76: { &filterfeedname($rawname) => $newname },
77: $udom,$uname);
78: }
79:
80: sub changefeeddisplay {
81: my ($rawname,$uname,$udom,$newstatus)=@_;
82: return &Apache::lonnet::put('nohist_all_rss_feeds',
83: { 'feed_display_option_'.&filterfeedname($rawname) => $newstatus },
84: $udom,$uname);
85: }
86:
87: sub advertisefeeds {
88: my ($uname,$udom,$edit)=@_;
89: my $feeds='';
90: my %feednames=&Apache::lonnet::dump('nohist_all_rss_feeds',$udom,$uname);
91: my $mode='public';
92: if ($edit) {
93: $mode='adm';
94: }
95: foreach my $feed (sort(keys(%feednames))) {
96: if ($feed ne ''
97: && ($feed!~/^error\:/) && ($feed!~/^feed\_display\_option\_/)) {
98: my $feedurl='http://'.$ENV{'HTTP_HOST'}.'/public/'.$udom.'/'.$uname.'/'.$feed.'.rss';
99: my $htmlurl='http://'.$ENV{'HTTP_HOST'}.'/'.$mode.'/'.$udom.'/'.$uname.'/'.$feed.'_rss.html';
100: if ($feednames{'feed_display_option_'.$feed} eq 'hidden') {
101: if ($edit) {
102: $feeds.='<li><i>'.$feednames{$feed}.'</i><br />'.&mt('Hidden').': <a href="'.$htmlurl.'"><tt>'.$htmlurl.'</tt></a></li>';
103: }
104: } else {
105: $feeds.='<li><b>'.$feednames{$feed}.
106: '</b><br />'.($edit?&mt('Edit'):'HTML').': <a href="'.$htmlurl.'"><tt>'.$htmlurl.'</tt></a>'.
107: '<br />RSS: <a href="'.$feedurl.'"><tt>'.$feedurl.'</tt></a></li>';
108: }
109: }
110: }
111: if ($feeds) {
112: return '<h4>'.&mt('Available RSS Feeds and Blogs').'</h4><ul>'.$feeds.'</ul>';
113: } else {
114: return '';
115: }
116: }
117:
118: sub rss_link {
119: my ($url) = @_;
120: return qq|<link rel="alternate" type="application/rss+xml" title="Course Announcements" href="$url" />|;
121: }
122:
123: {
124: my $feedcounter;
125: sub get_new_feed_id {
126: $feedcounter++;
127: return time().'00000'.$$.'00000'.$feedcounter;
128: }
129: }
130:
131: sub addentry {
132: my $id=&get_new_feed_id();
133: return &editentry($id,@_);
134: }
135:
136: sub editentry {
137: my ($id,$uname,$udom,$filename,$title,$description,$url,$status,$encurl,$enctype)=@_;
138: if ($status eq 'deleted') {
139: return &changestatus($id,$uname,$udom,$filename,$status);
140: }
141: my $feedname=&feedname($filename);
142: &Apache::lonnet::put('nohist_all_rss_feeds',
143: { &filterfeedname($filename) => &displayfeedname($filename,$uname,$udom) },
144: $udom,$uname);
145: return &Apache::lonnet::put($feedname,{
146: $id.'_title' => $title,
147: $id.'_description' => $description,
148: $id.'_link' => $url,
149: $id.'_enclosureurl' => $encurl,
150: $id.'_enclosuretype' => $enctype,
151: $id.'_status' => $status},$udom,$uname);
152: }
153:
154: sub changestatus {
155: my ($id,$uname,$udom,$filename,$status)=@_;
156: my $feedname=&feedname($filename);
157: if ($status eq 'deleted') {
158: return &Apache::lonnet::del($feedname,[$id.'_title',
159: $id.'_description',
160: $id.'_link',
161: $id.'_enclosureurl',
162: $id.'_enclosuretype',
163: $id.'_status'],$udom,$uname);
164: } else {
165: return &Apache::lonnet::put($feedname,{$id.'_status' => $status},$udom,$uname);
166: }
167: }
168:
169: sub changed_js {
170: return <<ENDSCRIPT;
171: <script type="text/javascript">
172: function changed(tform,id) {
173: tform.elements[id+"_modified"].checked=true;
174: }
175: </script>
176: ENDSCRIPT
177: }
178:
179: sub determine_enclosure_types {
180: my ($url)=@_;
181: my ($ending)=($url=~/\.(\w+)$/);
182: return &Apache::loncommon::filemimetype($ending);
183: }
184:
185: sub course_blog_link {
186: my ($id,$title,$description,$url,$encurl,$enctype)=@_;
187: if ($env{'request.course.id'}) {
188: return &add_blog_entry_link($id,
189: $env{'course.'.$env{'request.course.id'}.'.num'},
190: $env{'course.'.$env{'request.course.id'}.'.domain'},
191: 'Course_Announcements',
192: $title,$description,$url,'public',$encurl,$enctype,
193: &mt('Add to Course Announcements'));
194: } else {
195: return '';
196: }
197: }
198:
199: sub add_blog_entry_link {
200: my ($id,$uname,$udom,$filename,$title,$description,$url,$status,$encurl,$enctype,$linktext)=@_;
201: return "<a href='/adm/$udom/$uname/".&filterfeedname($filename).'_rss.html?queryid='.
202: &escape($id).
203: '&title='.&escape($title).
204: '&description='.&escape($description).
205: '&url='.&escape($url).
206: '&status='.&escape($status).
207: '&encurl='.&escape($encurl).
208: '&enctype='.&escape($enctype).
209: "'>".$linktext.'</a>';
210:
211: }
212:
213: sub handler {
214: my ($r) = @_;
215:
216: my $edit=0;
217: my $html=0;
218: my (undef,$mode,$udom,$uname,$filename)=split(/\//,$r->uri);
219: if (($mode eq 'adm') && ($env{'user.name'} eq $uname) && ($env{'user.domain'} eq $udom)) {
220: $edit=1;
221: $html=1;
222: }
223: if (($mode eq 'adm') && (&Apache::lonnet::allowed('mdc',$env{'request.course.id'}))) {
224: $edit=1;
225: $html=1;
226: }
227: if ($filename=~/\.html$/) {
228: $html=1;
229: }
230: if ($html) {
231: &Apache::loncommon::content_type($r,'text/html');
232: } else {
233: # Workaround Mozilla/Firefox
234: # &Apache::loncommon::content_type($r,'application/rss+xml');
235: &Apache::loncommon::content_type($r,'text/xml');
236: }
237: $r->send_http_header;
238: return OK if $r->header_only;
239:
240: my $filterfeedname=&filterfeedname($filename);
241: my $feedname=&feedname($filename);
242: my ($displayfeedname,$displayoption)=&displayfeedname($filename,$uname,$udom);
243: if ($html) {
244: $r->print(&Apache::loncommon::start_page(($displayfeedname?$displayfeedname:&mt("Available RSS Feeds and Blogs")),undef,
245: {'domain' => $udom,
246: 'force_register' =>
247: $env{'form.register'}}).
248: &changed_js());
249: } else { # render RSS
250: $r->print("<rss version='2.0' xmlns:dc='http://purl.org/dc/elements/1.1'>\n<channel>".
251: "\n<link>http://".$ENV{'HTTP_HOST'}.'/public/'.$udom.'/'.$uname.'/'.
252: $filterfeedname.'_rss.html</link>'.
253: "\n<description>".
254: &mt('An RSS Feed provided by the LON-CAPA Learning Content Management System').
255: '</description>');
256: }
257: # This will be the entry id for new additions to the blog
258: my $newid = &get_new_feed_id();
259: # Is this user for real?
260: my $homeserver=&Apache::lonnet::homeserver($uname,$udom);
261: if ($html) {
262: # Any new feeds or renaming of feeds?
263: if ($edit) {
264: # Hide a feed?
265: if ($env{'form.hidethisblog'}) {
266: &changefeeddisplay($feedname,$uname,$udom,'hidden');
267: ($displayfeedname,$displayoption)=&displayfeedname($filename,$uname,$udom);
268: }
269: # Advertise a feed?
270: if ($env{'form.advertisethisblog'}) {
271: &changefeeddisplay($feedname,$uname,$udom,'public');
272: ($displayfeedname,$displayoption)=&displayfeedname($filename,$uname,$udom);
273: }
274: # New feed?
275: if ($env{'form.namenewblog'}=~/\w/) {
276: &namefeed($env{'form.namenewblog'},$uname,$udom,$env{'form.namenewblog'});
277: }
278: # Old feed that is being renamed?
279: if (($displayfeedname) && ($env{'form.newblogname'}=~/\w/)) {
280: if ($env{'form.newblogname'} ne $displayfeedname) {
281: &namefeed($feedname,$uname,$udom,$env{'form.newblogname'});
282: ($displayfeedname,$displayoption)=&displayfeedname($filename,$uname,$udom);
283: }
284: }
285: }
286: $r->print(&advertisefeeds($uname,$udom,$edit));
287: }
288: if ($homeserver eq 'no_host') {
289: $r->print(($html?'<h3>':'<title>').&mt('No feed available').($html?'</h3>':'</title>'));
290: } else { # is indeed a user
291: # Course or user?
292: my $name='';
293: if ($uname=~/^\d/) {
294: my %cenv=&Apache::lonnet::dump('environment',$udom,$uname);
295: $name=$cenv{'description'};
296: } else {
297: $name=&Apache::loncommon::nickname($uname,$udom);
298: }
299: # Add a new feed
300: if (($html) && ($edit)) {
301: $r->print('<form method="post">');
302: $r->print(&mt('Name for New Feed').": <input type='text' size='40' name='namenewblog' />");
303: $r->print('<input type="submit" value="'.&mt('Start a New Feed').'" />');
304: $r->print('</form>');
305: }
306: if ($displayfeedname) { # this is an existing feed
307: # Anything to store?
308: if ($edit) {
309: # check if this was called with a query string
310: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},['queryid']);
311: if ($env{'form.queryid'}) {
312: # yes, collect the remainder
313: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},
314: ['title',
315: 'description',
316: 'url',
317: 'status',
318: 'enclosureurl',
319: 'enclosuretype']);
320: # my ($id,$uname,$udom,$filename,$title,$description,$url,$status,$encurl,$enctype)=@_;
321:
322: &editentry($env{'form.queryid'},
323: $uname,$udom,$filename,
324: $env{'form.title'},
325: $env{'form.description'},
326: $env{'form.url'},
327: $env{'form.status'},
328: $env{'form.encurl'},
329: $env{'form.enctype'}
330: );
331: }
332: my %newsfeed=&Apache::lonnet::dump($feedname,$udom,$uname);
333: foreach my $entry (sort(keys(%newsfeed)),$env{'form.newid'}.'_status') {
334: if ($entry=~/^(\d+)\_status$/) {
335: my $id=$1;
336: if ($env{'form.'.$id.'_modified'}) {
337: &editentry($id,$uname,$udom,$feedname,
338: $env{'form.'.$id.'_title'},
339: $env{'form.'.$id.'_description'},
340: $env{'form.'.$id.'_url'},
341: $env{'form.'.$id.'_status'},
342: $env{'form.'.$id.'_enclosureurl'},
343: $env{'form.'.$id.'_enclosuretype'},
344: );
345: }
346: }
347: }
348: } #done storing
349:
350: $r->print("\n".
351: ($html?'<hr /><h3>':'<title>').
352: &mt('LON-CAPA Feed "[_1]" for [_2]',$displayfeedname,$name).
353: ($displayoption eq 'hidden'?' ('.&mt('Hidden').')':'').
354: ($html?'</h3>'.($edit?'<form method="post"><br />'.
355: &mt('Name of this Feed').
356: ': <input type="text" size="50" name="newblogname" value="'.
357: $displayfeedname.'" />':'').'<ul>':'</title>'));
358: # Render private items?
359: my $viewpubliconly=1;
360: if (($env{'user.name'} eq $uname) && ($env{'user.domain'} eq $udom)) {
361: $viewpubliconly=0;
362: }
363: # Get feed items
364: my %newsfeed=&Apache::lonnet::dump($feedname,$udom,$uname);
365: foreach my $entry (sort(keys(%newsfeed)),$newid.'_status') {
366: if ($entry=~/^(\d+)\_status$/) { # is an entry
367: my $id=$1;
368: if ($edit) {
369: my %lt=&Apache::lonlocal::texthash('public' => 'public',
370: 'private' => 'private',
371: 'hidden' => 'hidden',
372: 'delete' => 'delete',
373: 'store' => 'Store changes',
374: 'title' => 'Title',
375: 'link' => 'Link',
376: 'description' => 'Description');
377: my %status=();
378: unless ($newsfeed{$id.'_status'}) { $newsfeed{$id.'_status'}='public'; }
379: $status{$newsfeed{$id.'_status'}}='checked="checked"';
380: $r->print(<<ENDEDIT);
381: <li>
382: <label><input name='$id\_modified' type='checkbox' value="modified" /> $lt{'store'}</label>
383:
384: <label><input name='$id\_status' type="radio" value="public" $status{'public'} onClick="changed(this.form,'$id');" /> $lt{'public'}</label>
385:
386: <label><input name='$id\_status' type="radio" value="private" $status{'private'} onClick="changed(this.form,'$id');" /> $lt{'private'}</label>
387:
388: <label><input name='$id\_status' type="radio" value="hidden" $status{'hidden'} onClick="changed(this.form,'$id');" /> $lt{'hidden'}</label>
389:
390: <label><input name='$id\_status' type="radio" value="deleted" onClick="changed(this.form,'$id');" /> $lt{'delete'}</label>
391: <br />
392: $lt{'title'}:
393: <input name='$id\_title' type='text' size='60' value='$newsfeed{$id.'_title'}' onChange="changed(this.form,'$id');" /><br />
394: $lt{'description'}:<br />
395: <textarea name='$id\_description' rows="6" cols="80" onChange="changed(this.form,'$id');">$newsfeed{$id.'_description'}</textarea><br />
396: $lt{'link'}:
397: <input name='$id\_link' type='text' size='60' value='$newsfeed{$id.'_link'}' onChange="changed(this.form,'$id');" />
398: <hr /></li>
399: ENDEDIT
400: } else { # not in edit mode, just displaying
401: if (($newsfeed{$id.'_status'} ne 'public') && ($viewpubliconly)) { next; }
402: if ($newsfeed{$id.'_status'} eq 'hidden') { next; }
403: $r->print("\n".($html?"\n<li><b>":"<item>\n<title>").$newsfeed{$id.'_title'}.
404: ($html?"</b><br />\n":"</title>\n<description>").
405: $newsfeed{$id.'_description'}.
406: ($html?"<br />\n<a href='":"</description>\n<link>").
407: "http://".$ENV{'HTTP_HOST'}.
408: $newsfeed{$id.'_link'}.
409: ($html?("'>".&mt('Read more')."</a><br />\n"):"</link>\n"));
410: # Enclosure? Get stats
411: if ($newsfeed{$id.'_enclosureurl'}) {
412: my @stat=&Apache::lonnet::stat_file($newsfeed{$id.'_enclosureurl'});
413: if ($stat[7]) {
414: # Has non-zero length (and exists)
415: my $enclosuretype=$newsfeed{$id.'_enclosetype'};
416: $r->print(($html?"<a href='":"\n<enclosure url='").
417: $newsfeed{$id.'_enclosureurl'}."' length='".$stat[7].
418: "' type='".$enclosuretype.($html?"'>".&mt('Enclosure')."</a>":"' />"));
419: }
420: }
421: if ($html) { # is HTML
422: $r->print("\n<hr /></li>\n");
423: } else { # is RSS
424: $r->print("\n<guid isPermaLink='false'>".$id.$filterfeedname.'_'.$udom.'_'.$uname."</guid></item>\n");
425: }
426: } # end of "in edit mode"
427: } # end of rendering a real entry
428: } # end of loop through all keys
429: if ($html) {
430: $r->print('</ul>');
431: if ($edit) {
432: $r->print('<input type="hidden" name="newid" value="'.$newid.'"/><input type="submit" value="'.&mt('Store Marked Changes').'" />'.
433: ($displayoption eq 'hidden'?'<input type="submit" name="advertisethisblog" value="'.&mt('Advertise this Feed').'" />':
434: '<input type="submit" name="hidethisblog" value="'.&mt('Hide this Feed').'" />'));
435: }
436: }
437: } # was a real display feedname
438: $r->print(($html?'</form>'.&Apache::loncommon::end_page():'</channel></rss>'."\n"));
439: } # a real user
440: return OK;
441: } # end handler
442: 1;
443: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to lonrss.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / interface