1: # The LearningOnline Network with CAPA
2: # Handler to rename files, etc, in construction space
3: #
4: # This file responds to the various buttons and events
5: # in the top frame of the construction space directory.
6: # Each event is processed in two phases. The first phase
7: # presents a page that describes the proposed action to the user
8: # and requests confirmation. The second phase commits the action
9: # and displays a page showing the results of the action.
10: #
11: #
12: # $Id: loncfile.pm,v 1.117 2012/11/30 11:36:14 bisitz Exp $
13: #
14: # Copyright Michigan State University Board of Trustees
15: #
16: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
17: #
18: # LON-CAPA is free software; you can redistribute it and/or modify
19: # it under the terms of the GNU General Public License as published by
20: # the Free Software Foundation; either version 2 of the License, or
21: # (at your option) any later version.
22: #
23: # LON-CAPA is distributed in the hope that it will be useful,
24: # but WITHOUT ANY WARRANTY; without even the implied warranty of
25: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
26: # GNU General Public License for more details.
27: #
28: # You should have received a copy of the GNU General Public License
29: # along with LON-CAPA; if not, write to the Free Software
30: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
31: #
32: # /home/httpd/html/adm/gpl.txt
33: #
34: # http://www.lon-capa.org/
35: #
36: =pod
37:
38: =head1 NAME
39:
40: Apache::loncfile - Construction space file management.
41:
42: =head1 SYNOPSIS
43:
44: Content handler for buttons on the top frame of the construction space
45: directory.
46:
47: =head1 INTRODUCTION
48:
49: loncfile is invoked when buttons in the top frame of the construction
50: space directory listing are clicked. All operations proceed in two phases.
51: The first phase describes to the user exactly what will be done. If the user
52: confirms the operation, the second phase commits the operation and indicates
53: completion. When the user dismisses the output of phase2, they are returned to
54: an "appropriate" directory listing in general.
55:
56: This is part of the LearningOnline Network with CAPA project
57: described at http://www.lon-capa.org.
58:
59: =head2 Subroutines
60:
61: =cut
62:
63: package Apache::loncfile;
64:
65: use strict;
66: use Apache::File;
67: use File::Basename;
68: use File::Copy;
69: use HTML::Entities();
70: use Apache::Constants qw(:common :http :methods);
71: use Apache::lonnet;
72: use Apache::loncommon();
73: use Apache::lonlocal;
74: use LONCAPA qw(:DEFAULT :match);
75:
76:
77: my $DEBUG=0;
78: my $r; # Needs to be global for some stuff RF.
79:
80: =pod
81:
82: =item Debug($request, $message)
83:
84: If debugging is enabled puts out a debugging message determined by the
85: caller. The debug message goes to the Apache error log file. Debugging
86: is enabled by setting the module global DEBUG variable to nonzero (TRUE).
87:
88: Parameters:
89:
90: =over 4
91:
92: =item $request - The current request operation.
93:
94: =item $message - The message to put in the log file.
95:
96: =back
97:
98: Returns:
99: nothing.
100:
101: =cut
102:
103: sub Debug {
104: # Put out the indicated message but only if DEBUG is true.
105: if ($DEBUG) {
106: my ($r,$message) = @_;
107: $r->log_reason($message);
108: }
109: }
110:
111: sub done {
112: my ($url) = @_;
113: return
114: '<p>'
115: .&Apache::lonhtmlcommon::confirm_success(&mt("Done"))
116: .'<br /><a href="'.$url.'">'.&mt("Continue").'</a>'
117: .'<script type="text/javascript">'
118: .'location.href="'.$url.'";'
119: .'</script>'
120: .'</p>';
121: }
122:
123: =pod
124:
125: =item URLToPath($url)
126:
127: Convert a URL to a file system path.
128:
129: In order to manipulate the construction space objects, it is necessary
130: to access url identified objects a filespace objects. This function
131: translates a construction space URL to a file system path.
132: Parameters:
133:
134: =over 4
135:
136: =item Url - string [in] The url to convert.
137:
138: =back
139:
140: Returns:
141:
142: =over 4
143:
144: =item The corresponding file system path.
145:
146: =back
147:
148: Global References
149:
150: =over 4
151:
152: =item $r - Request object [in] Referenced in the &Debug calls.
153:
154: =back
155:
156: =cut
157:
158: sub URLToPath {
159: my $Url = shift;
160: &Debug($r, "UrlToPath got: $Url");
161: $Url=~ s{^https?\://[^/]+}{};
162: $Url=~ s{//+}{/}g;
163: $Url=~ s{^/}{};
164: $Url=$Apache::lonnet::perlvar{'lonDocRoot'}."/$Url";
165: &Debug($r, "Returning $Url \n");
166: return $Url;
167: }
168:
169: sub url {
170: my $fn=shift;
171: my $londocroot = $Apache::lonnet::perlvar{'lonDocRoot'};
172: $fn=~ s/^\Q$londocroot\E//;
173: $fn=~s{/\./}{/}g;
174: $fn=&HTML::Entities::encode($fn,'<>"&');
175: return $fn;
176: }
177:
178: sub display {
179: my $fn=shift;
180: my $londocroot = $Apache::lonnet::perlvar{'lonDocRoot'};
181: $fn=~s/^\Q$londocroot\E//;
182: $fn=~s{/\./}{/}g;
183: return '<span class="LC_filename">'.$fn.'</span>';
184: }
185:
186:
187: # see if the file is
188: # a) published (return 0 if not)
189: # b) if, so obsolete (return 0 if not)
190:
191: sub obsolete_unpub {
192: my ($user,$domain,$construct)=@_;
193: my $londocroot = $Apache::lonnet::perlvar{'lonDocRoot'};
194: my $published=$construct;
195: $published=~s{^\Q$londocroot/priv/\E}{$londocroot/res/};
196: if (-e $published) {
197: if (&Apache::lonnet::metadata($published,'obsolete')) {
198: return 1;
199: }
200: return 0;
201: } else {
202: return 1;
203: }
204: }
205:
206: # see if directory is empty
207: # ignores any .meta, .save, .bak, and .log files created for a previously
208: # published file, which has since been marked obsolete and deleted.
209: # ignores a .DS_Store file put there when viewing directory via webDAV on MacOS.
210: sub empty_directory {
211: my ($dirname,$phase) = @_;
212: if (opendir DIR, $dirname) {
213: my @files = grep(!/^\.\.?$/, readdir(DIR)); # ignore . and ..
214: if (@files) {
215: my @orphans = grep(/\.(meta|save|log|bak|DS_Store)$/,@files);
216: if (scalar(@files) - scalar(@orphans) > 0) {
217: return 0;
218: } else {
219: if (($phase eq 'Delete2') && (@orphans > 0)) {
220: foreach my $file (@orphans) {
221: if ($file =~ /\.(meta|save|log|bak)$/) {
222: unlink($dirname.$file);
223: }
224: }
225: }
226: }
227: }
228: closedir(DIR);
229: return 1;
230: }
231: return 0;
232: }
233:
234: =pod
235:
236: =item exists($user, $domain, $file)
237:
238: Determine if a resource file name has been published or exists
239: in the construction space.
240:
241: Parameters:
242:
243: =over 4
244:
245: =item $user - string [in] - Name of the user for which to check.
246:
247: =item $domain - string [in] - Name of the domain in which the resource
248: might have been published.
249:
250: =item $file - string [in] - Name of the file.
251:
252: =item $creating - string [in] - optional, type of object being created,
253: either 'directory' or 'file'. Defaults to
254: 'file' if unspecified.
255:
256: =back
257:
258: Returns:
259:
260: =over 4
261:
262: =item string - Either undef, 'warning' or 'error' depending on the
263: type of problem
264:
265: =item string - Either where the resource exists as an html string that can
266: be embedded in a dialog or an empty string if the resource
267: does not exist.
268:
269: =back
270:
271: =cut
272:
273: sub exists {
274: my ($user, $domain, $construct, $creating) = @_;
275: $creating ||= 'file';
276:
277: my $londocroot = $Apache::lonnet::perlvar{'lonDocRoot'};
278: my $published=$construct;
279: $published=~s{^\Q$londocroot/priv/\E}{$londocroot/res/};
280: my ($type,$result);
281: if ( -d $construct ) {
282: return ('error','<p><span class="LC_error">'.&mt('Error: destination for operation is an existing directory.').'</span></p>');
283:
284: }
285:
286: if ( -e $published) {
287: if ( -e $construct ) {
288: $type = 'warning';
289: $result.='<p><span class="LC_warning">'.&mt('Warning: target file exists, and has been published!').'</span></p>';
290: } else {
291: my $published_type = (-d $published) ? 'directory' : 'file';
292:
293: if ($published_type eq $creating) {
294: $type = 'warning';
295: $result.='<p><span class="LC_warning">'.&mt("Warning: a published $published_type of this name exists.").'</span></p>';
296: } else {
297: $type = 'error';
298: $result.='<p><span class="LC_error">'.&mt("Error: a published $published_type of this name exists.").'</span></p>';
299: }
300: }
301: } elsif ( -e $construct) {
302: $type = 'warning';
303: $result.='<p><span class="LC_warning">'.&mt('Warning: target file exists!').'</span></p>';
304: }
305:
306: return ($type,$result);
307: }
308:
309: =pod
310:
311: =item checksuffix($old, $new)
312:
313: Determine if a resource filename suffix (the stuff after the .) would change
314: as a result of this operation.
315:
316: Parameters:
317:
318: =over 4
319:
320: =item $old = string [in] Previous filename.
321:
322: =item $new = string [in] Resultant filename.
323:
324: =back
325:
326: Returns:
327:
328: =over 4
329:
330: =item Empty string if everything worked.
331:
332: =item String containing an error message if there was a problem.
333:
334: =back
335:
336: =cut
337:
338: sub checksuffix {
339: my ($old,$new) = @_;
340: my $result;
341: my $oldsuffix;
342: my $newsuffix;
343: if ($new=~m:(.*/*)([^/]+)\.(\w+)$:) { $newsuffix=$3; }
344: if ($old=~m:(.*)/+([^/]+)\.(\w+)$:) { $oldsuffix=$3; }
345: if (lc($oldsuffix) ne lc($newsuffix)) {
346: $result.=
347: '<p><span class="LC_warning">'.&mt('Warning: change of MIME type!').'</span></p>';
348: }
349: return $result;
350: }
351:
352: sub cleanDest {
353: my ($request,$dest,$subdir,$fn,$uname,$udom)=@_;
354: #remove bad characters
355: my $foundbad=0;
356: my $error='';
357: if ($subdir && $dest =~/\./) {
358: $foundbad=1;
359: $dest=~s/\.//g;
360: }
361: $dest =~ s/(\s+$|^\s+)//g;
362: if ($dest=~/[\#\?&%\":]/) {
363: $foundbad=1;
364: $dest=~s/[\#\?&%\":]//g;
365: }
366: if ($dest=~m|/|) {
367: my ($newpath)=($dest=~m|(.*)/|);
368: ($newpath,$error)=&relativeDest($fn,$newpath,$uname,$udom);
369: if (! -d "$newpath") {
370: $request->print('<p><span class="LC_warning">'
371: .&mt("You have requested to create file in directory [_1] which doesn't exist. The requested directory path has been removed from the requested file name."
372: ,&display($newpath))
373: .'</span></p>');
374: $dest=~s|.*/||;
375: }
376: }
377: if ($dest =~ /\.(\d+)\.(\w+)$/){
378: $request->print('<p><span class="LC_warning">'
379: .&mt('Bad filename [_1]',&display($dest))
380: .'<br />'
381: .&mt('[_1](name).(number).(extension)[_2] not allowed.','<tt>','</tt>')
382: .'<br />'
383: .&mt('Removing the [_1].number.[_2] from requested filename.','<tt>','</tt>')
384: .'</span></p>');
385: $dest =~ s/\.(\d+)(\.\w+)$/$2/;
386: }
387: if ($foundbad) {
388: $request->print('<p><span class="LC_warning">'
389: .&mt('Invalid characters in requested name have been removed.')
390: .'</span></p>'
391: );
392: }
393: return ($dest,$error);
394: }
395:
396: sub relativeDest {
397: my ($fn,$newfilename,$uname,$udom)=@_;
398: my $error = '';
399: if ($newfilename=~/^\//) {
400: # absolute, simply add path
401: my $londocroot = $Apache::lonnet::perlvar{'lonDocRoot'};
402: $newfilename="$londocroot/res/$udom/$uname/";
403: } else {
404: my $dir=$fn;
405: $dir=~s{/[^/]+$}{};
406: $newfilename=$dir.'/'.$newfilename;
407: }
408: $newfilename=~s{//+}{/}g; # remove duplicate /
409: while ($newfilename=~m{/\.\./}) {
410: $newfilename=~ s{/[^/]+/\.\./}{/}g; #remove dir/..
411: }
412: my ($authorname,$authordom)=&Apache::lonnet::constructaccess($newfilename);
413: unless (($authorname) && ($authordom)) {
414: my $otherdir = &display($newfilename);
415: $error = &mt('Access denied to [_1]',$otherdir);
416: }
417: return ($newfilename,$error);
418: }
419:
420: =pod
421:
422: =item CloseForm1($request, $user, $file)
423:
424: Close of a form on the successful completion of phase 1 processing
425:
426: Parameters:
427:
428: =over 4
429:
430: =item $request - Apache Request Object [in] - Apache server request object.
431:
432: =item $cancelurl - the url to go to on cancel.
433:
434: =back
435:
436: =cut
437:
438: sub CloseForm1 {
439: my ($request, $fn) = @_;
440: $request->print('<input type="submit" value="'.&mt('Continue').'" /></form>');
441: $request->print(' <form action="'.&url($fn).'" method="post">'.
442: '<input type="submit" value="'.&mt('Cancel').'" /></form>');
443: }
444:
445:
446: =pod
447:
448: =item CloseForm2($request, $user, $directory)
449:
450: Successfully close off the phase 2 form.
451:
452: Parameters:
453:
454: =over 4
455:
456: =item $request - Apache Request object [in] - The request that is being
457: executed.
458:
459: =item $user - string [in] - Name of the user that is initiating the
460: request.
461:
462: =item $directory - string [in] - Directory in which the operation is
463: being done relative to the top level construction space
464: directory.
465:
466: =back
467:
468: =cut
469:
470: sub CloseForm2 {
471: my ($request, $user, $fn) = @_;
472: $request->print(&done(&url($fn)));
473: }
474:
475: =pod
476:
477: =item Rename1($request, $filename, $user, $domain, $dir)
478:
479: Perform phase 1 processing of the file rename operation.
480:
481: Parameters:
482:
483: =over 4
484:
485: =item $request - Apache Request Object [in] The request object for the
486: current request.
487:
488: =item $filename - The filename relative to construction space.
489:
490: =item $user - Name of the user making the request.
491:
492: =item $domain - User login domain.
493:
494: =item $dir - Directory specification of the path to the file.
495:
496: =back
497:
498: Side effects:
499:
500: =over 4
501:
502: =item A new form is displayed prompting for confirmation. The newfilename
503: hidden field of this form is loaded with
504: new filename relative to the current directory ($dir).
505:
506: =back
507:
508: =cut
509:
510: sub Rename1 {
511: my ($request, $user, $domain, $fn, $newfilename, $style) = @_;
512:
513: if(-e $fn) {
514: if($newfilename) {
515: # is dest a dir
516: if ($style eq 'move') {
517: if (-d $newfilename) {
518: if ($fn =~ m|/([^/]*)$|) { $newfilename .= '/'.$1; }
519: }
520: }
521: if ($newfilename =~ m|/[^\.]+$|) {
522: #no extension add on original extension
523: if ($fn =~ m|/[^\.]*\.([^\.]+)$|) {
524: $newfilename.='.'.$1;
525: }
526: }
527: $request->print(&checksuffix($fn, $newfilename));
528: #renaming a dir, delete the trailing /
529: #remove second to last element for current dir
530: if (-d $fn) {
531: $newfilename=~/\.(\w+)$/;
532: if (&Apache::loncommon::fileembstyle($1) eq 'ssi') {
533: $request->print('<p><span class="LC_error">'.
534: &mt('Cannot change MIME type of a directory.').
535: '</span>'.
536: '<br /><a href="'.&url($fn).'">'.&mt('Cancel').'</a></p>');
537: return;
538: }
539: $newfilename=~s/\/[^\/]+\/([^\/]+)$/\/$1/;
540: }
541: $newfilename=~s://+:/:g; # remove duplicate /
542: while ($newfilename=~m:/\.\./:) {
543: $newfilename=~ s:/[^/]+/\.\./:/:g; #remove dir/..
544: }
545: my ($type, $return)=&exists($user, $domain, $newfilename);
546: $request->print($return);
547: if ($type eq 'error') {
548: $request->print('<br /><a href="'.&url($fn).'">'.&mt('Cancel').'</a>');
549: return;
550: }
551: unless (&obsolete_unpub($user,$domain,$fn)) {
552: $request->print('<p><span class="LC_error">'
553: .&mt('Cannot rename or move non-obsolete published file.')
554: .'</span><br />'
555: .'<a href="'.&url($fn).'">'.&mt('Cancel').'</a></p>'
556: );
557: return;
558: }
559: my $action;
560: if ($style eq 'rename') {
561: $action='Rename';
562: } else {
563: $action='Move';
564: }
565: $request->print('<input type="hidden" name="newfilename" value="'
566: .$newfilename.'" />'
567: .'<p>'
568: .&mt($action.' [_1] to [_2]?',
569: &display($fn),
570: &display($newfilename))
571: .'</p>'
572: );
573: &CloseForm1($request, $fn);
574: } else {
575: $request->print('<p class="LC_error">'.&mt('No new filename specified.').'</p></form>');
576: return;
577: }
578: } else {
579: $request->print('<p class="LC_error">'
580: .&mt('No such file: [_1]',
581: &display($fn))
582: .'</p></form>'
583: );
584: return;
585: }
586:
587: }
588:
589: =pod
590:
591: =item Delete1
592:
593: Performs phase 1 processing of the delete operation. In phase one
594: we just check to be sure the file exists.
595:
596: Parameters:
597:
598: =over 4
599:
600: =item $request - Apache Request Object [in] request object for the current
601: request.
602:
603: =item $user - string [in] Name of the user initiating the request.
604:
605: =item $domain - string [in] Domain the initiating user is logged in as
606:
607: =item $filename - string [in] Source filename.
608:
609: =back
610:
611: =cut
612:
613: sub Delete1 {
614: my ($request, $user, $domain, $fn) = @_;
615:
616: if( -e $fn) {
617: $request->print('<input type="hidden" name="newfilename" value="'.
618: $fn.'" />');
619: if (-d $fn) {
620: unless (&empty_directory($fn,'Delete1')) {
621: $request->print('<p>'
622: .'<span class="LC_error">'
623: .&mt('Only empty directories may be deleted.')
624: .'</span><br />'
625: .&mt('You must delete the contents of the directory first.')
626: .'</p>'
627: .'<p><a href="'.&url($fn).'">'.&mt('Cancel').'</a></p>'
628: );
629: return;
630: }
631: } else {
632: unless (&obsolete_unpub($user,$domain,$fn)) {
633: $request->print('<p><span class="LC_error">'
634: .&mt('Cannot delete non-obsolete published file.')
635: .'</span><br />'
636: .'<a href="'.&url($fn).'">'.&mt('Cancel').'</a></p>'
637: );
638: return;
639: }
640: }
641: $request->print('<p>'
642: .&mt('Delete [_1]?',
643: &display($fn))
644: .'</p>'
645: );
646: &CloseForm1($request, $fn);
647: } else {
648: $request->print('<p class="LC_error">'
649: .&mt('No such file: [_1]',
650: &display($fn))
651: .'</p></form>'
652: );
653: }
654: }
655:
656: =pod
657:
658: =item Copy1($request, $user, $domain, $filename, $newfilename)
659:
660: Performs phase 1 processing of the construction space copy command.
661: Ensure that the source file exists. Ensure that a destination exists,
662: also warn if the destination already exists.
663:
664: Parameters:
665:
666: =over 4
667:
668: =item $request - Apache Request Object [in] request object for the current
669: request.
670:
671: =item $user - string [in] Name of the user initiating the request.
672:
673: =item $domain - string [in] Domain the initiating user is logged in as
674:
675: =item $fn - string [in] Source filename.
676:
677: =item $newfilename-string [in] Destination filename.
678:
679: =back
680:
681: =cut
682:
683: sub Copy1 {
684: my ($request, $user, $domain, $fn, $newfilename) = @_;
685:
686: if(-e $fn) {
687: # is dest a dir
688: if (-d $newfilename) {
689: if ($fn =~ m|/([^/]*)$|) { $newfilename .= '/'.$1; }
690: }
691: if ($newfilename =~ m|/[^\.]+$|) {
692: #no extension add on original extension
693: if ($fn =~ m|/[^\.]*\.([^\.]+)$|) { $newfilename.='.'.$1; }
694: }
695: $newfilename=~s://+:/:g; # remove duplicate /
696: while ($newfilename=~m:/\.\./:) {
697: $newfilename=~ s:/[^/]+/\.\./:/:g; #remove dir/..
698: }
699: $request->print(&checksuffix($fn,$newfilename));
700: my ($type,$return)=&exists($user, $domain, $newfilename);
701: $request->print($return);
702: if ($type eq 'error') {
703: $request->print('<br /><a href="'.&url($fn).'">'.&mt('Cancel').'</a>');
704: return;
705: }
706: $request->print(
707: '<input type="hidden" name="newfilename"'
708: .' value="'.$newfilename.'" />'
709: .'<p>'
710: .&mt('Copy [_1] to [_2]?',
711: &display($fn),
712: &display($newfilename))
713: .'</p>'
714: );
715: &CloseForm1($request, $fn);
716: } else {
717: $request->print('<p class="LC_error">'
718: .&mt('No such file: [_1]',
719: &display($fn))
720: .'</p></form>'
721: );
722: }
723: }
724:
725: =pod
726:
727: =item NewDir1
728:
729: Does all phase 1 processing of directory creation:
730: Ensures that the user provides a new directory name,
731: and that the directory does not already exist.
732:
733: Parameters:
734:
735: =over 4
736:
737: =item $request - Apache Request Object [in] - Server request object for the
738: current url.
739:
740: =item $username - Name of the user that is requesting the directory creation.
741:
742: =item $domain - Domain user is in
743:
744: =item $fn - source file.
745:
746: =item $newdir - Name of the directory to be created; path relative to the
747: top level of construction space.
748: =back
749:
750: Side Effects:
751:
752: =over 4
753:
754: =item A new form is displayed. Clicking on the confirmation button
755: causes the newdir operation to transition into phase 2. The hidden field
756: "newfilename" is set with the construction space path to the new directory.
757:
758:
759: =back
760:
761: =cut
762:
763:
764: sub NewDir1 {
765: my ($request, $username, $domain, $fn, $newfilename, $mode) = @_;
766:
767: my ($type, $result)=&exists($username,$domain,$newfilename,'directory');
768: $request->print($result);
769: if ($type eq 'error') {
770: $request->print('</form>');
771: } else {
772: if (($mode eq 'testbank') || ($mode eq 'imsimport')) {
773: $request->print('<input type="hidden" name="callingmode" value="'.$mode.'" />'."\n".
774: '<input type="hidden" name="inhibitmenu" value="yes" />');
775: }
776: $request->print('<input type="hidden" name="newfilename" value="'
777: .$newfilename.'" />'
778: .'<p>'
779: .&mt('Make new directory [_1]?',
780: &display($newfilename))
781: .'</p>'
782: );
783: &CloseForm1($request, $fn);
784: }
785: }
786:
787:
788: sub Decompress1 {
789: my ($request, $user, $domain, $fn) = @_;
790: if( -e $fn) {
791: $request->print('<input type="hidden" name="newfilename" value="'.$fn.'" />');
792: $request->print('<p>'
793: .&mt('Decompress [_1]?',
794: &display($fn))
795: .'</p>'
796: );
797: &CloseForm1($request, $fn);
798: } else {
799: $request->print('<p class="LC_error">'
800: .&mt('No such file: [_1]',
801: &display($fn))
802: .'</p></form>'
803: );
804: }
805: }
806:
807: =pod
808:
809: =item NewFile1
810:
811: Does all phase 1 processing of file creation:
812: Ensures that the user provides a new filename, adds proper extension
813: if needed and that the file does not already exist, if it is a html,
814: problem, page, or sequence, it then creates a form link to hand the
815: actual creation off to the proper handler.
816:
817: Parameters:
818:
819: =over 4
820:
821: =item $request - Apache Request Object [in] - Server request object for the
822: current url.
823:
824: =item $username - Name of the user that is requesting the directory creation.
825:
826: =item $domain - Name of the domain of the user
827:
828: =item $fn - Source file name
829:
830: =item $newfilename
831: - Name of the file to be created; no path information
832: =back
833:
834: Side Effects:
835:
836: =over 4
837:
838: =item 2 new forms are displayed. Clicking on the confirmation button
839: causes the browser to attempt to load the specfied URL, allowing the
840: proper handler to take care of file creation. There is also a Cancel
841: button which returns you to the directory listing you came from
842:
843: =back
844:
845: =cut
846:
847: sub NewFile1 {
848: my ($request, $user, $domain, $fn, $newfilename) = @_;
849: return if (&filename_check($newfilename) ne 'ok');
850:
851: if ($env{'form.action'} =~ /new(.+)file/) {
852: my $extension=$1;
853: if ($newfilename !~ /\Q.$extension\E$/) {
854: if ($newfilename =~ m|/[^/.]*\.(?:[^/.]+)$|) {
855: #already has an extension strip it and add in expected one
856: $newfilename =~ s|(/[^./])\.(?:[^.]+)$|$1|;
857: }
858: $newfilename.=".$extension";
859: }
860: }
861: my ($type, $result)=&exists($user,$domain,$newfilename);
862: $request->print($result);
863: if ($type eq 'error') {
864: $request->print('</form>');
865: } else {
866: my $extension;
867:
868: if ($newfilename =~ m{[^/.]+\.([^/.]+)$}) {
869: $extension = $1;
870: }
871:
872: my @okexts = qw(xml html xhtml htm xhtm problem page sequence rights sty task library js css txt);
873: if (($extension eq '') || (!grep(/^\Q$extension\E/,@okexts))) {
874: my $validexts = '.'.join(', .',@okexts);
875: $request->print('<p class="LC_warning">'.
876: &mt('Invalid filename: ').&display($newfilename).'</p><p>'.
877: &mt('The name of the new file needs to end with an appropriate file extension to indicate the type of file to create.').'<br />'.
878: &mt('The following are valid extensions: [_1].',$validexts).
879: '</p></form><p>'.
880: '<form name="fileaction" action="/adm/cfile" method="post">'.
881: '<input type="hidden" name="qualifiedfilename" value="'.$fn.'" />'.
882: '<input type="hidden" name="action" value="newfile" />'.
883: '<span class ="LC_nobreak">'.&mt('Enter a file name: ').'<input type="text" name="newfilename" value="Type Name Here" onfocus="if (this.value == '."'Type Name Here') this.value=''".'" /> <input type="submit" value="Go" />'.
884: '</span></form></p>'.
885: '<p><form action="'.&url($fn).
886: '" method="post"><p><input type="submit" value="'.&mt('Cancel').'" /></form></p>');
887: return;
888: }
889:
890: $request->print('<p>'.&mt('Make new file').' '.&display($newfilename).'?</p>');
891: $request->print('</form>');
892:
893: $request->print('<form action="'.&url($newfilename).
894: '" method="post"><p><input type="submit" value="'.&mt('Continue').'" /></p></form>');
895: $request->print('<form action="'.&url($fn).
896: '" method="post"><p><input type="submit" value="'.&mt('Cancel').'" /></p></form>');
897: }
898: return;
899: }
900:
901: sub filename_check {
902: my ($newfilename) = @_;
903: ##Informs User (name).(number).(extension) not allowed
904: if($newfilename =~ /\.(\d+)\.(\w+)$/){
905: $r->print('<span class="LC_error">'.$newfilename.
906: ' - '.&mt('Bad Filename').'<br />('.&mt('name').').('.&mt('number').').('.&mt('extension').') '.
907: ' '.&mt('Not Allowed').'</span>');
908: return;
909: }
910: if($newfilename =~ /(\:\:\:|\&\&\&|\_\_\_)/){
911: $r->print('<span class="LC_error">'.$newfilename.
912: ' - '.&mt('Bad Filename').'<br />('.&mt('Must not include').' '.$1.') '.
913: ' '.&mt('Not Allowed').'</span>');
914: return;
915: }
916: return 'ok';
917: }
918:
919: =pod
920:
921: =item phaseone($r, $fn, $uname, $udom)
922:
923: Peforms phase one processing of the request. In phase one, error messages
924: are returned if the request cannot be performed (e.g. attempts to manipulate
925: files that are nonexistent). If the operation can be performed, what is
926: about to be done will be presented to the user for confirmation. If the
927: user confirms the request, then phase two is executed, the action
928: performed and reported to the user.
929:
930: Parameters:
931:
932: =over 4
933:
934: =item $r - request object [in] - The Apache request being executed.
935:
936: =item $fn = string [in] - The filename being manipulated by the
937: request.
938:
939: =item $uname - string [in] Name of user logged in and doing this action.
940:
941: =item $udom - string [in] Domain name under which the user logged in.
942:
943: =back
944:
945: =cut
946:
947: sub phaseone {
948: my ($r,$fn,$uname,$udom)=@_;
949:
950: my $doingdir=0;
951: if ($env{'form.action'} eq 'newdir') { $doingdir=1; }
952: my ($newfilename,$error) =
953: &cleanDest($r,$env{'form.newfilename'},$doingdir,$fn,$uname,$udom);
954: unless ($error) {
955: ($newfilename,$error)=&relativeDest($fn,$newfilename,$uname,$udom);
956: }
957: if ($error) {
958: my $dirlist;
959: if ($fn=~m{^(.*/)[^/]+$}) {
960: $dirlist=$1;
961: } else {
962: $dirlist=$fn;
963: }
964: $r->print('<div class="LC_error">'.$error.'</div>'.
965: '<p><a href="'.&url($dirlist).'">'.&mt('Return to Directory').
966: '</a></p>');
967: return;
968: }
969: $r->print('<form action="/adm/cfile" method="post">'.
970: '<input type="hidden" name="qualifiedfilename" value="'.$fn.'" />'.
971: '<input type="hidden" name="phase" value="two" />'.
972: '<input type="hidden" name="action" value="'.$env{'form.action'}.'" />');
973:
974: if ($env{'form.action'} eq 'rename') {
975: &Rename1($r, $uname, $udom, $fn, $newfilename, 'rename');
976: } elsif ($env{'form.action'} eq 'move') {
977: &Rename1($r, $uname, $udom, $fn, $newfilename, 'move');
978: } elsif ($env{'form.action'} eq 'delete') {
979: &Delete1($r, $uname, $udom, $fn);
980: } elsif ($env{'form.action'} eq 'decompress') {
981: &Decompress1($r, $uname, $udom, $fn);
982: } elsif ($env{'form.action'} eq 'copy') {
983: if($newfilename) {
984: &Copy1($r, $uname, $udom, $fn, $newfilename);
985: } else {
986: $r->print('<p class="LC_error">'
987: .&mt('No new filename specified.')
988: .'</p></form>'
989: );
990: }
991: } elsif ($env{'form.action'} eq 'newdir') {
992: my $mode = '';
993: if (exists($env{'form.callingmode'}) ) {
994: $mode = $env{'form.callingmode'};
995: }
996: &NewDir1($r, $uname, $udom, $fn, $newfilename, $mode);
997: } elsif ($env{'form.action'} eq 'newfile' ||
998: $env{'form.action'} eq 'newhtmlfile' ||
999: $env{'form.action'} eq 'newproblemfile' ||
1000: $env{'form.action'} eq 'newpagefile' ||
1001: $env{'form.action'} eq 'newsequencefile' ||
1002: $env{'form.action'} eq 'newrightsfile' ||
1003: $env{'form.action'} eq 'newstyfile' ||
1004: $env{'form.action'} eq 'newtaskfile' ||
1005: $env{'form.action'} eq 'newlibraryfile' ||
1006: $env{'form.action'} eq 'Select Action') {
1007: my $empty=&mt('Type Name Here');
1008: if (($newfilename!~/\/$/) && ($newfilename!~/$empty$/)) {
1009: &NewFile1($r, $uname, $udom, $fn, $newfilename);
1010: } else {
1011: $r->print('<p class="LC_error">'
1012: .&mt('No new filename specified.')
1013: .'</p></form>'
1014: );
1015: }
1016: }
1017: }
1018:
1019: =pod
1020:
1021: =item Rename2($request, $user, $directory, $oldfile, $newfile)
1022:
1023: Performs phase 2 processing of a rename reequest. This is where the
1024: actual rename is performed.
1025:
1026: Parameters
1027:
1028: =over 4
1029:
1030: =item $request - Apache request object [in] The request being processed.
1031:
1032: =item $user - string [in] The name of the user initiating the request.
1033:
1034: =item $directory - string [in] The name of the directory relative to the
1035: construction space top level of the renamed file.
1036:
1037: =item $oldfile - Name of the file.
1038:
1039: =item $newfile - Name of the new file.
1040:
1041: =back
1042:
1043: Returns:
1044:
1045: =over 4
1046:
1047: =item 1 Success.
1048:
1049: =item 0 Failure.
1050:
1051: =cut
1052:
1053: sub Rename2 {
1054:
1055: my ($request, $user, $directory, $oldfile, $newfile) = @_;
1056:
1057: &Debug($request, "Rename2 directory: ".$directory." old file: ".$oldfile.
1058: " new file ".$newfile."\n");
1059: &Debug($request, "Target is: ".$directory.'/'.
1060: $newfile);
1061: if (-e $oldfile) {
1062:
1063: my $oRN=$oldfile;
1064: my $nRN=$newfile;
1065: unless (rename($oldfile,$newfile)) {
1066: $request->print('<span class="LC_error">'.&mt('Error').': '.$!.'</span>');
1067: return 0;
1068: }
1069: ## If old name.(extension) exits, move under new name.
1070: ## If it doesn't exist and a new.(extension) exists
1071: ## delete it (only concern when renaming over files)
1072: my $tmp1=$oRN.'.meta';
1073: my $tmp2=$nRN.'.meta';
1074: if(-e $tmp1){
1075: unless(rename($tmp1,$tmp2)){ }
1076: } elsif(-e $tmp2){
1077: unlink $tmp2;
1078: }
1079: $tmp1=$oRN.'.save';
1080: $tmp2=$nRN.'.save';
1081: if(-e $tmp1){
1082: unless(rename($tmp1,$tmp2)){ }
1083: } elsif(-e $tmp2){
1084: unlink $tmp2;
1085: }
1086: $tmp1=$oRN.'.log';
1087: $tmp2=$nRN.'.log';
1088: if(-e $tmp1){
1089: unless(rename($tmp1,$tmp2)){ }
1090: } elsif(-e $tmp2){
1091: unlink $tmp2;
1092: }
1093: $tmp1=$oRN.'.bak';
1094: $tmp2=$nRN.'.bak';
1095: if(-e $tmp1){
1096: unless(rename($tmp1,$tmp2)){ }
1097: } elsif(-e $tmp2){
1098: unlink $tmp2;
1099: }
1100: } else {
1101: $request->print(
1102: '<p class="LC_error">'
1103: .&mt('No such file: [_1]',
1104: &display($oldfile))
1105: .'</p></form>'
1106: );
1107: return 0;
1108: }
1109: return 1;
1110: }
1111:
1112: =pod
1113:
1114: =item Delete2($request, $user, $filename)
1115:
1116: Performs phase two of a delete. The user has confirmed that they want
1117: to delete the selected file. The file is deleted and the results of the
1118: delete attempt are indicated.
1119:
1120: Parameters:
1121:
1122: =over 4
1123:
1124: =item $request - Apache Request object [in] the request object for the current
1125: delete operation.
1126:
1127: =item $user - string [in] The name of the user initiating the delete
1128: request.
1129:
1130: =item $filename - string [in] The name of the file, relative to construction
1131: space, to delete.
1132:
1133: =back
1134:
1135: Returns:
1136: 1 - success.
1137: 0 - Failure.
1138:
1139: =cut
1140:
1141: sub Delete2 {
1142: my ($request, $user, $filename) = @_;
1143: if (-d $filename) {
1144: unless (&empty_directory($filename,'Delete2')) {
1145: $request->print('<span class="LC_error">'.&mt('Error: Directory Non Empty').'</span>');
1146: return 0;
1147: } else {
1148: if(-e $filename) {
1149: unless(rmdir($filename)) {
1150: $request->print('<span class="LC_error">'.&mt('Error').': '.$!.'</span>');
1151: return 0;
1152: }
1153: } else {
1154: $request->print('<p class="LC_error">'.&mt('No such file').'</p></form>');
1155: return 0;
1156: }
1157: }
1158: } else {
1159: if(-e $filename) {
1160: unless(unlink($filename)) {
1161: $request->print('<span class="LC_error">'.&mt('Error').': '.$!.'</span>');
1162: return 0;
1163: }
1164: } else {
1165: $request->print('<p class="LC_error">'.&mt('No such file').'</p></form>');
1166: return 0;
1167: }
1168: }
1169: return 1;
1170: }
1171:
1172: =pod
1173:
1174: =item Copy2($request, $username, $dir, $oldfile, $newfile)
1175:
1176: Performs phase 2 of a copy. The file is copied and the status
1177: of that copy is reported back to the user.
1178:
1179: =over 4
1180:
1181: =item $request - Apache request object [in]; the apache request currently
1182: being executed.
1183:
1184: =item $username - string [in] Name of the user who is requesting the copy.
1185:
1186: =item $dir - string [in] Directory path relative to the construction space
1187: of the destination file.
1188:
1189: =item $oldfile - string [in] Name of the source file.
1190:
1191: =item $newfile - string [in] Name of the destination file.
1192:
1193:
1194: =back
1195:
1196: Returns 0 failure, and 1 successs.
1197:
1198: =cut
1199:
1200: sub Copy2 {
1201: my ($request, $username, $dir, $oldfile, $newfile) = @_;
1202: &Debug($request ,"Will try to copy $oldfile to $newfile");
1203: if(-e $oldfile) {
1204: if ($oldfile eq $newfile) {
1205: $request->print('<span class="LC_error">'.&mt('Warning').': '.&mt('Name of new file is the same as name of old file').' - '.&mt('no action taken').'.</span>');
1206: return 1;
1207: }
1208: unless (copy($oldfile, $newfile)) {
1209: $request->print('<span class="LC_error">'.&mt('copy Error').': '.$!.'</span>');
1210: return 0;
1211: } elsif (!chmod(0660, $newfile)) {
1212: $request->print('<span class="LC_error">'.&mt('chmod error').': '.$!.'</span>');
1213: return 0;
1214: } elsif (-e $oldfile.'.meta' &&
1215: !copy($oldfile.'.meta', $newfile.'.meta') &&
1216: !chmod(0660, $newfile.'.meta')) {
1217: $request->print('<span class="LC_error">'.&mt('copy metadata error').
1218: ': '.$!.'</span>');
1219: return 0;
1220: } else {
1221: return 1;
1222: }
1223: } else {
1224: $request->print('<p class="LC_error">'.&mt('No such file').'</p>');
1225: return 0;
1226: }
1227: return 1;
1228: }
1229:
1230: =pod
1231:
1232: =item NewDir2($request, $user, $newdirectory)
1233:
1234: Performs phase 2 processing of directory creation. This involves creating the directory and
1235: reporting the results of that creation to the user.
1236:
1237: Parameters:
1238: =over 4
1239:
1240: =item $request - Apache request object [in]. Object representing the current HTTP request.
1241:
1242: =item $user - string [in] The name of the user that is initiating the request.
1243:
1244: =item $newdirectory - string [in] The full path of the directory being created.
1245:
1246: =back
1247:
1248: Returns 0 - failure 1 - success.
1249:
1250: =cut
1251:
1252: sub NewDir2 {
1253: my ($request, $user, $newdirectory) = @_;
1254:
1255: unless(mkdir($newdirectory, 02770)) {
1256: $request->print('<span class="LC_error">'.&mt('Error').': '.$!.'</span>');
1257: return 0;
1258: }
1259: unless(chmod(02770, ($newdirectory))) {
1260: $request->print('<span class="LC_error">'.&mt('Error').': '.$!.'</span>');
1261: return 0;
1262: }
1263: return 1;
1264: }
1265:
1266: sub decompress2 {
1267: my ($r, $user, $dir, $file) = @_;
1268: &Apache::lonnet::appenv({'cgi.file' => $file});
1269: &Apache::lonnet::appenv({'cgi.dir' => $dir});
1270: my $result=&Apache::lonnet::ssi_body('/cgi-bin/decompress.pl');
1271: $r->print($result);
1272: &Apache::lonnet::delenv('cgi.file');
1273: &Apache::lonnet::delenv('cgi.dir');
1274: return 1;
1275: }
1276:
1277: =pod
1278:
1279: =item phasetwo($r, $fn, $uname, $udom)
1280:
1281: Controls the phase 2 processing of file management
1282: requests for construction space. In phase one, the user
1283: was asked to confirm the operation. In phase 2, the operation
1284: is performed and the result is shown.
1285:
1286: The strategy is to break out the processing into specific action processors
1287: named action2 where action is the requested action and the 2 denotes
1288: phase 2 processing.
1289:
1290: Parameters:
1291:
1292: =over 4
1293:
1294: =item $r - Apache Request object [in] The request object for this httpd
1295: transaction.
1296:
1297: =item $fn - string [in] A filename indicating the object that is being
1298: manipulated.
1299:
1300: =item $uname - string [in] The name of the user initiating the file management
1301: request.
1302:
1303: =item $udom - string [in] The login domain of the user initiating the
1304: file management request.
1305: =back
1306:
1307: =cut
1308:
1309: sub phasetwo {
1310: my ($r,$fn,$uname,$udom)=@_;
1311:
1312: &Debug($r, "loncfile - Entering phase 2 for $fn");
1313:
1314: # Break down the file into its component pieces.
1315:
1316: my $dir; # Directory path
1317: my $main; # Filename.
1318: my $suffix; # Extension.
1319: if ($fn=~m:(.*)/([^/]+):) {
1320: $dir=$1; # Directory path
1321: $main=$2; # Filename.
1322: }
1323: if($main=~m:\.(\w+)$:){ # Fixes problems with filenames with no extensions
1324: $suffix=$1; #This is the actually filename extension if it exists
1325: $main=~s/\.\w+$//; #strip the extension
1326: }
1327: my $dest; #
1328: my $dest_dir; # On success this is where we'll go.
1329: my $disp_newname; #
1330: my $dest_newname; #
1331: &Debug($r,"loncfile::phase2 dir = $dir main = $main suffix = $suffix");
1332: &Debug($r," newfilename = ".$env{'form.newfilename'});
1333:
1334: my $conspace=$fn;
1335:
1336: &Debug($r,"loncfile::phase2 Full construction space name: $conspace");
1337:
1338: &Debug($r,"loncfie::phase2 action is $env{'form.action'}");
1339:
1340: # Select the appropriate processing sub.
1341: if ($env{'form.action'} eq 'decompress') {
1342: $main .= '.'.$suffix;
1343: if(!&decompress2($r, $uname, $dir, $main)) {
1344: return ;
1345: }
1346: $dest = $dir."/.";
1347: } elsif ($env{'form.action'} eq 'rename' ||
1348: $env{'form.action'} eq 'move') {
1349: if($env{'form.newfilename'}) {
1350: if (!defined($dir)) {
1351: $fn=~m:^(.*)/:;
1352: $dir=$1;
1353: }
1354: if(!&Rename2($r, $uname, $dir, $fn, $env{'form.newfilename'})) {
1355: return;
1356: }
1357: $dest = $dir."/";
1358: $dest_newname = $env{'form.newfilename'};
1359: $env{'form.newfilename'} =~ /.+(\/.+$)/;
1360: $disp_newname = $1;
1361: $disp_newname =~ s/\///;
1362: }
1363: } elsif ($env{'form.action'} eq 'delete') {
1364: if(!&Delete2($r, $uname, $env{'form.newfilename'})) {
1365: return ;
1366: }
1367: # Once a resource is deleted, we just list the directory that
1368: # previously held it.
1369: #
1370: $dest = $dir."/."; # Parent dir.
1371: } elsif ($env{'form.action'} eq 'copy') {
1372: if($env{'form.newfilename'}) {
1373: if(!&Copy2($r, $uname, $dir, $fn, $env{'form.newfilename'})) {
1374: return ;
1375: }
1376: $dest = $env{'form.newfilename'};
1377: } else {
1378: $r->print('<p class="LC_error">'.&mt('No New filename specified').'</p></form>');
1379: return;
1380: }
1381:
1382: } elsif ($env{'form.action'} eq 'newdir') {
1383: my $newdir= $env{'form.newfilename'};
1384: if(!&NewDir2($r, $uname, $newdir)) {
1385: return;
1386: }
1387: $dest = $newdir."/";
1388: }
1389: if ( ($env{'form.action'} eq 'newdir') && ($env{'form.phase'} eq 'two') && ( ($env{'form.callingmode'} eq 'testbank') || ($env{'form.callingmode'} eq 'imsimport') ) ) {
1390: $r->print(
1391: '<p>'
1392: .&Apache::lonhtmlcommon::confirm_success(&mt('Done'))
1393: .'<br /><a href="javascript:self.close()">'.&mt('Continue').'</a>'
1394: .'</p>'
1395: );
1396: } else {
1397: if ($env{'form.action'} eq 'rename') {
1398: $r->print(
1399: '<p>'.&Apache::lonhtmlcommon::confirm_success(&mt('Done')).'</p>'
1400: .&Apache::lonhtmlcommon::actionbox(
1401: ['<a href="'.&url($dest).'">'.&mt('Return to Directory').'</a>',
1402: '<a href="'.&url($dest_newname).'">'.$disp_newname.'</a>']));
1403: } else {
1404: $r->print(&done(&url($dest)));
1405: }
1406: }
1407: }
1408:
1409: sub handler {
1410:
1411: $r=shift;
1412:
1413: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},['decompress','action','filename','newfilename']);
1414:
1415: &Debug($r, "loncfile.pm - handler entered");
1416: &Debug($r, " filename: ".$env{'form.filename'});
1417: &Debug($r, " newfilename: ".$env{'form.newfilename'});
1418: #
1419: # Determine the root filename
1420: # This could come in as "filename", which actually is a URL, or
1421: # as "qualifiedfilename", which is indeed a real filename in filesystem
1422: #
1423: my $fn;
1424:
1425: if ($env{'form.filename'}) {
1426: &Debug($r, "test: $env{'form.filename'}");
1427: $fn=&unescape($env{'form.filename'});
1428: $fn=&URLToPath($fn);
1429: } elsif($ENV{'QUERY_STRING'} && $env{'form.phase'} ne 'two') {
1430: #Just hijack the script only the first time around to inject the
1431: #correct information for further processing
1432: $fn=&unescape($env{'form.decompress'});
1433: $fn=&URLToPath($fn);
1434: $env{'form.action'}="decompress";
1435: } elsif ($env{'form.qualifiedfilename'}) {
1436: $fn=$env{'form.qualifiedfilename'};
1437: } else {
1438: &Debug($r, "loncfile::handler - no form.filename");
1439: $r->log_reason($env{'user.name'}.' at '.$env{'user.domain'}.
1440: ' unspecified filename for cfile', $r->filename);
1441: return HTTP_NOT_FOUND;
1442: }
1443:
1444: unless ($fn) {
1445: &Debug($r, "loncfile::handler - doctored url is empty");
1446: $r->log_reason($env{'user.name'}.' at '.$env{'user.domain'}.
1447: ' trying to cfile non-existing file', $r->filename);
1448: return HTTP_NOT_FOUND;
1449: }
1450:
1451: # ----------------------------------------------------------- Start page output
1452:
1453: my ($uname,$udom) = &Apache::lonnet::constructaccess($fn);
1454: &Debug($r,
1455: "loncfile::handler constructaccess uname = $uname domain = $udom");
1456: if (($uname eq '') || ($udom eq '')) {
1457: $r->log_reason($uname.' at '.$udom.
1458: ' trying to manipulate file '.$env{'form.filename'}.
1459: ' ('.$fn.') - not authorized',
1460: $r->filename);
1461: return HTTP_NOT_ACCEPTABLE;
1462: }
1463:
1464:
1465: &Apache::loncommon::content_type($r,'text/html');
1466: $r->send_http_header;
1467:
1468: my (%loaditem,$js);
1469:
1470: if ( ($env{'form.action'} eq 'newdir') && ($env{'form.phase'} eq 'two') && ( ($env{'form.callingmode'} eq 'testbank') || ($env{'form.callingmode'} eq 'imsimport') ) ) {
1471: my $newdirname = $env{'form.newfilename'};
1472: $js = qq|
1473: <script type="text/javascript">
1474: function writeDone() {
1475: window.focus();
1476: opener.document.info.newdir.value = "$newdirname";
1477: setTimeout("self.close()",10000);
1478: }
1479: </script>
1480: |;
1481: $loaditem{'onload'} = "writeDone()";
1482: }
1483:
1484: my $londocroot = $r->dir_config('lonDocRoot');
1485: my $trailfile = $fn;
1486: $trailfile =~ s{^/(priv/)}{$londocroot/$1};
1487:
1488: # Breadcrumbs
1489: &Apache::lonhtmlcommon::clear_breadcrumbs();
1490: &Apache::lonhtmlcommon::add_breadcrumb({
1491: 'text' => 'Construction Space',
1492: 'href' => &Apache::loncommon::authorspace($fn),
1493: });
1494: &Apache::lonhtmlcommon::add_breadcrumb({
1495: 'text' => 'File Operation',
1496: 'title' => 'Construction Space File Operation',
1497: 'href' => '',
1498: });
1499:
1500: $r->print(&Apache::loncommon::start_page('Construction Space File Operation',
1501: $js,
1502: {'add_entries' => \%loaditem,})
1503: .&Apache::lonhtmlcommon::breadcrumbs()
1504: .&Apache::loncommon::head_subbox(
1505: &Apache::loncommon::CSTR_pageheader($trailfile))
1506: );
1507:
1508: $r->print('<p>'.&mt('Location').': '.&display($fn).'</p>');
1509:
1510: if (($uname ne $env{'user.name'}) || ($udom ne $env{'user.domain'})) {
1511: $r->print('<p class="LC_info">'
1512: .&mt('Co-Author [_1]',$uname.':'.$udom)
1513: .'</p>'
1514: );
1515: }
1516:
1517:
1518: &Debug($r, "loncfile::handler Form action is $env{'form.action'} ");
1519: my %action = &Apache::lonlocal::texthash(
1520: 'delete' => 'Delete',
1521: 'rename' => 'Rename',
1522: 'move' => 'Move',
1523: 'newdir' => 'New Directory',
1524: 'decompress' => 'Decompress',
1525: 'copy' => 'Copy',
1526: 'newfile' => 'New Resource',
1527: 'newhtmlfile' => 'New Resource',
1528: 'newproblemfile' => 'New Resource',
1529: 'newpagefile' => 'New Resource',
1530: 'newsequencefile' => 'New Resource',
1531: 'newrightsfile' => 'New Resource',
1532: 'newstyfile' => 'New Resource',
1533: 'newtaskfile' => 'New Resource',
1534: 'newlibraryfile' => 'New Resource',
1535: 'Select Action' => 'New Resource',
1536: );
1537: if ($action{$env{'form.action'}}) {
1538: $r->print('<h2>'.$action{$env{'form.action'}}.'</h2>');
1539: } else {
1540: $r->print('<p class="LC_error">'
1541: .&mt('Unknown Action: [_1]',$env{'form.action'})
1542: .'</p>'
1543: .&Apache::loncommon::end_page()
1544: );
1545: return OK;
1546: }
1547:
1548: if ($env{'form.phase'} eq 'two') {
1549: &Debug($r, "loncfile::handler entering phase2");
1550: &phasetwo($r,$fn,$uname,$udom);
1551: } else {
1552: &Debug($r, "loncfile::handler entering phase1");
1553: &phaseone($r,$fn,$uname,$udom);
1554: }
1555:
1556: $r->print(&Apache::loncommon::end_page());
1557: return OK;
1558: }
1559:
1560: 1;
1561: __END__
1562:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>