1: # The LearningOnline Network
2: # URL translation for encrypted filenames
3: #
4: # $Id: lonenc.pm,v 1.18 2006/12/08 22:04:57 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonenc;
30:
31: use strict;
32: use Apache::lonnet;
33: use Crypt::IDEA;
34: use Time::HiRes qw(gettimeofday);
35: use LONCAPA;
36:
37: sub encryptseed {
38: my $seed=$env{'course.'.$env{'request.course.id'}.'.internal.encseed'};
39: $seed=~s/[^0-9a-f]/0/g;
40: $seed.='0123456789abcdef';
41: $seed=substr($seed.$seed,0,32);
42: return pack("H32",$seed);
43: }
44:
45: sub unencrypted {
46: my $uri=shift;
47: $uri=~s/^\/enc\/(\d+)\///;
48: my $cmdlength=$1;
49: # strip any added extension
50: $uri=~s/\.[^.]*//;
51: my $seed=&encryptseed();
52: unless ($seed) {
53: return '/'.$uri;
54: }
55: $uri=&unescape($uri);
56: my $cipher=new IDEA $seed;
57: my $decuri='';
58: for (my $encidx=0;$encidx<length($uri);$encidx+=16) {
59: $decuri.=$cipher->decrypt(
60: pack("H16",substr($uri,$encidx,16))
61: );
62: }
63: $env{'request.enc'}=1;
64: $decuri=&remove_noise($decuri);
65: return substr($decuri,0,$cmdlength);
66: }
67:
68: # add a randomish character after every 4th caharacter
69: sub add_noise {
70: my ($uri)=@_;
71: my @noise=split(/(.)/,(&gettimeofday())[1]);
72: my $noisy;
73: my $i;
74: foreach my $chunk (split(/(....)/,$uri)) {
75: $noisy.=$chunk;
76: $noisy.=$noise[($i++)%(scalar@noise)];
77: }
78: return $noisy;
79: }
80:
81: # remove every fifth character
82: sub remove_noise {
83: my ($uri)=@_;
84: my $clean;
85: foreach my $chunk (split(/(....)./,$uri)) { $clean.=$chunk; }
86: return $clean;
87: }
88:
89: sub encrypted {
90: my ($uri,$force_enc) = @_;
91: if (!$force_enc && $env{'request.role.adv'}) { return($uri); }
92: my $seed=&encryptseed();
93: unless ($seed) {
94: return $uri;
95: }
96: my $cmdlength=length($uri);
97: # add noise before enc so that that same url's look different
98: $uri=&add_noise($uri);
99: my $noiselength=length($uri);
100: $uri.=time;
101: my $encuri='';
102: my $cipher=new IDEA $seed;
103: for (my $encidx=0;$encidx<=$noiselength;$encidx+=8) {
104: $encuri.=unpack("H16",
105: $cipher->encrypt(substr($uri,$encidx,8)));
106: }
107: return '/enc/'.$cmdlength.'/'.&escape($encuri);
108: }
109:
110: sub check_encrypt {
111: my $str=shift;
112: if (ref($str)) {
113: if ($env{'request.enc'}) { $$str = &Apache::lonenc::encrypted($$str); }
114: return;
115: } else {
116: if ($env{'request.enc'}) { return &Apache::lonenc::encrypted($str); }
117: }
118: return $str;
119: }
120:
121: sub check_decrypt {
122: my ($str)=@_;
123: if (ref($str)) {
124: if ($$str=~m|^/enc/|) { $$str=&Apache::lonenc::unencrypted($$str); }
125: return;
126: }
127: if ($str=~m|^/enc/|) { return &Apache::lonenc::unencrypted($str); }
128: return $str;
129: }
130:
131: sub encrypt_ref {
132: my ($token,$elements,$force_enc)=@_;
133: my $html;
134: if ($force_enc || $env{'request.enc'}) {
135: while (my ($name,$value)= each(%{ $elements })) {
136: if (!$value) { next; }
137: my $href=&Apache::lonnet::hreflocation($Apache::lonxml::pwd[-1],$value);
138: if ($href !~ /^http:/) {
139: # IE really wants an extension
140: my ($extension) = ($href =~ m/(\.[^.]*)$/);
141: $href = &Apache::lonenc::encrypted($href,$force_enc);
142: $href .= $extension;
143: }
144: $token->[2]->{$name}=$href;
145: }
146: delete($token->[2]->{'encrypturl'});
147: $html = &Apache::edit::rebuild_tag($token);
148: } else {
149: $html = $token->[4];
150: }
151: return $html;
152: }
153: 1;
154: __END__
155:
156:
157:
158:
159:
160:
161:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>