1: #!/usr/bin/perl
2: # The LearningOnline Network
3: # searchcat.pl "Search Catalog" batch script
4: #
5: # $Id: searchcat.pl,v 1.52 2003/12/27 01:52:04 www Exp $
6: #
7: # Copyright Michigan State University Board of Trustees
8: #
9: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
10: #
11: # LON-CAPA is free software; you can redistribute it and/or modify
12: # it under the terms of the GNU General Public License as published by
13: # the Free Software Foundation; either version 2 of the License, or
14: # (at your option) any later version.
15: #
16: # LON-CAPA is distributed in the hope that it will be useful,
17: # but WITHOUT ANY WARRANTY; without even the implied warranty of
18: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19: # GNU General Public License for more details.
20: #
21: # You should have received a copy of the GNU General Public License
22: # along with LON-CAPA; if not, write to the Free Software
23: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
24: #
25: # /home/httpd/html/adm/gpl.txt
26: #
27: # http://www.lon-capa.org/
28: #
29: ###
30:
31: =pod
32:
33: =head1 NAME
34:
35: B<searchcat.pl> - put authoritative filesystem data into sql database.
36:
37: =head1 SYNOPSIS
38:
39: Ordinarily this script is to be called from a loncapa cron job
40: (CVS source location: F<loncapa/loncom/cron/loncapa>; typical
41: filesystem installation location: F</etc/cron.d/loncapa>).
42:
43: Here is the cron job entry.
44:
45: C<# Repopulate and refresh the metadata database used for the search catalog.>
46: C<10 1 * * 7 www /home/httpd/perl/searchcat.pl>
47:
48: This script only allows itself to be run as the user C<www>.
49:
50: =head1 DESCRIPTION
51:
52: This script goes through a loncapa resource directory and gathers metadata.
53: The metadata is entered into a SQL database.
54:
55: This script also does general database maintenance such as reformatting
56: the C<loncapa:metadata> table if it is deprecated.
57:
58: This script evaluates dynamic metadata from the authors'
59: F<nohist_resevaldata.db> database file in order to store it in MySQL.
60:
61: This script is playing an increasingly important role for a loncapa
62: library server. The proper operation of this script is critical for a smooth
63: and correct user experience.
64:
65: =cut
66:
67: use strict;
68:
69: use lib '/home/httpd/lib/perl/';
70: use LONCAPA::Configuration;
71:
72: use IO::File;
73: use HTML::TokeParser;
74: use DBI;
75: use GDBM_File;
76: use POSIX qw(strftime mktime);
77:
78: require "find.pl";
79:
80: my @metalist;
81:
82: my $simplestatus='';
83: my %countext=();
84:
85: # ----------------------------------------------------- write out simple status
86: sub writesimple {
87: open(SMP,'>/home/httpd/html/lon-status/mysql.txt');
88: print SMP $simplestatus."\n";
89: close(SMP);
90: }
91:
92: sub writecount {
93: open(RSMP,'>/home/httpd/html/lon-status/rescount.txt');
94: foreach (keys %countext) {
95: print RSMP $_.'='.$countext{$_}.'&';
96: }
97: print RSMP 'time='.time."\n";
98: close(RSMP);
99: }
100:
101: # -------------------------------------- counts files with different extensions
102: sub count {
103: my $file=shift;
104: $file=~/\.(\w+)$/;
105: my $ext=lc($1);
106: if (defined($countext{$ext})) {
107: $countext{$ext}++;
108: } else {
109: $countext{$ext}=1;
110: }
111: }
112: # ----------------------------------------------------- Un-Escape Special Chars
113:
114: sub unescape {
115: my $str=shift;
116: $str =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
117: return $str;
118: }
119:
120: # -------------------------------------------------------- Escape Special Chars
121:
122: sub escape {
123: my $str=shift;
124: $str =~ s/(\W)/"%".unpack('H2',$1)/eg;
125: return $str;
126: }
127:
128: # ------------------------------------------- Code to evaluate dynamic metadata
129:
130: sub dynamicmeta {
131: my $url=&declutter(shift);
132: $url=~s/\.meta$//;
133: my %returnhash=(
134: 'count' => 0,
135: 'course' => 0,
136: 'course_list' => '',
137: 'avetries' => 'NULL',
138: 'avetries_list' => '',
139: 'stdno' => 0,
140: 'stdno_list' => '',
141: 'usage' => 0,
142: 'usage_list' => '',
143: 'goto' => 0,
144: 'goto_list' => '',
145: 'comefrom' => 0,
146: 'comefrom_list' => '',
147: 'difficulty' => 'NULL',
148: 'difficulty_list' => '',
149: 'clear' => 'NULL',
150: 'technical' => 'NULL',
151: 'correct' => 'NULL',
152: 'helpful' => 'NULL',
153: 'depth' => 'NULL',
154: 'comments' => ''
155: );
156: my ($adomain,$aauthor)=($url=~/^(\w+)\/(\w+)\//);
157: my $prodir=&propath($adomain,$aauthor);
158:
159: # Get metadata except counts
160: if (tie(my %evaldata,'GDBM_File',
161: $prodir.'/nohist_resevaldata.db',&GDBM_READER(),0640)) {
162: my %sum=();
163: my %cnt=();
164: my %concat=();
165: my %listitems=(
166: 'course' => 'add',
167: 'goto' => 'add',
168: 'comefrom' => 'add',
169: 'avetries' => 'avg',
170: 'stdno' => 'add',
171: 'difficulty' => 'avg',
172: 'clear' => 'avg',
173: 'technical' => 'avg',
174: 'helpful' => 'avg',
175: 'correct' => 'avg',
176: 'depth' => 'avg',
177: 'comments' => 'app',
178: 'usage' => 'cnt'
179: );
180:
181: my $regexp=$url;
182: $regexp=~s/(\W)/\\$1/g;
183: $regexp='___'.$regexp.'___([a-z]+)$';
184: while (my ($esckey,$value)=each %evaldata) {
185: my $key=&unescape($esckey);
186: if ($key=~/$regexp/) {
187: my ($item,$purl,$cat)=split(/___/,$key);
188: if (defined($cnt{$cat})) { $cnt{$cat}++; } else { $cnt{$cat}=1; }
189: unless ($listitems{$cat} eq 'app') {
190: if (defined($sum{$cat})) {
191: $sum{$cat}+=&unescape($evaldata{$esckey});
192: $concat{$cat}.=','.$item;
193: } else {
194: $sum{$cat}=&unescape($evaldata{$esckey});
195: $concat{$cat}=$item;
196: }
197: } else {
198: if (defined($sum{$cat})) {
199: if ($evaldata{$esckey}=~/\w/) {
200: $sum{$cat}.='<hr />'.&unescape($evaldata{$esckey});
201: }
202: } else {
203: $sum{$cat}=''.&unescape($evaldata{$esckey});
204: }
205: }
206: }
207: }
208: untie(%evaldata);
209: # transfer gathered data to returnhash, calculate averages where applicable
210: while (my $cat=each(%cnt)) {
211: if ($cnt{$cat} eq 'nan') { next; }
212: if ($sum{$cat} eq 'nan') { next; }
213: if ($listitems{$cat} eq 'avg') {
214: if ($cnt{$cat}) {
215: $returnhash{$cat}=int(($sum{$cat}/$cnt{$cat})*100.0+0.5)/100.0;
216: } else {
217: $returnhash{$cat}='NULL';
218: }
219: } elsif ($listitems{$cat} eq 'cnt') {
220: $returnhash{$cat}=$cnt{$cat};
221: } else {
222: $returnhash{$cat}=$sum{$cat};
223: }
224: $returnhash{$cat.'_list'}=$concat{$cat};
225: }
226: }
227: # get count
228: if (tie(my %evaldata,'GDBM_File',
229: $prodir.'/nohist_accesscount.db',&GDBM_READER(),0640)) {
230: my $escurl=&escape($url);
231: if (! exists($evaldata{$escurl})) {
232: $returnhash{'count'}=0;
233: } else {
234: $returnhash{'count'}=$evaldata{$escurl};
235: }
236: untie %evaldata;
237: }
238: return %returnhash;
239: }
240:
241: # --------------- Read loncapa_apache.conf and loncapa.conf and get variables
242: my $perlvarref=LONCAPA::Configuration::read_conf('loncapa.conf');
243: my %perlvar=%{$perlvarref};
244: undef $perlvarref;
245: delete $perlvar{'lonReceipt'}; # remove since sensitive and not needed
246:
247: # ------------------------------------- Only run if machine is a library server
248: exit unless $perlvar{'lonRole'} eq 'library';
249:
250: # ----------------------------- Make sure this process is running from user=www
251:
252: my $wwwid=getpwnam('www');
253: if ($wwwid!=$<) {
254: my $emailto="$perlvar{'lonAdmEMail'},$perlvar{'lonSysEMail'}";
255: my $subj="LON: $perlvar{'lonHostID'} User ID mismatch";
256: system("echo 'User ID mismatch. searchcat.pl must be run as user www.' |\
257: mailto $emailto -s '$subj' > /dev/null");
258: exit 1;
259: }
260:
261:
262: # ---------------------------------------------------------- We are in business
263:
264: open(LOG,'>'.$perlvar{'lonDaemons'}.'/logs/searchcat.log');
265: print LOG '==== Searchcat Run '.localtime()."====\n\n";
266: $simplestatus='time='.time.'&';
267: my $dbh;
268: # ------------------------------------- Make sure that database can be accessed
269: {
270: unless (
271: $dbh = DBI->connect("DBI:mysql:loncapa","www",$perlvar{'lonSqlAccess'},{ RaiseError =>0,PrintError=>0})
272: ) {
273: print LOG "Cannot connect to database!\n";
274: $simplestatus.='mysql=defunct';
275: &writesimple();
276: exit;
277: }
278:
279: # Make temporary table
280: $dbh->do("DROP TABLE IF EXISTS newmetadata");
281: my $make_metadata_table = "CREATE TABLE IF NOT EXISTS newmetadata (".
282: "title TEXT, author TEXT, subject TEXT, url TEXT, keywords TEXT, ".
283: "version TEXT, notes TEXT, abstract TEXT, mime TEXT, language TEXT, ".
284: "creationdate DATETIME, lastrevisiondate DATETIME, owner TEXT, ".
285: "copyright TEXT, dependencies TEXT, ".
286: "modifyinguser TEXT, authorspace TEXT, ".
287: "lowestgradelevel INTEGER UNSIGNED, highestgradelevel INTEGER UNSIGNED, ".
288: "standards TEXT, ".
289: "count INTEGER UNSIGNED, ".
290: "course INTEGER UNSIGNED, course_list TEXT, ".
291: "goto INTEGER UNSIGNED, goto_list TEXT, ".
292: "comefrom INTEGER UNSIGNED, comefrom_list TEXT, ".
293: "sequsage INTEGER UNSIGNED, sequsage_list TEXT, ".
294: "stdno INTEGER UNSIGNED, stdno_list TEXT, ".
295: "avetries FLOAT, avetries_list TEXT, ".
296: "difficulty FLOAT, difficulty_list TEXT, ".
297: "clear FLOAT, technical FLOAT, correct FLOAT, helpful FLOAT, depth FLOAT, ".
298: "comments TEXT, ".
299:
300: "FULLTEXT idx_title (title), ".
301: "FULLTEXT idx_author (author), FULLTEXT idx_subject (subject), ".
302: "FULLTEXT idx_url (url), FULLTEXT idx_keywords (keywords), ".
303: "FULLTEXT idx_notes (notes), ".
304: "FULLTEXT idx_abstract (abstract), FULLTEXT idx_mime (mime), ".
305: "FULLTEXT idx_owner (owner), ".
306: "FULLTEXT idx_standards (standards))".
307: "TYPE=MyISAM";
308: # It would sure be nice to have some logging mechanism.
309: unless ($dbh->do($make_metadata_table)) {
310: print LOG "\nMySQL Error Create: ".$dbh->errstr."\n";
311: die $dbh->errstr;
312: }
313: }
314:
315: # ------------------------------------------------------------- get .meta files
316: opendir(RESOURCES,"$perlvar{'lonDocRoot'}/res/$perlvar{'lonDefDomain'}");
317: my @homeusers = grep {
318: &ishome("$perlvar{'lonDocRoot'}/res/$perlvar{'lonDefDomain'}/$_")
319: } grep {!/^\.\.?$/} readdir(RESOURCES);
320: closedir RESOURCES;
321:
322: #
323: # Create the statement handlers we need
324:
325: my $insert_sth = $dbh->prepare
326: ("INSERT INTO newmetadata VALUES (".
327: "?,". # title
328: "?,". # author
329: "?,". # subject
330: "?,". # declutter url
331: "?,". # version
332: "?,". # current
333: "?,". # notes
334: "?,". # abstract
335: "?,". # mime
336: "?,". # language
337: "?,". # creationdate
338: "?,". # revisiondate
339: "?,". # owner
340: "?,". # copyright
341: "?,". # dependencies
342: "?,". # modifyinguser
343: "?,". # authorspace
344: "?,". # lowestgradelevel
345: "?,". # highestgradelevel
346: "?,". # standards
347: "?,". # count
348: "?,". # course
349: "?,". # course_list
350: "?,". # goto
351: "?,". # goto_list
352: "?,". # comefrom
353: "?,". # comefrom_list
354: "?,". # usage
355: "?,". # usage_list
356: "?,". # stdno
357: "?,". # stdno_list
358: "?,". # avetries
359: "?,". # avetries_list
360: "?,". # difficulty
361: "?,". # difficulty_list
362: "?,". # clear
363: "?,". # technical
364: "?,". # correct
365: "?,". # helpful
366: "?,". # depth
367: "?". # comments
368: ")"
369: );
370:
371: foreach my $user (@homeusers) {
372: print LOG "\n=== User: ".$user."\n\n";
373:
374: my $prodir=&propath($perlvar{'lonDefDomain'},$user);
375: # Use find.pl
376: undef @metalist;
377: @metalist=();
378: &find("$perlvar{'lonDocRoot'}/res/$perlvar{'lonDefDomain'}/$user");
379: # -- process each file to get metadata and put into search catalog SQL
380: # database. Also, check to see if already there.
381: # I could just delete (without searching first), but this works for now.
382: foreach my $m (@metalist) {
383: print LOG "- ".$m."\n";
384: my $ref=&metadata($m);
385: my $m2='/res/'.&declutter($m);
386: $m2=~s/\.meta$//;
387: if ($ref->{'obsolete'}) { print LOG "obsolete\n"; next; }
388: if ($ref->{'copyright'} eq 'private') { print LOG "private\n"; next; }
389: my %dyn=&dynamicmeta($m2);
390: &count($m2);
391: unless ($insert_sth->execute(
392: $ref->{'title'},
393: $ref->{'author'},
394: $ref->{'subject'},
395: $m2,
396: $ref->{'keywords'},
397: 'current',
398: $ref->{'notes'},
399: $ref->{'abstract'},
400: $ref->{'mime'},
401: $ref->{'language'},
402: sqltime($ref->{'creationdate'}),
403: sqltime($ref->{'lastrevisiondate'}),
404: $ref->{'owner'},
405: $ref->{'copyright'},
406: $ref->{'dependencies'},
407: $ref->{'modifyinguser'},
408: $ref->{'authorspace'},
409: $ref->{'lowestgradelevel'},
410: $ref->{'highestgradelevel'},
411: $ref->{'standards'},
412: $dyn{'count'},
413: $dyn{'course'},
414: $dyn{'course_list'},
415: $dyn{'goto'},
416: $dyn{'goto_list'},
417: $dyn{'comefrom'},
418: $dyn{'comefrom_list'},
419: $dyn{'usage'},
420: $dyn{'usage_list'},
421: $dyn{'stdno'},
422: $dyn{'stdno_list'},
423: $dyn{'avetries'},
424: $dyn{'avetries_list'},
425: $dyn{'difficulty'},
426: $dyn{'difficulty_list'},
427: $dyn{'clear'},
428: $dyn{'technical'},
429: $dyn{'correct'},
430: $dyn{'helpful'},
431: $dyn{'depth'},
432: $dyn{'comments'}
433: )) {
434: print LOG "\nMySQL Error Insert: ".$dbh->errstr."\n";
435: die $dbh->errstr;
436: }
437: $ref = undef;
438: }
439: }
440: # --------------------------------------------------- Close database connection
441: $dbh->do("DROP TABLE IF EXISTS metadata");
442: unless ($dbh->do("RENAME TABLE newmetadata TO metadata")) {
443: print LOG "\nMySQL Error Rename: ".$dbh->errstr."\n";
444: die $dbh->errstr;
445: }
446: unless ($dbh->disconnect) {
447: print LOG "\nMySQL Error Disconnect: ".$dbh->errstr."\n";
448: die $dbh->errstr;
449: }
450: print LOG "\n==== Searchcat completed ".localtime()." ====\n";
451: close(LOG);
452: &writesimple();
453: &writecount();
454: exit 0;
455:
456:
457:
458: # =============================================================================
459:
460: # ---------------------------------------------------------------- Get metadata
461: # significantly altered from subroutine present in lonnet
462: sub metadata {
463: my ($uri,$what)=@_;
464: my %metacache=();
465: $uri=&declutter($uri);
466: my $filename=$uri;
467: $uri=~s/\.meta$//;
468: $uri='';
469: unless ($metacache{$uri.'keys'}) {
470: unless ($filename=~/\.meta$/) { $filename.='.meta'; }
471: my $metastring=&getfile($perlvar{'lonDocRoot'}.'/res/'.$filename);
472: my $parser=HTML::TokeParser->new(\$metastring);
473: my $token;
474: while ($token=$parser->get_token) {
475: if ($token->[0] eq 'S') {
476: my $entry=$token->[1];
477: my $unikey=$entry;
478: if (defined($token->[2]->{'part'})) {
479: $unikey.='_'.$token->[2]->{'part'};
480: }
481: if (defined($token->[2]->{'name'})) {
482: $unikey.='_'.$token->[2]->{'name'};
483: }
484: if ($metacache{$uri.'keys'}) {
485: $metacache{$uri.'keys'}.=','.$unikey;
486: } else {
487: $metacache{$uri.'keys'}=$unikey;
488: }
489: map {
490: $metacache{$uri.''.$unikey.'.'.$_}=$token->[2]->{$_};
491: } @{$token->[3]};
492: unless (
493: $metacache{$uri.''.$unikey}=$parser->get_text('/'.$entry)
494: ) { $metacache{$uri.''.$unikey}=
495: $metacache{$uri.''.$unikey.'.default'};
496: }
497: }
498: }
499: }
500: return \%metacache;
501: }
502:
503: # ------------------------------------------------------------ Serves up a file
504: # returns either the contents of the file or a -1
505: sub getfile {
506: my $file=shift;
507: if (! -e $file ) { return -1; };
508: my $fh=IO::File->new($file);
509: my $a='';
510: while (<$fh>) { $a .=$_; }
511: return $a;
512: }
513:
514: # ------------------------------------------------------------- Declutters URLs
515: sub declutter {
516: my $thisfn=shift;
517: $thisfn=~s/^$perlvar{'lonDocRoot'}//;
518: $thisfn=~s/^\///;
519: $thisfn=~s/^res\///;
520: return $thisfn;
521: }
522:
523: # --------------------------------------- Is this the home server of an author?
524: # (copied from lond, modification of the return value)
525: sub ishome {
526: my $author=shift;
527: $author=~s/\/home\/httpd\/html\/res\/([^\/]*)\/([^\/]*).*/$1\/$2/;
528: my ($udom,$uname)=split(/\//,$author);
529: my $proname=propath($udom,$uname);
530: if (-e $proname) {
531: return 1;
532: } else {
533: return 0;
534: }
535: }
536:
537: # -------------------------------------------- Return path to profile directory
538: # (copied from lond)
539: sub propath {
540: my ($udom,$uname)=@_;
541: $udom=~s/\W//g;
542: $uname=~s/\W//g;
543: my $subdir=$uname.'__';
544: $subdir =~ s/(.)(.)(.).*/$1\/$2\/$3/;
545: my $proname="$perlvar{'lonUsersDir'}/$udom/$subdir/$uname";
546: return $proname;
547: }
548:
549: # ---------------------------- convert 'time' format into a datetime sql format
550: sub sqltime {
551: my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
552: localtime(&unsqltime(@_[0]));
553: $mon++; $year+=1900;
554: return "$year-$mon-$mday $hour:$min:$sec";
555: }
556:
557: sub maketime {
558: my %th=@_;
559: return POSIX::mktime(($th{'seconds'},$th{'minutes'},$th{'hours'},
560: $th{'day'},$th{'month'}-1,
561: $th{'year'}-1900,0,0,$th{'dlsav'}));
562: }
563:
564:
565: #########################################
566: #
567: # Retro-fixing of un-backward-compatible time format
568:
569: sub unsqltime {
570: my $timestamp=shift;
571: if ($timestamp=~/^(\d+)\-(\d+)\-(\d+)\s+(\d+)\:(\d+)\:(\d+)$/) {
572: $timestamp=&maketime('year'=>$1,'month'=>$2,'day'=>$3,
573: 'hours'=>$4,'minutes'=>$5,'seconds'=>$6);
574: }
575: return $timestamp;
576: }
577:
578: # ----------------- Code to enable 'find' subroutine listing of the .meta files
579:
580: no strict "vars";
581:
582: sub wanted {
583: (($dev,$ino,$mode,$nlink,$uid,$gid) = lstat($_)) &&
584: -f _ &&
585: /^.*\.meta$/ && !/^.+\.\d+\.[^\.]+\.meta$/ &&
586: push(@metalist,"$dir/$_");
587: }
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>