1: # The LearningOnline Network with CAPA
2: # Handler for requesting to have slots added to a students record
3: #
4: # $Id: slotrequest.pm,v 1.47 2006/02/09 18:04:51 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: package Apache::slotrequest;
31:
32: use strict;
33: use Apache::Constants qw(:common :http :methods);
34: use Apache::loncommon();
35: use Apache::lonlocal;
36: use Apache::lonnet;
37: use Date::Manip;
38:
39: sub fail {
40: my ($r,$code)=@_;
41: if ($code eq 'not_valid') {
42: $r->print('<p>'.&mt('Unable to understand what resource you wanted to sign up for.').'</p>');
43:
44: } elsif ($code eq 'not_allowed') {
45: $r->print('<p>'.&mt('Not allowed to sign up or change reservations at this time.').'</p>');
46: } else {
47: $r->print('<p>'.&mt('Failed.').'</p>');
48: }
49:
50: &return_link($r);
51: &end_page($r);
52: }
53:
54: sub start_page {
55: my ($r,$title)=@_;
56: my $html=&Apache::lonxml::xmlbegin();
57: $r->print($html.'<head><title>'.&mt($title).'</title></head>');
58: $r->print(&Apache::loncommon::bodytag($title));
59: }
60:
61: sub end_page {
62: my ($r)=@_;
63: $r->print(&Apache::loncommon::endbodytag().'</html>');
64: }
65:
66: =pod
67:
68: slot_reservations db
69: - keys are
70: - slotname\0id -> value is an hashref of
71: name -> user@domain of holder
72: timestamp -> timestamp of reservation
73: symb -> symb of resource that it is reserved for
74:
75: =cut
76:
77: sub get_course {
78: (undef,my $courseid)=&Apache::lonxml::whichuser();
79: my $cdom=$env{'course.'.$courseid.'.domain'};
80: my $cnum=$env{'course.'.$courseid.'.num'};
81: return ($cnum,$cdom);
82: }
83:
84: sub get_reservation_ids {
85: my ($slot_name)=@_;
86:
87: my ($cnum,$cdom)=&get_course();
88:
89: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
90: "^$slot_name\0");
91: if (&network_error(%consumed)) {
92: return 'error: Unable to determine current status';
93: }
94: my ($tmp)=%consumed;
95: if ($tmp=~/^error: 2 / ) {
96: return 0;
97: }
98: return keys(%consumed);
99: }
100:
101: sub space_available {
102: my ($slot_name,$slot)=@_;
103: my $max=$slot->{'maxspace'};
104:
105: if (!defined($max)) { return 1; }
106:
107: my $consumed=scalar(&get_reservation_ids($slot_name));
108: if ($consumed < $max) {
109: return 1
110: }
111: return 0;
112: }
113:
114: sub check_for_reservation {
115: my ($symb,$mode)=@_;
116: my $student = &Apache::lonnet::EXT("resource.0.availablestudent", $symb,
117: $env{'user.domain'}, $env{'user.name'});
118:
119: my $course = &Apache::lonnet::EXT("resource.0.available", $symb,
120: $env{'user.domain'}, $env{'user.name'});
121: my @slots = (split(/:/,$student), split(/:/, $course));
122:
123: &Apache::lonxml::debug(" slot list is ".join(':',@slots));
124:
125: my ($cnum,$cdom)=&get_course();
126: my %slots=&Apache::lonnet::get('slots', [@slots], $cdom, $cnum);
127:
128: if (&network_error($student) || &network_error($course) ||
129: &network_error(%slots)) {
130: return 'error: Unable to determine current status';
131: }
132: my @got;
133: foreach my $slot_name (sort {
134: if (ref($slots{$a}) && ref($slots{$b})) {
135: return $slots{$a}{'starttime'} <=> $slots{$b}{'starttime'}
136: }
137: if (ref($slots{$a})) { return -1;}
138: if (ref($slots{$b})) { return 1;}
139: return 0;
140: } @slots) {
141: next if (!defined($slots{$slot_name}) ||
142: !ref($slots{$slot_name}));
143: &Apache::lonxml::debug(time." $slot_name ".
144: $slots{$slot_name}->{'starttime'}." -- ".
145: $slots{$slot_name}->{'startreserve'});
146: if ($slots{$slot_name}->{'endtime'} > time &&
147: $slots{$slot_name}->{'startreserve'} < time) {
148: # between start of reservation times and end of slot
149: if ($mode eq 'allslots') {
150: push(@got,$slot_name);
151: } else {
152: return($slot_name, $slots{$slot_name});
153: }
154: }
155: }
156: if ($mode eq 'allslots' && @got) {
157: return @got;
158: }
159: return (undef,undef);
160: }
161:
162: sub check_for_conflict {
163: my ($symb,$new_slot_name,$new_slot,$slots)=@_;
164:
165: if (!defined($new_slot->{'uniqueperiod'})) { return undef; }
166:
167: my $student = &Apache::lonnet::EXT("resource.0.availablestudent", $symb,
168: $env{'user.domain'}, $env{'user.name'});
169: my $course = &Apache::lonnet::EXT("resource.0.available", $symb,
170: $env{'user.domain'}, $env{'user.name'});
171: my @slots = (split(/:/,$student), split(/:/, $course));
172: my ($cnum,$cdom)=&get_course();
173: if (!ref($slots)) {
174: my %slots=&Apache::lonnet::get('slots', [@slots], $cdom, $cnum);
175: $slots = \%slots;
176: }
177:
178: if (&network_error($student) || &network_error($course) ||
179: &network_error(%$slots)) {
180: return 'error: Unable to determine current status';
181: }
182:
183: my ($new_uniq_start,$new_uniq_end) = @{$new_slot->{'uniqueperiod'}};
184: foreach my $slot_name (@slots) {
185: next if (!defined($slots->{$slot_name}) ||
186: !ref($slots->{$slot_name}));
187:
188: next if (!defined($slots->{$slot_name}{'uniqueperiod'}) ||
189: !ref($slots->{$slot_name}{'uniqueperiod'}));
190: my ($start,$end)=@{$slots->{$slot_name}{'uniqueperiod'}};
191: if (!
192: ($start < $new_uniq_start && $end < $new_uniq_start) ||
193: ($start > $new_uniq_end && $end > $new_uniq_end )) {
194: return $slot_name;
195: }
196: }
197: return undef;
198:
199: }
200:
201: sub network_error {
202: my ($result) = @_;
203: if ($result =~ /^(con_lost|no_such_host|error: [^2])/) {
204: return 1;
205: }
206: return 0;
207: }
208:
209: sub make_reservation {
210: my ($slot_name,$slot,$symb)=@_;
211:
212: my ($cnum,$cdom)=&get_course();
213:
214: my $value=&Apache::lonnet::EXT("resource.0.availablestudent",$symb,
215: $env{'user.domain'},$env{'user.name'});
216: &Apache::lonxml::debug("value is $value<br />");
217: if (&network_error($value)) {
218: return 'error: Unable to determine current status';
219: }
220:
221: foreach my $other_slot (split(/:/, $value)) {
222: if ($other_slot eq $slot_name) {
223: my %consumed=&Apache::lonnet::dump('slot_reservations', $cdom,
224: $cnum, "^$slot_name\0");
225: if (&network_error($value)) {
226: return 'error: Unable to determine current status';
227: }
228: my $me=$env{'user.name'}.'@'.$env{'user.domain'};
229: foreach my $key (keys(%consumed)) {
230: if ($consumed{$key}->{'name'} eq $me) {
231: my $num=(split('\0',$key))[1];
232: return -$num;
233: }
234: }
235: }
236: }
237:
238: my $max=$slot->{'maxspace'};
239: if (!defined($max)) { $max=99999; }
240:
241: my (@ids)=&get_reservation_ids($slot_name);
242: if (&network_error(@ids)) {
243: return 'error: Unable to determine current status';
244: }
245: my $last=0;
246: foreach my $id (@ids) {
247: my $num=(split('\0',$id))[1];
248: if ($num > $last) { $last=$num; }
249: }
250:
251: my $wanted=$last+1;
252: &Apache::lonxml::debug("wanted $wanted<br />");
253: if (scalar(@ids) >= $max) {
254: # full up
255: return undef;
256: }
257:
258: my %reservation=('name' => $env{'user.name'}.'@'.$env{'user.domain'},
259: 'timestamp' => time,
260: 'symb' => $symb);
261:
262: my $success=&Apache::lonnet::newput('slot_reservations',
263: {"$slot_name\0$wanted" =>
264: \%reservation},
265: $cdom, $cnum);
266:
267: if ($success eq 'ok') {
268: my $new_value=$slot_name;
269: if ($value) {
270: $new_value=$value.':'.$new_value;
271: }
272: my $result=&Apache::lonparmset::storeparm_by_symb($symb,
273: '0_availablestudent',
274: 1, $new_value, 'string',
275: $env{'user.name'},
276: $env{'user.domain'});
277: &Apache::lonxml::debug("hrrm $result");
278: return $wanted;
279: }
280:
281: # someone else got it
282: return undef;
283: }
284:
285: sub remove_registration {
286: my ($r) = @_;
287: my $name = &Apache::loncommon::plainname($env{'form.uname'},
288: $env{'form.udom'});
289:
290: my $title = &Apache::lonnet::gettitle($env{'form.symb'});
291:
292: my $hidden_input;
293: foreach my $parm ('uname','udom','slotname','entry','symb') {
294: $hidden_input .=
295: '<input type="hidden" name="'.$parm.'" value="'
296: .&HTML::Entities::encode($env{'form.'.$parm},'"<>&\'').'" />'."\n";
297: }
298: $r->print(<<"END_CONFIRM");
299: <p> Remove $name from slot $env{'form.slotname'} for $title</p>
300: <form action="/adm/slotrequest" method="POST">
301: <input type="hidden" name="command" value="release" />
302: $hidden_input
303: <input type="submit" name="Yes" value="yes" />
304: </form>
305: <form action="/adm/slotrequest" method="POST">
306: <input type="hidden" name="command" value="showslots" />
307: <input type="submit" name="No" value="no" />
308: </form>
309: END_CONFIRM
310:
311: }
312:
313: sub release_slot {
314: my ($r,$symb,$slot_name,$inhibit_return_link,$mgr)=@_;
315:
316: if ($slot_name eq '') { $slot_name=$env{'form.slotname'}; }
317: my ($cnum,$cdom)=&get_course();
318:
319: my ($uname,$udom) = ($env{'user.name'}, $env{'user.domain'});
320: if ($mgr eq 'F'
321: && defined($env{'form.uname'}) && defined($env{'form.udom'})) {
322: ($uname,$udom) = ($env{'form.uname'}, $env{'form.udom'});
323: }
324:
325: if ($mgr eq 'F'
326: && defined($env{'form.symb'})) {
327: $symb = $env{'form.symb'};
328: }
329: my %slot=&Apache::lonnet::get_slot($slot_name);
330: my $description=&get_description($env{'form.slotname'},\%slot);
331:
332: if ($mgr ne 'F') {
333: if ($slot{'starttime'} < time) {
334: $r->print("<p>Not allowed to release Reservation: $description, as it has already ended. </p>");
335: &return_link($r);
336: return 0;
337: }
338: }
339: # get parameter string, check for existance, rebuild string with the slot
340: my @slots = split(/:/,&Apache::lonnet::EXT("resource.0.availablestudent",
341: $symb,$udom,$uname));
342:
343: my @new_slots;
344: foreach my $exist_slot (@slots) {
345: if ($exist_slot eq $slot_name) { next; }
346: push(@new_slots,$exist_slot);
347: }
348: my $new_param = join(':',@new_slots);
349:
350: # get slot reservations, check if user has one, if so remove reservation
351: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
352: "^$slot_name\0");
353: foreach my $entry (keys(%consumed)) {
354: if ( $consumed{$entry}->{'name'} eq ($uname.'@'.$udom) ) {
355: &Apache::lonnet::del('slot_reservations',[$entry],
356: $cdom,$cnum);
357: }
358: }
359:
360: # store new parameter string
361: my $result=&Apache::lonparmset::storeparm_by_symb($symb,
362: '0_availablestudent',
363: 1, $new_param, 'string',
364: $uname,$udom);
365: $r->print("<p>Released Reservation: $description</p>");
366: if ($mgr eq 'F') {
367: $r->print('<p><a href="/adm/slotrequest?command=showslots">'.
368: &mt('Return to slot list').'</a></p>');
369: }
370: if (!$inhibit_return_link) { &return_link($r); }
371: return 1;
372: }
373:
374: sub delete_slot {
375: my ($r)=@_;
376:
377: my $slot_name = $env{'form.slotname'};
378: my %slot=&Apache::lonnet::get_slot($slot_name);
379:
380: my ($cnum,$cdom)=&get_course();
381: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
382: "^$slot_name\0");
383: my ($tmp) = %consumed;
384: if ($tmp =~ /error: 2/) { undef(%consumed); }
385:
386: if (%slot && !%consumed) {
387: $slot{'type'} = 'deleted';
388: my $ret = &Apache::lonnet::cput('slots', {$slot_name => \%slot},
389: $cdom, $cnum);
390: if ($ret eq 'ok') {
391: $r->print("<p>Slot <tt>$slot_name</tt> marked as deleted.</p>");
392: } else {
393: $r->print("<p> An error ($ret) occurse when attempting to delete Slot <tt>$slot_name</tt>.</p>");
394: }
395: } else {
396: if (%consumed) {
397: $r->print("<p>Slot <tt>$slot_name</tt> has active reservations.</p>");
398: } else {
399: $r->print("<p>Slot <tt>$slot_name</tt> does not exist.</p>");
400: }
401: }
402: $r->print('<p><a href="/adm/slotrequest?command=showslots">'.
403: &mt('Return to slot list').'</a></p>');
404: &return_link($r);
405: }
406:
407: sub return_link {
408: my ($r) = @_;
409: $r->print('<p><a href="/adm/flip?postdata=return:">'.
410: &mt('Return to last resource').'</a></p>');
411: }
412:
413: sub get_slot {
414: my ($r,$symb)=@_;
415:
416: my %slot=&Apache::lonnet::get_slot($env{'form.slotname'});
417: my $slot_name=&check_for_conflict($symb,$env{'form.slotname'},\%slot);
418:
419: if ($slot_name =~ /^error: (.*)/) {
420: $r->print("<p>An error occured while attempting to make a reservation. ($1)</p>");
421: &return_link($r);
422: return;
423: }
424: if ($slot_name) {
425: my %slot=&Apache::lonnet::get_slot($slot_name);
426: my $description1=&get_description($slot_name,\%slot);
427: %slot=&Apache::lonnet::get_slot($env{'form.slotname'});
428: my $description2=&get_description($env{'form.slotname'},\%slot);
429: $r->print("<p>Already have a reservation: $description1</p>");
430: if ($slot_name ne $env{'form.slotname'}) {
431: $r->print(<<STUFF);
432: <form method="POST" action="/adm/slotrequest">
433: <input type="hidden" name="symb" value="$env{'form.symb'}" />
434: <input type="hidden" name="slotname" value="$env{'form.slotname'}" />
435: <input type="hidden" name="releaseslot" value="$slot_name" />
436: <input type="hidden" name="command" value="change" />
437: STUFF
438: $r->print("<p>You can either ");
439: $r->print(<<STUFF);
440: <input type="submit" name="change" value="Change" />
441: STUFF
442: $r->print(' your reservation from <b>'.$description1.'</b> to <b>'.
443: $description2.
444: '</b> <br />or </p>');
445: &return_link($r);
446: $r->print(<<STUFF);
447: </form>
448: STUFF
449: } else {
450: &return_link($r);
451: }
452: return;
453: }
454:
455: my $reserved=&make_reservation($env{'form.slotname'},
456: \%slot,$symb);
457: my $description=&get_description($env{'form.slotname'},\%slot);
458: if (defined($reserved)) {
459: if ($slot_name =~ /^error: (.*)/) {
460: $r->print("<p>An error occured while attempting to make a reservation. ($1)</p>");
461: } elsif ($reserved > -1) {
462: $r->print("<p>Success: $description</p>");
463: } elsif ($reserved < 0) {
464: $r->print("<p>Already reserved: $description</p>");
465: }
466: &return_link($r);
467: return;
468: }
469:
470: my %lt=('request'=>"Availibility list",
471: 'try' =>'Try again');
472: %lt=&Apache::lonlocal::texthash(%lt);
473:
474: $r->print(<<STUFF);
475: <p> <font color="red">Failed</font> to reserve a spot for $description. </p>
476: <p>
477: <form method="POST" action="/adm/slotrequest">
478: <input type="submit" name="Try Again" value="$lt{'try'}" />
479: <input type="hidden" name="symb" value="$env{'form.symb'}" />
480: <input type="hidden" name="slotname" value="$env{'form.slotname'}" />
481: <input type="hidden" name="command" value="get" />
482: </form>
483: ?
484: </p>
485: <p>
486: or
487: <form method="POST" action="/adm/slotrequest">
488: <input type="hidden" name="symb" value="$env{'form.symb'}" />
489: <input type="submit" name="requestattempt" value="$lt{'request'}" />
490: </form>
491: </p>
492: or
493: STUFF
494:
495: &return_link($r);
496: return;
497: }
498:
499: sub allowed_slot {
500: my ($slot_name,$slot,$symb,$slots)=@_;
501: #already started
502: if ($slot->{'starttime'} < time) {
503: # all open slot to be schedulable
504: #return 0;
505: }
506: &Apache::lonxml::debug("$slot_name starttime good");
507: #already ended
508: if ($slot->{'endtime'} < time) {
509: return 0;
510: }
511: &Apache::lonxml::debug("$slot_name endtime good");
512: # not allowed to pick this one
513: if (defined($slot->{'type'})
514: && $slot->{'type'} ne 'schedulable_student') {
515: return 0;
516: }
517: &Apache::lonxml::debug("$slot_name type good");
518: # not allowed for this resource
519: if (defined($slot->{'symb'})
520: && $slot->{'symb'} ne $symb) {
521: return 0;
522: }
523: my $conflict = &check_for_conflict($symb,$slot_name,$slot,$slots);
524: if ($conflict) {
525: if ($slots->{$conflict}{'starttime'} < time) {
526: return 0;
527: }
528: }
529: &Apache::lonxml::debug("$slot_name symb good");
530: return 1;
531: }
532:
533: sub get_description {
534: my ($slot_name,$slot)=@_;
535: my $description=$slot->{'description'};
536: if (!defined($description)) {
537: $description=&mt('[_1] From [_2] to [_3]',$slot_name,
538: &Apache::lonlocal::locallocaltime($slot->{'starttime'}),
539: &Apache::lonlocal::locallocaltime($slot->{'endtime'}));
540: }
541: return $description;
542: }
543:
544: sub show_choices {
545: my ($r,$symb)=@_;
546:
547: my ($cnum,$cdom)=&get_course();
548: my %slots=&Apache::lonnet::dump('slots',$cdom,$cnum);
549: my $available;
550: $r->print('<table border="1">');
551: &Apache::lonxml::debug("Checking Slots");
552: my @got_slots=&check_for_reservation($symb,'allslots');
553: foreach my $slot (sort
554: { return $slots{$a}->{'starttime'} <=> $slots{$b}->{'starttime'} }
555: (keys(%slots))) {
556:
557: &Apache::lonxml::debug("Checking Slot $slot");
558: next if (!&allowed_slot($slot,$slots{$slot},undef,\%slots));
559:
560: $available++;
561:
562: my $description=&get_description($slot,$slots{$slot});
563:
564: my $form=&mt('Unavailable');
565: if ((grep(/^\Q$slot\E$/,@got_slots)) ||
566: &space_available($slot,$slots{$slot},$symb)) {
567: my $text=&mt('Select');
568: my $command='get';
569: if (grep(/^\Q$slot\E$/,@got_slots)) {
570: $text=&mt('Free Reservation');
571: $command='release';
572: } else {
573: my $conflict = &check_for_conflict($symb,$slot,$slots{$slot},
574: \%slots);
575: if ($conflict) {
576: $text=&mt('Change Reservation');
577: $command='get';
578: }
579: }
580: my $escsymb=&Apache::lonnet::escape($symb);
581: $form=<<STUFF;
582: <form method="POST" action="/adm/slotrequest">
583: <input type="submit" name="Select" value="$text" />
584: <input type="hidden" name="symb" value="$escsymb" />
585: <input type="hidden" name="slotname" value="$slot" />
586: <input type="hidden" name="command" value="$command" />
587: </form>
588: STUFF
589: }
590: $r->print(<<STUFF);
591: <tr>
592: <td>$form</td>
593: <td>$description</td>
594: </tr>
595: STUFF
596: }
597:
598: if (!$available) {
599: $r->print('<tr><td>No available times. <a href="/adm/flip?postdata=return:">'.
600: &mt('Return to last resource').'</a></td></tr>');
601: }
602: $r->print('</table>');
603: }
604:
605: sub to_show {
606: my ($slot,$when,$deleted) = @_;
607: my $time=time;
608: my $week=60*60*24*7;
609: if ($deleted eq 'hide' && $slot->{'type'} eq 'deleted') {
610: return 0;
611: }
612: if ($when eq 'any') {
613: return 1;
614: } elsif ($when eq 'now') {
615: if ($time > $slot->{'starttime'} &&
616: $time < $slot->{'endtime'}) {
617: return 1;
618: }
619: return 0;
620: } elsif ($when eq 'nextweek') {
621: if ( ($time < $slot->{'starttime'} &&
622: ($time+$week) > $slot->{'starttime'})
623: ||
624: ($time < $slot->{'endtime'} &&
625: ($time+$week) > $slot->{'endtime'}) ) {
626: return 1;
627: }
628: return 0;
629: } elsif ($when eq 'lastweek') {
630: if ( ($time > $slot->{'starttime'} &&
631: ($time-$week) < $slot->{'starttime'})
632: ||
633: ($time > $slot->{'endtime'} &&
634: ($time-$week) < $slot->{'endtime'}) ) {
635: return 1;
636: }
637: return 0;
638: } elsif ($when eq 'willopen') {
639: if ($time < $slot->{'starttime'}) {
640: return 1;
641: }
642: return 0;
643: } elsif ($when eq 'wereopen') {
644: if ($time > $slot->{'endtime'}) {
645: return 1;
646: }
647: return 0;
648: }
649:
650: return 1;
651: }
652:
653: sub remove_link {
654: my ($slotname,$entry,$uname,$udom,$symb) = @_;
655:
656: $slotname = &Apache::lonnet::escape($slotname);
657: $entry = &Apache::lonnet::escape($entry);
658: $uname = &Apache::lonnet::escape($uname);
659: $udom = &Apache::lonnet::escape($udom);
660: $symb = &Apache::lonnet::escape($symb);
661:
662: my $remove= &mt('Remove');
663:
664: return <<"END_LINK";
665: <a href="/adm/slotrequest?command=remove_registration&slotname=$slotname&entry=$entry&uname=$uname&udom=$udom&symb=$symb"
666: >($remove)</a>
667: END_LINK
668:
669: }
670:
671: sub show_table {
672: my ($r,$mgr)=@_;
673:
674: my ($cnum,$cdom)=&get_course();
675: my %slots=&Apache::lonnet::dump('slots',$cdom,$cnum);
676: if ( (keys(%slots))[0] =~ /^error: 2 /) {
677: undef(%slots);
678: }
679: my $available;
680: if ($mgr eq 'F') {
681: $r->print('<div>');
682: $r->print('<form method="POST" action="/adm/slotrequest">
683: <input type="hidden" name="command" value="uploadstart" />
684: <input type="submit" name="start" value="'.&mt('Upload Slot List').'" />
685: </form>');
686: $r->print('<form method="POST" action="/adm/helper/newslot.helper">
687: <input type="submit" name="newslot" value="'.&mt('Create a New Slot').'" />
688: </form>');
689: $r->print('</div>');
690: }
691:
692: my %Saveable_Parameters = ('show' => 'array',
693: 'when' => 'scalar',
694: 'order' => 'scalar',
695: 'deleted' => 'scalar',
696: );
697: &Apache::loncommon::store_course_settings('slotrequest',
698: \%Saveable_Parameters);
699: &Apache::loncommon::restore_course_settings('slotrequest',
700: \%Saveable_Parameters);
701: &Apache::grades::init_perm();
702: my ($classlist,$section,$fullname)=&Apache::grades::getclasslist('all');
703: &Apache::grades::reset_perm();
704:
705: my %show_fields=&Apache::lonlocal::texthash(
706: 'name' => 'Slot Name',
707: 'description' => 'Description',
708: 'type' => 'Type',
709: 'starttime' => 'Start time',
710: 'endtime' => 'End Time',
711: 'startreserve' => 'Time students can start reserving',
712: 'secret' => 'Secret Word',
713: 'maxspace' => 'Maximum # of students',
714: 'ip' => 'IP or DNS restrictions',
715: 'symb' => 'Resource slot is restricted to.',
716: 'uniqueperiod' => 'Period of time slot is unique',
717: 'scheduled' => 'Scheduled Students',
718: 'proctor' => 'List of proctors');
719: my @show_order=('name','description','type','starttime','endtime',
720: 'startreserve','secret','maxspace','ip','symb',
721: 'uniqueperiod','scheduled','proctor');
722: my @show =
723: (exists($env{'form.show'})) ? &Apache::loncommon::get_env_multiple('form.show')
724: : keys(%show_fields);
725: my %show = map { $_ => 1 } (@show);
726:
727: my %when_fields=&Apache::lonlocal::texthash(
728: 'now' => 'Open now',
729: 'nextweek' => 'Open within the next week',
730: 'lastweek' => 'Were open last week',
731: 'willopen' => 'Will open later',
732: 'wereopen' => 'Were open',
733: 'any' => 'Anytime',
734: );
735: my @when_order=('any','now','nextweek','lastweek','willopen','wereopen');
736: $when_fields{'select_form_order'} = \@when_order;
737: my $when = (exists($env{'form.when'})) ? $env{'form.when'}
738: : 'now';
739:
740: my %stu_display_fields=
741: &Apache::lonlocal::texthash('username' => 'User name',
742: 'fullname' => 'Full name',
743: );
744: my @stu_display_order=('fullname','username');
745: my @stu_display =
746: (exists($env{'form.studisplay'})) ? &Apache::loncommon::get_env_multiple('form.studisplay')
747: : keys(%stu_display_fields);
748: my %stu_display = map { $_ => 1 } (@stu_display);
749:
750: my $hide_radio =
751: &Apache::lonhtmlcommon::radio('deleted',$env{'form.deleted'},'hide');
752: my $show_radio =
753: &Apache::lonhtmlcommon::radio('deleted',$env{'form.deleted'},'show');
754:
755: $r->print('<form method="POST" action="/adm/slotrequest">
756: <input type="hidden" name="command" value="showslots" />');
757: $r->print('<div>');
758: $r->print('<table class="inline">
759: <tr><th>'.&mt('Show').'</th>
760: <th>'.&mt('Student Display').'</th>
761: <th>'.&mt('Open').'</th>
762: <th>'.&mt('Options').'</th>
763: </tr>
764: <tr><td>'.&Apache::loncommon::multiple_select_form('show',\@show,6,\%show_fields,\@show_order).
765: '</td>
766: <td>
767: '.&Apache::loncommon::multiple_select_form('studisplay',\@stu_display,
768: 6,\%stu_display_fields,
769: \@stu_display_order).'
770: </td>
771: <td>'.&Apache::loncommon::select_form($when,'when',%when_fields).
772: '</td>
773: <td>
774: <table>
775: <tr>
776: <td rowspan="2">Deleted slots:</td>
777: <td><label>'.$show_radio.'Show</label></td>
778: </tr>
779: <tr>
780: <td><label>'.$hide_radio.'Hide</label></td>
781: </tr>
782: </table>
783: </td>
784: </tr>
785: </table>');
786: $r->print('</div>');
787: $r->print('<p><input type="submit" name="start" value="'.&mt('Update Display').'" /></p>');
788: my $linkstart='<a href="/adm/slotrequest?command=showslots&order=';
789: $r->print('<table class="thinborder">
790: <tr>
791: <th></th>');
792: foreach my $which (@show_order) {
793: if ($which ne 'proctor' && exists($show{$which})) {
794: $r->print('<th>'.$linkstart.$which.'">'.$show_fields{$which}.'</a></th>');
795: }
796: }
797:
798: my %name_cache;
799: my $slotsort = sub {
800: if ($env{'form.order'}=~/^(type|description|endtime|startreserve|maxspace|ip|symb)$/) {
801: if (lc($slots{$a}->{$env{'form.order'}})
802: ne lc($slots{$b}->{$env{'form.order'}})) {
803: return (lc($slots{$a}->{$env{'form.order'}})
804: cmp lc($slots{$b}->{$env{'form.order'}}));
805: }
806: } elsif ($env{'form.order'} eq 'name') {
807: if (lc($a) cmp lc($b)) {
808: return lc($a) cmp lc($b);
809: }
810: } elsif ($env{'form.order'} eq 'uniqueperiod') {
811:
812: if ($slots{$a}->{'uniqueperiod'}[0]
813: ne $slots{$b}->{'uniqueperiod'}[0]) {
814: return ($slots{$a}->{'uniqueperiod'}[0]
815: cmp $slots{$b}->{'uniqueperiod'}[0]);
816: }
817: if ($slots{$a}->{'uniqueperiod'}[1]
818: ne $slots{$b}->{'uniqueperiod'}[1]) {
819: return ($slots{$a}->{'uniqueperiod'}[1]
820: cmp $slots{$b}->{'uniqueperiod'}[1]);
821: }
822: }
823: return $slots{$a}->{'starttime'} <=> $slots{$b}->{'starttime'};
824: };
825: foreach my $slot (sort $slotsort (keys(%slots))) {
826: if (!&to_show($slots{$slot},$when,$env{'form.deleted'})) { next; }
827: if (defined($slots{$slot}->{'type'})
828: && $slots{$slot}->{'type'} ne 'schedulable_student') {
829: #next;
830: }
831: my $description=&get_description($slot,$slots{$slot});
832: my $ids;
833: if (exists($show{'scheduled'})) {
834: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
835: "^$slot\0");
836: my ($tmp)=%consumed;
837: if ($tmp !~ /^error: /) {
838: foreach my $entry (sort(keys(%consumed))) {
839: my (undef,$id)=split("\0",$entry);
840: my ($uname,$udom) = split('@',$consumed{$entry}{'name'});
841: $ids.= '<nobr>';
842: foreach my $item (@stu_display_order) {
843: if ($stu_display{$item}) {
844: if ($item eq 'fullname') {
845: $ids.=$fullname->{"$uname:$udom"}.' ';
846: } elsif ($item eq 'username') {
847: $ids.="<tt>$uname\@$udom</tt> ";
848: }
849: }
850: }
851: $ids.=&remove_link($slot,$entry,$uname,$udom,
852: $consumed{$entry}{'symb'}).'</nobr><br />';
853: }
854: }
855: }
856:
857: my $start=($slots{$slot}->{'starttime'}?
858: &Apache::lonlocal::locallocaltime($slots{$slot}->{'starttime'}):'');
859: my $end=($slots{$slot}->{'endtime'}?
860: &Apache::lonlocal::locallocaltime($slots{$slot}->{'endtime'}):'');
861: my $start_reserve=($slots{$slot}->{'startreserve'}?
862: &Apache::lonlocal::locallocaltime($slots{$slot}->{'startreserve'}):'');
863:
864: my $unique;
865: if (ref($slots{$slot}{'uniqueperiod'})) {
866: $unique=localtime($slots{$slot}{'uniqueperiod'}[0]).','.
867: localtime($slots{$slot}{'uniqueperiod'}[1]);
868: }
869:
870: my $title;
871: if (exists($slots{$slot}{'symb'})) {
872: my (undef,undef,$res)=
873: &Apache::lonnet::decode_symb($slots{$slot}{'symb'});
874: $res = &Apache::lonnet::clutter($res);
875: $title = &Apache::lonnet::gettitle($slots{$slot}{'symb'});
876: $title='<a href="'.$res.'?symb='.$slots{$slot}{'symb'}.'">'.$title.'</a>';
877: }
878:
879: my @proctors;
880: my $rowspan=1;
881: my $colspan=1;
882: if (exists($show{'proctor'})) {
883: $rowspan=2;
884: @proctors= map {
885: my ($uname,$udom)=split(/@/,$_);
886: my $fullname=$name_cache{$_};
887: if (!defined($fullname)) {
888: &Apache::lonnet::logthis("Gettign $uname $udom");
889: $fullname = &Apache::loncommon::plainname($uname,$udom);
890: $fullname =~s/\s/ /g;
891: $name_cache{$_} = $fullname;
892: }
893: &Apache::loncommon::aboutmewrapper($fullname,$uname,$udom);
894: } (sort(split(/\s*,\s*/,$slots{$slot}->{'proctor'})));
895: }
896: my $proctors=join(', ',@proctors);
897:
898: my $edit=(<<"EDITLINK");
899: <a href="/adm/helper/newslot.helper?name=$slot">Edit</a>
900: EDITLINK
901:
902: my $delete=(<<"DELETELINK");
903: <a href="/adm/slotrequest?command=delete&slotname=$slot">Delete</a>
904: DELETELINK
905: if ($ids ne '') { undef($delete); }
906:
907: $r->print("<tr>\n<td rowspan=\"$rowspan\">$edit $delete</td>\n");
908: if (exists($show{'name'})) {
909: $colspan++;$r->print("<td>$slot</td>");
910: }
911: if (exists($show{'description'})) {
912: $colspan++;$r->print("<td>$description</td>\n");
913: }
914: if (exists($show{'type'})) {
915: $colspan++;$r->print("<td>$slots{$slot}->{'type'}</td>\n");
916: }
917: if (exists($show{'starttime'})) {
918: $colspan++;$r->print("<td>$start</td>\n");
919: }
920: if (exists($show{'endtime'})) {
921: $colspan++;$r->print("<td>$end</td>\n");
922: }
923: if (exists($show{'startreserve'})) {
924: $colspan++;$r->print("<td>$start_reserve</td>\n");
925: }
926: if (exists($show{'secret'})) {
927: $colspan++;$r->print("<td>$slots{$slot}{'secret'}</td>\n");
928: }
929: if (exists($show{'maxspace'})) {
930: $colspan++;$r->print("<td>$slots{$slot}{'maxspace'}</td>\n");
931: }
932: if (exists($show{'ip'})) {
933: $colspan++;$r->print("<td>$slots{$slot}{'ip'}</td>\n");
934: }
935: if (exists($show{'symb'})) {
936: $colspan++;$r->print("<td>$title</td>\n");
937: }
938: if (exists($show{'uniqueperiod'})) {
939: $colspan++;$r->print("<td>$unique</td>\n");
940: }
941: if (exists($show{'scheduled'})) {
942: $colspan++;$r->print("<td>$ids</td>\n</tr>\n");
943: }
944: if (exists($show{'proctor'})) {
945: $r->print(<<STUFF);
946: <tr>
947: <td colspan="$colspan">$proctors</td>
948: </tr>
949: STUFF
950: }
951: }
952: $r->print('</table>');
953: }
954:
955: sub upload_start {
956: my ($r)=@_;
957: $r->print(&Apache::grades::checkforfile_js());
958: my $result.='<table width=100% border=0><tr bgcolor="#e6ffff"><td>'."\n";
959: $result.=' <b>'.
960: &mt('Specify a file containing the slot definitions.').
961: '</b></td></tr>'."\n";
962: $result.='<tr bgcolor=#ffffe6><td>'."\n";
963: my $upfile_select=&Apache::loncommon::upfile_select_html();
964: my $ignore=&mt('Ignore First Line');
965: $result.=<<ENDUPFORM;
966: <form method="post" enctype="multipart/form-data" action="/adm/slotrequest" name="slotupload">
967: <input type="hidden" name="command" value="csvuploadmap" />
968: $upfile_select
969: <br /><input type="button" onClick="javascript:checkUpload(this.form);" value="Upload Data" />
970: <label><input type="checkbox" name="noFirstLine" />$ignore</label>
971: </form>
972: ENDUPFORM
973: $result.='</td></tr></table>'."\n";
974: $result.='</td></tr></table>'."\n";
975: $r->print($result);
976: }
977:
978: sub csvuploadmap_header {
979: my ($r,$datatoken,$distotal)= @_;
980: my $javascript;
981: if ($env{'form.upfile_associate'} eq 'reverse') {
982: $javascript=&csvupload_javascript_reverse_associate();
983: } else {
984: $javascript=&csvupload_javascript_forward_associate();
985: }
986:
987: my $checked=(($env{'form.noFirstLine'})?' checked="checked"':'');
988: my $ignore=&mt('Ignore First Line');
989: $r->print(<<ENDPICK);
990: <form method="post" enctype="multipart/form-data" action="/adm/slotrequest" name="slotupload">
991: <h3>Identify fields</h3>
992: Total number of records found in file: $distotal <hr />
993: Enter as many fields as you can. The system will inform you and bring you back
994: to this page if the data selected is insufficient to create the slots.<hr />
995: <input type="button" value="Reverse Association" onClick="javascript:this.form.associate.value='Reverse Association';submit(this.form);" />
996: <label><input type="checkbox" name="noFirstLine" $checked />$ignore</label>
997: <input type="hidden" name="associate" value="" />
998: <input type="hidden" name="datatoken" value="$datatoken" />
999: <input type="hidden" name="fileupload" value="$env{'form.fileupload'}" />
1000: <input type="hidden" name="upfiletype" value="$env{'form.upfiletype'}" />
1001: <input type="hidden" name="upfile_associate"
1002: value="$env{'form.upfile_associate'}" />
1003: <input type="hidden" name="command" value="csvuploadassign" />
1004: <hr />
1005: <script type="text/javascript" language="Javascript">
1006: $javascript
1007: </script>
1008: ENDPICK
1009: return '';
1010:
1011: }
1012:
1013: sub csvuploadmap_footer {
1014: my ($request,$i,$keyfields) =@_;
1015: $request->print(<<ENDPICK);
1016: </table>
1017: <input type="hidden" name="nfields" value="$i" />
1018: <input type="hidden" name="keyfields" value="$keyfields" />
1019: <input type="button" onClick="javascript:verify(this.form)" value="Create Slots" /><br />
1020: </form>
1021: ENDPICK
1022: }
1023:
1024: sub csvupload_javascript_reverse_associate {
1025: my $error1=&mt('You need to specify the name, starttime, endtime and a type');
1026: return(<<ENDPICK);
1027: function verify(vf) {
1028: var foundstart=0;
1029: var foundend=0;
1030: var foundname=0;
1031: var foundtype=0;
1032: for (i=0;i<=vf.nfields.value;i++) {
1033: tw=eval('vf.f'+i+'.selectedIndex');
1034: if (i==0 && tw!=0) { foundname=1; }
1035: if (i==1 && tw!=0) { foundtype=1; }
1036: if (i==2 && tw!=0) { foundstat=1; }
1037: if (i==3 && tw!=0) { foundend=1; }
1038: }
1039: if (foundstart==0 && foundend==0 && foundtype==0 && foundname==0) {
1040: alert('$error1');
1041: return;
1042: }
1043: vf.submit();
1044: }
1045: function flip(vf,tf) {
1046: }
1047: ENDPICK
1048: }
1049:
1050: sub csvupload_javascript_forward_associate {
1051: my $error1=&mt('You need to specify the name, starttime, endtime and a type');
1052: return(<<ENDPICK);
1053: function verify(vf) {
1054: var foundstart=0;
1055: var foundend=0;
1056: var foundname=0;
1057: var foundtype=0;
1058: for (i=0;i<=vf.nfields.value;i++) {
1059: tw=eval('vf.f'+i+'.selectedIndex');
1060: if (tw==1) { foundname=1; }
1061: if (tw==2) { foundtype=1; }
1062: if (tw==3) { foundstat=1; }
1063: if (tw==4) { foundend=1; }
1064: }
1065: if (foundstart==0 && foundend==0 && foundtype==0 && foundname==0) {
1066: alert('$error1');
1067: return;
1068: }
1069: vf.submit();
1070: }
1071: function flip(vf,tf) {
1072: }
1073: ENDPICK
1074: }
1075:
1076: sub csv_upload_map {
1077: my ($r)= @_;
1078:
1079: my $datatoken;
1080: if (!$env{'form.datatoken'}) {
1081: $datatoken=&Apache::loncommon::upfile_store($r);
1082: } else {
1083: $datatoken=$env{'form.datatoken'};
1084: &Apache::loncommon::load_tmp_file($r);
1085: }
1086: my @records=&Apache::loncommon::upfile_record_sep();
1087: if ($env{'form.noFirstLine'}) { shift(@records); }
1088: &csvuploadmap_header($r,$datatoken,$#records+1);
1089: my ($i,$keyfields);
1090: if (@records) {
1091: my @fields=&csvupload_fields();
1092:
1093: if ($env{'form.upfile_associate'} eq 'reverse') {
1094: &Apache::loncommon::csv_print_samples($r,\@records);
1095: $i=&Apache::loncommon::csv_print_select_table($r,\@records,
1096: \@fields);
1097: foreach (@fields) { $keyfields.=$_->[0].','; }
1098: chop($keyfields);
1099: } else {
1100: unshift(@fields,['none','']);
1101: $i=&Apache::loncommon::csv_samples_select_table($r,\@records,
1102: \@fields);
1103: my %sone=&Apache::loncommon::record_sep($records[0]);
1104: $keyfields=join(',',sort(keys(%sone)));
1105: }
1106: }
1107: &csvuploadmap_footer($r,$i,$keyfields);
1108:
1109: return '';
1110: }
1111:
1112: sub csvupload_fields {
1113: return (['name','Slot name'],
1114: ['type','Type of slot'],
1115: ['starttime','Start Time of slot'],
1116: ['endtime','End Time of slot'],
1117: ['startreserve','Reservation Start Time'],
1118: ['ip','IP or DNS restriction'],
1119: ['proctor','List of proctor ids'],
1120: ['description','Slot Description'],
1121: ['maxspace','Maximum number of reservations'],
1122: ['symb','Resource Restriction'],
1123: ['uniqueperiod','Date range of slot exclusion'],
1124: ['secret','Secret word proctor uses to validate']);
1125: }
1126:
1127: sub csv_upload_assign {
1128: my ($r,$mgr)= @_;
1129: &Apache::loncommon::load_tmp_file($r);
1130: my @slotdata = &Apache::loncommon::upfile_record_sep();
1131: if ($env{'form.noFirstLine'}) { shift(@slotdata); }
1132: my %fields=&Apache::grades::get_fields();
1133: $r->print('<h3>Creating Slots</h3>');
1134: my $cname=$env{'course.'.$env{'request.course.id'}.'.num'};
1135: my $cdom=$env{'course.'.$env{'request.course.id'}.'.domain'};
1136: my $countdone=0;
1137: my @errors;
1138: foreach my $slot (@slotdata) {
1139: my %slot;
1140: my %entries=&Apache::loncommon::record_sep($slot);
1141: my $domain;
1142: my $name=$entries{$fields{'name'}};
1143: if ($name=~/^\s*$/) {
1144: push(@errors,"Did not create slot with no name");
1145: next;
1146: }
1147: if ($name=~/\s/) {
1148: push(@errors,"$name not created -- Name must not contain spaces");
1149: next;
1150: }
1151: if ($name=~/\W/) {
1152: push(@errors,"$name not created -- Name must contain only letters, numbers and _");
1153: next;
1154: }
1155: if ($entries{$fields{'type'}}) {
1156: $slot{'type'}=$entries{$fields{'type'}};
1157: } else {
1158: $slot{'type'}='preassigned';
1159: }
1160: if ($slot{'type'} ne 'preassigned' &&
1161: $slot{'type'} ne 'schedulable_student') {
1162: push(@errors,"$name not created -- invalid type ($slot{'type'}) must be either preassigned or schedulable_student");
1163: next;
1164: }
1165: if ($entries{$fields{'starttime'}}) {
1166: $slot{'starttime'}=&UnixDate($entries{$fields{'starttime'}},"%s");
1167: }
1168: if ($entries{$fields{'endtime'}}) {
1169: $slot{'endtime'}=&UnixDate($entries{$fields{'endtime'}},"%s");
1170: }
1171: if ($entries{$fields{'startreserve'}}) {
1172: $slot{'startreserve'}=
1173: &UnixDate($entries{$fields{'startreserve'}},"%s");
1174: }
1175: foreach my $key ('ip','proctor','description','maxspace',
1176: 'secret','symb') {
1177: if ($entries{$fields{$key}}) {
1178: $slot{$key}=$entries{$fields{$key}};
1179: }
1180: }
1181: if ($entries{$fields{'uniqueperiod'}}) {
1182: my ($start,$end)=split(',',$entries{$fields{'uniqueperiod'}});
1183: my @times=(&UnixDate($start,"%s"),
1184: &UnixDate($end,"%s"));
1185: $slot{'uniqueperiod'}=\@times;
1186: }
1187:
1188: &Apache::lonnet::cput('slots',{$name=>\%slot},$cdom,$cname);
1189: $r->print('.');
1190: $r->rflush();
1191: $countdone++;
1192: }
1193: $r->print("<p>Created $countdone slots\n</p>");
1194: foreach my $error (@errors) {
1195: $r->print("<p>$error\n</p>");
1196: }
1197: &show_table($r,$mgr);
1198: return '';
1199: }
1200:
1201: sub handler {
1202: my $r=shift;
1203:
1204: &Apache::loncommon::content_type($r,'text/html');
1205: &Apache::loncommon::no_cache($r);
1206: if ($r->header_only()) {
1207: $r->send_http_header();
1208: return OK;
1209: }
1210:
1211: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'});
1212:
1213: my $vgr=&Apache::lonnet::allowed('vgr',$env{'request.course.id'});
1214: my $mgr=&Apache::lonnet::allowed('mgr',$env{'request.course.id'});
1215: my $title='Requesting Another Worktime';
1216: if ($env{'form.command'} =~ /^(showslots|uploadstart|csvuploadmap|csvuploadassign)$/ && $vgr eq 'F') {
1217: $title = 'Managing Slots';
1218: }
1219: &start_page($r,$title);
1220:
1221: if ($env{'form.command'} eq 'showslots' && $vgr eq 'F') {
1222: &show_table($r,$mgr);
1223: } elsif ($env{'form.command'} eq 'remove_registration' && $mgr eq 'F') {
1224: &remove_registration($r);
1225: } elsif ($env{'form.command'} eq 'release' && $mgr eq 'F') {
1226: &release_slot($r,undef,undef,undef,$mgr);
1227: } elsif ($env{'form.command'} eq 'delete' && $mgr eq 'F') {
1228: &delete_slot($r);
1229: } elsif ($env{'form.command'} eq 'uploadstart' && $mgr eq 'F') {
1230: &upload_start($r);
1231: } elsif ($env{'form.command'} eq 'csvuploadmap' && $mgr eq 'F') {
1232: &csv_upload_map($r);
1233: } elsif ($env{'form.command'} eq 'csvuploadassign' && $mgr eq 'F') {
1234: if ($env{'form.associate'} ne 'Reverse Association') {
1235: &csv_upload_assign($r,$mgr);
1236: } else {
1237: if ( $env{'form.upfile_associate'} ne 'reverse' ) {
1238: $env{'form.upfile_associate'} = 'reverse';
1239: } else {
1240: $env{'form.upfile_associate'} = 'forward';
1241: }
1242: &csv_upload_map($r);
1243: }
1244: } else {
1245: my $symb=&Apache::lonnet::unescape($env{'form.symb'});
1246: my (undef,undef,$res)=&Apache::lonnet::decode_symb($symb);
1247: my $useslots = &Apache::lonnet::EXT("resource.0.useslots",$symb);
1248: if ($useslots ne 'resource') {
1249: &fail($r,'not_valid');
1250: return OK;
1251: }
1252: $env{'request.symb'}=$symb;
1253: my $type = ($res =~ /\.task$/) ? 'Task'
1254: : 'problem';
1255: my ($status) = &Apache::lonhomework::check_slot_access('0',$type);
1256: if ($status eq 'CAN_ANSWER' ||
1257: $status eq 'NEEDS_CHECKIN' ||
1258: $status eq 'WAITING_FOR_GRADE') {
1259: &fail($r,'not_allowed');
1260: return OK;
1261: }
1262: if ($env{'form.requestattempt'}) {
1263: &show_choices($r,$symb);
1264: } elsif ($env{'form.command'} eq 'release') {
1265: &release_slot($r,$symb);
1266: } elsif ($env{'form.command'} eq 'get') {
1267: &get_slot($r,$symb);
1268: } elsif ($env{'form.command'} eq 'change') {
1269: if (&release_slot($r,$symb,$env{'form.releaseslot'},1)) {
1270: &get_slot($r,$symb);
1271: }
1272: } else {
1273: $r->print("<p>Unknown command: ".$env{'form.command'}."</p>");
1274: }
1275: }
1276: &end_page($r);
1277: return OK;
1278: }
1279:
1280: 1;
1281: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to slotrequest.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / interface