1: # The LearningOnline Network
2: # Simple Page Editor
3: #
4: # $Id: lonsimplepage.pm,v 1.60 2008/12/16 19:01:45 ehlerst Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonsimplepage;
30:
31: use strict;
32: use Apache::Constants qw(:common);
33: use Apache::loncommon;
34: use Apache::lontemplate;
35: use Apache::lonnet;
36: use Apache::lontexconvert;
37: use Apache::lonfeedback;
38: use Apache::lonlocal;
39: use Apache::lonprintout;
40: use Apache::lonxml;
41: use Apache::longroup;
42: use HTML::Entities();
43: use LONCAPA;
44:
45: sub get_db_name {
46: my ($url) = @_;
47: my ($udom,$uname,$marker)=(split(m{/},$url))[2,3,4];
48: my $dom = $env{'course.'.$env{'request.course.id'}.'.domain'};
49: my $crs = $env{'course.'.$env{'request.course.id'}.'.num'};
50:
51: my $db_name;
52:
53: if ($dom && $crs && ($udom eq $dom) && ($uname eq $crs)) {
54: $marker =~ s/\W//g;
55: $db_name = 'grppage_'.$marker;
56: } else {
57: $marker=~s/\D//g;
58: $db_name = 'smppage_'.$marker;
59: }
60: return if (!defined($marker));
61:
62: return $db_name;
63: }
64:
65: sub handler {
66: my $r = shift;
67: &Apache::loncommon::content_type($r,'text/html');
68: $r->send_http_header;
69: return OK if $r->header_only;
70: my $target=$env{'form.grade_target'};
71: # ------------------------------------------------------------ Print the screen
72: if ($target eq 'tex') {
73: $r->print(&Apache::lonprintout::print_latex_header($env{'form.latex_type'}));
74: }
75:
76: # Is this even in a course?
77: unless ($env{'request.course.id'}) {
78: if ($target ne 'tex') {
79: &Apache::loncommon::simple_error_page($r,'','Not in a course');
80: } else {
81: $r->print('\textbf{Not in a course}\end{document}');
82: }
83: return OK;
84: }
85:
86: my $db_name = &get_db_name($r->uri);
87:
88: my $dom = $env{'course.'.$env{'request.course.id'}.'.domain'};
89: my $crs = $env{'course.'.$env{'request.course.id'}.'.num'};
90: my ($group,$group_desc,$group_home_view,$group_home_edit,
91: $group_view_perm,$group_edit_perm);
92: my %curr_group = ();
93: my %groupinfo = ();
94: if ($db_name =~ /^grppage_/) {
95: $group = (split(m{/},$r->uri))[4];
96: $group =~ s/\W//g;
97: my %curr_groups = &Apache::longroup::coursegroups($dom,$crs,$group);
98: if (!%curr_groups) {
99: &Apache::loncommon::simple_error_page($r,'','Invalid group name');
100: return OK;
101: }
102: %groupinfo =
103: &Apache::longroup::get_group_settings($curr_groups{$group});
104: $group_desc = &unescape($groupinfo{'description'});
105: }
106:
107: if (!$db_name) {
108: &Apache::loncommon::simple_error_page($r,'','Invalid call');
109: return OK;
110: }
111:
112: # --------------------------------------------------------- The syllabus fields
113: my %syllabusfields=&Apache::lonlocal::texthash(
114: 'aaa_title' => 'Page Title',
115: 'bbb_content' => 'Content',
116: 'ccc_webreferences' => 'Web References');
117: if ($group ne '') {
118: $syllabusfields{'abb_links'} = &mt('Available Group Tools');
119: }
120:
121:
122: # ------------------------------------------------------------ Get query string
123: &Apache::loncommon::get_unprocessed_cgi
124: ($ENV{'QUERY_STRING'},['forcestudent','forceedit',
125: 'register','ref']);
126: # --------------------------------------------------------------- Force Student
127: my $forcestudent='';
128: if ($env{'form.forcestudent'} || $target eq 'tex' ) { $forcestudent='student'; };
129: my $forceedit='';
130: if ($env{'form.forceedit'}) { $forceedit='edit'; }
131:
132: my $refarg;
133: if ($env{'form.ref'}) {
134: $refarg = '&ref='.$env{'form.ref'};
135: }
136:
137: my %syllabus=&Apache::lonnet::dump($db_name,$dom,$crs);
138:
139: # --------------------------------------- There is such a user, get environment
140:
141: if ($target ne 'tex') {
142: my $title = 'Course Page';
143: if ($group ne '') {
144: $title = 'Group Page';
145: }
146: my $start_page =
147: &Apache::loncommon::start_page($title,undef,
148: {'function' => $forcestudent,
149: 'domain' => $dom,
150: 'force_register' =>
151: $env{'form.register'},});
152: $r->print($start_page);
153: }
154:
155: if ($group ne '') {
156: my $group_view_perm =
157: &Apache::lonnet::allowed('vcg',$env{'request.course.id'}.
158: ($env{'request.course.sec'}?'/'.$env{'request.course.sec'}:''));
159: $group_edit_perm =
160: &Apache::lonnet::allowed('mdg',$env{'request.course.id'}.
161: ($env{'request.course.sec'}?'/'.$env{'request.course.sec'}:''));
162: $group_home_view = &Apache::lonnet::allowed('vgh',
163: $env{'request.course.id'}.'/'.$group);
164: $group_home_edit = &Apache::lonnet::allowed('mgh',
165: $env{'request.course.id'}.'/'.$group);
166: if ($group_view_perm || $group_edit_perm || $group_home_view ||
167: $group_home_edit || &Apache::longroup::check_group_access($group)) {
168: if (($env{'form.ref'} eq 'grouplist') && ($target ne 'tex')) {
169: $r->print(&grouppage_breadcrumbs($dom,$crs,$group,$group_desc));
170: }
171: if ((!$group_home_edit) && (!$group_home_view) &&
172: (!$group_view_perm) && (!$group_edit_perm)) {
173: &display_group_links($r,$target,$group,'view',$refarg,%groupinfo);
174: if ($env{'form.grade_target'} ne 'tex') {
175: $r->print(&Apache::loncommon::end_page());
176: } else {
177: $r->print('\end{document}');
178: }
179: return OK;
180: }
181: } else {
182: my $msg =
183: &mt('You do not currently have rights to view this group.');
184: if ($target ne 'tex') {
185: $r->print("<p>$msg</p>".
186: &Apache::loncommon::end_page());
187: } else {
188: $r->print('\textbf{'.$msg.'}\end{document}');
189: }
190: return OK;
191: }
192: my ($blocked,$blocktext) =
193: &Apache::loncommon::blocking_status('groups');
194: if ($blocked) {
195: $r->print($blocktext);
196: $r->print(&Apache::loncommon::end_page());
197: return OK;
198: }
199: }
200:
201: my $allowed;
202:
203: if ($group ne '') {
204: $allowed = $group_edit_perm;
205: if (!$allowed) {
206: $allowed = $group_home_edit;
207: }
208: } else {
209: $allowed=&Apache::lonnet::allowed('mdc',$env{'request.course.id'});
210: }
211: my $privileged=$allowed;
212: if (($syllabus{'uploaded.lastmodified'}) && (!$forceedit)) {
213: $forcestudent='student';
214: }
215:
216: if ($forcestudent or $target eq 'tex') { $allowed=0; }
217:
218: if ($allowed) {
219: $r->print('<p>'.'<br /><a href="'.$r->uri.'?forcestudent=1'.$refarg.'">'
220: .'<font size="+1">'.&mt('Show Student View').'</font></a>'.
221: &Apache::loncommon::help_open_topic('Uploaded_Templates_PublicView').
222: &Apache::loncommon::help_open_topic('Uploaded_Templates_TextBoxes',&mt('Help with filling in text boxes'))
223: .'</p>');
224: # .'<br /><a href="'.$r->uri.'?forcestudent=1'.$refarg.'">'
225: # .'<font size="+1">'.&mt('Show Student View').'</font></a>'.
226: # &Apache::loncommon::help_open_topic('Uploaded_Templates_PublicView').'</p>');
227: } elsif ($privileged and $target ne 'tex') {
228: my $edittext = &mt('Edit');
229: if ($group ne '') {
230: $edittext = &mt('Edit Group Homepage');
231: }
232: $r->print('<a href="'.$r->uri.'?forceedit=edit'.$refarg.'"><font size="+1">'.$edittext.'</font></a>');
233: if ($group ne '') {
234: if ($group_edit_perm) {
235: $r->print(' <font size="+1">'.
236: '<a href="/adm/coursegroups?action=modify&refpage=grouplist'.
237: '&state=pick_task&groupname='.$group.'">'.
238: &mt('Edit Group Settings').'</a></font>');
239: }
240: }
241: }
242: if (($env{'form.uploaddoc.filename'} and $target ne 'tex') &&
243: ($env{'form.storeupl'}) && ($allowed)) {
244: if ($env{'form.uploaddoc.filename'}=~/\.(gif|jpg|png|jpeg)$/i) {
245: if ($syllabus{'uploaded.photourl'}) {
246: &Apache::lonnet::removeuploadedurl($syllabus{'uploaded.photourl'});
247: }
248: if ($group ne '') {
249: $syllabus{'uploaded.photourl'}=&Apache::lonnet::userfileupload(
250: 'uploaddoc',1,"grouppage/$group");
251: } else {
252: $syllabus{'uploaded.photourl'}=
253: &Apache::lonnet::userfileupload('uploaddoc',1,'simplepage');
254: }
255: }
256: $syllabus{'uploaded.lastmodified'}=time;
257: &Apache::lonnet::put($db_name,\%syllabus,$dom,$crs);
258: }
259: if (($allowed) && ($env{'form.storesyl'})) {
260: foreach my $syl_field (keys(%syllabusfields)) {
261: my $field=$env{'form.'.$syl_field};
262: chomp($field);
263: $field=~s/\s+$//s;
264: $field=~s/^\s+//s;
265: $field=~s/\<br\s*\/*\>$//s;
266: $field=&Apache::lonfeedback::clear_out_html($field,1);
267: $syllabus{$syl_field}=$field;
268: }
269: $syllabus{'uploaded.lastmodified'}=time;
270: &Apache::lonnet::put($db_name,\%syllabus,$dom,$crs);
271: }
272:
273: # ---------------------------------------------------------------- Get syllabus
274: if ((($syllabus{'uploaded.lastmodified'}) &&
275: (($group ne '' && ($group_home_view || $group_edit_perm ||
276: $group_view_perm)) || ($group eq ''))) || ($allowed)) {
277: my $image;
278: if ($syllabus{'uploaded.photourl'}) {
279: &Apache::lonnet::allowuploaded('/adm/smppg',
280: $syllabus{'uploaded.photourl'});
281:
282: $image='<img src="'.$syllabus{'uploaded.photourl'}.'"
283: align="right" />';
284: if ($target eq 'tex') {
285: $image=&Apache::lonxml::xmlparse($r,'tex',$image);
286: }
287: }
288: if ($allowed) {
289: $r->print(
290: '<form method="post" enctype="multipart/form-data">'.
291: '<input type="hidden" name="forceedit" value="edit" />'.
292: '<h3>'.&mt('Upload a Photo').'</h3>'.
293: '<input type="file" name="uploaddoc" size="50" />'.
294: '<input type="submit" name="storeupl" value="'.&mt('Upload').'" />'.
295: '</form><form method="post">'.
296: '<input type="hidden" name="forceedit" value="edit" />');
297: }
298: &Apache::lontemplate::start_columnSection($r);
299: if($allowed){
300: $r->print($image.'<div class="clear"> </div>');
301: #'<br style="clear: both;" />');
302: }
303: &Apache::lontemplate::start_ContentBox($r,$allowed);
304: foreach my $field (sort(keys(%syllabusfields))) {
305: if (($syllabus{$field}) || ($allowed) ||
306: ($field eq 'abb_links' && $group ne '')) {
307: my $message=$syllabus{$field};
308: &Apache::lonfeedback::newline_to_br(\$message);
309: $message
310: =~s/(https*\:\/\/[^\s]+)/\<a href=\"$1\"\>\<tt\>$1\<\/tt\>\<\/a\>/g;
311: if ($allowed) {
312: $message=&Apache::lonspeller::markeduptext($message);
313: }
314: if ($target ne 'tex') {
315: $message=&Apache::lontexconvert::msgtexconverted($message);
316: }
317: if ($field eq 'abb_links' && $group ne '') {
318: $r->print('<br /><input type="hidden" name="'.$field.
319: '" value="'.$syllabus{$field}.'" />');
320: &display_group_links($r,$target,$group,'edit',$refarg,
321: %groupinfo);
322: $r->print('<br />');
323: } elsif ($field eq 'aaa_title') {
324: if ($target ne 'tex') {
325: $r->print('<h1>'.$message.'</h1>');
326: } else {
327: my $safeinit;
328: $r->print(&Apache::lonxml::xmlparse($r,'tex','<h1>'.$message.'</h1>'));
329: }
330: if ($allowed) {
331: if ($env{'form.grade_target'} ne 'tex') {
332: $r->print('<br /><h3>'.&mt('Title').'</h3>');
333: &Apache::lontemplate::print_editbox_template($r,$syllabus{$field},$field);
334: } else {
335: my $safeinit;
336: $r->print(&Apache::lonxml::xmlparse($r,'tex',$syllabus{$field},$safeinit));
337: }
338: }
339: } else {
340: if ($target ne 'tex') {
341: &Apache::lontemplate::print_template($r,$syllabusfields{$field},$message,$allowed);
342: } else {
343: my $safeinit;
344: $r->print(&Apache::lonxml::xmlparse($r,'tex','<h3>'.$syllabusfields{$field}.'</h3>'));
345: $r->print(&Apache::lonxml::xmlparse($r,'tex',$message));
346: }
347: if ($allowed) {
348: if ($target ne 'tex') {
349: &Apache::lontemplate::print_editbox_template($r,$syllabus{$field},$field);
350: } else {
351: my $safeinit;
352: $r->print(&Apache::lonxml::xmlparse($r,'tex',$syllabus{$field},$safeinit));
353: }
354: }
355: }
356: }
357: }
358: &Apache::lontemplate::end_ContentBox($r);
359: if(!$allowed){
360: $r->print($image);
361: }
362: &Apache::lontemplate::end_columnSection($r);
363: if ($allowed) {
364: $r->print('<p>'.'<br /><a href="'.$r->uri.'?forcestudent=1'.$refarg.'">'
365: .'<font size="+1">'.&mt('Show Student View').'</font></a>'.
366: &Apache::loncommon::help_open_topic('Uploaded_Templates_PublicView').'</p>');
367: }
368: if ($allowed && ($env{'form.grade_target'} ne 'tex')) {
369: $r->print(&Apache::lonhtmlcommon::htmlareaselectactive
370: ('bbb_content').'</form>');
371: }
372: if ($env{'form.grade_target'} ne 'tex') {$r->print('</p>');}
373: } else {
374: if ($group ne '') {
375: &display_group_links($r,$target,$group,'view',$refarg,%groupinfo);
376: } else {
377: $r->print(&mt('<p>No page information provided.</p>'));
378: }
379: }
380: if ($env{'form.grade_target'} ne 'tex') {
381: $r->print(&Apache::loncommon::end_page());
382: } else {
383: $r->print('\end{document}');
384: }
385: return OK;
386: }
387:
388: sub display_group_links {
389: my ($r,$target,$group,$context,$refarg,%groupinfo) = @_;
390: my @available = ();
391: my %menu = ();
392: %{$menu{'email'}} = (
393: text => 'Group Message',
394: href => '/adm/email?compose=group&group='.$group.
395: $refarg,
396: );
397: %{$menu{'discussion'}} = (
398: text => 'Discussion Boards',
399: href => '/adm/groupboards?group='.$group.$refarg,
400: );
401: %{$menu{'chat'}} = (
402: text => 'Group Chat',
403: href => "javascript:group_chat('$group')",
404: );
405: %{$menu{'files'}} = (
406: text => 'File Repository',
407: href => '/adm/coursegrp_portfolio?group='.$group.
408: $refarg,
409: );
410: %{$menu{'roster'}} = (
411: text => 'Membership Roster',
412: href => '/adm/grouproster?group='.$group.$refarg,
413: );
414: foreach my $tool (sort(keys(%menu))) {
415: if ($groupinfo{functions}{$tool} eq 'on') {
416: push(@available,$tool);
417: }
418: }
419: if (@available > 0) {
420: my $output = '<table cellspacing="4" cellpadding="4"><tr>';
421: foreach my $tool (@available) {
422: if ($target eq 'tex') {
423: $output .= '<td>'.&mt($menu{$tool}{text}).'</td>';
424: } else {
425: $output .= '<td><a href="'.$menu{$tool}{href}.'">'.
426: &mt($menu{$tool}{text}).'</a></td>';
427: }
428: }
429: $output .= '</tr></table>';
430: if ($target eq 'tex') {
431: $r->print(&Apache::lonxml::xmlparse($r,'tex',&mt('Available functions').'<br /><br />'.$output));
432: } else {
433: $r->print('<h3>'.&mt('Available Group Tools').'</h3>'.$output);
434: }
435: } else {
436: my $output;
437: if ($context eq 'edit') {
438: $output = &mt('No group functionality.');
439: } else {
440: $output = &mt('No group functionality (e.g., e-mail, discussion, chat or file upload) is currently available to you in this group: [_1].','<b>'.&unescape($groupinfo{'description'}).'</b>');
441: }
442: if ($target eq 'tex') {
443: $r->print(&Apache::lonxml::xmlparse($r,'tex',$output));
444: } else {
445: $r->print($output);
446: }
447: }
448: }
449:
450: sub grouppage_breadcrumbs {
451: my ($cdom,$cnum,$group,$description) = @_;
452: &Apache::lonhtmlcommon::clear_breadcrumbs();
453: &Apache::lonhtmlcommon::add_breadcrumb
454: ({href=>"/adm/coursegroups",
455: text=>"Groups",
456: title=>"Display Groups"},
457: {href=>"/adm/$cdom/$cnum/$group/smppg?ref=grouplist",
458: text=>"Group: $description",
459: title=>"Go to group's home page"},
460: );
461: my $output .= &Apache::lonhtmlcommon::breadcrumbs(&mt('Group page - [_1]',
462: $description));
463: return $output;
464: }
465:
466: 1;
467: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>