1: # The LearningOnline Network with CAPA
2: # Dynamic plot
3: #
4: # $Id: lonplot.pm,v 1.54 2002/03/01 14:03:50 matthew Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: # 12/15/01 Matthew
29: # 12/17 12/18 12/19 12/20 12/21 12/27 12/28 12/30 12/31 Matthew
30: # 01/01/02 Matthew
31: # 01/02 01/03 01/04 01/07 01/08 01/09 Matthew
32: # 01/21 02/05 02/06 2/28Matthew
33:
34: package Apache::lonplot;
35:
36: use strict;
37: use Apache::File;
38: use Apache::response;
39: use Apache::lonxml;
40: use Apache::edit;
41:
42: BEGIN {
43: &Apache::lonxml::register('Apache::lonplot',('gnuplot'));
44: }
45:
46: ##
47: ## Description of data structures:
48: ##
49: ## %plot %key %axis
50: ## --------------------------
51: ## height title color
52: ## width box xmin
53: ## bgcolor pos xmax
54: ## fgcolor ymin
55: ## transparent ymax
56: ## grid
57: ## border
58: ## font
59: ## align
60: ##
61: ## @labels: $labels[$i] = \%label
62: ## %label: text, xpos, ypos, justify
63: ##
64: ## @curves: $curves[$i] = \%curve
65: ## %curve: name, linestyle, ( function | data )
66: ##
67: ## $curves[$i]->{'data'} = [ [x1,x2,x3,x4],
68: ## [y1,y2,y3,y4] ]
69: ##
70:
71: ###################################################################
72: ## ##
73: ## Tests used in checking the validitity of input ##
74: ## ##
75: ###################################################################
76:
77: my $max_str_len = 50; # if a label, title, xlabel, or ylabel text
78: # is longer than this, it will be truncated.
79:
80: my %linestyles =
81: (
82: lines => 2, # Maybe this will be used in the future
83: linespoints => 2, # to check on whether or not they have
84: dots => 2, # supplied enough <data></data> fields
85: points => 2, # to use the given line style. But for
86: steps => 2, # now there are more important things
87: fsteps => 2, # for me to deal with.
88: histeps => 2,
89: errorbars => 3,
90: xerrorbars => [3,4],
91: yerrorbars => [3,4],
92: xyerrorbars => [4,6],
93: boxes => 3,
94: # boxerrorbars => [3,4,5],
95: # boxxyerrorbars => [4,6,7],
96: # financebars => 5,
97: # candlesticks => 5,
98: vector => 4
99: );
100:
101: my $int_test = sub {$_[0]=~s/\s+//g;$_[0]=~/^\d+$/};
102: my $real_test =
103: sub {$_[0]=~s/\s+//g;$_[0]=~/^[+-]?\d*\.?\d*([eE][+-]\d+)?$/};
104: my $color_test = sub {$_[0]=~s/\s+//g;$_[0]=~/^x[\da-f]{6}$/};
105: my $onoff_test = sub {$_[0]=~/^(on|off)$/};
106: my $key_pos_test = sub {$_[0]=~/^(top|bottom|right|left|outside|below| )+$/};
107: my $sml_test = sub {$_[0]=~/^(small|medium|large)$/};
108: my $linestyle_test = sub {exists($linestyles{$_[0]})};
109: my $words_test = sub {$_[0]=~s/\s+/ /g;$_[0]=~/^([\w\(\)]+ ?)+$/};
110:
111: ###################################################################
112: ## ##
113: ## Attribute metadata ##
114: ## ##
115: ###################################################################
116: my @gnuplot_edit_order =
117: qw/bgcolor fgcolor height width font transparent grid border align/;
118:
119: my $gnuplot_help_text = <<"ENDPLOTHELP";
120: <p>
121: The <b>gnuplot</b> tag allows an author to design a plot which can
122: be created on the fly. This is intended for use in homework problems
123: where each student needs to see a distinct plot. It can be used in
124: conjunction with a <b>script</b> tag to generate random plots.
125: </p><p>
126: A <b>gnuplot</b> tag can contain the following sub-tags:
127: </p>
128: <dl>
129: <dt> Plot Label
130: <dd> Allows you to place text at a given (x,y) coordinate on the plot.
131: <dt> Plot Title
132: <dd> The title of the plot
133: <dt> Plot Xlabel
134: <dd> The label on the horizontal axis of the plot
135: <dt> Plot Ylabel
136: <dd> The label on the vertical axis of the plot
137: <dt> Plot Axes
138: <dd> allows specification of the x and y ranges displayed in the plot
139: <dt> Plot Key
140: <dd> Lists the functions displayed in the plot.
141: <dt> Plot Curve
142: <dd> Sets the data used in the plot.
143: <dt> Plot Tics
144: <dd> Allows specification of the x and y coordinate 'tics' on the axes.
145: This is mostly used to adjust the grid lines when a grid is displayed.
146: </dl>
147: ENDPLOTHELP
148:
149: my %gnuplot_defaults =
150: (
151: height => {
152: default => 200,
153: test => $int_test,
154: description => 'height of image (pixels)',
155: edit_type => 'entry',
156: size => '10'
157: },
158: width => {
159: default => 200,
160: test => $int_test,
161: description => 'width of image (pixels)',
162: edit_type => 'entry',
163: size => '10'
164: },
165: bgcolor => {
166: default => 'xffffff',
167: test => $color_test,
168: description => 'background color of image (xffffff)',
169: edit_type => 'entry',
170: size => '10'
171: },
172: fgcolor => {
173: default => 'x000000',
174: test => $color_test,
175: description => 'foreground color of image (x000000)',
176: edit_type => 'entry',
177: size => '10'
178: },
179: transparent => {
180: default => 'off',
181: test => $onoff_test,
182: description => 'Transparent image',
183: edit_type => 'onoff'
184: },
185: grid => {
186: default => 'off',
187: test => $onoff_test,
188: description => 'Display grid',
189: edit_type => 'onoff'
190: },
191: border => {
192: default => 'on',
193: test => $onoff_test,
194: description => 'Draw border around plot',
195: edit_type => 'onoff'
196: },
197: font => {
198: default => 'medium',
199: test => $sml_test,
200: description => 'Size of font to use',
201: edit_type => 'choice',
202: choices => ['small','medium','large']
203: },
204: align => {
205: default => 'left',
206: test => sub {$_[0]=~/^(left|right|center)$/},
207: description => 'alignment for image in html',
208: edit_type => 'choice',
209: choices => ['left','right','center']
210: }
211: );
212:
213: my %key_defaults =
214: (
215: title => {
216: default => '',
217: test => $words_test,
218: description => 'Title of key',
219: edit_type => 'entry',
220: size => '40'
221: },
222: box => {
223: default => 'off',
224: test => $onoff_test,
225: description => 'Draw a box around the key?',
226: edit_type => 'onoff'
227: },
228: pos => {
229: default => 'top right',
230: test => $key_pos_test,
231: description => 'position of the key on the plot',
232: edit_type => 'choice',
233: choices => ['top left','top right','bottom left','bottom right',
234: 'outside','below']
235: }
236: );
237:
238: my %label_defaults =
239: (
240: xpos => {
241: default => 0,
242: test => $real_test,
243: description => 'x position of label (graph coordinates)',
244: edit_type => 'entry',
245: size => '10'
246: },
247: ypos => {
248: default => 0,
249: test => $real_test,
250: description => 'y position of label (graph coordinates)',
251: edit_type => 'entry',
252: size => '10'
253: },
254: justify => {
255: default => 'left',
256: test => sub {$_[0]=~/^(left|right|center)$/},
257: description => 'justification of the label text on the plot',
258: edit_type => 'choice',
259: choices => ['left','right','center']
260: }
261: );
262:
263: my @tic_edit_order = ('location','mirror','start','increment','end');
264: my %tic_defaults =
265: (
266: location => {
267: default => 'border',
268: test => sub {$_[0]=~/^(border|axis)$/},
269: description => 'Location of tick marks',
270: edit_type => 'choice',
271: choices => ['border','axis']
272: },
273: mirror => {
274: default => 'on',
275: test => $onoff_test,
276: description => 'mirror ticks on opposite axis?',
277: edit_type => 'onoff'
278: },
279: start => {
280: default => '-10.0',
281: test => $real_test,
282: description => 'Start ticks at',
283: edit_type => 'entry',
284: size => '10'
285: },
286: increment => {
287: default => '1.0',
288: test => $real_test,
289: description => 'Place a tick every',
290: edit_type => 'entry',
291: size => '10'
292: },
293: end => {
294: default => ' 10.0',
295: test => $real_test,
296: description => 'Stop ticks at ',
297: edit_type => 'entry',
298: size => '10'
299: },
300: );
301:
302: my %axis_defaults =
303: (
304: color => {
305: default => 'x000000',
306: test => $color_test,
307: description => 'color of axes (x000000)',
308: edit_type => 'entry',
309: size => '10'
310: },
311: xmin => {
312: default => '-10.0',
313: test => $real_test,
314: description => 'minimum x-value shown in plot',
315: edit_type => 'entry',
316: size => '10'
317: },
318: xmax => {
319: default => ' 10.0',
320: test => $real_test,
321: description => 'maximum x-value shown in plot',
322: edit_type => 'entry',
323: size => '10'
324: },
325: ymin => {
326: default => '-10.0',
327: test => $real_test,
328: description => 'minimum y-value shown in plot',
329: edit_type => 'entry',
330: size => '10'
331: },
332: ymax => {
333: default => ' 10.0',
334: test => $real_test,
335: description => 'maximum y-value shown in plot',
336: edit_type => 'entry',
337: size => '10'
338: }
339: );
340:
341: my $curve_help_text = <<"ENDCURVEHELP";
342: The <b>curve</b> tag is where you set the data to be plotted by gnuplot.
343: There are two ways of entering the information:
344: <dl>
345: <dt> Curve Data
346: <dd> Using a <b>data</b> tag you can specify the numbers used to produce
347: the plot.
348: <p>
349: By default, two <b>data</b> tags will be available in a plot. The
350: first will specify X coordinates of the data and the second will
351: give the Y coordinates of the data. When working with a linestyle that
352: requires more than two data sets, inserting another <b>data</b> tag is
353: required. Unfortunately, you must make sure the <b>data</b> tags appear
354: in the order gnuplot expects the data.
355: </p><p>
356: Specifying the data should usually be done with a perl variable or array,
357: such as \@Xdata and \@Ydata. You may also specify numerical data seperated
358: by commas. Again, the order of the <b>data</b> tags is important. The
359: first tag will be the X data and the second will be the Y data.
360: </p>
361: <dt> Curve Function
362: <dd> The <b>function</b> tag allows you to specify the curve to be
363: plotted as a formula that gnuplot can understand. Be careful using this
364: tag - it is surprisingly easy to give gnuplot a function it cannot deal
365: with properly. Be explicit: 2*sin(2*3.141592*x/4) will work but
366: 2sin(2*3.141592x/4) will not. If you do not receive any errors in the
367: gnuplot data but still do not have an image produced, it is likely there
368: is an error in your <b>function</b> tag.
369: </dl>
370: ENDCURVEHELP
371:
372: my %curve_defaults =
373: (
374: color => {
375: default => 'x000000',
376: test => $color_test,
377: description => 'color of curve (x000000)',
378: edit_type => 'entry',
379: size => '10'
380: },
381: name => {
382: default => '',
383: test => $words_test,
384: description => 'name of curve to appear in key',
385: edit_type => 'entry',
386: size => '20'
387: },
388: linestyle => {
389: default => 'lines',
390: test => $linestyle_test,
391: description => 'Line style',
392: edit_type => 'choice',
393: choices => [keys(%linestyles)]
394: }
395: );
396:
397: ###################################################################
398: ## ##
399: ## parsing and edit rendering ##
400: ## ##
401: ###################################################################
402: my (%plot,%key,%axis,$title,$xlabel,$ylabel,@labels,@curves,%xtics,%ytics);
403:
404: sub start_gnuplot {
405: %plot = (); %key = (); %axis = ();
406: $title = undef; $xlabel = undef; $ylabel = undef;
407: $#labels = -1; $#curves = -1;
408: %xtics = (); %ytics = ();
409: #
410: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
411: my $result='';
412: &Apache::lonxml::register('Apache::lonplot',
413: ('title','xlabel','ylabel','key','axis','label','curve',
414: 'xtics','ytics'));
415: push (@Apache::lonxml::namespace,'lonplot');
416: if ($target eq 'web' || $target eq 'tex') {
417: my $inside = &Apache::lonxml::get_all_text("/gnuplot",$$parser[-1]);
418: $inside=&Apache::run::evaluate($inside,$safeeval,$$parstack[-1]);
419: &Apache::lonxml::newparser($parser,\$inside);
420: &get_attributes(\%plot,\%gnuplot_defaults,$parstack,$safeeval,
421: $tagstack->[-1]);
422: } elsif ($target eq 'edit') {
423: $result .= &Apache::edit::tag_start($target,$token,'GnuPlot');
424: $result .= &make_javascript();
425: $result .= &help_win($gnuplot_help_text);
426: $result .= &edit_attributes($target,$token,\%gnuplot_defaults,
427: \@gnuplot_edit_order);
428: } elsif ($target eq 'modified') {
429: my $constructtag=&Apache::edit::get_new_args
430: ($token,$parstack,$safeeval,keys(%gnuplot_defaults));
431: if ($constructtag) {
432: $result = &Apache::edit::rebuild_tag($token);
433: }
434: }
435: return $result;
436: }
437:
438: sub end_gnuplot {
439: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
440: pop @Apache::lonxml::namespace;
441: &Apache::lonxml::deregister('Apache::lonplot',
442: ('title','xlabel','ylabel','key','axis','label','curve'));
443: my $result = '';
444: if ($target eq 'web' || $target eq 'tex') {
445: &check_inputs(); # Make sure we have all the data we need
446: ##
447: ## Determine filename
448: my $tmpdir = '/home/httpd/perl/tmp/';
449: my $filename = $ENV{'user.name'}.'_'.$ENV{'user.domain'}.
450: '_'.time.'_'.$$.int(rand(1000)).'_plot.data';
451: ## Write the plot description to the file
452: &write_gnuplot_file($tmpdir,$filename,$target);
453: $filename = &Apache::lonnet::escape($filename);
454: ## return image tag for the plot
455: if ($target eq 'web') {
456: $result .= <<"ENDIMAGE";
457: <img src = "/cgi-bin/plot.gif?file=$filename&output=gif"
458: width = "$plot{'width'}"
459: height = "$plot{'height'}"
460: align = "$plot{'align'}"
461: alt = "image should be /cgi-bin/plot.gif?$filename" />
462: ENDIMAGE
463: } elsif ($target eq 'tex') {
464: &Apache::lonnet::ssi('cgi-bin/plot.gif?file=$filename'.
465: '&output=eps');
466: $result = "$filename.eps";
467: }
468: } elsif ($target eq 'edit') {
469: $result.=&Apache::edit::tag_end($target,$token);
470: }
471: return $result;
472: }
473:
474:
475: ##--------------------------------------------------------------- xtics
476: sub start_xtics {
477: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
478: my $result='';
479: if ($target eq 'web' || $target eq 'tex') {
480: &get_attributes(\%xtics,\%tic_defaults,$parstack,$safeeval,
481: $tagstack->[-1]);
482: } elsif ($target eq 'edit') {
483: $result .= &Apache::edit::tag_start($target,$token,'xtics');
484: $result .= &edit_attributes($target,$token,\%tic_defaults,
485: \@tic_edit_order);
486: } elsif ($target eq 'modified') {
487: my $constructtag=&Apache::edit::get_new_args
488: ($token,$parstack,$safeeval,keys(%tic_defaults));
489: if ($constructtag) {
490: $result = &Apache::edit::rebuild_tag($token);
491: }
492: }
493: return $result;
494: }
495:
496: sub end_xtics {
497: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
498: my $result = '';
499: if ($target eq 'web' || $target eq 'tex') {
500: } elsif ($target eq 'edit') {
501: $result.=&Apache::edit::tag_end($target,$token);
502: }
503: return $result;
504: }
505:
506: ##--------------------------------------------------------------- ytics
507: sub start_ytics {
508: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
509: my $result='';
510: if ($target eq 'web' || $target eq 'tex') {
511: &get_attributes(\%ytics,\%tic_defaults,$parstack,$safeeval,
512: $tagstack->[-1]);
513: } elsif ($target eq 'edit') {
514: $result .= &Apache::edit::tag_start($target,$token,'ytics');
515: $result .= &edit_attributes($target,$token,\%tic_defaults,
516: \@tic_edit_order);
517: } elsif ($target eq 'modified') {
518: my $constructtag=&Apache::edit::get_new_args
519: ($token,$parstack,$safeeval,keys(%tic_defaults));
520: if ($constructtag) {
521: $result = &Apache::edit::rebuild_tag($token);
522: }
523: }
524: return $result;
525: }
526:
527: sub end_ytics {
528: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
529: my $result = '';
530: if ($target eq 'web' || $target eq 'tex') {
531: } elsif ($target eq 'edit') {
532: $result.=&Apache::edit::tag_end($target,$token);
533: }
534: return $result;
535: }
536:
537:
538: ##----------------------------------------------------------------- key
539: sub start_key {
540: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
541: my $result='';
542: if ($target eq 'web' || $target eq 'tex') {
543: &get_attributes(\%key,\%key_defaults,$parstack,$safeeval,
544: $tagstack->[-1]);
545: } elsif ($target eq 'edit') {
546: $result .= &Apache::edit::tag_start($target,$token,'Plot Key');
547: $result .= &edit_attributes($target,$token,\%key_defaults);
548: } elsif ($target eq 'modified') {
549: my $constructtag=&Apache::edit::get_new_args
550: ($token,$parstack,$safeeval,keys(%key_defaults));
551: if ($constructtag) {
552: $result = &Apache::edit::rebuild_tag($token);
553: }
554: }
555: return $result;
556: }
557:
558: sub end_key {
559: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
560: my $result = '';
561: if ($target eq 'web' || $target eq 'tex') {
562: } elsif ($target eq 'edit') {
563: $result.=&Apache::edit::tag_end($target,$token);
564: }
565: return $result;
566: }
567:
568: ##------------------------------------------------------------------- title
569: sub start_title {
570: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
571: my $result='';
572: if ($target eq 'web' || $target eq 'tex') {
573: $title = &Apache::lonxml::get_all_text("/title",$$parser[-1]);
574: $title =~ s/\n/ /g;
575: if (length($title) > $max_str_len) {
576: $title = substr($title,0,$max_str_len);
577: }
578: } elsif ($target eq 'edit') {
579: $result.=&Apache::edit::tag_start($target,$token,'Plot Title');
580: my $text=&Apache::lonxml::get_all_text("/title",$$parser[-1]);
581: $result.=&Apache::edit::end_row().
582: &Apache::edit::start_spanning_row().
583: &Apache::edit::editfield('',$text,'',60,1);
584: } elsif ($target eq 'modified') {
585: my $text=$$parser[-1]->get_text("/title");
586: $result.=&Apache::edit::rebuild_tag($token);
587: $result.=&Apache::edit::modifiedfield($token);
588: }
589: return $result;
590: }
591:
592: sub end_title {
593: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
594: my $result = '';
595: if ($target eq 'web' || $target eq 'tex') {
596: } elsif ($target eq 'edit') {
597: $result.=&Apache::edit::tag_end($target,$token);
598: }
599: return $result;
600: }
601: ##------------------------------------------------------------------- xlabel
602: sub start_xlabel {
603: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
604: my $result='';
605: if ($target eq 'web' || $target eq 'tex') {
606: $xlabel = &Apache::lonxml::get_all_text("/xlabel",$$parser[-1]);
607: $xlabel =~ s/\n/ /g;
608: if (length($xlabel) > $max_str_len) {
609: $xlabel = substr($xlabel,0,$max_str_len);
610: }
611: } elsif ($target eq 'edit') {
612: $result.=&Apache::edit::tag_start($target,$token,'Plot Xlabel');
613: my $text=&Apache::lonxml::get_all_text("/xlabel",$$parser[-1]);
614: $result.=&Apache::edit::end_row().
615: &Apache::edit::start_spanning_row().
616: &Apache::edit::editfield('',$text,'',60,1);
617: } elsif ($target eq 'modified') {
618: my $text=$$parser[-1]->get_text("/xlabel");
619: $result.=&Apache::edit::rebuild_tag($token);
620: $result.=&Apache::edit::modifiedfield($token);
621: }
622: return $result;
623: }
624:
625: sub end_xlabel {
626: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
627: my $result = '';
628: if ($target eq 'web' || $target eq 'tex') {
629: } elsif ($target eq 'edit') {
630: $result.=&Apache::edit::tag_end($target,$token);
631: }
632: return $result;
633: }
634:
635: ##------------------------------------------------------------------- ylabel
636: sub start_ylabel {
637: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
638: my $result='';
639: if ($target eq 'web' || $target eq 'tex') {
640: $ylabel = &Apache::lonxml::get_all_text("/ylabel",$$parser[-1]);
641: $ylabel =~ s/\n/ /g;
642: if (length($ylabel) > $max_str_len) {
643: $ylabel = substr($ylabel,0,$max_str_len);
644: }
645: } elsif ($target eq 'edit') {
646: $result .= &Apache::edit::tag_start($target,$token,'Plot Ylabel');
647: my $text = &Apache::lonxml::get_all_text("/ylabel",$$parser[-1]);
648: $result .= &Apache::edit::end_row().
649: &Apache::edit::start_spanning_row().
650: &Apache::edit::editfield('',$text,'',60,1);
651: } elsif ($target eq 'modified') {
652: my $text=$$parser[-1]->get_text("/ylabel");
653: $result.=&Apache::edit::rebuild_tag($token);
654: $result.=&Apache::edit::modifiedfield($token);
655: }
656: return $result;
657: }
658:
659: sub end_ylabel {
660: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
661: my $result = '';
662: if ($target eq 'web' || $target eq 'tex') {
663: } elsif ($target eq 'edit') {
664: $result.=&Apache::edit::tag_end($target,$token);
665: }
666: return $result;
667: }
668:
669: ##------------------------------------------------------------------- label
670: sub start_label {
671: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
672: my $result='';
673: if ($target eq 'web' || $target eq 'tex') {
674: my %label;
675: &get_attributes(\%label,\%label_defaults,$parstack,$safeeval,
676: $tagstack->[-1]);
677: my $text = &Apache::lonxml::get_all_text("/label",$$parser[-1]);
678: $text =~ s/\n/ /g;
679: $text = substr($text,0,$max_str_len) if (length($text) > $max_str_len);
680: $label{'text'} = $text;
681: push(@labels,\%label);
682: } elsif ($target eq 'edit') {
683: $result .= &Apache::edit::tag_start($target,$token,'Plot Label');
684: $result .= &edit_attributes($target,$token,\%label_defaults);
685: my $text = &Apache::lonxml::get_all_text("/label",$$parser[-1]);
686: $result .= &Apache::edit::end_row().
687: &Apache::edit::start_spanning_row().
688: &Apache::edit::editfield('',$text,'',60,1);
689: } elsif ($target eq 'modified') {
690: &Apache::edit::get_new_args
691: ($token,$parstack,$safeeval,keys(%label_defaults));
692: $result.=&Apache::edit::rebuild_tag($token);
693: my $text=$$parser[-1]->get_text("/label");
694: $result.=&Apache::edit::modifiedfield($token);
695: }
696: return $result;
697: }
698:
699: sub end_label {
700: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
701: my $result = '';
702: if ($target eq 'web' || $target eq 'tex') {
703: } elsif ($target eq 'edit') {
704: $result.=&Apache::edit::tag_end($target,$token);
705: }
706: return $result;
707: }
708:
709: ##------------------------------------------------------------------- curve
710: sub start_curve {
711: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
712: my $result='';
713: &Apache::lonxml::register('Apache::lonplot',('function','data'));
714: push (@Apache::lonxml::namespace,'curve');
715: if ($target eq 'web' || $target eq 'tex') {
716: my %curve;
717: &get_attributes(\%curve,\%curve_defaults,$parstack,$safeeval,
718: $tagstack->[-1]);
719: push (@curves,\%curve);
720: } elsif ($target eq 'edit') {
721: $result .= &Apache::edit::tag_start($target,$token,'Curve');
722: $result .= &help_win($curve_help_text);
723: $result .= &edit_attributes($target,$token,\%curve_defaults);
724: } elsif ($target eq 'modified') {
725: my $constructtag=&Apache::edit::get_new_args
726: ($token,$parstack,$safeeval,keys(%curve_defaults));
727: if ($constructtag) {
728: $result = &Apache::edit::rebuild_tag($token);
729: $result.= &Apache::edit::handle_insert();
730: }
731: }
732: return $result;
733: }
734:
735: sub end_curve {
736: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
737: my $result = '';
738: pop @Apache::lonxml::namespace;
739: &Apache::lonxml::deregister('Apache::lonplot',('function','data'));
740: if ($target eq 'web' || $target eq 'tex') {
741: } elsif ($target eq 'edit') {
742: $result.=&Apache::edit::tag_end($target,$token);
743: }
744: return $result;
745: }
746:
747: ##------------------------------------------------------------ curve function
748: sub start_function {
749: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
750: my $result='';
751: if ($target eq 'web' || $target eq 'tex') {
752: if (exists($curves[-1]->{'data'})) {
753: &Apache::lonxml::warning('Use of <function> precludes use of <data>. The <data> will be omitted in favor of the <function> declaration.');
754: delete $curves[-1]->{'data'} ;
755: }
756: $curves[-1]->{'function'} =
757: &Apache::lonxml::get_all_text("/function",$$parser[-1]);
758: } elsif ($target eq 'edit') {
759: $result .= &Apache::edit::tag_start($target,$token,'Gnuplot compatible curve function');
760: my $text = &Apache::lonxml::get_all_text("/function",$$parser[-1]);
761: $result .= &Apache::edit::end_row().
762: &Apache::edit::start_spanning_row().
763: &Apache::edit::editfield('',$text,'',60,1);
764: } elsif ($target eq 'modified') {
765: $result.=&Apache::edit::rebuild_tag($token);
766: my $text=$$parser[-1]->get_text("/function");
767: $result.=&Apache::edit::modifiedfield($token);
768: }
769: return $result;
770: }
771:
772: sub end_function {
773: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
774: my $result = '';
775: if ($target eq 'web' || $target eq 'tex') {
776: } elsif ($target eq 'edit') {
777: $result .= &Apache::edit::end_table();
778: }
779: return $result;
780: }
781:
782: ##------------------------------------------------------------ curve data
783: sub start_data {
784: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
785: my $result='';
786: if ($target eq 'web' || $target eq 'tex') {
787: if (exists($curves[-1]->{'function'})) {
788: &Apache::lonxml::warning('Use of <data> precludes use of .'.
789: '<function>. The <function> will be omitted in favor of '.
790: 'the <data> declaration.');
791: delete($curves[-1]->{'function'});
792: }
793: my $datatext = &Apache::lonxml::get_all_text("/data",$$parser[-1]);
794: # Deal with cases where we're given an array...
795: if ($datatext =~ /^\@/) {
796: $datatext = &Apache::run::run('return "'.$datatext.'"',
797: $safeeval,1);
798: }
799: $datatext =~ s/\s+/ /g;
800: # Need to do some error checking on the @data array -
801: # make sure it's all numbers and make sure each array
802: # is of the same length.
803: my @data;
804: if ($datatext =~ /,/) { # comma deliminated
805: @data = split /,/,$datatext;
806: } else { # Assume it's space seperated.
807: @data = split / /,$datatext;
808: }
809: for (my $i=0;$i<=$#data;$i++) {
810: # Check that it's non-empty
811: if (! defined($data[$i])) {
812: &Apache::lonxml::warning(
813: 'undefined <data> value. Replacing with '.
814: ' pi/e = 1.15572734979092');
815: $data[$i] = 1.15572734979092;
816: }
817: # Check that it's a number
818: if (! &$real_test($data[$i]) & ! &$int_test($data[$i])) {
819: &Apache::lonxml::warning(
820: 'Bad <data> value of '.$data[$i].' Replacing with '.
821: ' pi/e = 1.15572734979092');
822: $data[$i] = 1.15572734979092;
823: }
824: }
825: # complain if the number of data points is not the same as
826: # in previous sets of data.
827: if (($curves[-1]->{'data'}) && ($#data != $#{@{$curves[-1]->{'data'}->[0]}})){
828: &Apache::lonxml::warning
829: ('Number of data points is not consistent with previous '.
830: 'number of data points');
831: }
832: push @{$curves[-1]->{'data'}},\@data;
833: } elsif ($target eq 'edit') {
834: $result .= &Apache::edit::tag_start($target,$token,'Comma or space deliminated curve data');
835: my $text = &Apache::lonxml::get_all_text("/data",$$parser[-1]);
836: $result .= &Apache::edit::end_row().
837: &Apache::edit::start_spanning_row().
838: &Apache::edit::editfield('',$text,'',60,1);
839: } elsif ($target eq 'modified') {
840: $result.=&Apache::edit::rebuild_tag($token);
841: my $text=$$parser[-1]->get_text("/data");
842: $result.=&Apache::edit::modifiedfield($token);
843: }
844: return $result;
845: }
846:
847: sub end_data {
848: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
849: my $result = '';
850: if ($target eq 'web' || $target eq 'tex') {
851: } elsif ($target eq 'edit') {
852: $result .= &Apache::edit::end_table();
853: }
854: return $result;
855: }
856:
857: ##------------------------------------------------------------------- axis
858: sub start_axis {
859: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
860: my $result='';
861: if ($target eq 'web' || $target eq 'tex') {
862: &get_attributes(\%axis,\%axis_defaults,$parstack,$safeeval,
863: $tagstack->[-1]);
864: } elsif ($target eq 'edit') {
865: $result .= &Apache::edit::tag_start($target,$token,'Plot Axes');
866: $result .= &edit_attributes($target,$token,\%axis_defaults);
867: } elsif ($target eq 'modified') {
868: my $constructtag=&Apache::edit::get_new_args
869: ($token,$parstack,$safeeval,keys(%axis_defaults));
870: if ($constructtag) {
871: $result = &Apache::edit::rebuild_tag($token);
872: }
873: }
874: return $result;
875: }
876:
877: sub end_axis {
878: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
879: my $result = '';
880: if ($target eq 'web' || $target eq 'tex') {
881: } elsif ($target eq 'edit') {
882: $result.=&Apache::edit::tag_end($target,$token);
883: } elsif ($target eq 'modified') {
884: }
885: return $result;
886: }
887:
888: ###################################################################
889: ## ##
890: ## Utility Functions ##
891: ## ##
892: ###################################################################
893:
894: ##----------------------------------------------------------- set_defaults
895: sub set_defaults {
896: my ($var,$defaults) = @_;
897: my $key;
898: foreach $key (keys(%$defaults)) {
899: $var->{$key} = $defaults->{$key}->{'default'};
900: }
901: }
902:
903: ##------------------------------------------------------------------- misc
904: sub get_attributes{
905: my ($values,$defaults,$parstack,$safeeval,$tag) = @_;
906: foreach my $attr (keys(%{$defaults})) {
907: $values->{$attr} =
908: &Apache::lonxml::get_param($attr,$parstack,$safeeval);
909: if ($values->{$attr} eq '' | !defined($values->{$attr})) {
910: $values->{$attr} = $defaults->{$attr}->{'default'};
911: next;
912: }
913: my $test = $defaults->{$attr}->{'test'};
914: if (! &$test($values->{$attr})) {
915: &Apache::lonxml::warning
916: ($tag.':'.$attr.': Bad value.'.'Replacing your value with : '
917: .$defaults->{$attr}->{'default'} );
918: $values->{$attr} = $defaults->{$attr}->{'default'};
919: }
920: }
921: return ;
922: }
923:
924: ##------------------------------------------------------- write_gnuplot_file
925: sub write_gnuplot_file {
926: my ($tmpdir,$filename,$target)= @_;
927: my $gnuplot_input = '';
928: my $curve;
929: # Collect all the colors
930: my @Colors;
931: push @Colors, $plot{'bgcolor'};
932: push @Colors, $plot{'fgcolor'};
933: push @Colors, (defined($axis{'color'})?$axis{'color'}:$plot{'fgcolor'});
934: foreach $curve (@curves) {
935: push @Colors, ($curve->{'color'} ne '' ?
936: $curve->{'color'} :
937: $plot{'fgcolor'} );
938: }
939: # set term
940: if ($target eq 'web') {
941: $gnuplot_input .= 'set term gif ';
942: $gnuplot_input .= 'transparent ' if ($plot{'transparent'} eq 'on');
943: $gnuplot_input .= $plot{'font'} . ' ';
944: $gnuplot_input .= 'size '.$plot{'width'}.','.$plot{'height'}.' ';
945: $gnuplot_input .= "@Colors\n";
946: # set output
947: $gnuplot_input .= "set output\n";
948: } elsif ($target eq 'tex') {
949: $gnuplot_input .= "set term postscript eps monochrome\n";
950: $gnuplot_input .= "set output \"$filename.eps\"\n";
951: }
952: # grid
953: $gnuplot_input .= 'set grid'.$/ if ($plot{'grid'} eq 'on');
954: # border
955: $gnuplot_input .= ($plot{'border'} eq 'on'?
956: 'set border'.$/ :
957: 'set noborder'.$/ ); # title, xlabel, ylabel
958: # titles
959: $gnuplot_input .= "set title \"$title\"\n" if (defined($title)) ;
960: $gnuplot_input .= "set xlabel \"$xlabel\"\n" if (defined($xlabel));
961: $gnuplot_input .= "set ylabel \"$ylabel\"\n" if (defined($ylabel));
962: # tics
963: if (%xtics) {
964: $gnuplot_input .= "set xtics $xtics{'location'} ";
965: $gnuplot_input .= ( $xtics{'mirror'} eq 'on'?"mirror ":"nomirror ");
966: $gnuplot_input .= "$xtics{'start'}, ";
967: $gnuplot_input .= "$xtics{'increment'}, ";
968: $gnuplot_input .= "$xtics{'end'}\n";
969: }
970: if (%ytics) {
971: $gnuplot_input .= "set ytics $ytics{'location'} ";
972: $gnuplot_input .= ( $ytics{'mirror'} eq 'on'?"mirror ":"nomirror ");
973: $gnuplot_input .= "$ytics{'start'}, ";
974: $gnuplot_input .= "$ytics{'increment'}, ";
975: $gnuplot_input .= "$ytics{'end'}\n";
976: }
977: # axis
978: if (%axis) {
979: $gnuplot_input .= "set xrange \[$axis{'xmin'}:$axis{'xmax'}\]\n";
980: $gnuplot_input .= "set yrange \[$axis{'ymin'}:$axis{'ymax'}\]\n";
981: }
982: # Key
983: if (%key) {
984: $gnuplot_input .= 'set key '.$key{'pos'}.' ';
985: if ($key{'title'} ne '') {
986: $gnuplot_input .= 'title " '.$key{'title'}.'" ';
987: }
988: $gnuplot_input .= ($key{'box'} eq 'on' ? 'box ' : 'nobox ').$/;
989: } else {
990: $gnuplot_input .= 'set nokey'.$/;
991: }
992: # labels
993: my $label;
994: foreach $label (@labels) {
995: $gnuplot_input .= 'set label "'.$label->{'text'}.'" at '.
996: $label->{'xpos'}.','.$label->{'ypos'}.' '.$label->{'justify'}.$/ ;
997: }
998: # curves
999: $gnuplot_input .= 'plot ';
1000: for (my $i = 0;$i<=$#curves;$i++) {
1001: $curve = $curves[$i];
1002: $gnuplot_input.= ', ' if ($i > 0);
1003: if (exists($curve->{'function'})) {
1004: $gnuplot_input.=
1005: $curve->{'function'}.' title "'.
1006: $curve->{'name'}.'" with '.
1007: $curve->{'linestyle'};
1008: } elsif (exists($curve->{'data'})) {
1009: # Store data values in $datatext
1010: my $datatext = '';
1011: # get new filename
1012: my $datafilename = "$tmpdir/$filename.$i";
1013: my $fh=Apache::File->new(">$datafilename");
1014: # Compile data
1015: my @Data = @{$curve->{'data'}};
1016: my @Data0 = @{$Data[0]};
1017: for (my $i =0; $i<=$#Data0; $i++) {
1018: my $dataset;
1019: foreach $dataset (@Data) {
1020: $datatext .= $dataset->[$i] . ' ';
1021: }
1022: $datatext .= $/;
1023: }
1024: # write file
1025: print $fh $datatext;
1026: close ($fh);
1027: # generate gnuplot text
1028: $gnuplot_input.= '"'.$datafilename.'" title "'.
1029: $curve->{'name'}.'" with '.
1030: $curve->{'linestyle'};
1031: }
1032: }
1033: # Write the output to a file.
1034: my $fh=Apache::File->new(">$tmpdir$filename");
1035: print $fh $gnuplot_input;
1036: close($fh);
1037: # That's all folks.
1038: return ;
1039: }
1040:
1041: #---------------------------------------------- check_inputs
1042: sub check_inputs {
1043: ## Note: no inputs, no outputs - this acts only on global variables.
1044: ## Make sure we have all the input we need:
1045: if (! %plot) { &set_defaults(\%plot,\%gnuplot_defaults); }
1046: if (! %key ) {} # No key for this plot, thats okay
1047: # if (! %axis) { &set_defaults(\%axis,\%axis_defaults); }
1048: if (! defined($title )) {} # No title for this plot, thats okay
1049: if (! defined($xlabel)) {} # No xlabel for this plot, thats okay
1050: if (! defined($ylabel)) {} # No ylabel for this plot, thats okay
1051: if ($#labels < 0) { } # No labels for this plot, thats okay
1052: if ($#curves < 0) {
1053: &Apache::lonxml::warning("No curves specified for plot!!!!");
1054: return '';
1055: }
1056: my $curve;
1057: foreach $curve (@curves) {
1058: if (!defined($curve->{'function'})&&!defined($curve->{'data'})){
1059: &Apache::lonxml::warning("One of the curves specified did not contain any <data> or <function> declarations\n");
1060: return '';
1061: }
1062: }
1063: }
1064:
1065: #------------------------------------------------ make_edit
1066: sub edit_attributes {
1067: my ($target,$token,$defaults,$keys) = @_;
1068: my ($result,@keys);
1069: if ($keys && ref($keys) eq 'ARRAY') {
1070: @keys = @$keys;
1071: } else {
1072: @keys = sort(keys(%$defaults));
1073: }
1074: foreach my $attr (@keys) {
1075: # append a ' ' to the description if it doesn't have one already.
1076: my $description = $defaults->{$attr}->{'description'};
1077: $description .= ' ' if ($description !~ / $/);
1078: if ($defaults->{$attr}->{'edit_type'} eq 'entry') {
1079: $result .= &Apache::edit::text_arg
1080: ($description,$attr,$token,
1081: $defaults->{$attr}->{'size'});
1082: } elsif ($defaults->{$attr}->{'edit_type'} eq 'choice') {
1083: $result .= &Apache::edit::select_arg
1084: ($description,$attr,$defaults->{$attr}->{'choices'},$token);
1085: } elsif ($defaults->{$attr}->{'edit_type'} eq 'onoff') {
1086: $result .= &Apache::edit::select_arg
1087: ($description,$attr,['on','off'],$token);
1088: }
1089: $result .= '<br />';
1090: }
1091: return $result;
1092: }
1093:
1094:
1095: ###################################################################
1096: ## ##
1097: ## Insertion functions for editing plots ##
1098: ## ##
1099: ###################################################################
1100:
1101: sub insert_gnuplot {
1102: my $result = '';
1103: # plot attributes
1104: $result .= "<gnuplot \n";
1105: foreach my $attr (keys(%gnuplot_defaults)) {
1106: $result .= " $attr=\"$gnuplot_defaults{$attr}->{'default'}\"\n";
1107: }
1108: $result .= ">\n";
1109: # Add the components (most are commented out for simplicity)
1110: # $result .= &insert_key();
1111: # $result .= &insert_axis();
1112: # $result .= &insert_title();
1113: # $result .= &insert_xlabel();
1114: # $result .= &insert_ylabel();
1115: $result .= &insert_curve();
1116: # close up the <gnuplot>
1117: $result .= "</gnuplot>\n";
1118: return $result;
1119: }
1120:
1121: sub insert_tics {
1122: my $result;
1123: $result .= &insert_xtics() . &insert_ytics;
1124: return $result;
1125: }
1126:
1127: sub insert_xtics {
1128: my $result;
1129: $result .= "\n <xtics ";
1130: foreach my $attr (keys(%tic_defaults)) {
1131: $result .= "$attr=\"$tic_defaults{$attr}->{'default'}\" ";
1132: }
1133: $result .= "/>\n";
1134: return $result;
1135: }
1136:
1137: sub insert_ytics {
1138: my $result;
1139: $result .= "\n <ytics ";
1140: foreach my $attr (keys(%tic_defaults)) {
1141: $result .= "$attr=\"$tic_defaults{$attr}->{'default'}\" ";
1142: }
1143: $result .= "/>\n";
1144: return $result;
1145: }
1146:
1147: sub insert_key {
1148: my $result;
1149: $result .= "\n <key \n";
1150: foreach my $attr (keys(%key_defaults)) {
1151: $result .= " $attr=\"$key_defaults{$attr}->{'default'}\"\n";
1152: }
1153: $result .= " />\n";
1154: return $result;
1155: }
1156:
1157: sub insert_axis{
1158: my $result;
1159: $result .= "\n <axis ";
1160: foreach my $attr (keys(%axis_defaults)) {
1161: $result .= " $attr=\"$axis_defaults{$attr}->{'default'}\"\n";
1162: }
1163: $result .= " />\n";
1164: return $result;
1165: }
1166:
1167: sub insert_title { return "\n <title></title>\n"; }
1168: sub insert_xlabel { return "\n <xlabel></xlabel>\n"; }
1169: sub insert_ylabel { return "\n <ylabel></ylabel>\n"; }
1170:
1171: sub insert_label {
1172: my $result;
1173: $result .= "\n <label ";
1174: foreach my $attr (keys(%label_defaults)) {
1175: $result .= ' '.$attr.'="'.
1176: $label_defaults{$attr}->{'default'}."\"\n";
1177: }
1178: $result .= " ></label>\n";
1179: return $result;
1180: }
1181:
1182: sub insert_curve {
1183: my $result;
1184: $result .= "\n <curve ";
1185: foreach my $attr (keys(%curve_defaults)) {
1186: $result .= ' '.$attr.'="'.
1187: $curve_defaults{$attr}->{'default'}."\"\n";
1188: }
1189: $result .= " >\n";
1190: $result .= &insert_data().&insert_data()."</curve>\n";
1191: }
1192:
1193: sub insert_function {
1194: my $result;
1195: $result .= "<function></function>\n";
1196: return $result;
1197: }
1198:
1199: sub insert_data {
1200: my $result;
1201: $result .= " <data></data>\n";
1202: return $result;
1203: }
1204:
1205: ##----------------------------------------------------------------------
1206: # Javascript functions to display help for tags
1207:
1208: sub make_javascript {
1209: my $helpwindowwidth = 400;
1210: my $helpwindowheight = 400;
1211: my $result = '';
1212: $result.=<<"ENDFUNCTION";
1213: <script language="JavaScript">
1214: function openWin(text)
1215: {
1216: newWin = open("", "new_W", "width=$helpwindowwidth,height=$helpwindowheight,resizable=1,scrollbars=1");
1217: newWin.document.open("text/html", "replace");
1218: newWin.document.writeln(text);
1219: newWin.document.writeln('<center><a href=\"javascript:window.close()\">close this window</a></center>');
1220: newWin.document.close();
1221: }
1222: </script>
1223: ENDFUNCTION
1224: return $result;
1225: }
1226:
1227: sub help_win {
1228: my ($helptext)=@_;
1229: $helptext =~ s/\n/ /g;
1230: $helptext =~ s/\'/\\\'/g;
1231: my $result = '';
1232: $result.=<<"ENDWIN";
1233: <table width="100%"><tr><td align="right">
1234: <a href="javascript:openWin('$helptext')">help</a>
1235: </td></tr></table><hr />
1236: ENDWIN
1237: return $result;
1238: }
1239: ##----------------------------------------------------------------------
1240: 1;
1241: __END__
1242:
1243:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to lonplot.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / xml