1: #!/usr/bin/perl
2:
3: # Housekeeping program, started by cron, loncontrol and loncron.pl
4: #
5: # $Id: loncron,v 1.102 2015/05/28 23:50:15 raeburn Exp $
6: #
7: # Copyright Michigan State University Board of Trustees
8: #
9: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
10: #
11: # LON-CAPA is free software; you can redistribute it and/or modify
12: # it under the terms of the GNU General Public License as published by
13: # the Free Software Foundation; either version 2 of the License, or
14: # (at your option) any later version.
15: #
16: # LON-CAPA is distributed in the hope that it will be useful,
17: # but WITHOUT ANY WARRANTY; without even the implied warranty of
18: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19: # GNU General Public License for more details.
20: #
21: # You should have received a copy of the GNU General Public License
22: # along with LON-CAPA; if not, write to the Free Software
23: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
24: #
25: # /home/httpd/html/adm/gpl.txt
26: #
27: # http://www.lon-capa.org/
28: #
29:
30: $|=1;
31: use strict;
32:
33: use lib '/home/httpd/lib/perl/';
34: use LONCAPA::Configuration;
35: use LONCAPA::Checksumming;
36: use LONCAPA;
37: use Apache::lonnet;
38: use Apache::loncommon;
39:
40: use IO::File;
41: use IO::Socket;
42: use HTML::Entities;
43: use Getopt::Long;
44: #globals
45: use vars qw (%perlvar %simplestatus $errors $warnings $notices $totalcount);
46:
47: my $statusdir="/home/httpd/html/lon-status";
48:
49:
50: # --------------------------------------------------------- Output error status
51:
52: sub log {
53: my $fh=shift;
54: if ($fh) { print $fh @_ }
55: }
56:
57: sub errout {
58: my $fh=shift;
59: &log($fh,(<<ENDERROUT));
60: <table border="2" bgcolor="#CCCCCC">
61: <tr><td>Notices</td><td>$notices</td></tr>
62: <tr><td>Warnings</td><td>$warnings</td></tr>
63: <tr><td>Errors</td><td>$errors</td></tr>
64: </table><p><a href="#top">Top</a></p>
65: ENDERROUT
66: }
67:
68: sub rotate_logfile {
69: my ($file,$fh,$description) = @_;
70: my $size=(stat($file))[7];
71: if ($size>40000) {
72: &log($fh,"<p>Rotating $description ...</p>");
73: rename("$file.2","$file.3");
74: rename("$file.1","$file.2");
75: rename("$file","$file.1");
76: }
77: }
78:
79: sub start_daemon {
80: my ($fh,$daemon,$pidfile,$args) = @_;
81: my $progname=$daemon;
82: if ($daemon eq 'lonc') {
83: $progname='loncnew';
84: }
85: my $error_fname="$perlvar{'lonDaemons'}/logs/${daemon}_errors";
86: &rotate_logfile($error_fname,$fh,'error logs');
87: if ($daemon eq 'lonc') {
88: &clean_sockets($fh);
89: }
90: system("$perlvar{'lonDaemons'}/$progname 2>$perlvar{'lonDaemons'}/logs/${daemon}_errors");
91: sleep 1;
92: if (-e $pidfile) {
93: &log($fh,"<p>Seems like it started ...</p>");
94: my $lfh=IO::File->new("$pidfile");
95: my $daemonpid=<$lfh>;
96: chomp($daemonpid);
97: if ($daemonpid =~ /^\d+$/ && kill 0 => $daemonpid) {
98: return 1;
99: } else {
100: return 0;
101: }
102: }
103: &log($fh,"<p>Seems like that did not work!</p>");
104: $errors++;
105: return 0;
106: }
107:
108: sub checkon_daemon {
109: my ($fh,$daemon,$maxsize,$send,$args)=@_;
110:
111: my $result;
112: &log($fh,'<hr /><a name="'.$daemon.'" /><h2>'.$daemon.'</h2><h3>Log</h3><p style="white-space: pre;"><tt>');
113: printf("%-15s ",$daemon);
114: if (-e "$perlvar{'lonDaemons'}/logs/$daemon.log"){
115: open (DFH,"tail -n25 $perlvar{'lonDaemons'}/logs/$daemon.log|");
116: while (my $line=<DFH>) {
117: &log($fh,"$line");
118: if ($line=~/INFO/) { $notices++; }
119: if ($line=~/WARNING/) { $notices++; }
120: if ($line=~/CRITICAL/) { $warnings++; }
121: };
122: close (DFH);
123: }
124: &log($fh,"</tt></p>");
125:
126: my $pidfile="$perlvar{'lonDaemons'}/logs/$daemon.pid";
127:
128: my $restartflag=1;
129: my $daemonpid;
130: if (-e $pidfile) {
131: my $lfh=IO::File->new("$pidfile");
132: $daemonpid=<$lfh>;
133: chomp($daemonpid);
134: if ($daemonpid =~ /^\d+$/ && kill 0 => $daemonpid) {
135: &log($fh,"<h3>$daemon at pid $daemonpid responding");
136: if ($send) { &log($fh,", sending $send"); }
137: &log($fh,"</h3>");
138: if ($send eq 'USR1') { kill USR1 => $daemonpid; }
139: if ($send eq 'USR2') { kill USR2 => $daemonpid; }
140: $restartflag=0;
141: if ($send eq 'USR2') {
142: $result = 'reloaded';
143: print "reloaded\n";
144: } else {
145: $result = 'running';
146: print "running\n";
147: }
148: } else {
149: $errors++;
150: &log($fh,"<h3>$daemon at pid $daemonpid not responding</h3>");
151: $restartflag=1;
152: &log($fh,"<h3>Decided to clean up stale .pid file and restart $daemon</h3>");
153: }
154: }
155: if ($restartflag==1) {
156: $simplestatus{$daemon}='off';
157: $errors++;
158: my $kadaemon=$daemon;
159: if ($kadaemon eq 'lonmemcached') { $kadaemon='memcached'; }
160: &log($fh,'<br /><font color="red">Killall '.$daemon.': '.
161: `killall $kadaemon 2>&1`.' - ');
162: sleep 1;
163: &log($fh,unlink($pidfile).' - '.
164: `killall -9 $kadaemon 2>&1`.
165: '</font><br />');
166: &log($fh,"<h3>$daemon not running, trying to start</h3>");
167:
168: if (&start_daemon($fh,$daemon,$pidfile,$args)) {
169: &log($fh,"<h3>$daemon at pid $daemonpid responding</h3>");
170: $simplestatus{$daemon}='restarted';
171: $result = 'started';
172: print "started\n";
173: } else {
174: $errors++;
175: &log($fh,"<h3>$daemon at pid $daemonpid not responding</h3>");
176: &log($fh,"<p>Give it one more try ...</p>");
177: print " ";
178: if (&start_daemon($fh,$daemon,$pidfile,$args)) {
179: &log($fh,"<h3>$daemon at pid $daemonpid responding</h3>");
180: $simplestatus{$daemon}='restarted';
181: $result = 'started';
182: print "started\n";
183: } else {
184: $result = 'failed';
185: print " failed\n";
186: $simplestatus{$daemon}='failed';
187: $errors++; $errors++;
188: &log($fh,"<h3>$daemon at pid $daemonpid not responding</h3>");
189: &log($fh,"<p>Unable to start $daemon</p>");
190: }
191: }
192:
193: if (-e "$perlvar{'lonDaemons'}/logs/$daemon.log"){
194: &log($fh,"<p><pre>");
195: open (DFH,"tail -n100 $perlvar{'lonDaemons'}/logs/$daemon.log|");
196: while (my $line=<DFH>) {
197: &log($fh,"$line");
198: if ($line=~/WARNING/) { $notices++; }
199: if ($line=~/CRITICAL/) { $notices++; }
200: };
201: close (DFH);
202: &log($fh,"</pre></p>");
203: }
204: }
205:
206: my $fname="$perlvar{'lonDaemons'}/logs/$daemon.log";
207: &rotate_logfile($fname,$fh,'logs');
208:
209: &errout($fh);
210: return $result;
211: }
212:
213: # --------------------------------------------------------------------- Machine
214: sub log_machine_info {
215: my ($fh)=@_;
216: &log($fh,'<hr /><a name="machine" /><h2>Machine Information</h2>');
217: &log($fh,"<h3>loadavg</h3>");
218:
219: open (LOADAVGH,"/proc/loadavg");
220: my $loadavg=<LOADAVGH>;
221: close (LOADAVGH);
222:
223: &log($fh,"<tt>$loadavg</tt>");
224:
225: my @parts=split(/\s+/,$loadavg);
226: if ($parts[1]>4.0) {
227: $errors++;
228: } elsif ($parts[1]>2.0) {
229: $warnings++;
230: } elsif ($parts[1]>1.0) {
231: $notices++;
232: }
233:
234: &log($fh,"<h3>df</h3>");
235: &log($fh,"<pre>");
236:
237: open (DFH,"df|");
238: while (my $line=<DFH>) {
239: &log($fh,&encode_entities($line,'<>&"'));
240: @parts=split(/\s+/,$line);
241: my $usage=$parts[4];
242: $usage=~s/\W//g;
243: if ($usage>90) {
244: $warnings++;
245: $notices++;
246: } elsif ($usage>80) {
247: $warnings++;
248: } elsif ($usage>60) {
249: $notices++;
250: }
251: if ($usage>95) { $warnings++; $warnings++; $simplestatus{'diskfull'}++; }
252: }
253: close (DFH);
254: &log($fh,"</pre>");
255:
256:
257: &log($fh,"<h3>ps</h3>");
258: &log($fh,"<pre>");
259: my $psproc=0;
260:
261: open (PSH,"ps aux --cols 140 |");
262: while (my $line=<PSH>) {
263: &log($fh,&encode_entities($line,'<>&"'));
264: $psproc++;
265: }
266: close (PSH);
267: &log($fh,"</pre>");
268:
269: if ($psproc>200) { $notices++; }
270: if ($psproc>250) { $notices++; }
271:
272: &log($fh,"<h3>distprobe</h3>");
273: &log($fh,"<pre>");
274: &log($fh,&encode_entities(&LONCAPA::distro(),'<>&"'));
275: &log($fh,"</pre>");
276:
277: &errout($fh);
278: }
279:
280: sub start_logging {
281: my $fh=IO::File->new(">$statusdir/newstatus.html");
282: my %simplestatus=();
283: my $now=time;
284: my $date=localtime($now);
285:
286:
287: &log($fh,(<<ENDHEADERS));
288: <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
289: <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
290: <head>
291: <title>LON Status Report $perlvar{'lonHostID'}</title>
292: <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
293: </head>
294: <body bgcolor="#AAAAAA">
295: <a name="top" />
296: <h1>LON Status Report $perlvar{'lonHostID'}</h1>
297: <h2>$date ($now)</h2>
298: <ol>
299: <li><a href="#configuration">Configuration</a></li>
300: <li><a href="#machine">Machine Information</a></li>
301: <li><a href="#tmp">Temporary Files</a></li>
302: <li><a href="#tokens">Session Tokens</a></li>
303: <li><a href="#webdav">WebDAV Session Tokens</a></li>
304: <li><a href="#httpd">httpd</a></li>
305: <li><a href="#lonsql">lonsql</a></li>
306: <li><a href="#lond">lond</a></li>
307: <li><a href="#lonc">lonc</a></li>
308: <li><a href="#lonnet">lonnet</a></li>
309: <li><a href="#connections">Connections</a></li>
310: <li><a href="#delayed">Delayed Messages</a></li>
311: <li><a href="#errcount">Error Count</a></li>
312: </ol>
313: <hr />
314: <a name="configuration" />
315: <h2>Configuration</h2>
316: <h3>PerlVars</h3>
317: <table border="2">
318: ENDHEADERS
319:
320: foreach my $varname (sort(keys(%perlvar))) {
321: &log($fh,"<tr><td>$varname</td><td>".
322: &encode_entities($perlvar{$varname},'<>&"')."</td></tr>\n");
323: }
324: &log($fh,"</table><h3>Hosts</h3><table border='2'>");
325: my %hostname = &Apache::lonnet::all_hostnames();
326: foreach my $id (sort(keys(%hostname))) {
327: my $role = (&Apache::lonnet::is_library($id) ? 'library'
328: : 'access');
329: &log($fh,
330: "<tr><td>$id</td><td>".&Apache::lonnet::host_domain($id).
331: "</td><td>".$role.
332: "</td><td>".&Apache::lonnet::hostname($id)."</td></tr>\n");
333: }
334: &log($fh,"</table><h3>Spare Hosts</h3>");
335: if (keys(%Apache::lonnet::spareid) > 0) {
336: &log($fh,"<ul>");
337: foreach my $type (sort(keys(%Apache::lonnet::spareid))) {
338: &log($fh,"<li>$type\n<ol>");
339: foreach my $id (@{ $Apache::lonnet::spareid{$type} }) {
340: &log($fh,"<li>$id</li>\n");
341: }
342: &log($fh,"</ol>\n</li>\n");
343: }
344: &log($fh,"</ul>\n");
345: } else {
346: &log($fh,"No spare hosts specified<br />\n");
347: }
348: return $fh;
349: }
350:
351: # --------------------------------------------------------------- clean out tmp
352: sub clean_tmp {
353: my ($fh)=@_;
354: &log($fh,'<hr /><a name="tmp" /><h2>Temporary Files</h2>');
355: my ($cleaned,$old,$removed) = (0,0,0);
356: my %errors = (
357: dir => [],
358: file => [],
359: failopen => [],
360: );
361: my %error_titles = (
362: dir => 'failed to remove empty directory:',
363: file => 'failed to unlike stale file',
364: failopen => 'failed to open file or directory'
365: );
366: ($cleaned,$old,$removed) = &recursive_clean_tmp('',$cleaned,$old,$removed,\%errors);
367: &log($fh,"Cleaned up: ".$cleaned." files; removed: $removed empty directories; (found: $old old checkout tokens)");
368: foreach my $key (sort(keys(%errors))) {
369: if (ref($errors{$key}) eq 'ARRAY') {
370: if (@{$errors{$key}} > 0) {
371: &log($fh,"Error during cleanup ($error_titles{$key}):<ul><li>".
372: join('</li><li><tt>',@{$errors{$key}}).'</tt></li></ul><br />');
373: }
374: }
375: }
376: }
377:
378: sub recursive_clean_tmp {
379: my ($subdir,$cleaned,$old,$removed,$errors) = @_;
380: my $base = "$perlvar{'lonDaemons'}/tmp";
381: my $path = $base;
382: next if ($subdir =~ m{\.\./});
383: next unless (ref($errors) eq 'HASH');
384: unless ($subdir eq '') {
385: $path .= '/'.$subdir;
386: }
387: if (opendir(my $dh,"$path")) {
388: while (my $file = readdir($dh)) {
389: next if ($file =~ /^\.\.?$/);
390: my $fname = "$path/$file";
391: if (-d $fname) {
392: my $innerdir;
393: if ($subdir eq '') {
394: $innerdir = $file;
395: } else {
396: $innerdir = $subdir.'/'.$file;
397: }
398: ($cleaned,$old,$removed) =
399: &recursive_clean_tmp($innerdir,$cleaned,$old,$removed,$errors);
400: my @doms = &Apache::lonnet::current_machine_domains();
401:
402: if (open(my $dirhandle,$fname)) {
403: unless (($innerdir eq 'helprequests') ||
404: (($innerdir =~ /^addcourse/) && ($innerdir !~ m{/\d+$}))) {
405: my @contents = grep {!/^\.\.?$/} readdir($dirhandle);
406: join('&&',@contents)."\n";
407: if (scalar(grep {!/^\.\.?$/} readdir($dirhandle)) == 0) {
408: closedir($dirhandle);
409: if ($fname =~ m{^\Q$perlvar{'lonDaemons'}\E/tmp/}) {
410: if (rmdir($fname)) {
411: $removed ++;
412: } elsif (ref($errors->{dir}) eq 'ARRAY') {
413: push(@{$errors->{dir}},$fname);
414: }
415: }
416: }
417: } else {
418: closedir($dirhandle);
419: }
420: }
421: } else {
422: my ($dev,$ino,$mode,$nlink,
423: $uid,$gid,$rdev,$size,
424: $atime,$mtime,$ctime,
425: $blksize,$blocks)=stat($fname);
426: my $now=time;
427: my $since=$now-$mtime;
428: if ($since>$perlvar{'lonExpire'}) {
429: if ($subdir eq '') {
430: my $line='';
431: if ($fname =~ /\.db$/) {
432: if (unlink($fname)) {
433: $cleaned++;
434: } elsif (ref($errors->{file}) eq 'ARRAY') {
435: push(@{$errors->{file}},$fname);
436: }
437: } elsif (open(PROBE,$fname)) {
438: my $line='';
439: $line=<PROBE>;
440: close(PROBE);
441: if ($line=~/^CHECKOUTTOKEN\&/) {
442: if ($since>365*$perlvar{'lonExpire'}) {
443: if (unlink($fname)) {
444: $cleaned++;
445: } elsif (ref($errors->{file}) eq 'ARRAY') {
446: push(@{$errors->{file}},$fname);
447: }
448: } else {
449: $old++;
450: }
451: } else {
452: if (unlink($fname)) {
453: $cleaned++;
454: } elsif (ref($errors->{file}) eq 'ARRAY') {
455: push(@{$errors->{file}},$fname);
456: }
457: }
458: } elsif (ref($errors->{failopen}) eq 'ARRAY') {
459: push(@{$errors->{failopen}},$fname);
460: }
461: } else {
462: if (unlink($fname)) {
463: $cleaned++;
464: } elsif (ref($errors->{file}) eq 'ARRAY') {
465: push(@{$errors->{file}},$fname);
466: }
467: }
468: }
469: }
470: }
471: closedir($dh);
472: } elsif (ref($errors->{failopen}) eq 'ARRAY') {
473: push(@{$errors->{failopen}},$path);
474: }
475: return ($cleaned,$old,$removed);
476: }
477:
478: # ------------------------------------------------------------ clean out lonIDs
479: sub clean_lonIDs {
480: my ($fh)=@_;
481: &log($fh,'<hr /><a name="tokens" /><h2>Session Tokens</h2>');
482: my $cleaned=0;
483: my $active=0;
484: while (my $fname=<$perlvar{'lonIDsDir'}/*>) {
485: my ($dev,$ino,$mode,$nlink,
486: $uid,$gid,$rdev,$size,
487: $atime,$mtime,$ctime,
488: $blksize,$blocks)=stat($fname);
489: my $now=time;
490: my $since=$now-$mtime;
491: if ($since>$perlvar{'lonExpire'}) {
492: $cleaned++;
493: &log($fh,"Unlinking $fname<br />");
494: unlink("$fname");
495: } else {
496: $active++;
497: }
498: }
499: &log($fh,"<p>Cleaned up ".$cleaned." stale session token(s).</p>");
500: &log($fh,"<h3>$active open session(s)</h3>");
501: }
502:
503: # ------------------------------------------------ clean out webDAV Session IDs
504: sub clean_webDAV_sessionIDs {
505: my ($fh)=@_;
506: if ($perlvar{'lonRole'} eq 'library') {
507: &log($fh,'<hr /><a name="webdav" /><h2>WebDAV Session Tokens</h2>');
508: my $cleaned=0;
509: my $active=0;
510: my $now = time;
511: if (-d $perlvar{'lonDAVsessDir'}) {
512: while (my $fname=<$perlvar{'lonDAVsessDir'}/*>) {
513: my @stats = stat($fname);
514: my $since=$now-$stats[9];
515: if ($since>$perlvar{'lonExpire'}) {
516: $cleaned++;
517: &log($fh,"Unlinking $fname<br />");
518: unlink("$fname");
519: } else {
520: $active++;
521: }
522: }
523: &log($fh,"<p>Cleaned up ".$cleaned." stale webDAV session token(s).</p>");
524: &log($fh,"<h3>$active open webDAV session(s)</h3>");
525: }
526: }
527: }
528:
529: # ----------------------------------------------------------- clean out sockets
530: sub clean_sockets {
531: my ($fh)=@_;
532: my $cleaned=0;
533: opendir(SOCKETS,$perlvar{'lonSockDir'});
534: while (my $fname=readdir(SOCKETS)) {
535: next if (-d $fname
536: || $fname=~/(mysqlsock|maximasock|rsock|\Q$perlvar{'lonSockDir'}\E)/);
537: $cleaned++;
538: &log($fh,"Unlinking $fname<br />");
539: unlink("/home/httpd/sockets/$fname");
540: }
541: &log($fh,"<p>Cleaned up ".$cleaned." stale sockets.</p>");
542: }
543:
544:
545: # ----------------------------------------------------------------------- httpd
546: sub check_httpd_logs {
547: my ($fh)=@_;
548: if (open(PIPE,"./lchttpdlogs|")) {
549: while (my $line=<PIPE>) {
550: &log($fh,$line);
551: if ($line=~/\[error\]/) { $notices++; }
552: }
553: close(PIPE);
554: }
555: &errout($fh);
556: }
557:
558: # ---------------------------------------------------------------------- lonnet
559:
560: sub rotate_lonnet_logs {
561: my ($fh)=@_;
562: &log($fh,'<hr /><a name="lonnet" /><h2>lonnet</h2><h3>Temp Log</h3><pre>');
563: print "Checking logs.\n";
564: if (-e "$perlvar{'lonDaemons'}/logs/lonnet.log"){
565: open (DFH,"tail -n50 $perlvar{'lonDaemons'}/logs/lonnet.log|");
566: while (my $line=<DFH>) {
567: &log($fh,&encode_entities($line,'<>&"'));
568: }
569: close (DFH);
570: }
571: &log($fh,"</pre><h3>Perm Log</h3><pre>");
572:
573: if (-e "$perlvar{'lonDaemons'}/logs/lonnet.perm.log") {
574: open(DFH,"tail -n10 $perlvar{'lonDaemons'}/logs/lonnet.perm.log|");
575: while (my $line=<DFH>) {
576: &log($fh,&encode_entities($line,'<>&"'));
577: }
578: close (DFH);
579: } else { &log($fh,"No perm log\n") }
580:
581: my $fname="$perlvar{'lonDaemons'}/logs/lonnet.log";
582: &rotate_logfile($fname,$fh,'lonnet log');
583:
584: &log($fh,"</pre>");
585: &errout($fh);
586: }
587:
588: sub rotate_other_logs {
589: my ($fh) = @_;
590: my %logs = (
591: autoenroll => 'Auto Enroll log',
592: autocreate => 'Create Course log',
593: searchcat => 'Search Cataloguing log',
594: autoupdate => 'Auto Update log',
595: refreshcourseids_db => 'Refresh CourseIDs db log',
596: );
597: foreach my $item (keys(%logs)) {
598: my $fname=$perlvar{'lonDaemons'}.'/logs/'.$item.'.log';
599: &rotate_logfile($fname,$fh,$logs{$item});
600: }
601: }
602:
603: # ----------------------------------------------------------------- Connections
604: sub test_connections {
605: my ($fh)=@_;
606: &log($fh,'<hr /><a name="connections" /><h2>Connections</h2>');
607: print "Testing connections.\n";
608: &log($fh,"<table border='2'>");
609: my ($good,$bad)=(0,0);
610: my %hostname = &Apache::lonnet::all_hostnames();
611: foreach my $tryserver (sort(keys(%hostname))) {
612: print(".");
613: my $result;
614: my $answer=&Apache::lonnet::reply("ping",$tryserver);
615: if ($answer eq "$tryserver:$perlvar{'lonHostID'}") {
616: $result="<b>ok</b>";
617: $good++;
618: } else {
619: $result=$answer;
620: $warnings++;
621: if ($answer eq 'con_lost') {
622: $bad++;
623: $warnings++;
624: } else {
625: $good++; #self connection
626: }
627: }
628: if ($answer =~ /con_lost/) { print(" $tryserver down\n"); }
629: &log($fh,"<tr><td>$tryserver</td><td>$result</td></tr>\n");
630: }
631: &log($fh,"</table>");
632: print "\n$good good, $bad bad connections\n";
633: &errout($fh);
634: }
635:
636:
637: # ------------------------------------------------------------ Delayed messages
638: sub check_delayed_msg {
639: my ($fh)=@_;
640: &log($fh,'<hr /><a name="delayed" /><h2>Delayed Messages</h2>');
641: print "Checking buffers.\n";
642:
643: &log($fh,'<h3>Scanning Permanent Log</h3>');
644:
645: my $unsend=0;
646:
647: my $dfh=IO::File->new("$perlvar{'lonDaemons'}/logs/lonnet.perm.log");
648: while (my $line=<$dfh>) {
649: my ($time,$sdf,$dserv,$dcmd)=split(/:/,$line);
650: if ($sdf eq 'F') {
651: my $local=localtime($time);
652: &log($fh,"<b>Failed: $time, $dserv, $dcmd</b><br />");
653: $warnings++;
654: }
655: if ($sdf eq 'S') { $unsend--; }
656: if ($sdf eq 'D') { $unsend++; }
657: }
658:
659: &log($fh,"<p>Total unsend messages: <b>$unsend</b></p>\n");
660: if ($unsend > 0) {
661: $warnings=$warnings+5*$unsend;
662: }
663:
664: if ($unsend) { $simplestatus{'unsend'}=$unsend; }
665: &log($fh,"<h3>Outgoing Buffer</h3>\n<pre>");
666: # list directory with delayed messages and remember offline servers
667: my %servers=();
668: open (DFH,"ls -lF $perlvar{'lonSockDir'}/delayed|");
669: while (my $line=<DFH>) {
670: my ($server)=($line=~/\.(\w+)$/);
671: if ($server) { $servers{$server}=1; }
672: &log($fh,&encode_entities($line,'<>&"'));
673: }
674: &log($fh,"</pre>\n");
675: close (DFH);
676: my %hostname = &Apache::lonnet::all_hostnames();
677: my $numhosts = scalar(keys(%hostname));
678: # pong to all servers that have delayed messages
679: # this will trigger a reverse connection, which should flush the buffers
680: foreach my $tryserver (sort(keys(%servers))) {
681: if ($hostname{$tryserver} || !$numhosts) {
682: my $answer;
683: eval {
684: local $SIG{ ALRM } = sub { die "TIMEOUT" };
685: alarm(20);
686: $answer = &Apache::lonnet::reply("pong",$tryserver);
687: alarm(0);
688: };
689: if ($@ && $@ =~ m/TIMEOUT/) {
690: &log($fh,"Attempted pong to $tryserver timed out<br />");
691: print "Time out while contacting: $tryserver for pong.\n";
692: } else {
693: &log($fh,"Pong to $tryserver: $answer<br />");
694: }
695: } else {
696: &log($fh,"$tryserver has delayed messages, but is not part of the cluster -- skipping 'Pong'.<br />");
697: }
698: }
699: }
700:
701: sub finish_logging {
702: my ($fh)=@_;
703: &log($fh,"<a name='errcount' />\n");
704: $totalcount=$notices+4*$warnings+100*$errors;
705: &errout($fh);
706: &log($fh,"<h1>Total Error Count: $totalcount</h1>");
707: my $now=time;
708: my $date=localtime($now);
709: &log($fh,"<hr />$date ($now)</body></html>\n");
710: print "lon-status webpage updated.\n";
711: $fh->close();
712:
713: if ($errors) { $simplestatus{'errors'}=$errors; }
714: if ($warnings) { $simplestatus{'warnings'}=$warnings; }
715: if ($notices) { $simplestatus{'notices'}=$notices; }
716: $simplestatus{'time'}=time;
717: }
718:
719: sub log_simplestatus {
720: rename("$statusdir/newstatus.html","$statusdir/index.html");
721:
722: my $sfh=IO::File->new(">$statusdir/loncron_simple.txt");
723: foreach (keys %simplestatus) {
724: print $sfh $_.'='.$simplestatus{$_}.'&';
725: }
726: print $sfh "\n";
727: $sfh->close();
728: }
729:
730: sub write_loncaparevs {
731: print "Retrieving LON-CAPA version information.\n";
732: my %hostname = &Apache::lonnet::all_hostnames();
733: my $output;
734: foreach my $id (sort(keys(%hostname))) {
735: if ($id ne '') {
736: my $loncaparev;
737: eval {
738: local $SIG{ ALRM } = sub { die "TIMEOUT" };
739: alarm(10);
740: $loncaparev =
741: &Apache::lonnet::get_server_loncaparev('',$id,1,'loncron');
742: alarm(0);
743: };
744: if ($@ && $@ =~ m/TIMEOUT/) {
745: print "Time out while contacting lonHost: $id for version.\n";
746: }
747: if ($loncaparev =~ /^[\w.\-]+$/) {
748: $output .= $id.':'.$loncaparev."\n";
749: }
750: }
751: }
752: if ($output) {
753: if (open(my $fh,">$perlvar{'lonTabDir'}/loncaparevs.tab")) {
754: print $fh $output;
755: close($fh);
756: &Apache::lonnet::load_loncaparevs();
757: }
758: }
759: return;
760: }
761:
762: sub write_serverhomeIDs {
763: print "Retrieving LON-CAPA lonHostID information.\n";
764: my %name_to_host = &Apache::lonnet::all_names();
765: my $output;
766: foreach my $name (sort(keys(%name_to_host))) {
767: if ($name ne '') {
768: if (ref($name_to_host{$name}) eq 'ARRAY') {
769: my $serverhomeID;
770: eval {
771: local $SIG{ ALRM } = sub { die "TIMEOUT" };
772: alarm(10);
773: $serverhomeID =
774: &Apache::lonnet::get_server_homeID($name,1,'loncron');
775: alarm(0);
776: };
777: if ($@ && $@ =~ m/TIMEOUT/) {
778: print "Time out while contacting server: $name\n";
779: }
780: if ($serverhomeID ne '') {
781: $output .= $name.':'.$serverhomeID."\n";
782: } else {
783: $output .= $name.':'.$name_to_host{$name}->[0]."\n";
784: }
785: }
786: }
787: }
788: if ($output) {
789: if (open(my $fh,">$perlvar{'lonTabDir'}/serverhomeIDs.tab")) {
790: print $fh $output;
791: close($fh);
792: &Apache::lonnet::load_serverhomeIDs();
793: }
794: }
795: return;
796: }
797:
798: sub write_checksums {
799: my $distro = &LONCAPA::distro();
800: if ($distro) {
801: print "Retrieving file version and checksumming.\n";
802: my $numchksums = 0;
803: my ($chksumsref,$versionsref) =
804: &LONCAPA::Checksumming::get_checksums($distro,$perlvar{'lonDaemons'},
805: $perlvar{'lonLib'},
806: $perlvar{'lonIncludes'},
807: $perlvar{'lonTabDir'});
808: if (ref($chksumsref) eq 'HASH') {
809: $numchksums = scalar(keys(%{$chksumsref}));
810: }
811: print "File version retrieved and checksumming completed for $numchksums files.\n";
812: } else {
813: print "File version retrieval and checksumming skipped - could not determine Linux distro.\n";
814: }
815: return;
816: }
817:
818: sub send_mail {
819: my $defdom = $perlvar{'lonDefDomain'};
820: my $origmail = $perlvar{'lonAdmEMail'};
821: my $emailto = &Apache::loncommon::build_recipient_list(undef,
822: 'lonstatusmail',$defdom,$origmail);
823: if ($totalcount>2500) {
824: $emailto.=",$perlvar{'lonSysEMail'}";
825: }
826: my $from;
827: my $hostname=`/bin/hostname`;
828: chop($hostname);
829: $hostname=~s/[^\w\.]//g;
830: if ($hostname) {
831: $from = 'www@'.$hostname;
832: }
833: my $subj="LON: $perlvar{'lonHostID'} E:$errors W:$warnings N:$notices";
834: my $loncronmail = "To: $emailto\n".
835: "From: $from\n".
836: "Subject: ".$subj."\n".
837: "Content-type: text/html\; charset=UTF-8\n".
838: "MIME-Version: 1.0\n\n";
839: if (open(my $fh,"<$statusdir/index.html")) {
840: while (<$fh>) {
841: $loncronmail .= $_;
842: }
843: close($fh);
844: } else {
845: $loncronmail .= "Failed to read from http://$hostname/lon-status/index.html\n";
846: }
847: $loncronmail .= "\n\n";
848: if (open(my $mailh, "|/usr/lib/sendmail -oi -t -odb")) {
849: print $mailh $loncronmail;
850: close($mailh);
851: print "Sending mail.\n";
852: } else {
853: print "Sending mail failed.\n";
854: }
855: }
856:
857: sub usage {
858: print(<<USAGE);
859: loncron - housekeeping program that checks up on various parts of LON-CAPA
860:
861: Options:
862: --help Display
863: --noemail Do not send the status email
864: --justcheckconnections Only check the current status of the lonc/d
865: connections, do not send emails do not
866: check if the daemons are running, do not
867: generate lon-status
868: --justcheckdaemons Only check that all of the Lon-CAPA daemons are
869: running, do not send emails do not
870: check the lonc/d connections, do not
871: generate lon-status
872: --justreload Only tell the daemons to reload the config files,
873: do not send emails do not
874: check if the daemons are running, do not
875: generate lon-status
876:
877: USAGE
878: }
879:
880: # ================================================================ Main Program
881: sub main () {
882: my ($help,$justcheckdaemons,$noemail,$justcheckconnections,
883: $justreload);
884: &GetOptions("help" => \$help,
885: "justcheckdaemons" => \$justcheckdaemons,
886: "noemail" => \$noemail,
887: "justcheckconnections" => \$justcheckconnections,
888: "justreload" => \$justreload
889: );
890: if ($help) { &usage(); return; }
891: # --------------------------------- Read loncapa_apache.conf and loncapa.conf
892: my $perlvarref=LONCAPA::Configuration::read_conf('loncapa.conf');
893: %perlvar=%{$perlvarref};
894: undef $perlvarref;
895: delete $perlvar{'lonReceipt'}; # remove since sensitive and not needed
896: delete $perlvar{'lonSqlAccess'}; # remove since sensitive and not needed
897: chdir($perlvar{'lonDaemons'});
898: # --------------------------------------- Make sure that LON-CAPA is configured
899: # I only test for one thing here (lonHostID). This is just a safeguard.
900: if ('{[[[[lonHostID]]]]}' eq $perlvar{'lonHostID'}) {
901: print("Unconfigured machine.\n");
902: my $emailto=$perlvar{'lonSysEMail'};
903: my $hostname=`/bin/hostname`;
904: chop $hostname;
905: $hostname=~s/[^\w\.]//g; # make sure is safe to pass through shell
906: my $subj="LON: Unconfigured machine $hostname";
907: system("echo 'Unconfigured machine $hostname.' |\
908: mailto $emailto -s '$subj' > /dev/null");
909: exit 1;
910: }
911:
912: # ----------------------------- Make sure this process is running from user=www
913: my $wwwid=getpwnam('www');
914: if ($wwwid!=$<) {
915: print("User ID mismatch. This program must be run as user 'www'.\n");
916: my $emailto="$perlvar{'lonAdmEMail'},$perlvar{'lonSysEMail'}";
917: my $subj="LON: $perlvar{'lonHostID'} User ID mismatch";
918: system("echo 'User ID mismatch. loncron must be run as user www.' |\
919: mailto $emailto -s '$subj' > /dev/null");
920: exit 1;
921: }
922:
923: # -------------------------------------------- Force reload of host information
924: &Apache::lonnet::load_hosts_tab(1);
925: &Apache::lonnet::load_domain_tab(1);
926: &Apache::lonnet::get_iphost(1);
927:
928: # ----------------------------------------- Force firewall update for lond port
929:
930: if ((!$justcheckdaemons) && (!$justreload)) {
931: my $now = time;
932: my $tmpfile = $perlvar{'lonDaemons'}.'/tmp/lciptables_iphost_'.
933: $now.$$.int(rand(10000));
934: if (open(my $fh,">$tmpfile")) {
935: my %iphosts = &Apache::lonnet::get_iphost();
936: foreach my $key (keys(%iphosts)) {
937: print $fh "$key\n";
938: }
939: close($fh);
940: if (&LONCAPA::try_to_lock('/tmp/lock_lciptables')) {
941: my $execpath = $perlvar{'lonDaemons'}.'/lciptables';
942: system("$execpath $tmpfile");
943: unlink('/tmp/lock_lciptables'); # Remove the lock file.
944: }
945: unlink($tmpfile);
946: }
947: }
948:
949: # ---------------------------------------------------------------- Start report
950:
951: $errors=0;
952: $warnings=0;
953: $notices=0;
954:
955:
956: my $fh;
957: if (!$justcheckdaemons && !$justcheckconnections && !$justreload) {
958: $fh=&start_logging();
959:
960: &log_machine_info($fh);
961: &clean_tmp($fh);
962: &clean_lonIDs($fh);
963: &clean_webDAV_sessionIDs($fh);
964: &check_httpd_logs($fh);
965: &rotate_lonnet_logs($fh);
966: &rotate_other_logs($fh);
967: }
968: if (!$justcheckconnections && !$justreload) {
969: &checkon_daemon($fh,'lonmemcached',40000);
970: &checkon_daemon($fh,'lonsql',200000);
971: if ( &checkon_daemon($fh,'lond',40000,'USR1') eq 'running') {
972: &checkon_daemon($fh,'lond',40000,'USR2');
973: }
974: &checkon_daemon($fh,'lonc',40000,'USR1');
975: &checkon_daemon($fh,'lonmaxima',40000);
976: &checkon_daemon($fh,'lonr',40000);
977: }
978: if ($justreload) {
979: &checkon_daemon($fh,'lond',40000,'USR2');
980: &checkon_daemon($fh,'lonc',40000,'USR2');
981: }
982: if ($justcheckconnections) {
983: &test_connections($fh);
984: }
985: if (!$justcheckdaemons && !$justcheckconnections && !$justreload) {
986: &check_delayed_msg($fh);
987: &finish_logging($fh);
988: &log_simplestatus();
989: &write_loncaparevs();
990: &write_serverhomeIDs();
991: &write_checksums();
992: if ($totalcount>200 && !$noemail) { &send_mail(); }
993: }
994: }
995:
996: &main();
997: 1;
998:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>