1: # The LearningOnline Network with CAPA
2: # Handler for requesting to have slots added to a students record
3: #
4: # $Id: slotrequest.pm,v 1.32 2005/11/21 17:50:45 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: package Apache::slotrequest;
31:
32: use strict;
33: use Apache::Constants qw(:common :http :methods);
34: use Apache::loncommon();
35: use Apache::lonlocal;
36: use Apache::lonnet;
37: use Date::Manip;
38:
39: sub fail {
40: my ($r,$code)=@_;
41: if ($code eq 'not_valid') {
42: $r->print('<p>'.&mt('Unable to understand what resource you wanted to sign up for.').'</p>');
43:
44: } elsif ($code eq 'not_allowed') {
45: $r->print('<p>'.&mt('Not allowed to sign up or change reservations at this time.').'</p>');
46: } else {
47: $r->print('<p>'.&mt('Failed.').'</p>');
48: }
49:
50: $r->print('<p><a href="/adm/flip?postdata=return:">'.
51: &mt('Return to last resource').'</a></p>');
52: &end_page($r);
53: }
54:
55: sub start_page {
56: my ($r,$title)=@_;
57: my $html=&Apache::lonxml::xmlbegin();
58: $r->print($html.'<head><title>'.&mt($title).'</title></head>');
59: $r->print(&Apache::loncommon::bodytag($title));
60: }
61:
62: sub end_page {
63: my ($r)=@_;
64: $r->print(&Apache::loncommon::endbodytag().'</html>');
65: }
66:
67: =pod
68:
69: slot_reservations db
70: - keys are
71: - slotname\0id -> value is an hashref of
72: name -> user@domain of holder
73: timestamp -> timestamp of reservation
74: symb -> symb of resource that it is reserved for
75:
76: =cut
77:
78: sub get_course {
79: (undef,my $courseid)=&Apache::lonxml::whichuser();
80: my $cdom=$env{'course.'.$courseid.'.domain'};
81: my $cnum=$env{'course.'.$courseid.'.num'};
82: return ($cnum,$cdom);
83: }
84:
85: sub get_reservation_ids {
86: my ($slot_name)=@_;
87:
88: my ($cnum,$cdom)=&get_course();
89:
90: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
91: "^$slot_name\0");
92:
93: my ($tmp)=%consumed;
94: if ($tmp=~/^error: 2 / ) {
95: return 0;
96: }
97: return keys(%consumed);
98: }
99:
100: sub space_available {
101: my ($slot_name,$slot)=@_;
102: my $max=$slot->{'maxspace'};
103:
104: if (!defined($max)) { return 1; }
105:
106: my $consumed=scalar(&get_reservation_ids($slot_name));
107: if ($consumed < $max) {
108: return 1
109: }
110: return 0;
111: }
112:
113: sub check_for_reservation {
114: my ($symb)=@_;
115: my $student = &Apache::lonnet::EXT("resource.0.availablestudent", $symb,
116: $env{'user.domain'}, $env{'user.name'});
117:
118: my $course = &Apache::lonnet::EXT("resource.0.available", $symb,
119: $env{'user.domain'}, $env{'user.name'});
120: my @slots = (split(/:/,$student), split(/:/, $course));
121:
122: &Apache::lonxml::debug(" slot list is ".join(':',@slots));
123:
124: my ($cnum,$cdom)=&get_course();
125: my %slots=&Apache::lonnet::get('slots', [@slots], $cdom, $cnum);
126:
127: foreach my $slot_name (@slots) {
128: next if (!defined($slots{$slot_name}) ||
129: !ref($slots{$slot_name}));
130: &Apache::lonxml::debug(time." $slot_name ".
131: $slots{$slot_name}->{'starttime'}." -- ".
132: $slots{$slot_name}->{'startreserve'});
133: if ($slots{$slot_name}->{'endtime'} > time &&
134: $slots{$slot_name}->{'startreserve'} < time) {
135: # between start of reservation times and end of slot
136: return($slot_name, $slots{$slot_name});
137: }
138: }
139: return (undef,undef);
140: }
141:
142: sub check_for_conflict {
143: my ($symb,$new_slot_name)=@_;
144: my $student = &Apache::lonnet::EXT("resource.0.availablestudent", $symb,
145: $env{'user.domain'}, $env{'user.name'});
146: my $course = &Apache::lonnet::EXT("resource.0.available", $symb,
147: $env{'user.domain'}, $env{'user.name'});
148: my @slots = (split(/:/,$student), split(/:/, $course));
149: my ($cnum,$cdom)=&get_course();
150: my %slots=&Apache::lonnet::get('slots', [@slots], $cdom, $cnum);
151: foreach my $slot_name (@slots) {
152: next if (!defined($slots{$slot_name}) ||
153: !ref($slots{$slot_name}));
154:
155: next if (!defined($slots{$slot_name}->{'uniqueperiod'}) ||
156: !ref($slots{$slot_name}->{'uniqueperiod'}));
157: my ($start,$end)=@{$slots{$slot_name}->{'uniqueperiod'}};
158: if ($start<time && time < $end) {
159: return $slot_name;
160: }
161: }
162: return undef;
163:
164: }
165:
166: sub make_reservation {
167: my ($slot_name,$slot,$symb)=@_;
168:
169: my ($cnum,$cdom)=&get_course();
170:
171: my $value=&Apache::lonnet::EXT("resource.0.availablestudent",$symb,
172: $env{'user.domain'},$env{'user.name'});
173: &Apache::lonxml::debug("value is $value<br />");
174: foreach my $other_slot (split(/:/, $value)) {
175: if ($other_slot eq $slot_name) {
176: my %consumed=&Apache::lonnet::dump('slot_reservations', $cdom,
177: $cnum, "^$slot_name\0");
178:
179: my $me=$env{'user.name'}.'@'.$env{'user.domain'};
180: foreach my $key (keys(%consumed)) {
181: if ($consumed{$key}->{'name'} eq $me) {
182: my $num=(split('\0',$key))[1];
183: return -$num;
184: }
185: }
186: }
187: }
188:
189: my $max=$slot->{'maxspace'};
190: if (!defined($max)) { $max=99999; }
191:
192: my (@ids)=&get_reservation_ids($slot_name);
193:
194: my $last=0;
195: foreach my $id (@ids) {
196: my $num=(split('\0',$id))[1];
197: if ($num > $last) { $last=$num; }
198: }
199:
200: my $wanted=$last+1;
201: &Apache::lonxml::debug("wanted $wanted<br />");
202: if (scalar(@ids) >= $max) {
203: # full up
204: return undef;
205: }
206:
207: my %reservation=('name' => $env{'user.name'}.'@'.$env{'user.domain'},
208: 'timestamp' => time,
209: 'symb' => $symb);
210:
211: my $success=&Apache::lonnet::newput('slot_reservations',
212: {"$slot_name\0$wanted" =>
213: \%reservation},
214: $cdom, $cnum);
215:
216: if ($success eq 'ok') {
217: my $new_value=$slot_name;
218: if ($value) {
219: $new_value=$value.':'.$new_value;
220: }
221: my $result=&Apache::lonparmset::storeparm_by_symb($symb,
222: '0_availablestudent',
223: 1, $new_value, 'string',
224: $env{'user.name'},
225: $env{'user.domain'});
226: &Apache::lonxml::debug("hrrm $result");
227: return $wanted;
228: }
229:
230: # someone else got it
231: return undef;
232: }
233:
234: sub release_slot {
235: my ($r,$symb,$slot_name,$inhibit_return_link)=@_;
236:
237: if ($slot_name eq '') { $slot_name=$env{'form.slotname'}; }
238: my ($cnum,$cdom)=&get_course();
239:
240: # get parameter string, check for existance, rebuild string with the slot
241:
242: my @slots = split(/:/,&Apache::lonnet::EXT("resource.0.availablestudent",
243: $symb,$env{'user.domain'},
244: $env{'user.name'}));
245: my @new_slots;
246: foreach my $exist_slot (@slots) {
247: if ($exist_slot eq $slot_name) { next; }
248: push(@new_slots,$exist_slot);
249: }
250: my $new_param = join(':',@new_slots);
251:
252: # get slot reservations, check if user has one, if so remove reservation
253: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
254: "^$slot_name\0");
255: foreach my $entry (keys(%consumed)) {
256: if ( $consumed{$entry}->{'name'} eq
257: ($env{'user.name'}.'@'.$env{'user.domain'}) ) {
258: &Apache::lonnet::del('slot_reservations',[$entry],
259: $cdom,$cnum);
260: }
261: }
262: # store new parameter string
263: my $result=&Apache::lonparmset::storeparm_by_symb($symb,
264: '0_availablestudent',
265: 1, $new_param, 'string',
266: $env{'user.name'},
267: $env{'user.domain'});
268: my %slot=&Apache::lonnet::get_slot($slot_name);
269: my $description=&get_description($env{'form.slotname'},\%slot);
270: $r->print("<p>Released Reservation: $description</p>");
271: if (!$inhibit_return_link) {
272: $r->print('<p><a href="/adm/flip?postdata=return:">'.
273: &mt('Return to last resource').'</a></p>');
274: }
275: return 1;
276: }
277:
278: sub get_slot {
279: my ($r,$symb)=@_;
280:
281: my $slot_name=&check_for_conflict($symb,$env{'form.slotname'});
282: if ($slot_name) {
283: my %slot=&Apache::lonnet::get_slot($slot_name);
284: my $description1=&get_description($slot_name,\%slot);
285: %slot=&Apache::lonnet::get_slot($env{'form.slotname'});
286: my $description2=&get_description($env{'form.slotname'},\%slot);
287: $r->print("<p>Already have a reservation: $description1</p>");
288: if ($slot_name ne $env{'form.slotname'}) {
289: $r->print(<<STUFF);
290: <form method="POST" action="/adm/slotrequest">
291: <input type="hidden" name="symb" value="$env{'form.symb'}" />
292: <input type="hidden" name="slotname" value="$env{'form.slotname'}" />
293: <input type="hidden" name="releaseslot" value="$slot_name" />
294: <input type="hidden" name="command" value="change" />
295: STUFF
296: $r->print("<p>You can either ");
297: $r->print(<<STUFF);
298: <input type="submit" name="change" value="Change" />
299: STUFF
300: $r->print(' your reservation from <b>'.$description1.'</b> to <b>'.
301: $description2.
302: '</b> <br />or <a href="/adm/flip?postdata=return:">'.
303: &mt('Return to last resource').'</a></p>');
304: $r->print(<<STUFF);
305: </form>
306: STUFF
307: } else {
308: $r->print('<p><a href="/adm/flip?postdata=return:">'.
309: &mt('Return to last resource').'</a></p>');
310: }
311: return;
312: }
313: my %slot=&Apache::lonnet::get_slot($env{'form.slotname'});
314: my $reserved=&make_reservation($env{'form.slotname'},
315: \%slot,$symb);
316: my $description=&get_description($env{'form.slotname'},\%slot);
317: if (defined($reserved)) {
318: if ($reserved > -1) {
319: $r->print("<p>Success: $description</p>");
320: $r->print('<p><a href="/adm/flip?postdata=return:">'.
321: &mt('Return to last resource').'</a></p>');
322: return;
323: } elsif ($reserved < 0) {
324: $r->print("<p>Already reserved: $description</p>");
325: $r->print('<p><a href="/adm/flip?postdata=return:">'.
326: &mt('Return to last resource').'</a></p>');
327: return;
328: }
329: }
330:
331: my %lt=('request'=>"Availibility list",
332: 'try' =>'Try again');
333: %lt=&Apache::lonlocal::texthash(%lt);
334:
335: $r->print(<<STUFF);
336: <p> <font color="red">Failed</font> to reserve a spot for $description. </p>
337: <p>
338: <form method="POST" action="/adm/slotrequest">
339: <input type="submit" name="Try Again" value="$lt{'try'}" />
340: <input type="hidden" name="symb" value="$env{'form.symb'}" />
341: <input type="hidden" name="slotname" value="$env{'form.slotname'}" />
342: <input type="hidden" name="command" value="get" />
343: </form>
344: ?
345: </p>
346: <p>
347: or
348: <form method="POST" action="/adm/slotrequest">
349: <input type="hidden" name="symb" value="$env{'form.symb'}" />
350: <input type="submit" name="requestattempt" value="$lt{'request'}" />
351: </form>
352: </p>
353: or
354: STUFF
355: $r->print('<p><a href="/adm/flip?postdata=return:">'.
356: &mt('Return to last resource').'</a></p>');
357: return;
358: }
359:
360: sub allowed_slot {
361: my ($slot_name,$slot,$symb)=@_;
362: #already started
363: if ($slot->{'starttime'} < time) {
364: # all open slot to be schedulable
365: #return 0;
366: }
367: &Apache::lonxml::debug("$slot_name starttime good");
368: #already ended
369: if ($slot->{'endtime'} < time) {
370: return 0;
371: }
372: &Apache::lonxml::debug("$slot_name endtime good");
373: # not allowed to pick this one
374: if (defined($slot->{'type'})
375: && $slot->{'type'} ne 'schedulable_student') {
376: return 0;
377: }
378: &Apache::lonxml::debug("$slot_name type good");
379: # not allowed for this resource
380: if (defined($slot->{'symb'})
381: && $slot->{'symb'} ne $symb) {
382: return 0;
383: }
384: &Apache::lonxml::debug("$slot_name symb good");
385: return 1;
386: }
387:
388: sub get_description {
389: my ($slot_name,$slot)=@_;
390: my $description=$slot->{'description'};
391: if (!defined($description)) {
392: $description=&mt('[_1] From [_2] to [_3]',$slot_name,
393: &Apache::lonlocal::locallocaltime($slot->{'starttime'}),
394: &Apache::lonlocal::locallocaltime($slot->{'endtime'}));
395: }
396: return $description;
397: }
398:
399: sub show_choices {
400: my ($r,$symb)=@_;
401:
402: my ($cnum,$cdom)=&get_course();
403: my %slots=&Apache::lonnet::dump('slots',$cdom,$cnum);
404: my $available;
405: $r->print('<table border="1">');
406: &Apache::lonxml::debug("Checking Slots");
407: my ($got_slot)=&check_for_reservation($symb);
408: foreach my $slot (sort
409: { return $slots{$a}->{'starttime'} <=> $slots{$b}->{'starttime'} }
410: (keys(%slots))) {
411:
412: &Apache::lonxml::debug("Checking Slot $slot");
413: next if (!&allowed_slot($slot,$slots{$slot}));
414:
415: $available++;
416:
417: my $description=&get_description($slot,$slots{$slot});
418:
419: my $form=&mt('Unavailable');
420: if (($slot eq $got_slot) ||
421: &space_available($slot,$slots{$slot},$symb)) {
422: my $text=&mt('Select');
423: my $command='get';
424: if ($slot eq $got_slot) {
425: $text=&mt('Free Reservation');
426: $command='release';
427: }
428: my $escsymb=&Apache::lonnet::escape($symb);
429: $form=<<STUFF;
430: <form method="POST" action="/adm/slotrequest">
431: <input type="submit" name="Select" value="$text" />
432: <input type="hidden" name="symb" value="$escsymb" />
433: <input type="hidden" name="slotname" value="$slot" />
434: <input type="hidden" name="command" value="$command" />
435: </form>
436: STUFF
437: }
438: $r->print(<<STUFF);
439: <tr>
440: <td>$form</td>
441: <td>$description</td>
442: </tr>
443: STUFF
444: }
445:
446: if (!$available) {
447: $r->print('<tr><td>No available times. <a href="/adm/flip?postdata=return:">'.
448: &mt('Return to last resource').'</a></td></tr>');
449: }
450: $r->print('</table>');
451: }
452:
453: sub to_show {
454: my ($when,$slot) = @_;
455: my $time=time;
456: my $week=60*60*24*7;
457: if ($when eq 'now') {
458: if ($time > $slot->{'starttime'} &&
459: $time < $slot->{'endtime'}) {
460: return 1;
461: }
462: return 0;
463: } elsif ($when eq 'nextweek') {
464: if ( ($time < $slot->{'starttime'} &&
465: ($time+$week) > $slot->{'starttime'})
466: ||
467: ($time < $slot->{'endtime'} &&
468: ($time+$week) > $slot->{'endtime'}) ) {
469: return 1;
470: }
471: return 0;
472: } elsif ($when eq 'lastweek') {
473: if ( ($time > $slot->{'starttime'} &&
474: ($time-$week) < $slot->{'starttime'})
475: ||
476: ($time > $slot->{'endtime'} &&
477: ($time-$week) < $slot->{'endtime'}) ) {
478: return 1;
479: }
480: return 0;
481: } elsif ($when eq 'willopen') {
482: if ($time < $slot->{'starttime'}) {
483: return 1;
484: }
485: return 0;
486: } elsif ($when eq 'wereopen') {
487: if ($time > $slot->{'endtime'}) {
488: return 1;
489: }
490: return 0;
491: }
492:
493: return 1;
494: }
495:
496: sub show_table {
497: my ($r,$mgr)=@_;
498:
499: my ($cnum,$cdom)=&get_course();
500: my %slots=&Apache::lonnet::dump('slots',$cdom,$cnum);
501: if ( (keys(%slots))[0] =~ /^error: 2 /) {
502: undef(%slots);
503: }
504: my $available;
505: if ($mgr eq 'F') {
506: $r->print('<div>');
507: $r->print('<form method="POST" action="/adm/slotrequest">
508: <input type="hidden" name="command" value="uploadstart" />
509: <input type="submit" name="start" value="'.&mt('Upload Slot List').'" />
510: </form>');
511: $r->print('<form method="POST" action="/adm/helper/newslot.helper">
512: <input type="submit" name="newslot" value="'.&mt('Create a New Slot').'" />
513: </form>');
514: $r->print('</div>');
515: }
516:
517: my %Saveable_Parameters = ('show' => 'array',
518: 'when' => 'scalar',
519: 'order' => 'scalar');
520:
521: &Apache::loncommon::store_course_settings('slotrequest',\%Saveable_Parameters);
522: &Apache::loncommon::restore_course_settings('slotrequest',\%Saveable_Parameters);
523:
524: my %show_fields=&Apache::lonlocal::texthash(
525: 'name' => 'Slot Name',
526: 'description' => 'Description',
527: 'type' => 'Type',
528: 'starttime' => 'Start time',
529: 'endtime' => 'End Time',
530: 'startreserve' => 'Time students can start reserving',
531: 'secret' => 'Secret Word',
532: 'maxspace' => 'Maxium # of students',
533: 'ip' => 'IP or DNS restrictions',
534: 'symb' => 'Resource slot is restricted to.',
535: 'uniqueperiod' => 'Period of time slot is unique',
536: 'proctor' => 'List of proctors');
537: my @show_order=('name','description','type','starttime','endtime',
538: 'startreserve','secret','maxspace','ip','symb',
539: 'uniqueperiod','proctor');
540: my @show =
541: (exists($env{'form.show'})) ? &Apache::loncommon::get_env_multiple('form.show')
542: : keys(%show_fields);
543: my %show = map { $_ => 1 } (@show);
544:
545: my %when_fields=&Apache::lonlocal::texthash(
546: 'now' => 'Open now',
547: 'nextweek' => 'Open within the next week',
548: 'lastweek' => 'Were open last week',
549: 'willopen' => 'Will open later',
550: 'wereopen' => 'Were open');
551: my @when_order=('now','nextweek','lastweek','willopen','wereopen');
552: $when_fields{'select_form_order'} = \@when_order;
553: my $when = (exists($env{'form.when'})) ? $env{'form.when'}
554: : 'now';
555:
556: $r->print('<form method="POST" action="/adm/slotrequest">
557: <input type="hidden" name="command" value="showslots" />');
558: $r->print('<div>');
559: $r->print('<table class="inline"><tr><th>'.&mt('Show').'</th><th>'.&mt('Open').'</th></tr><tr><td>'.&Apache::loncommon::multiple_select_form('show',\@show,6,\%show_fields,\@show_order).
560: '</td><td>'.&Apache::loncommon::select_form($when,'when',%when_fields).
561: '</td></tr></table>');
562: $r->print('</div>');
563: $r->print('<p><input type="submit" name="start" value="'.&mt('Update Display').'" /></p>');
564: my $linkstart='<a href="/adm/slotrequest?command=showslots&order=';
565: $r->print('<table class="thinborder">
566: <tr>
567: <th></th>');
568: foreach my $which (@show_order) {
569: if ($which ne 'proctor' && exists($show{$which})) {
570: $r->print('<th>'.$linkstart.$which.'">'.$show_fields{$which}.'</a></th>');
571: }
572: }
573: $r->print('<th>Scheduled Students</th></tr>');
574:
575: my %name_cache;
576: my $slotsort = sub {
577: if ($env{'form.order'}=~/^(type|description|endtime|startreserve|maxspace|ip|symb)$/) {
578: if (lc($slots{$a}->{$env{'form.order'}})
579: ne lc($slots{$b}->{$env{'form.order'}})) {
580: return (lc($slots{$a}->{$env{'form.order'}})
581: cmp lc($slots{$b}->{$env{'form.order'}}));
582: }
583: } elsif ($env{'form.order'} eq 'name') {
584: if (lc($a) cmp lc($b)) {
585: return lc($a) cmp lc($b);
586: }
587: } elsif ($env{'form.order'} eq 'uniqueperiod') {
588:
589: if ($slots{$a}->{'uniqueperiod'}[0]
590: ne $slots{$b}->{'uniqueperiod'}[0]) {
591: return ($slots{$a}->{'uniqueperiod'}[0]
592: cmp $slots{$b}->{'uniqueperiod'}[0]);
593: }
594: if ($slots{$a}->{'uniqueperiod'}[1]
595: ne $slots{$b}->{'uniqueperiod'}[1]) {
596: return ($slots{$a}->{'uniqueperiod'}[1]
597: cmp $slots{$b}->{'uniqueperiod'}[1]);
598: }
599: }
600: return $slots{$a}->{'starttime'} <=> $slots{$b}->{'starttime'};
601: };
602: foreach my $slot (sort $slotsort (keys(%slots))) {
603: if (!&to_show($when,$slots{$slot})) { next; }
604: if (defined($slots{$slot}->{'type'})
605: && $slots{$slot}->{'type'} ne 'schedulable_student') {
606: #next;
607: }
608: my $description=&get_description($slot,$slots{$slot});
609: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
610: "^$slot\0");
611: my $ids;
612: foreach my $entry (sort(keys(%consumed))) {
613: my (undef,$id)=split("\0",$entry);
614: $ids.= $id.'-> '.$consumed{$entry}->{'name'}.'<br />';
615: }
616: my $start=($slots{$slot}->{'starttime'}?
617: &Apache::lonlocal::locallocaltime($slots{$slot}->{'starttime'}):'');
618: my $end=($slots{$slot}->{'endtime'}?
619: &Apache::lonlocal::locallocaltime($slots{$slot}->{'endtime'}):'');
620: my $start_reserve=($slots{$slot}->{'startreserve'}?
621: &Apache::lonlocal::locallocaltime($slots{$slot}->{'startreserve'}):'');
622:
623: my $unique;
624: if (ref($slots{$slot}{'uniqueperiod'})) {
625: $unique=localtime($slots{$slot}{'uniqueperiod'}[0]).','.
626: localtime($slots{$slot}{'uniqueperiod'}[1]);
627: }
628: my $title;
629: if (exists($slots{$slot}{'symb'})) {
630: my (undef,undef,$res)=
631: &Apache::lonnet::decode_symb($slots{$slot}{'symb'});
632: $res = &Apache::lonnet::clutter($res);
633: $title = &Apache::lonnet::gettitle($slots{$slot}{'symb'});
634: $title='<a href="'.$res.'?symb='.$slots{$slot}{'symb'}.'">'.$title.'</a>';
635: }
636: my @proctors;
637: my $rowspan=1;
638: my $colspan=1;
639: if (exists($show{'proctor'})) {
640: $rowspan=2;
641: @proctors= map {
642: my ($uname,$udom)=split(/@/,$_);
643: my $fullname=$name_cache{$_};
644: if (!defined($fullname)) {
645: &Apache::lonnet::logthis("Gettign $uname $udom");
646: $fullname = &Apache::loncommon::plainname($uname,$udom);
647: $fullname =~s/\s/ /g;
648: $name_cache{$_} = $fullname;
649: }
650: &Apache::loncommon::aboutmewrapper($fullname,$uname,$udom);
651: } (sort(split(/\s*,\s*/,$slots{$slot}->{'proctor'})));
652: }
653: my $proctors=join(', ',@proctors);
654:
655: my $edit=(<<EDITLINK);
656: <a href="/adm/helper/newslot.helper?name=$slot">Edit</a>
657: EDITLINK
658:
659: $r->print("<tr>\n<td rowspan=\"$rowspan\">$edit</td>\n");
660: if (exists($show{'name'})) {
661: $colspan++;$r->print("<td>$slot</td>");
662: }
663: if (exists($show{'type'})) {
664: $colspan++;$r->print("<td>$slots{$slot}->{'type'}</td>\n");
665: }
666: if (exists($show{'description'})) {
667: $colspan++;$r->print("<td>$description</td>\n");
668: }
669: if (exists($show{'starttime'})) {
670: $colspan++;$r->print("<td>$start</td>\n");
671: }
672: if (exists($show{'endtime'})) {
673: $colspan++;$r->print("<td>$end</td>\n");
674: }
675: if (exists($show{'startreserve'})) {
676: $colspan++;$r->print("<td>$start_reserve</td>\n");
677: }
678: if (exists($show{'secret'})) {
679: $colspan++;$r->print("<td>$slots{$slot}{'secret'}</td>\n");
680: }
681: if (exists($show{'maxspace'})) {
682: $colspan++;$r->print("<td>$slots{$slot}{'maxspace'}</td>\n");
683: }
684: if (exists($show{'ip'})) {
685: $colspan++;$r->print("<td>$slots{$slot}{'ip'}</td>\n");
686: }
687: if (exists($show{'symb'})) {
688: $colspan++;$r->print("<td>$title</td>\n");
689: }
690: if (exists($show{'uniqueperiod'})) {
691: $colspan++;$r->print("<td>$unique</td>\n");
692: }
693: $colspan++;$r->print("<td>$ids</td>\n</tr>\n");
694: if (exists($show{'proctor'})) {
695: $r->print(<<STUFF);
696: <tr>
697: <td colspan="$colspan">$proctors</td>
698: </tr>
699: STUFF
700: }
701: }
702: $r->print('</table>');
703: }
704:
705: sub upload_start {
706: my ($r)=@_;
707: $r->print(&Apache::grades::checkforfile_js());
708: my $result.='<table width=100% border=0><tr bgcolor="#e6ffff"><td>'."\n";
709: $result.=' <b>'.
710: &mt('Specify a file containing the slot definitions.').
711: '</b></td></tr>'."\n";
712: $result.='<tr bgcolor=#ffffe6><td>'."\n";
713: my $upfile_select=&Apache::loncommon::upfile_select_html();
714: my $ignore=&mt('Ignore First Line');
715: $result.=<<ENDUPFORM;
716: <form method="post" enctype="multipart/form-data" action="/adm/slotrequest" name="slotupload">
717: <input type="hidden" name="command" value="csvuploadmap" />
718: $upfile_select
719: <br /><input type="button" onClick="javascript:checkUpload(this.form);" value="Upload Data" />
720: <label><input type="checkbox" name="noFirstLine" />$ignore</label>
721: </form>
722: ENDUPFORM
723: $result.='</td></tr></table>'."\n";
724: $result.='</td></tr></table>'."\n";
725: $r->print($result);
726: }
727:
728: sub csvuploadmap_header {
729: my ($r,$datatoken,$distotal)= @_;
730: my $javascript;
731: if ($env{'form.upfile_associate'} eq 'reverse') {
732: $javascript=&csvupload_javascript_reverse_associate();
733: } else {
734: $javascript=&csvupload_javascript_forward_associate();
735: }
736:
737: my $checked=(($env{'form.noFirstLine'})?' checked="checked"':'');
738: my $ignore=&mt('Ignore First Line');
739: $r->print(<<ENDPICK);
740: <form method="post" enctype="multipart/form-data" action="/adm/slotrequest" name="slotupload">
741: <h3>Identify fields</h3>
742: Total number of records found in file: $distotal <hr />
743: Enter as many fields as you can. The system will inform you and bring you back
744: to this page if the data selected is insufficient to create the slots.<hr />
745: <input type="button" value="Reverse Association" onClick="javascript:this.form.associate.value='Reverse Association';submit(this.form);" />
746: <label><input type="checkbox" name="noFirstLine" $checked />$ignore</label>
747: <input type="hidden" name="associate" value="" />
748: <input type="hidden" name="datatoken" value="$datatoken" />
749: <input type="hidden" name="fileupload" value="$env{'form.fileupload'}" />
750: <input type="hidden" name="upfiletype" value="$env{'form.upfiletype'}" />
751: <input type="hidden" name="upfile_associate"
752: value="$env{'form.upfile_associate'}" />
753: <input type="hidden" name="command" value="csvuploadassign" />
754: <hr />
755: <script type="text/javascript" language="Javascript">
756: $javascript
757: </script>
758: ENDPICK
759: return '';
760:
761: }
762:
763: sub csvuploadmap_footer {
764: my ($request,$i,$keyfields) =@_;
765: $request->print(<<ENDPICK);
766: </table>
767: <input type="hidden" name="nfields" value="$i" />
768: <input type="hidden" name="keyfields" value="$keyfields" />
769: <input type="button" onClick="javascript:verify(this.form)" value="Create Slots" /><br />
770: </form>
771: ENDPICK
772: }
773:
774: sub csvupload_javascript_reverse_associate {
775: my $error1=&mt('You need to specify the name, starttime, endtime and a type');
776: return(<<ENDPICK);
777: function verify(vf) {
778: var foundstart=0;
779: var foundend=0;
780: var foundname=0;
781: var foundtype=0;
782: for (i=0;i<=vf.nfields.value;i++) {
783: tw=eval('vf.f'+i+'.selectedIndex');
784: if (i==0 && tw!=0) { foundname=1; }
785: if (i==1 && tw!=0) { foundtype=1; }
786: if (i==2 && tw!=0) { foundstat=1; }
787: if (i==3 && tw!=0) { foundend=1; }
788: }
789: if (foundstart==0 && foundend==0 && foundtype==0 && foundname==0) {
790: alert('$error1');
791: return;
792: }
793: vf.submit();
794: }
795: function flip(vf,tf) {
796: }
797: ENDPICK
798: }
799:
800: sub csvupload_javascript_forward_associate {
801: my $error1=&mt('You need to specify the name, starttime, endtime and a type');
802: return(<<ENDPICK);
803: function verify(vf) {
804: var foundstart=0;
805: var foundend=0;
806: var foundname=0;
807: var foundtype=0;
808: for (i=0;i<=vf.nfields.value;i++) {
809: tw=eval('vf.f'+i+'.selectedIndex');
810: if (tw==1) { foundname=1; }
811: if (tw==2) { foundtype=1; }
812: if (tw==3) { foundstat=1; }
813: if (tw==4) { foundend=1; }
814: }
815: if (foundstart==0 && foundend==0 && foundtype==0 && foundname==0) {
816: alert('$error1');
817: return;
818: }
819: vf.submit();
820: }
821: function flip(vf,tf) {
822: }
823: ENDPICK
824: }
825:
826: sub csv_upload_map {
827: my ($r)= @_;
828:
829: my $datatoken;
830: if (!$env{'form.datatoken'}) {
831: $datatoken=&Apache::loncommon::upfile_store($r);
832: } else {
833: $datatoken=$env{'form.datatoken'};
834: &Apache::loncommon::load_tmp_file($r);
835: }
836: my @records=&Apache::loncommon::upfile_record_sep();
837: if ($env{'form.noFirstLine'}) { shift(@records); }
838: &csvuploadmap_header($r,$datatoken,$#records+1);
839: my ($i,$keyfields);
840: if (@records) {
841: my @fields=&csvupload_fields();
842:
843: if ($env{'form.upfile_associate'} eq 'reverse') {
844: &Apache::loncommon::csv_print_samples($r,\@records);
845: $i=&Apache::loncommon::csv_print_select_table($r,\@records,
846: \@fields);
847: foreach (@fields) { $keyfields.=$_->[0].','; }
848: chop($keyfields);
849: } else {
850: unshift(@fields,['none','']);
851: $i=&Apache::loncommon::csv_samples_select_table($r,\@records,
852: \@fields);
853: my %sone=&Apache::loncommon::record_sep($records[0]);
854: $keyfields=join(',',sort(keys(%sone)));
855: }
856: }
857: &csvuploadmap_footer($r,$i,$keyfields);
858:
859: return '';
860: }
861:
862: sub csvupload_fields {
863: return (['name','Slot name'],
864: ['type','Type of slot'],
865: ['starttime','Start Time of slot'],
866: ['endtime','End Time of slot'],
867: ['startreserve','Reservation Start Time'],
868: ['ip','IP or DNS restriction'],
869: ['proctor','List of proctor ids'],
870: ['description','Slot Description'],
871: ['maxspace','Maximum number of reservations'],
872: ['symb','Resource Restriction'],
873: ['uniqueperiod','Date range of slot exclusion'],
874: ['secret','Secret word proctor uses to validate']);
875: }
876:
877: sub csv_upload_assign {
878: my ($r,$mgr)= @_;
879: &Apache::loncommon::load_tmp_file($r);
880: my @slotdata = &Apache::loncommon::upfile_record_sep();
881: if ($env{'form.noFirstLine'}) { shift(@slotdata); }
882: my %fields=&Apache::grades::get_fields();
883: $r->print('<h3>Creating Slots</h3>');
884: my $cname=$env{'course.'.$env{'request.course.id'}.'.num'};
885: my $cdom=$env{'course.'.$env{'request.course.id'}.'.domain'};
886: my $countdone=0;
887: my @errors;
888: foreach my $slot (@slotdata) {
889: my %slot;
890: my %entries=&Apache::loncommon::record_sep($slot);
891: my $domain;
892: my $name=$entries{$fields{'name'}};
893: if ($name=~/^\s*$/) {
894: push(@errors,"Did not create slot with no name");
895: next;
896: }
897: if ($name=~/\s/) {
898: push(@errors,"$name not created -- Name must not contain spaces");
899: next;
900: }
901: if ($name=~/\W/) {
902: push(@errors,"$name not created -- Name must contain only letters, numbers and _");
903: next;
904: }
905: if ($entries{$fields{'type'}}) {
906: $slot{'type'}=$entries{$fields{'type'}};
907: } else {
908: $slot{'type'}='preassigned';
909: }
910: if ($slot{'type'} ne 'preassigned' &&
911: $slot{'type'} ne 'schedulable_student') {
912: push(@errors,"$name not created -- invalid type ($slot{'type'}) must be either preassigned or schedulable_student");
913: next;
914: }
915: if ($entries{$fields{'starttime'}}) {
916: $slot{'starttime'}=&UnixDate($entries{$fields{'starttime'}},"%s");
917: }
918: if ($entries{$fields{'endtime'}}) {
919: $slot{'endtime'}=&UnixDate($entries{$fields{'endtime'}},"%s");
920: }
921: if ($entries{$fields{'startreserve'}}) {
922: $slot{'startreserve'}=
923: &UnixDate($entries{$fields{'startreserve'}},"%s");
924: }
925: foreach my $key ('ip','proctor','description','maxspace',
926: 'secret','symb') {
927: if ($entries{$fields{$key}}) {
928: $slot{$key}=$entries{$fields{$key}};
929: }
930: }
931: if ($entries{$fields{'uniqueperiod'}}) {
932: my ($start,$end)=split(',',$entries{$fields{'uniqueperiod'}});
933: my @times=(&UnixDate($start,"%s"),
934: &UnixDate($end,"%s"));
935: $slot{'uniqueperiod'}=\@times;
936: }
937:
938: &Apache::lonnet::cput('slots',{$name=>\%slot},$cdom,$cname);
939: $r->print('.');
940: $r->rflush();
941: $countdone++;
942: }
943: $r->print("<p>Created $countdone slots\n</p>");
944: foreach my $error (@errors) {
945: $r->print("<p>$error\n</p>");
946: }
947: &show_table($r,$mgr);
948: return '';
949: }
950:
951: sub handler {
952: my $r=shift;
953:
954: &Apache::loncommon::content_type($r,'text/html');
955: &Apache::loncommon::no_cache($r);
956: if ($r->header_only()) {
957: $r->send_http_header();
958: return OK;
959: }
960:
961: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'});
962:
963: my $vgr=&Apache::lonnet::allowed('vgr',$env{'request.course.id'});
964: my $mgr=&Apache::lonnet::allowed('mgr',$env{'request.course.id'});
965: my $title='Requesting Another Worktime';
966: if ($env{'form.command'} =~ /^(showslots|uploadstart|csvuploadmap|csvuploadassign)$/ && $vgr eq 'F') {
967: $title = 'Managing Slots';
968: }
969: &start_page($r,$title);
970:
971: if ($env{'form.command'} eq 'showslots' && $vgr eq 'F') {
972: &show_table($r,$mgr);
973: } elsif ($env{'form.command'} eq 'uploadstart' && $mgr eq 'F') {
974: &upload_start($r);
975: } elsif ($env{'form.command'} eq 'csvuploadmap' && $mgr eq 'F') {
976: &csv_upload_map($r);
977: } elsif ($env{'form.command'} eq 'csvuploadassign' && $mgr eq 'F') {
978: if ($env{'form.associate'} ne 'Reverse Association') {
979: &csv_upload_assign($r,$mgr);
980: } else {
981: if ( $env{'form.upfile_associate'} ne 'reverse' ) {
982: $env{'form.upfile_associate'} = 'reverse';
983: } else {
984: $env{'form.upfile_associate'} = 'forward';
985: }
986: &csv_upload_map($r);
987: }
988: } else {
989: my $symb=&Apache::lonnet::unescape($env{'form.symb'});
990: my (undef,undef,$res)=&Apache::lonnet::decode_symb($symb);
991: if ($res !~ /\.task$/) {
992: &fail($r,'not_valid');
993: return OK;
994: }
995: $env{'request.symb'}=$symb;
996: my ($status) = &Apache::lonhomework::check_task_access('0');
997: if ($status eq 'CAN_ANSWER' ||
998: $status eq 'NEEDS_CHECKIN' ||
999: $status eq 'WAITING_FOR_GRADE') {
1000: &fail($r,'not_allowed');
1001: return OK;
1002: }
1003: if ($env{'form.requestattempt'}) {
1004: &show_choices($r,$symb);
1005: } elsif ($env{'form.command'} eq 'release') {
1006: &release_slot($r,$symb);
1007: } elsif ($env{'form.command'} eq 'get') {
1008: &get_slot($r,$symb);
1009: } elsif ($env{'form.command'} eq 'change') {
1010: &release_slot($r,$symb,$env{'form.releaseslot'},1);
1011: &get_slot($r,$symb);
1012: } else {
1013: $r->print("<p>Unknown command: ".$env{'form.command'}."</p>");
1014: }
1015: }
1016: &end_page($r);
1017: return OK;
1018: }
1019:
1020: 1;
1021: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to slotrequest.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / interface